lib/PublicInbox/LeiStore.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Local storage (cache/memo) for lei(1), suitable for personal/private
   5 # mail iff on encrypted device/FS.  Based on v2, but only deduplicates
   6 # git storage based on git OID (index deduplication is done in ContentHash)
   7 #
   8 # for xref3, the following are constant: $eidx_key = '.', $xnum = -1
   9 #
  10 # We rely on the synchronous IPC API for this in lei-daemon and
  11 # multiple lei clients to write to it at once.  This allows the
  12 # lei/store IPC process to be decoupled from network latency in
  13 # lei WQ workers.
  14 package PublicInbox::LeiStore;
  15 use strict;
  16 use v5.10.1;
  17 use parent qw(PublicInbox::Lock PublicInbox::IPC);
  18 use PublicInbox::ExtSearchIdx;
  19 use PublicInbox::Eml;
  20 use PublicInbox::Import;
  21 use PublicInbox::InboxWritable qw(eml_from_path);
  22 use PublicInbox::V2Writable;
  23 use PublicInbox::ContentHash qw(content_hash);
  24 use PublicInbox::MID qw(mids);
  25 use PublicInbox::LeiSearch;
  26 use PublicInbox::MDA;
  27 use PublicInbox::Spawn qw(spawn);
  28 use PublicInbox::MdirReader;
  29 use PublicInbox::LeiToMail;
  30 use File::Temp ();
  31 use POSIX ();
  32 use IO::Handle (); # ->autoflush
  33 use Sys::Syslog qw(syslog openlog);
  34 use Errno qw(EEXIST ENOENT);
  35 use PublicInbox::Syscall qw(rename_noreplace);
  36
  37 sub new {
  38         my (undef, $dir, $opt) = @_;
  39         my $eidx = PublicInbox::ExtSearchIdx->new($dir, $opt);
  40         my $self = bless { priv_eidx => $eidx }, __PACKAGE__;
  41         eidx_init($self)->done if $opt->{creat};
  42         $self;
  43 }
  44
  45 sub git { $_[0]->{priv_eidx}->git } # read-only
  46
  47 sub packing_factor { $PublicInbox::V2Writable::PACKING_FACTOR }
  48
  49 sub rotate_bytes {
  50         $_[0]->{rotate_bytes} // ((1024 * 1024 * 1024) / $_[0]->packing_factor)
  51 }
  52
  53 sub git_ident ($) {
  54         my ($git) = @_;
  55         my $rdr = {};
  56         open $rdr->{2}, '>', '/dev/null' or die "open /dev/null: $!";
  57         chomp(my $i = $git->qx([qw(var GIT_COMMITTER_IDENT)], undef, $rdr));
  58         $i =~ /\A(.+) <([^>]+)> [0-9]+ [-\+]?[0-9]+$/ and return ($1, $2);
  59         my ($user, undef, undef, undef, undef, undef, $gecos) = getpwuid($<);
  60         ($user) = (($user // $ENV{USER} // '') =~ /([\w\-\.\+]+)/);
  61         $user //= 'lei-user';
  62         ($gecos) = (($gecos // '') =~ /([\w\-\.\+ \t]+)/);
  63         $gecos //= 'lei user';
  64         require Sys::Hostname;
  65         my ($host) = (Sys::Hostname::hostname() =~ /([\w\-\.]+)/);
  66         $host //= 'localhost';
  67         ($gecos, "$user\@$host")
  68 }
  69
  70 sub importer {
  71         my ($self) = @_;
  72         my $max;
  73         my $im = $self->{im};
  74         if ($im) {
  75                 return $im if $im->{bytes_added} < $self->rotate_bytes;
  76
  77                 delete $self->{im};
  78                 $im->done;
  79                 undef $im;
  80                 $self->checkpoint;
  81                 $max = $self->{priv_eidx}->{mg}->git_epochs + 1;
  82         }
  83         my (undef, $tl) = eidx_init($self); # acquire lock
  84         $max //= $self->{priv_eidx}->{mg}->git_epochs;
  85         while (1) {
  86                 my $latest = $self->{priv_eidx}->{mg}->add_epoch($max);
  87                 my $git = PublicInbox::Git->new($latest);
  88                 $self->done; # unlock
  89                 # re-acquire lock, update alternates for new epoch
  90                 (undef, $tl) = eidx_init($self);
  91                 my $packed_bytes = $git->packed_bytes;
  92                 my $unpacked_bytes = $packed_bytes / $self->packing_factor;
  93                 if ($unpacked_bytes >= $self->rotate_bytes) {
  94                         $max++;
  95                         next;
  96                 }
  97                 my ($n, $e) = git_ident($git);
  98                 $self->{im} = $im = PublicInbox::Import->new($git, $n, $e);
  99                 $im->{bytes_added} = int($packed_bytes / $self->packing_factor);
 100                 $im->{lock_path} = undef;
 101                 $im->{path_type} = 'v2';
 102                 return $im;
 103         }
 104 }
 105
 106 sub search {
 107         PublicInbox::LeiSearch->new($_[0]->{priv_eidx}->{topdir});
 108 }
 109
 110 # follows the stderr file
 111 sub _tail_err {
 112         my ($self) = @_;
 113         print { $self->{-err_wr} } readline($self->{-tmp_err});
 114 }
 115
 116 sub eidx_init {
 117         my ($self) = @_;
 118         my $eidx = $self->{priv_eidx};
 119         my $tl = wantarray && $self->{-err_wr} ?
 120                         PublicInbox::OnDestroy->new($$, \&_tail_err, $self) :
 121                         undef;
 122         $eidx->idx_init({-private => 1}); # acquires lock
 123         wantarray ? ($eidx, $tl) : $eidx;
 124 }
 125
 126 sub _docids_for ($$) {
 127         my ($self, $eml) = @_;
 128         my %docids;
 129         my $eidx = $self->{priv_eidx};
 130         my ($chash, $mids) = PublicInbox::LeiSearch::content_key($eml);
 131         my $oidx = $eidx->{oidx};
 132         my $im = $self->{im};
 133         for my $mid (@$mids) {
 134                 my ($id, $prev);
 135                 while (my $cur = $oidx->next_by_mid($mid, \$id, \$prev)) {
 136                         next if $cur->{bytes} == 0; # external-only message
 137                         my $oid = $cur->{blob};
 138                         my $docid = $cur->{num};
 139                         my $bref = $im ? $im->cat_blob($oid) : undef;
 140                         $bref //= $eidx->git->cat_file($oid) //
 141                                 _lms_rw($self)->local_blob($oid, 1) // do {
 142                                 warn "W: $oid (#$docid) <$mid> not found\n";
 143                                 next;
 144                         };
 145                         local $self->{current_info} = $oid;
 146                         my $x = PublicInbox::Eml->new($bref);
 147                         $docids{$docid} = $docid if content_hash($x) eq $chash;
 148                 }
 149         }
 150         sort { $a <=> $b } values %docids;
 151 }
 152
 153 # n.b. similar to LeiExportKw->export_kw_md, but this is for a single eml
 154 sub export1_kw_md ($$$$$) {
 155         my ($self, $mdir, $bn, $oidbin, $vmdish) = @_; # vmd/vmd_mod
 156         my $orig = $bn;
 157         my (@try, $unkn, $kw);
 158         if ($bn =~ s/:2,([a-zA-Z]*)\z//) {
 159                 ($kw, $unkn) = PublicInbox::MdirReader::flags2kw($1);
 160                 if (my $set = $vmdish->{kw}) {
 161                         $kw = $set;
 162                 } elsif (my $add = $vmdish->{'+kw'}) {
 163                         @$kw{@$add} = ();
 164                 } elsif (my $del = $vmdish->{-kw}) {
 165                         delete @$kw{@$del};
 166                 } # else no changes...
 167                 @try = qw(cur new);
 168         } else { # no keywords, yet, could be in new/
 169                 @try = qw(new cur);
 170                 $unkn = [];
 171                 if (my $set = $vmdish->{kw}) {
 172                         $kw = $set;
 173                 } elsif (my $add = $vmdish->{'+kw'}) {
 174                         @$kw{@$add} = (); # auto-vivify
 175                 } else { # ignore $vmdish->{-kw}
 176                         $kw = [];
 177                 }
 178         }
 179         $kw = [ keys %$kw ] if ref($kw) eq 'HASH';
 180         $bn .= ':2,'. PublicInbox::LeiToMail::kw2suffix($kw, @$unkn);
 181         return if $orig eq $bn; # no change
 182
 183         # we use link(2) + unlink(2) since rename(2) may
 184         # inadvertently clobber if the "uniquefilename" part wasn't
 185         # actually unique.
 186         my $dst = "$mdir/cur/$bn";
 187         for my $d (@try) {
 188                 my $src = "$mdir/$d/$orig";
 189                 if (rename_noreplace($src, $dst)) {
 190                         # TODO: verify oidbin?
 191                         $self->{lms}->mv_src("maildir:$mdir",
 192                                         $oidbin, \$orig, $bn);
 193                         return;
 194                 } elsif ($! == EEXIST) { # lost race with "lei export-kw"?
 195                         return;
 196                 } elsif ($! != ENOENT) {
 197                         syslog('warning', "rename_noreplace($src -> $dst): $!");
 198                 }
 199         }
 200         for (@try) { return if -e "$mdir/$_/$orig" };
 201         $self->{lms}->clear_src("maildir:$mdir", \$orig);
 202 }
 203
 204 sub sto_export_kw ($$$) {
 205         my ($self, $docid, $vmdish) = @_; # vmdish (vmd or vmd_mod)
 206         my ($eidx, $tl) = eidx_init($self);
 207         my $lms = _lms_rw($self) // return;
 208         my $xr3 = $eidx->{oidx}->get_xref3($docid, 1);
 209         for my $row (@$xr3) {
 210                 my (undef, undef, $oidbin) = @$row;
 211                 my $locs = $lms->locations_for($oidbin) // next;
 212                 while (my ($loc, $ids) = each %$locs) {
 213                         if ($loc =~ s!\Amaildir:!!i) {
 214                                 for my $id (@$ids) {
 215                                         export1_kw_md($self, $loc, $id,
 216                                                         $oidbin, $vmdish);
 217                                 }
 218                         }
 219                         # TODO: IMAP
 220                 }
 221         }
 222 }
 223
 224 # vmd = { kw => [ qw(seen ...) ], L => [ qw(inbox ...) ] }
 225 sub set_eml_vmd {
 226         my ($self, $eml, $vmd, $docids) = @_;
 227         my ($eidx, $tl) = eidx_init($self);
 228         $docids //= [ _docids_for($self, $eml) ];
 229         for my $docid (@$docids) {
 230                 $eidx->idx_shard($docid)->ipc_do('set_vmd', $docid, $vmd);
 231                 sto_export_kw($self, $docid, $vmd);
 232         }
 233         $docids;
 234 }
 235
 236 sub add_eml_vmd {
 237         my ($self, $eml, $vmd) = @_;
 238         my ($eidx, $tl) = eidx_init($self);
 239         my @docids = _docids_for($self, $eml);
 240         for my $docid (@docids) {
 241                 $eidx->idx_shard($docid)->ipc_do('add_vmd', $docid, $vmd);
 242         }
 243         \@docids;
 244 }
 245
 246 sub remove_eml_vmd { # remove just the VMD
 247         my ($self, $eml, $vmd) = @_;
 248         my ($eidx, $tl) = eidx_init($self);
 249         my @docids = _docids_for($self, $eml);
 250         for my $docid (@docids) {
 251                 $eidx->idx_shard($docid)->ipc_do('remove_vmd', $docid, $vmd);
 252         }
 253         \@docids;
 254 }
 255
 256 sub _lms_rw ($) { # it is important to have eidx processes open before lms
 257         my ($self) = @_;
 258         $self->{lms} // do {
 259                 require PublicInbox::LeiMailSync;
 260                 my ($eidx, $tl) = eidx_init($self);
 261                 my $f = "$self->{priv_eidx}->{topdir}/mail_sync.sqlite3";
 262                 my $lms = PublicInbox::LeiMailSync->new($f);
 263                 $lms->lms_write_prepare;
 264                 $self->{lms} = $lms;
 265         };
 266 }
 267
 268 sub _remove_if_local { # git->cat_async arg
 269         my ($bref, $oidhex, $type, $size, $self) = @_;
 270         $self->{im}->remove($bref) if $bref;
 271 }
 272
 273 sub remove_docids ($;@) {
 274         my ($self, @docids) = @_;
 275         my $eidx = eidx_init($self);
 276         for my $docid (@docids) {
 277                 $eidx->remove_doc($docid);
 278                 $eidx->{oidx}->{dbh}->do(<<EOF, undef, $docid);
 279 DELETE FROM xref3 WHERE docid = ?
 280 EOF
 281         }
 282 }
 283
 284 # remove the entire message from the index, does not touch mail_sync.sqlite3
 285 sub remove_eml {
 286         my ($self, $eml) = @_;
 287         my $im = $self->importer; # may create new epoch
 288         my ($eidx, $tl) = eidx_init($self);
 289         my $oidx = $eidx->{oidx};
 290         my @docids = _docids_for($self, $eml);
 291         my $git = $eidx->git;
 292         for my $docid (@docids) {
 293                 my $xr3 = $oidx->get_xref3($docid, 1);
 294                 for my $row (@$xr3) {
 295                         my (undef, undef, $oidbin) = @$row;
 296                         my $oidhex = unpack('H*', $oidbin);
 297                         $git->cat_async($oidhex, \&_remove_if_local, $self);
 298                 }
 299         }
 300         $git->async_wait_all;
 301         remove_docids($self, @docids);
 302         \@docids;
 303 }
 304
 305 sub oid2docid ($$) {
 306         my ($self, $oid) = @_;
 307         my $eidx = eidx_init($self);
 308         my ($docid, @cull) = $eidx->{oidx}->blob_exists($oid);
 309         if (@cull) { # fixup old bugs...
 310                 warn <<EOF;
 311 W: $oid indexed as multiple docids: $docid @cull, culling to fixup old bugs
 312 EOF
 313                 remove_docids($self, @cull);
 314         }
 315         $docid;
 316 }
 317
 318 sub _add_vmd ($$$$) {
 319         my ($self, $idx, $docid, $vmd) = @_;
 320         $idx->ipc_do('add_vmd', $docid, $vmd);
 321         sto_export_kw($self, $docid, $vmd);
 322 }
 323
 324 sub _docids_and_maybe_kw ($$) {
 325         my ($self, $docids) = @_;
 326         return $docids unless wantarray;
 327         my $kw = {};
 328         for my $num (@$docids) { # likely only 1, unless ContentHash changes
 329                 # can't use ->search->msg_keywords on uncommitted docs
 330                 my $idx = $self->{priv_eidx}->idx_shard($num);
 331                 my $tmp = eval { $idx->ipc_do('get_terms', 'K', $num) };
 332                 if ($@) { warn "#$num get_terms: $@" }
 333                 else { @$kw{keys %$tmp} = values(%$tmp) };
 334         }
 335         ($docids, [ sort keys %$kw ]);
 336 }
 337
 338 sub _reindex_1 { # git->cat_async callback
 339         my ($bref, $hex, $type, $size, $smsg) = @_;
 340         my $self = delete $smsg->{-sto};
 341         my ($eidx, $tl) = eidx_init($self);
 342         $bref //= _lms_rw($self)->local_blob($hex, 1);
 343         if ($bref) {
 344                 my $eml = PublicInbox::Eml->new($bref);
 345                 $smsg->{-merge_vmd} = 1; # preserve existing keywords
 346                 $eidx->idx_shard($smsg->{num})->index_eml($eml, $smsg);
 347         } else {
 348                 warn("E: $type $hex\n");
 349         }
 350 }
 351
 352 sub reindex_art {
 353         my ($self, $art) = @_;
 354         my ($eidx, $tl) = eidx_init($self);
 355         my $smsg = $eidx->{oidx}->get_art($art) // return;
 356         return if $smsg->{bytes} == 0; # external-only message
 357         $smsg->{-sto} = $self;
 358         $eidx->git->cat_async($smsg->{blob} // die("no blob (#$art)"),
 359                                 \&_reindex_1, $smsg);
 360 }
 361
 362 sub reindex_done {
 363         my ($self) = @_;
 364         my ($eidx, $tl) = eidx_init($self);
 365         $eidx->git->async_wait_all;
 366         # ->done to be called via sto_done_request
 367 }
 368
 369 sub add_eml {
 370         my ($self, $eml, $vmd, $xoids) = @_;
 371         my $im = $self->{-fake_im} // $self->importer; # may create new epoch
 372         my ($eidx, $tl) = eidx_init($self);
 373         my $oidx = $eidx->{oidx}; # PublicInbox::Import::add checks this
 374         my $smsg = bless { -oidx => $oidx }, 'PublicInbox::Smsg';
 375         $smsg->{-eidx_git} = $eidx->git if !$self->{-fake_im};
 376         my $im_mark = $im->add($eml, undef, $smsg);
 377         if ($vmd && $vmd->{sync_info}) {
 378                 _lms_rw($self)->set_src($smsg->oidbin, @{$vmd->{sync_info}});
 379         }
 380         unless ($im_mark) { # duplicate blob returns undef
 381                 return unless wantarray;
 382                 my @docids = $oidx->blob_exists($smsg->{blob});
 383                 return _docids_and_maybe_kw $self, \@docids;
 384         }
 385
 386         local $self->{current_info} = $smsg->{blob};
 387         my $vivify_xvmd = delete($smsg->{-vivify_xvmd}) // []; # exact matches
 388         if ($xoids) { # fuzzy matches from externals in ale->xoids_for
 389                 delete $xoids->{$smsg->{blob}}; # added later
 390                 if (scalar keys %$xoids) {
 391                         my %docids = map { $_ => 1 } @$vivify_xvmd;
 392                         for my $oid (keys %$xoids) {
 393                                 my $docid = oid2docid($self, $oid);
 394                                 $docids{$docid} = $docid if defined($docid);
 395                         }
 396                         @$vivify_xvmd = sort { $a <=> $b } keys(%docids);
 397                 }
 398         }
 399         if (@$vivify_xvmd) { # docids list
 400                 $xoids //= {};
 401                 $xoids->{$smsg->{blob}} = 1;
 402                 for my $docid (@$vivify_xvmd) {
 403                         my $cur = $oidx->get_art($docid);
 404                         my $idx = $eidx->idx_shard($docid);
 405                         if (!$cur || $cur->{bytes} == 0) { # really vivifying
 406                                 $smsg->{num} = $docid;
 407                                 $oidx->add_overview($eml, $smsg);
 408                                 $smsg->{-merge_vmd} = 1;
 409                                 $idx->index_eml($eml, $smsg);
 410                         } else { # lse fuzzy hit off ale
 411                                 $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 412                         }
 413                         for my $oid (keys %$xoids) {
 414                                 $oidx->add_xref3($docid, -1, $oid, '.');
 415                         }
 416                         _add_vmd($self, $idx, $docid, $vmd) if $vmd;
 417                 }
 418                 _docids_and_maybe_kw $self, $vivify_xvmd;
 419         } elsif (my @docids = _docids_for($self, $eml)) {
 420                 # fuzzy match from within lei/store
 421                 for my $docid (@docids) {
 422                         my $idx = $eidx->idx_shard($docid);
 423                         $oidx->add_xref3($docid, -1, $smsg->{blob}, '.');
 424                         # add_eidx_info for List-Id
 425                         $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 426                         _add_vmd($self, $idx, $docid, $vmd) if $vmd;
 427                 }
 428                 _docids_and_maybe_kw $self, \@docids;
 429         } else { # totally new message, no keywords
 430                 delete $smsg->{-oidx}; # for IPC-friendliness
 431                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 432                 $oidx->add_overview($eml, $smsg);
 433                 $oidx->add_xref3($smsg->{num}, -1, $smsg->{blob}, '.');
 434                 my $idx = $eidx->idx_shard($smsg->{num});
 435                 $idx->index_eml($eml, $smsg);
 436                 _add_vmd($self, $idx, $smsg->{num}, $vmd) if $vmd;
 437                 wantarray ? ($smsg, []) : $smsg;
 438         }
 439 }
 440
 441 sub set_eml {
 442         my ($self, $eml, $vmd, $xoids) = @_;
 443         add_eml($self, $eml, $vmd, $xoids) //
 444                 set_eml_vmd($self, $eml, $vmd);
 445 }
 446
 447 sub index_eml_only {
 448         my ($self, $eml, $vmd, $xoids) = @_;
 449         require PublicInbox::FakeImport;
 450         local $self->{-fake_im} = PublicInbox::FakeImport->new;
 451         set_eml($self, $eml, $vmd, $xoids);
 452 }
 453
 454 # store {kw} / {L} info for a message which is only in an external
 455 sub _external_only ($$$) {
 456         my ($self, $xoids, $eml) = @_;
 457         my $eidx = $self->{priv_eidx};
 458         my $oidx = $eidx->{oidx} // die 'BUG: {oidx} missing';
 459         my $smsg = bless { blob => '' }, 'PublicInbox::Smsg';
 460         $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 461         # save space for an externals-only message
 462         my $hdr = $eml->header_obj;
 463         $smsg->populate($hdr); # sets lines == 0
 464         $smsg->{bytes} = 0;
 465         delete @$smsg{qw(From Subject)};
 466         $smsg->{to} = $smsg->{cc} = $smsg->{from} = '';
 467         $oidx->add_overview($hdr, $smsg); # subject+references for threading
 468         $smsg->{subject} = '';
 469         for my $oid (keys %$xoids) {
 470                 $oidx->add_xref3($smsg->{num}, -1, $oid, '.');
 471         }
 472         my $idx = $eidx->idx_shard($smsg->{num});
 473         $idx->index_eml(PublicInbox::Eml->new("\n\n"), $smsg);
 474         ($smsg, $idx);
 475 }
 476
 477 sub update_xvmd {
 478         my ($self, $xoids, $eml, $vmd_mod) = @_;
 479         my ($eidx, $tl) = eidx_init($self);
 480         my $oidx = $eidx->{oidx};
 481         my %seen;
 482         for my $oid (keys %$xoids) {
 483                 my $docid = oid2docid($self, $oid) // next;
 484                 delete $xoids->{$oid};
 485                 next if $seen{$docid}++;
 486                 my $idx = $eidx->idx_shard($docid);
 487                 $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 488                 sto_export_kw($self, $docid, $vmd_mod);
 489         }
 490         return unless scalar(keys(%$xoids));
 491
 492         # see if it was indexed, but with different OID(s)
 493         if (my @docids = _docids_for($self, $eml)) {
 494                 for my $docid (@docids) {
 495                         next if $seen{$docid};
 496                         for my $oid (keys %$xoids) {
 497                                 $oidx->add_xref3($docid, -1, $oid, '.');
 498                         }
 499                         my $idx = $eidx->idx_shard($docid);
 500                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 501                         sto_export_kw($self, $docid, $vmd_mod);
 502                 }
 503                 return;
 504         }
 505         # totally unseen
 506         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 507         $idx->ipc_do('update_vmd', $smsg->{num}, $vmd_mod);
 508         sto_export_kw($self, $smsg->{num}, $vmd_mod);
 509 }
 510
 511 # set or update keywords for external message, called via ipc_do
 512 sub set_xvmd {
 513         my ($self, $xoids, $eml, $vmd) = @_;
 514
 515         my ($eidx, $tl) = eidx_init($self);
 516         my $oidx = $eidx->{oidx};
 517         my %seen;
 518
 519         # see if we can just update existing docs
 520         for my $oid (keys %$xoids) {
 521                 my $docid = oid2docid($self, $oid) // next;
 522                 delete $xoids->{$oid}; # all done with this oid
 523                 next if $seen{$docid}++;
 524                 my $idx = $eidx->idx_shard($docid);
 525                 $idx->ipc_do('set_vmd', $docid, $vmd);
 526                 sto_export_kw($self, $docid, $vmd);
 527         }
 528         return unless scalar(keys(%$xoids));
 529
 530         # n.b. we don't do _docids_for here, we expect the caller
 531         # already checked $lse->kw_changed before calling this sub
 532
 533         return unless (@{$vmd->{kw} // []}) || (@{$vmd->{L} // []});
 534         # totally unseen:
 535         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 536         $idx->ipc_do('add_vmd', $smsg->{num}, $vmd);
 537         sto_export_kw($self, $smsg->{num}, $vmd);
 538 }
 539
 540 sub checkpoint {
 541         my ($self, $wait) = @_;
 542         if (my $im = $self->{im}) {
 543                 $wait ? $im->barrier : $im->checkpoint;
 544         }
 545         delete $self->{lms};
 546         $self->{priv_eidx}->checkpoint($wait);
 547 }
 548
 549 sub xchg_stderr {
 550         my ($self) = @_;
 551         _tail_err($self) if $self->{-err_wr};
 552         my $dir = $self->{priv_eidx}->{topdir};
 553         return unless -e $dir;
 554         my $old = delete $self->{-tmp_err};
 555         my $pfx = POSIX::strftime('%Y%m%d%H%M%S', gmtime(time));
 556         my $err = File::Temp->new(TEMPLATE => "$pfx.$$.err-XXXX",
 557                                 SUFFIX => '.err', DIR => $dir);
 558         open STDERR, '>>', $err->filename or die "dup2: $!";
 559         STDERR->autoflush(1); # shared with shard subprocesses
 560         $self->{-tmp_err} = $err; # separate file description for RO access
 561         undef;
 562 }
 563
 564 sub done {
 565         my ($self, $sock_ref) = @_;
 566         my $err = '';
 567         if (my $im = delete($self->{im})) {
 568                 eval { $im->done };
 569                 if ($@) {
 570                         $err .= "import done: $@\n";
 571                         warn $err;
 572                 }
 573         }
 574         delete $self->{lms};
 575         $self->{priv_eidx}->done; # V2Writable::done
 576         xchg_stderr($self);
 577         die $err if $err;
 578 }
 579
 580 sub ipc_atfork_child {
 581         my ($self) = @_;
 582         my $lei = $self->{lei};
 583         $lei->_lei_atfork_child(1) if $lei;
 584         xchg_stderr($self);
 585         if (my $to_close = delete($self->{to_close})) {
 586                 close($_) for @$to_close;
 587         }
 588         openlog('lei/store', 'pid,nowait,nofatal,ndelay', 'user');
 589         $self->SUPER::ipc_atfork_child;
 590 }
 591
 592 sub recv_and_run {
 593         my ($self, @args) = @_;
 594         local $PublicInbox::DS::in_loop = 0; # waitpid synchronously
 595         $self->SUPER::recv_and_run(@args);
 596 }
 597
 598 sub _sto_atexit { # dwaitpid callback
 599         my ($args, $pid) = @_;
 600         my $self = $args->[0];
 601         warn "lei/store PID:$pid died \$?=$?\n" if $?;
 602 }
 603
 604 sub write_prepare {
 605         my ($self, $lei) = @_;
 606         $lei // die 'BUG: $lei not passed';
 607         unless ($self->{-ipc_req}) {
 608                 my $dir = $lei->store_path;
 609                 substr($dir, -length('/lei/store'), 10, '');
 610                 pipe(my ($r, $w)) or die "pipe: $!";
 611                 $w->autoflush(1);
 612                 # Mail we import into lei are private, so headers filtered out
 613                 # by -mda for public mail are not appropriate
 614                 local @PublicInbox::MDA::BAD_HEADERS = ();
 615                 $self->wq_workers_start("lei/store $dir", 1, $lei->oldset, {
 616                                         lei => $lei,
 617                                         -err_wr => $w,
 618                                         to_close => [ $r ],
 619                                 });
 620                 $self->wq_wait_async(\&_sto_atexit); # outlives $lei
 621                 require PublicInbox::LeiStoreErr;
 622                 PublicInbox::LeiStoreErr->new($r, $lei);
 623         }
 624         $lei->{sto} = $self;
 625 }
 626
 627 1;