]> Sergey Matveev's repositories - public-inbox.git/blob - lib/PublicInbox/LeiMirror.pm
lei_mirror: add a hint for skipped epoch permissions
[public-inbox.git] / lib / PublicInbox / LeiMirror.pm
1 # Copyright (C) all contributors <meta@public-inbox.org>
2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
3
4 # "lei add-external --mirror" support (also "public-inbox-clone");
5 package PublicInbox::LeiMirror;
6 use strict;
7 use v5.10.1;
8 use parent qw(PublicInbox::IPC);
9 use PublicInbox::Config;
10 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
11 use IO::Compress::Gzip qw(gzip $GzipError);
12 use PublicInbox::Spawn qw(popen_rd spawn);
13 use File::Temp ();
14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
15 use Carp qw(croak);
16 our %LIVE;
17
18 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
19         my ($arg, $pid) = @_;
20         my ($mrr, $lei) = @$arg;
21         my $f = "$mrr->{dst}/mirror.done";
22         if ($?) {
23                 $lei->child_error($?);
24         } elsif (!unlink($f)) {
25                 warn("unlink($f): $!\n") unless $!{ENOENT};
26         } else {
27                 if ($lei->{cmd} ne 'public-inbox-clone') {
28                         # calls _finish_add_external
29                         $lei->lazy_cb('add-external', '_finish_'
30                                         )->($lei, $mrr->{dst});
31                 }
32                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
33         }
34         $lei->dclose;
35 }
36
37 # for old installations without manifest.js.gz
38 sub try_scrape {
39         my ($self) = @_;
40         my $uri = URI->new($self->{src});
41         my $lei = $self->{lei};
42         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
43         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
44         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
45         my $fh = popen_rd($cmd, undef, $opt);
46         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
47         close($fh) or return $lei->child_error($?, "@$cmd failed");
48
49         # we grep with URL below, we don't want Subject/From headers
50         # making us clone random URLs
51         my @html = split(/<hr>/, $html);
52         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
53         my $url = $uri->as_string;
54         chop($url) eq '/' or die "BUG: $uri not canonicalized";
55
56         # since this is for old instances w/o manifest.js.gz, try v1 first
57         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
58         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
59                 my %v2_epochs = map {
60                         my ($n) = (m!/([0-9]+)\z!);
61                         $n => [ URI->new($_), '' ]
62                 } @v2_urls; # uniq
63                 clone_v2($self, \%v2_epochs);
64                 reap_live() while keys(%LIVE);
65                 return;
66         }
67
68         # filter out common URLs served by WWW (e.g /$MSGID/T/)
69         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
70                         grep(m!\A\Q$url\E/*\z!, @urls)) {
71                 die <<"";
72 E: confused by scraping <$uri>, did you mean <$url>?
73
74         }
75         @urls and die <<"";
76 E: confused by scraping <$uri>, got ambiguous results:
77 @urls
78
79         die "E: scraping <$uri> revealed nothing\n";
80 }
81
82 sub clone_cmd {
83         my ($lei, $opt) = @_;
84         my @cmd = qw(git);
85         $opt->{$_} = $lei->{$_} for (0..2);
86         # we support "-c $key=$val" for arbitrary git config options
87         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
88         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
89         push @cmd, qw(clone --mirror);
90         push @cmd, '-q' if $lei->{opt}->{quiet} ||
91                         ($lei->{opt}->{jobs} // 1) > 1;
92         push @cmd, '-v' if $lei->{opt}->{verbose};
93         # XXX any other options to support?
94         # --reference is tricky with multiple epochs...
95         @cmd;
96 }
97
98 sub ft_rename ($$$) {
99         my ($ft, $dst, $open_mode) = @_;
100         my $fn = $ft->filename;
101         my @st = stat($dst);
102         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
103         chmod($mode, $ft) or croak "E: chmod $fn: $!";
104         rename($fn, $dst) or croak "E: rename($fn => $ft): $!";
105         $ft->unlink_on_destroy(0);
106 }
107
108 sub _get_txt_start { # non-fatal
109         my ($self, $endpoint, $fini) = @_;
110         my $uri = URI->new($self->{cur_src} // $self->{src});
111         my $lei = $self->{lei};
112         my $path = $uri->path;
113         chop($path) eq '/' or die "BUG: $uri not canonicalized";
114         $uri->path("$path/$endpoint");
115         my $f = (split(m!/!, $endpoint))[-1];
116         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
117         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
118         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(--compressed -R -o),
119                                         $ft->filename);
120         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
121         $lei->qerr("# @$cmd");
122         my $jobs = $lei->{opt}->{jobs} // 1;
123         reap_live() while keys(%LIVE) >= $jobs;
124         $LIVE{spawn($cmd, undef, $opt)} =
125                         [ \&_get_txt_done, $self, $endpoint, $fini ];
126 }
127
128 sub _get_txt_done { # returns true on error (non-fatal), undef on success
129         my ($self, $endpoint) = @_;
130         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
131         my $cerr = $?;
132         $? = 0; # don't influence normal lei exit
133         return warn("$uri missing\n") if ($cerr >> 8) == 22;
134         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
135         seek($fh, SEEK_SET, 0) or die "seek: $!";
136         $self->{"mtime.$endpoint"} = (stat($fh))[9];
137         local $/;
138         $self->{"txt.$endpoint"} = <$fh>;
139         undef; # success
140 }
141
142 sub _write_inbox_config {
143         my ($self) = @_;
144         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
145         my $dst = $self->{cur_dst} // $self->{dst};
146         my $f = "$dst/inbox.config.example";
147         open my $fh, '>', $f or die "open($f): $!";
148         print $fh $buf or die "print: $!";
149         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
150         my $mtime = delete $self->{'mtime._/text/config/raw'};
151         $fh->flush or die "flush($f): $!";
152         if (defined $mtime) {
153                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
154         }
155         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
156         my $ibx = $self->{ibx} = {};
157         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
158                 for (qw(address newsgroup nntpmirror)) {
159                         $ibx->{$_} = $cfg->{"$sec.$_"};
160                 }
161         }
162 }
163
164 sub set_description ($) {
165         my ($self) = @_;
166         my $dst = $self->{cur_dst} // $self->{dst};
167         my $f = "$dst/description";
168         open my $fh, '+>>', $f or die "open($f): $!";
169         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
170         my $d = do { local $/; <$fh> } // die "read($f): $!";
171         my $orig = $d;
172         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
173                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
174                 $d = delete($self->{'txt.description'});
175         }
176         $d //= 'mirror of '.($self->{cur_src} // $self->{src})."\n";
177         return if $d eq $orig;
178         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
179         truncate($fh, 0) or die "truncate($f): $!";
180         print $fh $d or die "print($f): $!";
181         close $fh or die "close($f): $!";
182 }
183
184 sub index_cloned_inbox {
185         my ($self, $iv) = @_;
186         my $lei = $self->{lei};
187         eval { set_description($self) };
188         warn $@ if $@;
189
190         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
191         # lei is useless without Xapian + SQLite
192         if ($lei->{cmd} ne 'public-inbox-clone') {
193                 my $ibx = delete($self->{ibx}) // {
194                         address => [ 'lei@example.com' ],
195                         version => $iv,
196                 };
197                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
198                 PublicInbox::Inbox->new($ibx);
199                 PublicInbox::InboxWritable->new($ibx);
200                 my $opt = {};
201                 for my $sw ($lei->index_opt) {
202                         my ($k) = ($sw =~ /\A([\w-]+)/);
203                         $opt->{$k} = $lei->{opt}->{$k};
204                 }
205                 # force synchronous dwaitpid for v2:
206                 local $PublicInbox::DS::in_loop = 0;
207                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
208                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
209                 local %ENV = (%ENV, %$env) if $env;
210                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
211                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
212         }
213         return if defined $self->{cur_dst};
214         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
215 }
216
217 sub run_reap {
218         my ($lei, $cmd, $opt) = @_;
219         $lei->qerr("# @$cmd");
220         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
221         my $ret = $?;
222         $? = 0; # don't let it influence normal exit
223         $ret;
224 }
225
226 sub clone_v1 {
227         my ($self, $nohang) = @_;
228         my $lei = $self->{lei};
229         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
230         my $uri = URI->new($self->{cur_src} // $self->{src});
231         defined($lei->{opt}->{epoch}) and
232                 die "$uri is a v1 inbox, --epoch is not supported\n";
233         my $pfx = $curl->torsocks($lei, $uri) or return;
234         my $dst = $self->{cur_dst} // $self->{dst};
235         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
236         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
237         my $cmd = [ @$pfx, clone_cmd($lei, my $opt = {}), "$uri", $dst ];
238         $lei->qerr("# @$cmd");
239         $LIVE{spawn($cmd, undef, $opt)} = [ \&reap_clone, $lei, $cmd, $fini ];
240         reap_live() while keys(%LIVE) >= $jobs;
241
242         _get_txt_start($self, '_/text/config/raw', $fini);
243         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
244         defined($d) ? ($self->{'txt.description'} = $d) :
245                 _get_txt_start($self, 'description', $fini);
246
247         reap_live() until ($nohang || !keys(%LIVE)); # for non-manifest clone
248 }
249
250 sub parse_epochs ($$) {
251         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
252         $opt_epochs // return; # undef => all epochs
253         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
254         undef($lo) if ($lo // '') eq '';
255         my $re = qr/\A~?[0-9]+\z/;
256         if (@extra || (($lo // '0') !~ $re) ||
257                         (($hi // '0') !~ $re) ||
258                         !(grep(defined, $lo, $hi))) {
259                 die <<EOM;
260 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
261 EOM
262         }
263         my @n = sort { $a <=> $b } keys %$v2_epochs;
264         for (grep(defined, $lo, $hi)) {
265                 if (/\A[0-9]+\z/) {
266                         $_ > $n[-1] and die
267 "`$_' exceeds maximum available epoch ($n[-1])\n";
268                         $_ < $n[0] and die
269 "`$_' is lower than minimum available epoch ($n[0])\n";
270                 } elsif (/\A~([0-9]+)/) {
271                         my $off = -$1 - 1;
272                         $n[$off] // die "`$_' is out of range\n";
273                         $_ = $n[$off];
274                 } else { die "`$_' not understood\n" }
275         }
276         defined($lo) && defined($hi) && $lo > $hi and die
277 "low value (`$lo') exceeds high (`$hi')\n";
278         $lo //= $n[0] if $dotdot;
279         $hi //= $n[-1] if $dotdot;
280         $hi //= $lo;
281         my $want = {};
282         for ($lo..$hi) {
283                 if (defined $v2_epochs->{$_}) {
284                         $want->{$_} = 1;
285                 } else {
286                         warn
287 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
288                 }
289         }
290         $want
291 }
292
293 sub init_placeholder ($$) {
294         my ($src, $edst) = @_;
295         PublicInbox::Import::init_bare($edst);
296         my $f = "$edst/config";
297         open my $fh, '>>', $f or die "open($f): $!";
298         print $fh <<EOM or die "print($f): $!";
299 [remote "origin"]
300         url = $src
301         fetch = +refs/*:refs/*
302         mirror = true
303
304 ; This git epoch was created read-only and "public-inbox-fetch"
305 ; will not fetch updates for it unless write permission is added.
306 ; Hint: chmod +w $edst
307 EOM
308         close $fh or die "close:($f): $!";
309 }
310
311 sub reap_clone { # async, called via SIGCHLD
312         my ($lei, $cmd) = @_;
313         my $cerr = $?;
314         $? = 0; # don't let it influence normal exit
315         if ($cerr) {
316                 kill('TERM', keys %LIVE);
317                 $lei->child_error($cerr, "@$cmd failed");
318         }
319 }
320
321 sub v1_done { # called via OnDestroy
322         my ($self) = @_;
323         _write_inbox_config($self);
324         write_makefile($self->{cur_dst} // $self->{dst}, 1);
325         index_cloned_inbox($self, 1);
326 }
327
328 sub v2_done { # called via OnDestroy
329         my ($self) = @_;
330         _write_inbox_config($self);
331         require PublicInbox::MultiGit;
332         my $dst = $self->{cur_dst} // $self->{dst};
333         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
334         $mg->fill_alternates;
335         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
336         for my $edst (@{delete($self->{-read_only}) // []}) {
337                 my @st = stat($edst) or die "stat($edst): $!";
338                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
339         }
340         write_makefile($dst, 2);
341         delete $self->{-locked} // die "BUG: $dst not locked"; # unlock
342         index_cloned_inbox($self, 2);
343 }
344
345 sub reap_live {
346         my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
347         if (my $x = delete $LIVE{$pid}) {
348                 my $cb = shift @$x;
349                 $cb->(@$x);
350         } else {
351                 warn "reaped unknown PID=$pid ($?)\n";
352         }
353 }
354
355 sub clone_v2 ($$;$) {
356         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
357         my $lei = $self->{lei};
358         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
359         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
360         my $pfx = $curl->torsocks($lei, $first_uri) or return;
361         my $dst = $self->{cur_dst} // $self->{dst};
362         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
363         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
364         my (@src_edst, @skip);
365         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
366                 my ($uri, $key) = @{$v2_epochs->{$nr}};
367                 my $src = $uri->as_string;
368                 my $edst = $dst;
369                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
370 failed to extract epoch number from $src
371
372                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
373                 $edst .= "/git/$nr.git";
374                 if (!$want || $want->{$nr}) {
375                         push @src_edst, $src, $edst;
376                 } else { # create a placeholder so users only need to chmod +w
377                         init_placeholder($src, $edst);
378                         push @{$task->{-read_only}}, $edst;
379                         push @skip, $key;
380                 }
381         }
382         # filter out the epochs we skipped
383         $self->{-culled_manifest} = 1 if delete(@$m{@skip});
384
385         if (!-d $dst || !mkdir($dst)) {
386                 require File::Path;
387                 File::Path::mkpath($dst);
388                 -d $dst or die "mkpath($dst): $!\n";
389         }
390         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
391         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
392
393         _get_txt_start($task, '_/text/config/raw', $fini);
394         _get_txt_start($self, 'description', $fini);
395
396         $task->{-locked} = $lk->lock_for_scope($$);
397         my @cmd = clone_cmd($lei, my $opt = {});
398         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
399         do {
400                 reap_live() while keys(%LIVE) >= $jobs;
401                 while (keys(%LIVE) < $jobs && @src_edst &&
402                                 !$lei->{child_error}) {
403                         my $cmd = [ @$pfx, @cmd, splice(@src_edst, 0, 2) ];
404                         $lei->qerr("# @$cmd");
405                         $LIVE{spawn($cmd, undef, $opt)} = [ \&reap_clone,
406                                                         $lei, $cmd, $fini ];
407                 }
408         } while (@src_edst && !$lei->{child_error});
409 }
410
411 sub decode_manifest ($$$) {
412         my ($fh, $fn, $uri) = @_;
413         my $js;
414         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
415         gunzip(\$gz => \$js, MultiStream => 1) or
416                 die "gunzip($uri): $GunzipError\n";
417         my $m = eval { PublicInbox::Config->json->decode($js) };
418         die "$uri: error decoding `$js': $@\n" if $@;
419         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
420         $m;
421 }
422
423 sub multi_inbox ($$$) {
424         my ($self, $path, $m) = @_;
425         my $incl = $self->{lei}->{opt}->{include};
426         my $excl = $self->{lei}->{opt}->{exclude};
427
428         # assuming everything not v2 is v1, for now
429         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
430         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
431         my $v2 = {};
432
433         for (@v2_epochs) {
434                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
435                 push @{$v2->{$1}}, $_;
436         }
437         my $n = scalar(keys %$v2) + scalar(@v1);
438         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
439         if (defined $incl) {
440                 my $re = '(?:'.join('|', map {
441                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E\z/
442                         } @$incl).')';
443                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
444                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
445                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
446                 @v1 = grep(/$re/, @v1);
447         }
448         if (defined $excl) {
449                 my $re = '(?:'.join('|', map {
450                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E\z/
451                         } @$excl).')';
452                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
453                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
454                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
455                 @v1 = grep(!/$re/, @v1);
456         }
457         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
458         $ret->{v1} = \@v1 if @v1;
459         $ret->{v2} = $v2 if keys %$v2;
460         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
461                                 join("\n\t", sort @orig)
462                         : "Nothing available to clone\n";
463         my $path_pfx = '';
464
465         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
466         if (@v2_epochs) {
467                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
468                                 @v2_epochs) == @v2_epochs) {
469                         $$path =~ s!\A(/[^/]+)/!/! or last;
470                         $path_pfx .= $1;
471                 }
472         } elsif (@v1) {
473                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
474                         $path_pfx .= $1;
475                 }
476         }
477         ($path_pfx, $n, $ret);
478 }
479
480 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
481 sub try_manifest {
482         my ($self) = @_;
483         my $uri = URI->new($self->{src});
484         my $lei = $self->{lei};
485         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
486         my $path = $uri->path;
487         chop($path) eq '/' or die "BUG: $uri not canonicalized";
488         $uri->path($path . '/manifest.js.gz');
489         my $pdir = $lei->rel2abs($self->{dst});
490         $pdir =~ s!/[^/]+/?\z!!;
491         my $ft = File::Temp->new(TEMPLATE => 'm-XXXX',
492                                 UNLINK => 1, DIR => $pdir, SUFFIX => '.tmp');
493         my $fn = $ft->filename;
494         my ($bn) = ($fn =~ m!/([^/]+)\z!);
495         my $cmd = $curl->for_uri($lei, $uri, '-R', '-o', $bn);
496         my $opt = { -C => $pdir };
497         $opt->{$_} = $lei->{$_} for (0..2);
498         my $cerr = run_reap($lei, $cmd, $opt);
499         local %LIVE;
500         if ($cerr) {
501                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
502                 return $lei->child_error($cerr, "@$cmd failed");
503         }
504         my $m = eval { decode_manifest($ft, $fn, $uri) };
505         if ($@) {
506                 warn $@;
507                 return try_scrape($self);
508         }
509         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
510         return $lei->child_error(1, $multi) if !ref($multi);
511         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
512         if (my $v2 = delete $multi->{v2}) {
513                 for my $name (sort keys %$v2) {
514                         my $epochs = delete $v2->{$name};
515                         my %v2_epochs = map {
516                                 $uri->path($n > 1 ? $path_pfx.$path.$_
517                                                 : $path_pfx.$_);
518                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
519                                 $e // die "no [0-9]+\.git in `$uri'";
520                                 $e => [ $uri->clone, $_ ];
521                         } @$epochs;
522                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
523                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
524                         local $self->{cur_src} = $1;
525                         local $self->{cur_dst} = $self->{dst};
526                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
527                                                         git/[0-9]+\.git\z!x) {
528                                 $self->{cur_dst} .= "/$1";
529                         }
530                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
531 E: `$self->{cur_dst}' must not contain newline
532 EOM
533                         clone_v2($self, \%v2_epochs, $m);
534                         reap_live() while keys(%LIVE) >= $jobs;
535                         return if $self->{lei}->{child_error};
536                 }
537         }
538         if (my $v1 = delete $multi->{v1}) {
539                 my $p = $path_pfx.$path;
540                 chop($p) if substr($p, -1, 1) eq '/';
541                 $uri->path($p);
542                 for my $name (@$v1) {
543                         reap_live() while keys(%LIVE) >= $jobs;
544                         return if $self->{lei}->{child_error};
545
546                         my $task = bless { %$self }, __PACKAGE__;
547                         $task->{-ent} = $m->{$name} //
548                                         die("BUG: no `$name' in manifest");
549                         $task->{cur_src} = "$uri";
550                         $task->{cur_dst} = $task->{dst};
551                         if ($n > 1) {
552                                 $task->{cur_dst} .= $name;
553                                 $task->{cur_src} .= $name;
554                         }
555                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
556 E: `$task->{cur_dst}' must not contain newline
557 EOM
558                         $task->{cur_src} .= '/';
559                         clone_v1($task, 1);
560                 }
561         }
562         reap_live() while keys(%LIVE);
563         return if $self->{lei}->{child_error};
564
565         if (delete $self->{-culled_manifest}) { # set by clone_v2/-I/--exclude
566                 # write the smaller manifest if epochs were skipped so
567                 # users won't have to delete manifest if they +w an
568                 # epoch they no longer want to skip
569                 my $json = PublicInbox::Config->json->encode($m);
570                 my $mtime = (stat($fn))[9];
571                 gzip(\$json => $fn) or die "gzip: $GzipError";
572                 utime($mtime, $mtime, $fn) or die "utime(..., $fn): $!";
573         }
574         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
575         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
576 }
577
578 sub start_clone_url {
579         my ($self) = @_;
580         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
581         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
582 }
583
584 sub do_mirror { # via wq_io_do
585         my ($self) = @_;
586         my $lei = $self->{lei};
587         umask($lei->{client_umask}) if defined $lei->{client_umask};
588         eval {
589                 my $iv = $lei->{opt}->{'inbox-version'};
590                 if (defined $iv) {
591                         local %LIVE;
592                         return clone_v1($self) if $iv == 1;
593                         return try_scrape($self) if $iv == 2;
594                         die "bad --inbox-version=$iv\n";
595                 }
596                 return start_clone_url($self) if $self->{src} =~ m!://!;
597                 die "TODO: cloning local directories not supported, yet";
598         };
599         $lei->fail($@) if $@;
600 }
601
602 sub start {
603         my ($cls, $lei, $src, $dst) = @_;
604         my $self = bless { src => $src, dst => $dst }, $cls;
605         if ($src =~ m!https?://!) {
606                 require URI;
607                 require PublicInbox::LeiCurl;
608         }
609         require PublicInbox::Lock;
610         require PublicInbox::Inbox;
611         require PublicInbox::Admin;
612         require PublicInbox::InboxWritable;
613         $lei->request_umask;
614         my ($op_c, $ops) = $lei->workers_start($self, 1);
615         $lei->{wq1} = $self;
616         $self->wq_io_do('do_mirror', []);
617         $self->wq_close;
618         $lei->wait_wq_events($op_c, $ops);
619 }
620
621 sub ipc_atfork_child {
622         my ($self) = @_;
623         $self->{lei}->_lei_atfork_child;
624         $self->SUPER::ipc_atfork_child;
625 }
626
627 sub write_makefile {
628         my ($dir, $ibx_ver) = @_;
629         my $f = "$dir/Makefile";
630         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
631                 print $fh <<EOM or die "print($f) $!";
632 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
633 # manpage for more information on the format.  This Makefile is
634 # intended as a familiar wrapper for users unfamiliar with
635 # public-inbox-* commands.
636 #
637 # See the respective manpages for public-inbox-fetch(1),
638 # public-inbox-index(1), etc for more information on
639 # some of the commands used by this Makefile.
640 #
641 # This Makefile will not be modified nor read by public-inbox,
642 # so you may edit it freely with your own convenience targets
643 # and notes.  public-inbox-fetch will recreate it if removed.
644 EOM
645                 print $fh <<'EOM' or die "print($f): $!";
646 # the default target:
647 help :
648         @echo Common targets:
649         @echo '    make fetch        - fetch from remote git repostorie(s)'
650         @echo '    make update       - fetch and update index '
651         @echo
652         @echo Rarely needed targets:
653         @echo '    make reindex      - may be needed for new features/bugfixes'
654         @echo '    make compact      - rewrite Xapian storage to save space'
655
656 fetch :
657         public-inbox-fetch
658 update :
659         @if ! public-inbox-fetch --exit-code; \
660         then \
661                 c=$$?; \
662                 test $$c -eq 127 && exit 0; \
663                 exit $$c; \
664         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
665         then \
666                 public-inbox-index; \
667         else \
668                 echo 'public-inbox index not initialized'; \
669                 echo 'see public-inbox-index(1) man page'; \
670         fi
671 reindex :
672         public-inbox-index --reindex
673 compact :
674         public-inbox-compact
675
676 .PHONY : help fetch update reindex compact
677 EOM
678                 close $fh or die "close($f): $!";
679         } else {
680                 die "open($f): $!" unless $!{EEXIST};
681         }
682 }
683
684 1;