lib/PublicInbox/LeiSearch.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # read-only counterpart for PublicInbox::LeiStore
   5 package PublicInbox::LeiSearch;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::ExtSearch); # PublicInbox::Search->reopen
   9 use PublicInbox::Search qw(xap_terms);
  10 use PublicInbox::ContentHash qw(content_digest content_hash);
  11 use PublicInbox::MID qw(mids mids_for_index);
  12
  13 # get combined docid from over.num:
  14 # (not generic Xapian, only works with our sharding scheme)
  15 sub num2docid ($$) {
  16         my ($self, $num) = @_;
  17         my $nshard = $self->{nshard};
  18         ($num - 1) * $nshard + $num % $nshard + 1;
  19 }
  20
  21 sub _msg_kw { # retry_reopen callback
  22         my ($self, $num) = @_;
  23         my $xdb = $self->xdb; # set {nshard} for num2docid;
  24         xap_terms('K', $xdb, num2docid($self, $num));
  25 }
  26
  27 sub msg_keywords { # array or hashref
  28         my ($self, $num) = @_;
  29         $self->retry_reopen(\&_msg_kw, $num);
  30 }
  31
  32 sub _oid_kw { # retry_reopen callback
  33         my ($self, $nums) = @_;
  34         my $xdb = $self->xdb; # set {nshard};
  35         my %kw;
  36         for my $num (@$nums) { # there should only be one...
  37                 my $doc = $xdb->get_document(num2docid($self, $num));
  38                 my $x = xap_terms('K', $doc);
  39                 %kw = (%kw, %$x);
  40         }
  41         \%kw;
  42 }
  43
  44 # returns undef if blob is unknown
  45 sub oid_keywords {
  46         my ($self, $oidhex) = @_;
  47         my @num = $self->over->blob_exists($oidhex) or return;
  48         $self->retry_reopen(\&_oid_kw, \@num);
  49 }
  50
  51 sub _xsmsg_vmd { # retry_reopen
  52         my ($self, $smsg, $want_label) = @_;
  53         my $xdb = $self->xdb; # set {nshard};
  54         my (%kw, %L, $doc, $x);
  55         $kw{flagged} = 1 if delete($smsg->{lei_q_tt_flagged});
  56         my @num = $self->over->blob_exists($smsg->{blob});
  57         for my $num (@num) { # there should only be one...
  58                 $doc = $xdb->get_document(num2docid($self, $num));
  59                 $x = xap_terms('K', $doc);
  60                 %kw = (%kw, %$x);
  61                 if ($want_label) { # JSON/JMAP only
  62                         $x = xap_terms('L', $doc);
  63                         %L = (%L, %$x);
  64                 }
  65         }
  66         $smsg->{kw} = [ sort keys %kw ] if scalar(keys(%kw));
  67         $smsg->{L} = [ sort keys %L ] if scalar(keys(%L));
  68 }
  69
  70 # lookup keywords+labels for external messages
  71 sub xsmsg_vmd {
  72         my ($self, $smsg, $want_label) = @_;
  73         return if $smsg->{kw}; # already set by LeiXSearch->mitem_kw
  74         $self->retry_reopen(\&_xsmsg_vmd, $smsg, $want_label);
  75 }
  76
  77 # when a message has no Message-IDs at all, this is needed for
  78 # unsent Draft messages, at least
  79 sub content_key ($) {
  80         my ($eml) = @_;
  81         my $dig = content_digest($eml);
  82         my $chash = $dig->clone->digest;
  83         my $mids = mids_for_index($eml);
  84         unless (@$mids) {
  85                 $eml->{-lei_fake_mid} = $mids->[0] =
  86                                 PublicInbox::Import::digest2mid($dig, $eml, 0);
  87         }
  88         ($chash, $mids);
  89 }
  90
  91 sub _cmp_1st { # git->cat_async callback
  92         my ($bref, $oid, $type, $size, $cmp) = @_;
  93         # cmp: [chash, xoids, smsg, lms]
  94         $bref //= $cmp->[3] ? $cmp->[3]->local_blob($oid, 1) : undef;
  95         if ($bref && content_hash(PublicInbox::Eml->new($bref)) eq $cmp->[0]) {
  96                 $cmp->[1]->{$oid} = $cmp->[2]->{num};
  97         }
  98 }
  99
 100 # returns { OID => num } mapping for $eml matches
 101 # The `num' hash value only makes sense from LeiSearch itself
 102 # and is nonsense from the PublicInbox::LeiALE subclass
 103 sub xoids_for {
 104         my ($self, $eml, $min) = @_;
 105         my ($chash, $mids) = content_key($eml);
 106         my @overs = ($self->over // $self->overs_all);
 107         my $git = $self->git;
 108         my $xoids = {};
 109         # no lms when used via {ale}:
 110         my $lms = $self->{-lms_ro} //= lms($self) if defined($self->{topdir});
 111         for my $mid (@$mids) {
 112                 for my $o (@overs) {
 113                         my ($id, $prev);
 114                         while (my $cur = $o->next_by_mid($mid, \$id, \$prev)) {
 115                                 next if $cur->{bytes} == 0 ||
 116                                         $xoids->{$cur->{blob}};
 117                                 $git->cat_async($cur->{blob}, \&_cmp_1st,
 118                                                 [$chash, $xoids, $cur, $lms]);
 119                                 if ($min && scalar(keys %$xoids) >= $min) {
 120                                         $git->cat_async_wait;
 121                                         return $xoids;
 122                                 }
 123                         }
 124                 }
 125         }
 126         $git->cat_async_wait;
 127         scalar(keys %$xoids) ? $xoids : undef;
 128 }
 129
 130 # returns true if $eml is indexed by lei/store and keywords don't match
 131 sub kw_changed {
 132         my ($self, $eml, $new_kw_sorted, $docids) = @_;
 133         if ($eml) {
 134                 my $xoids = xoids_for($self, $eml) // return;
 135                 $docids //= [];
 136                 @$docids = sort { $a <=> $b } values %$xoids;
 137         }
 138         my $cur_kw = eval { msg_keywords($self, $docids->[0]) };
 139         die "E: #$docids->[0] keyword lookup failure: $@\n" if $@;
 140
 141         # RFC 5550 sec 5.9 on the $Forwarded keyword states:
 142         # "Once set, the flag SHOULD NOT be cleared"
 143         if (exists($cur_kw->{forwarded}) &&
 144                         !grep(/\Aforwarded\z/, @$new_kw_sorted)) {
 145                 delete $cur_kw->{forwarded};
 146         }
 147         $cur_kw = join("\0", sort keys %$cur_kw);
 148         join("\0", @$new_kw_sorted) eq $cur_kw ? 0 : 1;
 149 }
 150
 151 sub all_terms {
 152         my ($self, $pfx) = @_;
 153         my $xdb = $self->xdb;
 154         my $cur = $xdb->allterms_begin($pfx);
 155         my $end = $xdb->allterms_end($pfx);
 156         my %ret;
 157         for (; $cur != $end; $cur++) {
 158                 my $tn = $cur->get_termname;
 159                 index($tn, $pfx) == 0 and
 160                         $ret{substr($tn, length($pfx))} = undef;
 161         }
 162         wantarray ? (sort keys %ret) : \%ret;
 163 }
 164
 165 sub qparse_new {
 166         my ($self) = @_;
 167         my $qp = $self->SUPER::qparse_new; # PublicInbox::Search
 168         $qp->add_boolean_prefix('kw', 'K');
 169         $qp->add_boolean_prefix('L', 'L');
 170         $qp
 171 }
 172
 173 sub lms {
 174         my ($self) = @_;
 175         require PublicInbox::LeiMailSync;
 176         my $f = "$self->{topdir}/mail_sync.sqlite3";
 177         -f $f ? PublicInbox::LeiMailSync->new($f) : undef;
 178 }
 179
 180 # allow SolverGit->resolve_patch to work with "lei index"
 181 sub smsg_eml {
 182         my ($self, $smsg) = @_;
 183         PublicInbox::Inbox::smsg_eml($self, $smsg) // do {
 184                 my $lms = lms($self);
 185                 my $bref = $lms ? $lms->local_blob($smsg->{blob}, 1) : undef;
 186                 $bref ? PublicInbox::Eml->new($bref) : undef;
 187         };
 188 }
 189
 190 1;