lib/PublicInbox/Linkify.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # two-step linkification.
   5 # intended usage is in the following order:
   6 #
   7 #   linkify_1
   8 #   <escape unsafe chars for HTML>
   9 #   linkify_2
  10 #
  11 # Maybe this could be done more efficiently...
  12 package PublicInbox::Linkify;
  13 use strict;
  14 use warnings;
  15 use Digest::SHA qw/sha1_hex/;
  16
  17 my $SALT = rand;
  18 my $LINK_RE = qr{(\()?\b((?:ftps?|https?|nntps?|gopher)://
  19                  [\@:\w\.-]+(?:/
  20                  (?:[a-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@/%]*)
  21                  (?:\?[a-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@/%]+)?
  22                  (?:\#[a-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@/%\?]+)?
  23                  )?
  24                 )}xi;
  25
  26 sub new { bless {}, $_[0] }
  27
  28 sub linkify_1 {
  29         $_[1] =~ s^$LINK_RE^
  30                 my $beg = $1 || '';
  31                 my $url = $2;
  32                 my $end = '';
  33
  34                 # it's fairly common to end URLs in messages with
  35                 # '.', ',' or ';' to denote the end of a statement;
  36                 # assume the intent was to end the statement/sentence
  37                 # in English
  38                 # Markdown compatibility:
  39                 if ($beg eq '(') {
  40                         if ($url =~ s/(\)[\.,;]?)\z//) {
  41                                 $end = $1;
  42                         }
  43                 } elsif ($url =~ s/([\.,;])\z//) {
  44                         $end = $1;
  45                 } elsif ($url !~ /\(/ && $url =~ s/\)\z//) {
  46                         $end = ')';
  47                 }
  48
  49                 # salt this, as this could be exploited to show
  50                 # links in the HTML which don't show up in the raw mail.
  51                 my $key = sha1_hex($url . $SALT);
  52
  53                 # only escape ampersands, others do not match LINK_RE
  54                 $url =~ s/&/&#38;/g;
  55                 $_[0]->{$key} = $url;
  56                 $beg . 'PI-LINK-'. $key . $end;
  57         ^ge;
  58         $_[1];
  59 }
  60
  61 sub linkify_2 {
  62         # Added "PI-LINK-" prefix to avoid false-positives on git commits
  63         $_[1] =~ s!\bPI-LINK-([a-f0-9]{40})\b!
  64                 my $key = $1;
  65                 my $url = $_[0]->{$key};
  66                 if (defined $url) {
  67                         "<a\nhref=\"$url\">$url</a>";
  68                 } else {
  69                         # false positive or somebody tried to mess with us
  70                         $key;
  71                 }
  72         !ge;
  73         $_[1];
  74 }
  75
  76 1;