lib/PublicInbox/MID.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Various Message-ID-related functions.
   5 package PublicInbox::MID;
   6 use strict;
   7 use warnings;
   8 use base qw/Exporter/;
   9 our @EXPORT_OK = qw(mid_clean id_compress mid2path mid_mime mid_escape MID_ESC
  10         mids references mids_for_index $MID_EXTRACT);
  11 use URI::Escape qw(uri_escape_utf8);
  12 use Digest::SHA qw/sha1_hex/;
  13 require PublicInbox::Address;
  14 use constant {
  15         MID_MAX => 40, # SHA-1 hex length # TODO: get rid of this
  16         MAX_MID_SIZE => 244, # max term size (Xapian limitation) - length('Q')
  17 };
  18
  19 our $MID_EXTRACT = qr/<([^>]+)>/s;
  20
  21 sub mid_clean {
  22         my ($mid) = @_;
  23         defined($mid) or die "no Message-ID";
  24         # MDA->precheck did more checking for us
  25         if ($mid =~ $MID_EXTRACT) {
  26                 $mid = $1;
  27         }
  28         $mid;
  29 }
  30
  31 # this is idempotent, used for HTML anchor/ids and such
  32 sub id_compress {
  33         my ($id, $force) = @_;
  34
  35         if ($force || $id =~ /[^a-zA-Z0-9_\-]/ || length($id) > MID_MAX) {
  36                 utf8::encode($id);
  37                 return sha1_hex($id);
  38         }
  39         $id;
  40 }
  41
  42 sub mid2path {
  43         my ($mid) = @_;
  44         my ($x2, $x38) = ($mid =~ /\A([a-f0-9]{2})([a-f0-9]{38})\z/);
  45
  46         unless (defined $x38) {
  47                 # compatibility with old links (or short Message-IDs :)
  48                 $mid = mid_clean($mid);
  49                 utf8::encode($mid);
  50                 $mid = sha1_hex($mid);
  51                 ($x2, $x38) = ($mid =~ /\A([a-f0-9]{2})([a-f0-9]{38})\z/);
  52         }
  53         "$x2/$x38";
  54 }
  55
  56 # Only for v1 code paths:
  57 sub mid_mime ($) { mids($_[0]->header_obj)->[0] }
  58
  59 # only intended for Message-ID and X-Alt-Message-ID
  60 sub extract_mids {
  61         my @mids;
  62         for my $v (@_) {
  63                 my @cur = ($v =~ /$MID_EXTRACT/g);
  64                 if (@cur) {
  65                         push(@mids, @cur);
  66                 } else {
  67                         push(@mids, $v);
  68                 }
  69         }
  70         \@mids;
  71 }
  72
  73 sub mids ($) {
  74         my ($hdr) = @_;
  75         my @mids = $hdr->header_raw('Message-ID');
  76         uniq_mids(extract_mids(@mids));
  77 }
  78
  79 # we allow searching on X-Alt-Message-ID since PublicInbox::NNTP uses them
  80 # to placate some clients, and we want to ensure NNTP-only clients can
  81 # import and index without relying on HTTP endpoints
  82 sub mids_for_index ($) {
  83         my ($hdr) = @_;
  84         my @mids = $hdr->header_raw('Message-ID');
  85         my @alts = $hdr->header_raw('X-Alt-Message-ID');
  86         uniq_mids(extract_mids(@mids, @alts));
  87 }
  88
  89 # last References should be IRT, but some mail clients do things
  90 # out of order, so trust IRT over References iff IRT exists
  91 sub references ($) {
  92         my ($hdr) = @_;
  93         my @mids;
  94         foreach my $f (qw(References In-Reply-To)) {
  95                 my @v = $hdr->header_raw($f);
  96                 foreach my $v (@v) {
  97                         push(@mids, ($v =~ /$MID_EXTRACT/g));
  98                 }
  99         }
 100
 101         # old versions of git-send-email would prompt users for
 102         # In-Reply-To and users' muscle memory would use 'y' or 'n'
 103         # as responses:
 104         my %addr = ( y => 1, n => 1 );
 105
 106         foreach my $f (qw(To From Cc)) {
 107                 my @v = $hdr->header_raw($f);
 108                 foreach my $v (@v) {
 109                         $addr{$_} = 1 for (PublicInbox::Address::emails($v));
 110                 }
 111         }
 112         uniq_mids(\@mids, \%addr);
 113 }
 114
 115 sub uniq_mids ($;$) {
 116         my ($mids, $seen) = @_;
 117         my @ret;
 118         $seen ||= {};
 119         foreach my $mid (@$mids) {
 120                 $mid =~ tr/\n\t\r//d;
 121                 if (length($mid) > MAX_MID_SIZE) {
 122                         warn "Message-ID: <$mid> too long, truncating\n";
 123                         $mid = substr($mid, 0, MAX_MID_SIZE);
 124                 }
 125                 push(@ret, $mid) unless $seen->{$mid}++;
 126         }
 127         \@ret;
 128 }
 129
 130 # RFC3986, section 3.3:
 131 sub MID_ESC () { '^A-Za-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@' }
 132 sub mid_escape ($) { uri_escape_utf8($_[0], MID_ESC) }
 133
 134 1;