lib/PublicInbox/MID.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Various Message-ID-related functions.
   5 package PublicInbox::MID;
   6 use strict;
   7 use warnings;
   8 use base qw/Exporter/;
   9 our @EXPORT_OK = qw/mid_clean id_compress mid2path mid_mime mid_escape MID_ESC
  10         mids references/;
  11 use URI::Escape qw(uri_escape_utf8);
  12 use Digest::SHA qw/sha1_hex/;
  13 require PublicInbox::Address;
  14 use constant {
  15         MID_MAX => 40, # SHA-1 hex length # TODO: get rid of this
  16         MAX_MID_SIZE => 244, # max term size (Xapian limitation) - length('Q')
  17 };
  18
  19 sub mid_clean {
  20         my ($mid) = @_;
  21         defined($mid) or die "no Message-ID";
  22         # MDA->precheck did more checking for us
  23         if ($mid =~ /<([^>]+)>/) {
  24                 $mid = $1;
  25         }
  26         $mid;
  27 }
  28
  29 # this is idempotent, used for HTML anchor/ids and such
  30 sub id_compress {
  31         my ($id, $force) = @_;
  32
  33         if ($force || $id =~ /[^a-zA-Z0-9_\-]/ || length($id) > MID_MAX) {
  34                 utf8::encode($id);
  35                 return sha1_hex($id);
  36         }
  37         $id;
  38 }
  39
  40 sub mid2path {
  41         my ($mid) = @_;
  42         my ($x2, $x38) = ($mid =~ /\A([a-f0-9]{2})([a-f0-9]{38})\z/);
  43
  44         unless (defined $x38) {
  45                 # compatibility with old links (or short Message-IDs :)
  46                 $mid = mid_clean($mid);
  47                 utf8::encode($mid);
  48                 $mid = sha1_hex($mid);
  49                 ($x2, $x38) = ($mid =~ /\A([a-f0-9]{2})([a-f0-9]{38})\z/);
  50         }
  51         "$x2/$x38";
  52 }
  53
  54 # Only for v1 code paths:
  55 sub mid_mime ($) { mids($_[0]->header_obj)->[0] }
  56
  57 sub mids ($) {
  58         my ($hdr) = @_;
  59         my @mids;
  60         my @v = $hdr->header_raw('Message-Id');
  61         foreach my $v (@v) {
  62                 my @cur = ($v =~ /<([^>]+)>/sg);
  63                 if (@cur) {
  64                         push(@mids, @cur);
  65                 } else {
  66                         push(@mids, $v);
  67                 }
  68         }
  69         uniq_mids(\@mids);
  70 }
  71
  72 # last References should be IRT, but some mail clients do things
  73 # out of order, so trust IRT over References iff IRT exists
  74 sub references ($) {
  75         my ($hdr) = @_;
  76         my @mids;
  77         foreach my $f (qw(References In-Reply-To)) {
  78                 my @v = $hdr->header_raw($f);
  79                 foreach my $v (@v) {
  80                         push(@mids, ($v =~ /<([^>]+)>/sg));
  81                 }
  82         }
  83
  84         # old versions of git-send-email would prompt users for
  85         # In-Reply-To and users' muscle memory would use 'y' or 'n'
  86         # as responses:
  87         my %addr = ( y => 1, n => 1 );
  88
  89         foreach my $f (qw(To From Cc)) {
  90                 my @v = $hdr->header_raw($f);
  91                 foreach my $v (@v) {
  92                         $addr{$_} = 1 for (PublicInbox::Address::emails($v));
  93                 }
  94         }
  95         uniq_mids(\@mids, \%addr);
  96 }
  97
  98 sub uniq_mids ($;$) {
  99         my ($mids, $seen) = @_;
 100         my @ret;
 101         $seen ||= {};
 102         foreach my $mid (@$mids) {
 103                 $mid =~ tr/\n\t\r//d;
 104                 if (length($mid) > MAX_MID_SIZE) {
 105                         warn "Message-ID: <$mid> too long, truncating\n";
 106                         $mid = substr($mid, 0, MAX_MID_SIZE);
 107                 }
 108                 next if $seen->{$mid};
 109                 push @ret, $mid;
 110                 $seen->{$mid} = 1;
 111         }
 112         \@ret;
 113 }
 114
 115 # RFC3986, section 3.3:
 116 sub MID_ESC () { '^A-Za-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@' }
 117 sub mid_escape ($) { uri_escape_utf8($_[0], MID_ESC) }
 118
 119 1;