lib/PublicInbox/LeiImport.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # front-end for the "lei import" sub-command
   5 package PublicInbox::LeiImport;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::MboxReader;
  10 use PublicInbox::Eml;
  11 use PublicInbox::InboxWritable qw(eml_from_path);
  12 use PublicInbox::PktOp;
  13
  14 sub _import_eml { # MboxReader callback
  15         my ($eml, $sto, $set_kw) = @_;
  16         $sto->ipc_do('set_eml', $eml, $set_kw ? $sto->mbox_keywords($eml) : ());
  17 }
  18
  19 sub import_done_wait { # dwaitpid callback
  20         my ($arg, $pid) = @_;
  21         my ($imp, $lei) = @$arg;
  22         $lei->child_error($?, 'non-fatal errors during import') if $?;
  23         my $ign = $lei->{sto}->ipc_do('done'); # PublicInbox::LeiStore::done
  24         $lei->dclose;
  25 }
  26
  27 sub import_done { # EOF callback for main daemon
  28         my ($lei) = @_;
  29         my $imp = delete $lei->{imp} or return;
  30         $imp->wq_wait_old(\&import_done_wait, $lei);
  31 }
  32
  33 sub call { # the main "lei import" method
  34         my ($cls, $lei, @argv) = @_;
  35         my $sto = $lei->_lei_store(1);
  36         $sto->write_prepare($lei);
  37         $lei->{opt}->{kw} //= 1;
  38         my $fmt = $lei->{opt}->{'format'};
  39         my $self = $lei->{imp} = bless {}, $cls;
  40         if (my @f = grep { -f } @argv && !$fmt) {
  41                 return $lei->fail("--format unset for regular files:\n@f");
  42         }
  43         $self->{0} = $lei->{0} if $lei->{opt}->{stdin};
  44         my $ops = {
  45                 '!' => [ $lei->can('fail_handler'), $lei ],
  46                 'x_it' => [ $lei->can('x_it'), $lei ],
  47                 'child_error' => [ $lei->can('child_error'), $lei ],
  48                 '' => [ \&import_done, $lei ],
  49         };
  50         ($lei->{pkt_op_c}, $lei->{pkt_op_p}) = PublicInbox::PktOp->pair($ops);
  51         my $j = $lei->{opt}->{jobs} // scalar(@argv) || 1;
  52         my $nproc = $self->detect_nproc;
  53         $j = $nproc if $j > $nproc;
  54         $self->wq_workers_start('lei_import', $j, $lei->oldset, {lei => $lei});
  55         my $op = delete $lei->{pkt_op_c};
  56         delete $lei->{pkt_op_p};
  57         $self->wq_io_do('import_stdin', []) if $self->{0};
  58         for my $x (@argv) {
  59                 $self->wq_io_do('import_path_url', [], $x);
  60         }
  61         $self->wq_close(1);
  62         $lei->event_step_init; # wait for shutdowns
  63         if ($lei->{oneshot}) {
  64                 while ($op->{sock}) { $op->event_step }
  65         }
  66 }
  67
  68 sub ipc_atfork_child {
  69         my ($self) = @_;
  70         $self->{lei}->lei_atfork_child;
  71         $self->SUPER::ipc_atfork_child;
  72 }
  73
  74 sub _import_fh {
  75         my ($lei, $fh, $x) = @_;
  76         my $set_kw = $lei->{opt}->{kw};
  77         my $fmt = $lei->{opt}->{'format'};
  78         eval {
  79                 if ($fmt eq 'eml') {
  80                         my $buf = do { local $/; <$fh> } //
  81                                 return $lei->child_error(1 >> 8, <<"");
  82 error reading $x: $!
  83
  84                         my $eml = PublicInbox::Eml->new(\$buf);
  85                         _import_eml($eml, $lei->{sto}, $set_kw);
  86                 } else { # some mbox
  87                         my $cb = PublicInbox::MboxReader->can($fmt);
  88                         $cb or return $lei->child_error(1 >> 8, <<"");
  89 --format $fmt unsupported for $x
  90
  91                         $cb->(undef, $fh, \&_import_eml, $lei->{sto}, $set_kw);
  92                 }
  93         };
  94         $lei->child_error(1 >> 8, "<stdin>: $@") if $@;
  95 }
  96
  97 sub _import_maildir { # maildir_each_file cb
  98         my ($f, $sto, $set_kw) = @_;
  99         $sto->ipc_do('set_eml_from_maildir', $f, $set_kw);
 100 }
 101
 102 sub import_path_url {
 103         my ($self, $x) = @_;
 104         my $lei = $self->{lei};
 105         # TODO auto-detect?
 106         if (-f $x) {
 107                 open my $fh, '<', $x or return $lei->child_error(1 >> 8, <<"");
 108 unable to open $x: $!
 109
 110                 _import_fh($lei, $fh, $x);
 111         } elsif (-d _ && (-d "$x/cur" || -d "$x/new")) {
 112                 require PublicInbox::LeiToMail;
 113                 PublicInbox::LeiToMail::maildir_each_file($x,
 114                                         \&_import_maildir,
 115                                         $lei->{sto}, $lei->{opt}->{kw});
 116         } else {
 117                 $lei->fail("$x unsupported (TODO)");
 118         }
 119 }
 120
 121 sub import_stdin {
 122         my ($self) = @_;
 123         _import_fh($self->{lei}, $self->{0}, '<stdin>');
 124 }
 125
 126 1;