lib/PublicInbox/LeiRefreshMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei refresh-mail-sync" drops dangling sync information
   5 # and attempts to detect moved files
   6 package PublicInbox::LeiRefreshMailSync;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC PublicInbox::LeiInput);
  10 use PublicInbox::LeiImport;
  11 use PublicInbox::InboxWritable qw(eml_from_path);
  12 use PublicInbox::Import;
  13
  14 sub folder_missing { # may be called by LeiInput
  15         my ($self, $folder) = @_;
  16         $self->{lms}->forget_folders($folder);
  17 }
  18
  19 sub prune_mdir { # lms->each_src callback
  20         my ($oidbin, $id, $self, $mdir) = @_;
  21         my @try = $$id =~ /:2,[a-zA-Z]*\z/ ? qw(cur new) : qw(new cur);
  22         for (@try) { return if -f "$mdir/$_/$$id" }
  23         # both tries failed
  24         $self->{lms}->clear_src("maildir:$mdir", $id);
  25 }
  26
  27 sub prune_imap { # lms->each_src callback
  28         my ($oidbin, $uid, $self, $uids, $url) = @_;
  29         return if exists $uids->{$uid};
  30         $self->{lms}->clear_src($url, $uid);
  31 }
  32
  33 # detects missed file moves
  34 sub pmdir_cb { # called via LeiPmdir->each_mdir_fn
  35         my ($self, $f, $fl) = @_;
  36         my ($folder, $bn) = ($f =~ m!\A(.+?)/(?:new|cur)/([^/]+)\z!) or
  37                 die "BUG: $f was not from a Maildir?";
  38         substr($folder, 0, 0) = 'maildir:'; # add prefix
  39         return if scalar($self->{lms}->name_oidbin($folder, $bn));
  40         my $eml = eml_from_path($f) // return;
  41         my $oidbin = $self->{lei}->git_oid($eml)->digest;
  42         $self->{lms}->set_src($oidbin, $folder, \$bn);
  43 }
  44
  45 sub input_path_url { # overrides PublicInbox::LeiInput::input_path_url
  46         my ($self, $input, @args) = @_;
  47         if ($input =~ /\Amaildir:(.+)/i) {
  48                 $self->{lms}->each_src($input, \&prune_mdir, $self, $1);
  49                 $self->{lse} //= $self->{lei}->{sto}->search;
  50                 # call pmdir_cb (via maildir_each_file -> each_mdir_fn)
  51                 PublicInbox::LeiInput::input_path_url($self, $input);
  52         } elsif ($input =~ m!\Aimaps?://!i) {
  53                 my $uri = PublicInbox::URIimap->new($input);
  54                 if (my $mic = $self->{lei}->{net}->mic_for_folder($uri)) {
  55                         my $uids = $mic->search('UID 1:*');
  56                         $uids = +{ map { $_ => undef } @$uids };
  57                         $self->{lms}->each_src($$uri, \&prune_imap, $self,
  58                                                 $uids, $$uri)
  59                 } else {
  60                         $self->folder_missing($$uri);
  61                 }
  62         } else { die "BUG: $input not supported" }
  63         $self->{lei}->sto_done_request;
  64 }
  65
  66 sub lei_refresh_mail_sync {
  67         my ($lei, @folders) = @_;
  68         my $sto = $lei->_lei_store or return $lei->fail(<<EOM);
  69 lei/store uninitialized, see lei-import(1)
  70 EOM
  71         my $lms = $lei->lms or return $lei->fail(<<EOM);
  72 lei mail_sync.sqlite3 uninitialized, see lei-import(1)
  73 EOM
  74         if (defined(my $all = $lei->{opt}->{all})) {
  75                 $lms->group2folders($lei, $all, \@folders) or return;
  76                 # TODO: handle NNTP servers which delete messages
  77                 @folders = grep(!m!\Anntps?://!, @folders);
  78         } else {
  79                 $lms->arg2folder($lei, \@folders); # may die
  80         }
  81         $lms->lms_pause; # must be done before fork
  82         $sto->write_prepare($lei);
  83         my $self = bless { missing_ok => 1, lms => $lms }, __PACKAGE__;
  84         $lei->{opt}->{'mail-sync'} = 1; # for prepare_inputs
  85         $self->prepare_inputs($lei, \@folders) or return;
  86         $lei->{-err_type} = 'non-fatal';
  87         $lei->wq1_start($self);
  88 }
  89
  90 sub ipc_atfork_child { # needed for PublicInbox::LeiPmdir
  91         my ($self) = @_;
  92         PublicInbox::LeiInput::input_only_atfork_child($self);
  93         $self->{lms}->lms_write_prepare;
  94         undef;
  95 }
  96
  97 sub _complete_refresh_mail_sync {
  98         my ($lei, @argv) = @_;
  99         my $lms = $lei->lms or return ();
 100         my $match_cb = $lei->complete_url_prepare(\@argv);
 101         my @k = $lms->folders($argv[-1] // undef, 1);
 102         my @m = map { $match_cb->($_) } @k;
 103         @m ? @m : @k
 104 }
 105
 106 no warnings 'once';
 107 *net_merge_all_done = \&PublicInbox::LeiInput::input_only_net_merge_all_done;
 108
 109 1;