lib/PublicInbox/LeiBlob.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei blob $OID" command
   5 # TODO: this doesn't scan submodules, but maybe it should
   6 package PublicInbox::LeiBlob;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC);
  10 use PublicInbox::Spawn qw(spawn popen_rd which);
  11 use PublicInbox::DS;
  12
  13 sub sol_done { # EOF callback for main daemon
  14         my ($lei) = @_;
  15         my $sol = delete $lei->{sol} // return $lei->dclose; # already failed
  16         $sol->wq_wait_old($lei->can('wq_done_wait'), $lei);
  17 }
  18
  19 sub get_git_dir ($$) {
  20         my ($lei, $d) = @_;
  21         return $d if -d "$d/objects" && -d "$d/refs" && -e "$d/HEAD";
  22
  23         my $cmd = [ qw(git rev-parse --git-dir) ];
  24         my $opt = { '-C' => $d };
  25         if (defined($lei->{opt}->{cwd})) { # --cwd used, report errors
  26                 $opt->{2} = $lei->{2};
  27         } else { # implicit --cwd, quiet errors
  28                 open $opt->{2}, '>', '/dev/null' or die "open /dev/null: $!";
  29         }
  30         my ($r, $pid) = popen_rd($cmd, {GIT_DIR => undef}, $opt);
  31         chomp(my $gd = do { local $/; <$r> });
  32         waitpid($pid, 0) == $pid or die "BUG: waitpid @$cmd ($!)";
  33         $? == 0 ? $gd : undef;
  34 }
  35
  36 sub solver_user_cb { # called by solver when done
  37         my ($res, $self) = @_;
  38         my $lei = $self->{lei};
  39         my $log_buf = delete $lei->{'log_buf'};
  40         $$log_buf =~ s/^/# /sgm;
  41         ref($res) eq 'ARRAY' or return $lei->child_error(1 << 8, $$log_buf);
  42         $lei->qerr($$log_buf);
  43         my ($git, $oid, $type, $size, $di) = @$res;
  44         my $gd = $git->{git_dir};
  45
  46         # don't try to support all the git-show(1) options for non-blob,
  47         # this is just a convenience:
  48         $type ne 'blob' and
  49                 $lei->err("# $oid is a $type of $size bytes in:\n#\t$gd");
  50
  51         my $cmd = [ 'git', "--git-dir=$gd", 'show', $oid ];
  52         my $rdr = { 1 => $lei->{1}, 2 => $lei->{2} };
  53         waitpid(spawn($cmd, $lei->{env}, $rdr), 0);
  54         $lei->child_error($?) if $?;
  55 }
  56
  57 sub do_solve_blob { # via wq_do
  58         my ($self) = @_;
  59         my $lei = $self->{lei};
  60         my $git_dirs = $lei->{opt}->{'git-dir'};
  61         my $hints = {};
  62         for my $x (qw(oid-a path-a path-b)) {
  63                 my $v = $lei->{opt}->{$x} // next;
  64                 $x =~ tr/-/_/;
  65                 $hints->{$x} = $v;
  66         }
  67         open my $log, '+>', \(my $log_buf = '') or die "PerlIO::scalar: $!";
  68         $lei->{log_buf} = \$log_buf;
  69         my $git = $lei->{ale}->git;
  70         my @rmt = map {
  71                 PublicInbox::LeiRemote->new($lei, $_)
  72         } $self->{lxs}->remotes;
  73         my $solver = bless {
  74                 gits => [ map {
  75                                 PublicInbox::Git->new($lei->rel2abs($_))
  76                         } @$git_dirs ],
  77                 user_cb => \&solver_user_cb,
  78                 uarg => $self,
  79                 # -cur_di, -qsp, -msg => temporary fields for Qspawn callbacks
  80                 inboxes => [ $self->{lxs}->locals, @rmt ],
  81         }, 'PublicInbox::SolverGit';
  82         $lei->{env}->{'psgi.errors'} = $lei->{2}; # ugh...
  83         local $PublicInbox::DS::in_loop = 0; # waitpid synchronously
  84         $solver->solve($lei->{env}, $log, $self->{oid_b}, $hints);
  85 }
  86
  87 sub lei_blob {
  88         my ($lei, $blob) = @_;
  89         $lei->start_pager if -t $lei->{1};
  90         my $opt = $lei->{opt};
  91         my $has_hints = grep(defined, @$opt{qw(oid-a path-a path-b)});
  92         my $lxs;
  93
  94         # first, see if it's a blob returned by "lei q" JSON output:k
  95         if ($opt->{mail} // ($has_hints ? 0 : 1)) {
  96                 if (grep(defined, @$opt{qw(include only)})) {
  97                         $lxs = $lei->lxs_prepare;
  98                         $lei->ale->refresh_externals($lxs);
  99                 }
 100                 my $rdr = { 1 => $lei->{1} };
 101                 if ($opt->{mail}) {
 102                         $rdr->{2} = $lei->{2};
 103                 } else {
 104                         open $rdr->{2}, '>', '/dev/null' or die "open: $!";
 105                 }
 106                 my $cmd = [ 'git', '--git-dir='.$lei->ale->git->{git_dir},
 107                                 'cat-file', 'blob', $blob ];
 108                 waitpid(spawn($cmd, $lei->{env}, $rdr), 0);
 109                 return if $? == 0;
 110                 return $lei->child_error($?) if $opt->{mail};
 111         }
 112
 113         # maybe it's a non-email (code) blob from a coderepo
 114         my $git_dirs = $opt->{'git-dir'} //= [];
 115         if ($opt->{'cwd'} // 1) {
 116                 my $cgd = get_git_dir($lei, '.');
 117                 unshift(@$git_dirs, $cgd) if defined $cgd;
 118         }
 119         return $lei->fail('no --git-dir to try') unless @$git_dirs;
 120         unless ($lxs) {
 121                 $lxs = $lei->lxs_prepare or return;
 122                 $lei->ale->refresh_externals($lxs);
 123         }
 124         if ($lxs->remotes) {
 125                 require PublicInbox::LeiRemote;
 126                 $lei->{curl} //= which('curl') or return
 127                         $lei->fail('curl needed for', $lxs->remotes);
 128                 $lei->_lei_store(1)->write_prepare($lei);
 129         }
 130         require PublicInbox::SolverGit;
 131         my $self = bless { lxs => $lxs, oid_b => $blob }, __PACKAGE__;
 132         my ($op_c, $ops) = $lei->workers_start($self, 'lei_solve', 1,
 133                 { '' => [ \&sol_done, $lei ] });
 134         $lei->{sol} = $self;
 135         $self->wq_io_do('do_solve_blob', []);
 136         $self->wq_close(1);
 137         $op_c->op_wait_event($ops);
 138 }
 139
 140 sub ipc_atfork_child {
 141         my ($self) = @_;
 142         $self->{lei}->_lei_atfork_child;
 143         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 144         $self->SUPER::ipc_atfork_child;
 145 }
 146
 147 1;