lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Config;
  10 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
  11 use IO::Compress::Gzip qw(gzip $GzipError);
  12 use PublicInbox::Spawn qw(popen_rd spawn);
  13 use File::Temp ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 our %LIVE;
  17
  18 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  19         my ($arg, $pid) = @_;
  20         my ($mrr, $lei) = @$arg;
  21         my $f = "$mrr->{dst}/mirror.done";
  22         if ($?) {
  23                 $lei->child_error($?);
  24         } elsif (!unlink($f)) {
  25                 warn("unlink($f): $!\n") unless $!{ENOENT};
  26         } else {
  27                 if ($lei->{cmd} ne 'public-inbox-clone') {
  28                         # calls _finish_add_external
  29                         $lei->lazy_cb('add-external', '_finish_'
  30                                         )->($lei, $mrr->{dst});
  31                 }
  32                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  33         }
  34         $lei->dclose;
  35 }
  36
  37 # for old installations without manifest.js.gz
  38 sub try_scrape {
  39         my ($self) = @_;
  40         my $uri = URI->new($self->{src});
  41         my $lei = $self->{lei};
  42         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  43         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  44         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  45         my $fh = popen_rd($cmd, undef, $opt);
  46         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  47         close($fh) or return $lei->child_error($?, "@$cmd failed");
  48
  49         # we grep with URL below, we don't want Subject/From headers
  50         # making us clone random URLs
  51         my @html = split(/<hr>/, $html);
  52         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  53         my $url = $uri->as_string;
  54         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  55
  56         # since this is for old instances w/o manifest.js.gz, try v1 first
  57         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  58         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  59                 my %v2_epochs = map {
  60                         my ($n) = (m!/([0-9]+)\z!);
  61                         $n => [ URI->new($_), '' ]
  62                 } @v2_urls; # uniq
  63                 clone_v2($self, \%v2_epochs);
  64                 reap_live() while keys(%LIVE);
  65                 return;
  66         }
  67
  68         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  69         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  70                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  71                 die <<"";
  72 E: confused by scraping <$uri>, did you mean <$url>?
  73
  74         }
  75         @urls and die <<"";
  76 E: confused by scraping <$uri>, got ambiguous results:
  77 @urls
  78
  79         die "E: scraping <$uri> revealed nothing\n";
  80 }
  81
  82 sub clone_cmd {
  83         my ($lei, $opt) = @_;
  84         my @cmd = qw(git);
  85         $opt->{$_} = $lei->{$_} for (0..2);
  86         # we support "-c $key=$val" for arbitrary git config options
  87         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
  88         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
  89         push @cmd, qw(clone --mirror);
  90         push @cmd, '-q' if $lei->{opt}->{quiet} ||
  91                         ($lei->{opt}->{jobs} // 1) > 1;
  92         push @cmd, '-v' if $lei->{opt}->{verbose};
  93         # XXX any other options to support?
  94         # --reference is tricky with multiple epochs...
  95         @cmd;
  96 }
  97
  98 sub ft_rename ($$$) {
  99         my ($ft, $dst, $open_mode) = @_;
 100         my $fn = $ft->filename;
 101         my @st = stat($dst);
 102         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 103         chmod($mode, $ft) or croak "E: chmod $fn: $!";
 104         rename($fn, $dst) or croak "E: rename($fn => $ft): $!";
 105         $ft->unlink_on_destroy(0);
 106 }
 107
 108 sub _get_txt_start { # non-fatal
 109         my ($self, $endpoint, $file, $mode) = @_;
 110         my $uri = URI->new($self->{cur_src} // $self->{src});
 111         my $lei = $self->{lei};
 112         my $path = $uri->path;
 113         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 114         $uri->path("$path/$endpoint");
 115         my $dst = $self->{cur_dst} // $self->{dst};
 116         my $ft = File::Temp->new(TEMPLATE => "$file-XXXX", DIR => $dst);
 117         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 118         my $cmd = $self->{curl}->for_uri($lei, $uri,
 119                                         qw(--compressed -R -o), $ft->filename);
 120         $self->{-get_txt} = [ $ft, $cmd, $uri, $file, $mode ];
 121         $lei->qerr("# @$cmd");
 122         spawn($cmd, undef, $opt);
 123 }
 124
 125 sub _get_txt_done {
 126         my ($self) = @_;
 127         my ($ft, $cmd, $uri, $file, $mode) = @{delete $self->{-get_txt}};
 128         my $cerr = $?;
 129         $? = 0;
 130         return "$uri missing" if ($cerr >> 8) == 22;
 131         return "# @$cmd failed (non-fatal)" if $cerr;
 132         my $dst = $self->{cur_dst} // $self->{dst};
 133         ft_rename($ft, "$dst/$file", $mode);
 134         undef; # success
 135 }
 136
 137 # tries the relatively new /$INBOX/_/text/config/raw endpoint
 138 sub _try_config_start {
 139         my ($self) = @_;
 140         _get_txt_start($self, qw(_/text/config/raw inbox.config.example), 0444);
 141 }
 142
 143 sub _try_config_done {
 144         my ($self) = @_;
 145         my $err = _get_txt_done($self);
 146         return warn($err, "\n") if $err;
 147         my $dst = $self->{cur_dst} // $self->{dst};
 148         my $f = "$dst/inbox.config.example";
 149         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 150         my $ibx = $self->{ibx} = {};
 151         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 152                 for (qw(address newsgroup nntpmirror)) {
 153                         $ibx->{$_} = $cfg->{"$sec.$_"};
 154                 }
 155         }
 156 }
 157
 158 sub _get_txt { # non-fatal temporary compat function
 159         waitpid(_get_txt_start(@_), 0) > 0 or die "waitpid: $!";
 160         _get_txt_done($_[0]);
 161 }
 162
 163 sub set_description ($) {
 164         my ($self) = @_;
 165         my $dst = $self->{cur_dst} // $self->{dst};
 166         my $f = "$dst/description";
 167         open my $fh, '+>>', $f or die "open($f): $!";
 168         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 169         chomp(my $d = do { local $/; <$fh> } // die "read($f): $!");
 170         if ($d eq '($INBOX_DIR/description missing)' ||
 171                         $d =~ /^Unnamed repository/ || $d !~ /\S/) {
 172                 seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 173                 truncate($fh, 0) or die "truncate($f): $!";
 174                 my $src = $self->{cur_src} // $self->{src};
 175                 print $fh "mirror of $src\n" or die "print($f): $!";
 176                 close $fh or die "close($f): $!";
 177         }
 178 }
 179
 180 sub index_cloned_inbox {
 181         my ($self, $iv) = @_;
 182         my $lei = $self->{lei};
 183         my $err = _get_txt($self, qw(description description), 0666);
 184         warn($err, "\n") if $err; # non fatal
 185         eval { set_description($self) };
 186         warn $@ if $@;
 187
 188         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 189         # lei is useless without Xapian + SQLite
 190         if ($lei->{cmd} ne 'public-inbox-clone') {
 191                 my $ibx = delete($self->{ibx}) // {
 192                         address => [ 'lei@example.com' ],
 193                         version => $iv,
 194                 };
 195                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 196                 PublicInbox::Inbox->new($ibx);
 197                 PublicInbox::InboxWritable->new($ibx);
 198                 my $opt = {};
 199                 for my $sw ($lei->index_opt) {
 200                         my ($k) = ($sw =~ /\A([\w-]+)/);
 201                         $opt->{$k} = $lei->{opt}->{$k};
 202                 }
 203                 # force synchronous dwaitpid for v2:
 204                 local $PublicInbox::DS::in_loop = 0;
 205                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 206                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 207                 local %ENV = (%ENV, %$env) if $env;
 208                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 209                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 210         }
 211         return if defined $self->{cur_dst};
 212         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 213 }
 214
 215 sub run_reap {
 216         my ($lei, $cmd, $opt) = @_;
 217         $lei->qerr("# @$cmd");
 218         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 219         my $ret = $?;
 220         $? = 0; # don't let it influence normal exit
 221         $ret;
 222 }
 223
 224 sub clone_v1 {
 225         my ($self, $nohang) = @_;
 226         my $lei = $self->{lei};
 227         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 228         my $uri = URI->new($self->{cur_src} // $self->{src});
 229         defined($lei->{opt}->{epoch}) and
 230                 die "$uri is a v1 inbox, --epoch is not supported\n";
 231         my $pfx = $curl->torsocks($lei, $uri) or return;
 232         my $dst = $self->{cur_dst} // $self->{dst};
 233         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 234         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
 235         my $cmd = [ @$pfx, clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 236         $lei->qerr("# @$cmd");
 237         $LIVE{spawn($cmd, undef, $opt)} = [ \&reap_clone, $lei, $cmd, $fini ];
 238         reap_live() while keys(%LIVE) >= $jobs;
 239
 240         # wait for `git clone' to mkdir $dst (TODO: inotify/kevent?)
 241         select(undef, undef, undef, 0.011) until -d $dst;
 242         $LIVE{_try_config_start($self)} = [ \&_try_config_done, $self, $fini ];
 243         reap_live() until ($nohang || !keys(%LIVE));
 244 }
 245
 246 sub parse_epochs ($$) {
 247         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 248         $opt_epochs // return; # undef => all epochs
 249         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 250         undef($lo) if ($lo // '') eq '';
 251         my $re = qr/\A~?[0-9]+\z/;
 252         if (@extra || (($lo // '0') !~ $re) ||
 253                         (($hi // '0') !~ $re) ||
 254                         !(grep(defined, $lo, $hi))) {
 255                 die <<EOM;
 256 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 257 EOM
 258         }
 259         my @n = sort { $a <=> $b } keys %$v2_epochs;
 260         for (grep(defined, $lo, $hi)) {
 261                 if (/\A[0-9]+\z/) {
 262                         $_ > $n[-1] and die
 263 "`$_' exceeds maximum available epoch ($n[-1])\n";
 264                         $_ < $n[0] and die
 265 "`$_' is lower than minimum available epoch ($n[0])\n";
 266                 } elsif (/\A~([0-9]+)/) {
 267                         my $off = -$1 - 1;
 268                         $n[$off] // die "`$_' is out of range\n";
 269                         $_ = $n[$off];
 270                 } else { die "`$_' not understood\n" }
 271         }
 272         defined($lo) && defined($hi) && $lo > $hi and die
 273 "low value (`$lo') exceeds high (`$hi')\n";
 274         $lo //= $n[0] if $dotdot;
 275         $hi //= $n[-1] if $dotdot;
 276         $hi //= $lo;
 277         my $want = {};
 278         for ($lo..$hi) {
 279                 if (defined $v2_epochs->{$_}) {
 280                         $want->{$_} = 1;
 281                 } else {
 282                         warn
 283 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 284                 }
 285         }
 286         $want
 287 }
 288
 289 sub init_placeholder ($$) {
 290         my ($src, $edst) = @_;
 291         PublicInbox::Import::init_bare($edst);
 292         my $f = "$edst/config";
 293         open my $fh, '>>', $f or die "open($f): $!";
 294         print $fh <<EOM or die "print($f): $!";
 295 [remote "origin"]
 296         url = $src
 297         fetch = +refs/*:refs/*
 298         mirror = true
 299
 300 ; This git epoch was created read-only and "public-inbox-fetch"
 301 ; will not fetch updates for it unless write permission is added.
 302 EOM
 303         close $fh or die "close:($f): $!";
 304 }
 305
 306 sub reap_clone { # async, called via SIGCHLD
 307         my ($lei, $cmd) = @_;
 308         my $cerr = $?;
 309         $? = 0; # don't let it influence normal exit
 310         if ($cerr) {
 311                 kill('TERM', keys %LIVE);
 312                 $lei->child_error($cerr, "@$cmd failed");
 313         }
 314 }
 315
 316 sub v1_done { # called via OnDestroy
 317         my ($self) = @_;
 318         my $dst = $self->{cur_dst} // $self->{dst};
 319         write_makefile($dst, 1);
 320         index_cloned_inbox($self, 1);
 321 }
 322
 323 sub v2_done { # called via OnDestroy
 324         my ($self) = @_;
 325         require PublicInbox::MultiGit;
 326         my $dst = $self->{cur_dst} // $self->{dst};
 327         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 328         $mg->fill_alternates;
 329         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 330         for my $edst (@{delete($self->{-read_only}) // []}) {
 331                 my @st = stat($edst) or die "stat($edst): $!";
 332                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 333         }
 334         write_makefile($dst, 2);
 335         delete $self->{-locked} // die "BUG: $dst not locked"; # unlock
 336         index_cloned_inbox($self, 2);
 337 }
 338
 339 sub reap_live {
 340         my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 341         if (my $x = delete $LIVE{$pid}) {
 342                 my $cb = shift @$x;
 343                 $cb->(@$x);
 344         } else {
 345                 warn "reaped unknown PID=$pid ($?)\n";
 346         }
 347 }
 348
 349 sub clone_v2 ($$;$) {
 350         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 351         my $lei = $self->{lei};
 352         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 353         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 354         my $pfx = $curl->torsocks($lei, $first_uri) or return;
 355         my $dst = $self->{cur_dst} // $self->{dst};
 356         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 357         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 358         my (@src_edst, @skip);
 359         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 360                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 361                 my $src = $uri->as_string;
 362                 my $edst = $dst;
 363                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 364 failed to extract epoch number from $src
 365
 366                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 367                 $edst .= "/git/$nr.git";
 368                 if (!$want || $want->{$nr}) {
 369                         push @src_edst, $src, $edst;
 370                 } else { # create a placeholder so users only need to chmod +w
 371                         init_placeholder($src, $edst);
 372                         push @{$task->{-read_only}}, $edst;
 373                         push @skip, $key;
 374                 }
 375         }
 376         # filter out the epochs we skipped
 377         $self->{-culled_manifest} = 1 if delete(@$m{@skip});
 378
 379         if (!-d $dst || !mkdir($dst)) {
 380                 require File::Path;
 381                 File::Path::mkpath($dst);
 382                 -d $dst or die "mkpath($dst): $!\n";
 383         }
 384         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 385         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 386         $LIVE{_try_config_start($task)} = [ \&_try_config_done, $task, $fini ];
 387         $task->{-locked} = $lk->lock_for_scope($$);
 388         my @cmd = clone_cmd($lei, my $opt = {});
 389         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
 390         do {
 391                 reap_live() while keys(%LIVE) >= $jobs;
 392                 while (keys(%LIVE) < $jobs && @src_edst &&
 393                                 !$lei->{child_error}) {
 394                         my $cmd = [ @$pfx, @cmd, splice(@src_edst, 0, 2) ];
 395                         $lei->qerr("# @$cmd");
 396                         $LIVE{spawn($cmd, undef, $opt)} = [ \&reap_clone,
 397                                                         $lei, $cmd, $fini ];
 398                 }
 399         } while (@src_edst && !$lei->{child_error});
 400 }
 401
 402 sub decode_manifest ($$$) {
 403         my ($fh, $fn, $uri) = @_;
 404         my $js;
 405         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 406         gunzip(\$gz => \$js, MultiStream => 1) or
 407                 die "gunzip($uri): $GunzipError\n";
 408         my $m = eval { PublicInbox::Config->json->decode($js) };
 409         die "$uri: error decoding `$js': $@\n" if $@;
 410         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 411         $m;
 412 }
 413
 414 sub multi_inbox ($$$) {
 415         my ($self, $path, $m) = @_;
 416         my $incl = $self->{lei}->{opt}->{include};
 417         my $excl = $self->{lei}->{opt}->{exclude};
 418
 419         # assuming everything not v2 is v1, for now
 420         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 421         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 422         my $v2 = {};
 423
 424         for (@v2_epochs) {
 425                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 426                 push @{$v2->{$1}}, $_;
 427         }
 428         my $n = scalar(keys %$v2) + scalar(@v1);
 429         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 430         if (defined $incl) {
 431                 my $re = '(?:'.join('|', map {
 432                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E\z/
 433                         } @$incl).')';
 434                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 435                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 436                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 437                 @v1 = grep(/$re/, @v1);
 438         }
 439         if (defined $excl) {
 440                 my $re = '(?:'.join('|', map {
 441                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E\z/
 442                         } @$excl).')';
 443                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 444                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 445                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 446                 @v1 = grep(!/$re/, @v1);
 447         }
 448         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 449         $ret->{v1} = \@v1 if @v1;
 450         $ret->{v2} = $v2 if keys %$v2;
 451         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 452                                 join("\n\t", sort @orig)
 453                         : "Nothing available to clone\n";
 454         my $path_pfx = '';
 455
 456         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 457         if (@v2_epochs) {
 458                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 459                                 @v2_epochs) == @v2_epochs) {
 460                         $$path =~ s!\A(/[^/]+)/!/! or last;
 461                         $path_pfx .= $1;
 462                 }
 463         } elsif (@v1) {
 464                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 465                         $path_pfx .= $1;
 466                 }
 467         }
 468         ($path_pfx, $n, $ret);
 469 }
 470
 471 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 472 sub try_manifest {
 473         my ($self) = @_;
 474         my $uri = URI->new($self->{src});
 475         my $lei = $self->{lei};
 476         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 477         my $path = $uri->path;
 478         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 479         $uri->path($path . '/manifest.js.gz');
 480         my $pdir = $lei->rel2abs($self->{dst});
 481         $pdir =~ s!/[^/]+/?\z!!;
 482         my $ft = File::Temp->new(TEMPLATE => 'm-XXXX',
 483                                 UNLINK => 1, DIR => $pdir, SUFFIX => '.tmp');
 484         my $fn = $ft->filename;
 485         my ($bn) = ($fn =~ m!/([^/]+)\z!);
 486         my $cmd = $curl->for_uri($lei, $uri, '-R', '-o', $bn);
 487         my $opt = { -C => $pdir };
 488         $opt->{$_} = $lei->{$_} for (0..2);
 489         my $cerr = run_reap($lei, $cmd, $opt);
 490         local %LIVE;
 491         if ($cerr) {
 492                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 493                 return $lei->child_error($cerr, "@$cmd failed");
 494         }
 495         my $m = eval { decode_manifest($ft, $fn, $uri) };
 496         if ($@) {
 497                 warn $@;
 498                 return try_scrape($self);
 499         }
 500         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 501         return $lei->child_error(1, $multi) if !ref($multi);
 502         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
 503         if (my $v2 = delete $multi->{v2}) {
 504                 for my $name (sort keys %$v2) {
 505                         my $epochs = delete $v2->{$name};
 506                         my %v2_epochs = map {
 507                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 508                                                 : $path_pfx.$_);
 509                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 510                                 $e // die "no [0-9]+\.git in `$uri'";
 511                                 $e => [ $uri->clone, $_ ];
 512                         } @$epochs;
 513                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 514                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 515                         local $self->{cur_src} = $1;
 516                         local $self->{cur_dst} = $self->{dst};
 517                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 518                                                         git/[0-9]+\.git\z!x) {
 519                                 $self->{cur_dst} .= "/$1";
 520                         }
 521                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 522 E: `$self->{cur_dst}' must not contain newline
 523 EOM
 524                         clone_v2($self, \%v2_epochs, $m);
 525                         reap_live() while keys(%LIVE) >= $jobs;
 526                         return if $self->{lei}->{child_error};
 527                 }
 528         }
 529         if (my $v1 = delete $multi->{v1}) {
 530                 my $p = $path_pfx.$path;
 531                 chop($p) if substr($p, -1, 1) eq '/';
 532                 $uri->path($p);
 533                 for my $name (@$v1) {
 534                         reap_live() while keys(%LIVE) >= $jobs;
 535                         return if $self->{lei}->{child_error};
 536
 537                         my $task = bless { %$self }, __PACKAGE__;
 538                         $task->{cur_src} = "$uri";
 539                         $task->{cur_dst} = $task->{dst};
 540                         if ($n > 1) {
 541                                 $task->{cur_dst} .= $name;
 542                                 $task->{cur_src} .= $name;
 543                         }
 544                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 545 E: `$task->{cur_dst}' must not contain newline
 546 EOM
 547                         $task->{cur_src} .= '/';
 548                         clone_v1($task, 1);
 549                 }
 550         }
 551         reap_live() while keys(%LIVE);
 552         return if $self->{lei}->{child_error};
 553
 554         if (delete $self->{-culled_manifest}) { # set by clone_v2/-I/--exclude
 555                 # write the smaller manifest if epochs were skipped so
 556                 # users won't have to delete manifest if they +w an
 557                 # epoch they no longer want to skip
 558                 my $json = PublicInbox::Config->json->encode($m);
 559                 my $mtime = (stat($fn))[9];
 560                 gzip(\$json => $fn) or die "gzip: $GzipError";
 561                 utime($mtime, $mtime, $fn) or die "utime(..., $fn): $!";
 562         }
 563         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 564         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 565 }
 566
 567 sub start_clone_url {
 568         my ($self) = @_;
 569         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 570         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 571 }
 572
 573 sub do_mirror { # via wq_io_do
 574         my ($self) = @_;
 575         my $lei = $self->{lei};
 576         umask($lei->{client_umask}) if defined $lei->{client_umask};
 577         eval {
 578                 my $iv = $lei->{opt}->{'inbox-version'};
 579                 if (defined $iv) {
 580                         local %LIVE;
 581                         return clone_v1($self) if $iv == 1;
 582                         return try_scrape($self) if $iv == 2;
 583                         die "bad --inbox-version=$iv\n";
 584                 }
 585                 return start_clone_url($self) if $self->{src} =~ m!://!;
 586                 die "TODO: cloning local directories not supported, yet";
 587         };
 588         $lei->fail($@) if $@;
 589 }
 590
 591 sub start {
 592         my ($cls, $lei, $src, $dst) = @_;
 593         my $self = bless { src => $src, dst => $dst }, $cls;
 594         if ($src =~ m!https?://!) {
 595                 require URI;
 596                 require PublicInbox::LeiCurl;
 597         }
 598         require PublicInbox::Lock;
 599         require PublicInbox::Inbox;
 600         require PublicInbox::Admin;
 601         require PublicInbox::InboxWritable;
 602         $lei->request_umask;
 603         my ($op_c, $ops) = $lei->workers_start($self, 1);
 604         $lei->{wq1} = $self;
 605         $self->wq_io_do('do_mirror', []);
 606         $self->wq_close;
 607         $lei->wait_wq_events($op_c, $ops);
 608 }
 609
 610 sub ipc_atfork_child {
 611         my ($self) = @_;
 612         $self->{lei}->_lei_atfork_child;
 613         $self->SUPER::ipc_atfork_child;
 614 }
 615
 616 sub write_makefile {
 617         my ($dir, $ibx_ver) = @_;
 618         my $f = "$dir/Makefile";
 619         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 620                 print $fh <<EOM or die "print($f) $!";
 621 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 622 # manpage for more information on the format.  This Makefile is
 623 # intended as a familiar wrapper for users unfamiliar with
 624 # public-inbox-* commands.
 625 #
 626 # See the respective manpages for public-inbox-fetch(1),
 627 # public-inbox-index(1), etc for more information on
 628 # some of the commands used by this Makefile.
 629 #
 630 # This Makefile will not be modified nor read by public-inbox,
 631 # so you may edit it freely with your own convenience targets
 632 # and notes.  public-inbox-fetch will recreate it if removed.
 633 EOM
 634                 print $fh <<'EOM' or die "print($f): $!";
 635 # the default target:
 636 help :
 637         @echo Common targets:
 638         @echo '    make fetch        - fetch from remote git repostorie(s)'
 639         @echo '    make update       - fetch and update index '
 640         @echo
 641         @echo Rarely needed targets:
 642         @echo '    make reindex      - may be needed for new features/bugfixes'
 643         @echo '    make compact      - rewrite Xapian storage to save space'
 644
 645 fetch :
 646         public-inbox-fetch
 647 update :
 648         @if ! public-inbox-fetch --exit-code; \
 649         then \
 650                 c=$$?; \
 651                 test $$c -eq 127 && exit 0; \
 652                 exit $$c; \
 653         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
 654         then \
 655                 public-inbox-index; \
 656         else \
 657                 echo 'public-inbox index not initialized'; \
 658                 echo 'see public-inbox-index(1) man page'; \
 659         fi
 660 reindex :
 661         public-inbox-index --reindex
 662 compact :
 663         public-inbox-compact
 664
 665 .PHONY : help fetch update reindex compact
 666 EOM
 667                 close $fh or die "close($f): $!";
 668         } else {
 669                 die "open($f): $!" unless $!{EEXIST};
 670         }
 671 }
 672
 673 1;