lib/PublicInbox/Mbox.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Streaming interface for mboxrd HTTP responses
   5 # See PublicInbox::GzipFilter for details.
   6 package PublicInbox::Mbox;
   7 use strict;
   8 use parent 'PublicInbox::GzipFilter';
   9 use PublicInbox::MID qw/mid_escape/;
  10 use PublicInbox::Hval qw/to_filename/;
  11 use PublicInbox::Smsg;
  12 use PublicInbox::Eml;
  13
  14 # called by PSGI server as body response
  15 # this gets called twice for every message, once to return the header,
  16 # once to retrieve the body
  17 sub getline {
  18         my ($ctx) = @_; # ctx
  19         my $smsg = $ctx->{smsg} or return;
  20         my $ibx = $ctx->{-inbox};
  21         my $eml = $ibx->smsg_eml($smsg) or return;
  22         my $n = $ctx->{smsg} = $ibx->over->next_by_mid(@{$ctx->{next_arg}});
  23         $ctx->zmore(msg_hdr($ctx, $eml, $smsg->{mid}));
  24         if ($n) {
  25                 $ctx->translate(msg_body($eml));
  26         } else { # last message
  27                 $ctx->zmore(msg_body($eml));
  28                 $ctx->zflush;
  29         }
  30 }
  31
  32 # called by PublicInbox::DS::write after http->next_step
  33 sub async_next {
  34         my ($http) = @_; # PublicInbox::HTTP
  35         my $ctx = $http->{forward} or return; # client aborted
  36         eval {
  37                 my $smsg = $ctx->{smsg} or return $ctx->close;
  38                 $ctx->smsg_blob($smsg);
  39         };
  40         warn "E: $@" if $@;
  41 }
  42
  43 sub async_eml { # for async_blob_cb
  44         my ($ctx, $eml) = @_;
  45         my $smsg = delete $ctx->{smsg};
  46         # next message
  47         $ctx->{smsg} = $ctx->{-inbox}->over->next_by_mid(@{$ctx->{next_arg}});
  48
  49         $ctx->zmore(msg_hdr($ctx, $eml, $smsg->{mid}));
  50         $ctx->{http_out}->write($ctx->translate(msg_body($eml)));
  51 }
  52
  53 sub res_hdr ($$) {
  54         my ($ctx, $subject) = @_;
  55         my $fn = $subject // '';
  56         $fn =~ s/^re:\s+//i;
  57         $fn = to_filename($fn) // 'no-subject';
  58         my @hdr = ('Content-Type');
  59         if ($ctx->{-inbox}->{obfuscate}) {
  60                 # obfuscation is stupid, but maybe scrapers are, too...
  61                 push @hdr, 'application/mbox';
  62                 $fn .= '.mbox';
  63         } else {
  64                 push @hdr, 'text/plain';
  65                 $fn .= '.txt';
  66         }
  67         push @hdr, 'Content-Disposition', "inline; filename=$fn";
  68         \@hdr;
  69 }
  70
  71 # for rare cases where v1 inboxes aren't indexed w/ ->over at all
  72 sub no_over_raw ($) {
  73         my ($ctx) = @_;
  74         my $mref = $ctx->{-inbox}->msg_by_mid($ctx->{mid}) or return;
  75         my $eml = PublicInbox::Eml->new($mref);
  76         [ 200, res_hdr($ctx, $eml->header_str('Subject')),
  77                 [ msg_hdr($ctx, $eml, $ctx->{mid}) . msg_body($eml) ] ]
  78 }
  79
  80 # /$INBOX/$MESSAGE_ID/raw
  81 sub emit_raw {
  82         my ($ctx) = @_;
  83         $ctx->{base_url} = $ctx->{-inbox}->base_url($ctx->{env});
  84         my $over = $ctx->{-inbox}->over or return no_over_raw($ctx);
  85         my ($id, $prev);
  86         my $mip = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  87         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$mip) or return;
  88         my $res_hdr = res_hdr($ctx, $smsg->{subject});
  89         bless $ctx, __PACKAGE__;
  90         $ctx->psgi_response(200, $res_hdr);
  91 }
  92
  93 sub msg_hdr ($$;$) {
  94         my ($ctx, $eml, $mid) = @_;
  95         my $header_obj = $eml->header_obj;
  96
  97         # drop potentially confusing headers, ssoma already should've dropped
  98         # Lines and Content-Length
  99         foreach my $d (qw(Lines Bytes Content-Length Status)) {
 100                 $header_obj->header_set($d);
 101         }
 102         my $ibx = $ctx->{-inbox};
 103         my $base = $ctx->{base_url};
 104         $mid = $ctx->{mid} unless defined $mid;
 105         $mid = mid_escape($mid);
 106         my @append = (
 107                 'Archived-At', "<$base$mid/>",
 108                 'List-Archive', "<$base>",
 109                 'List-Post', "<mailto:$ibx->{-primary_address}>",
 110         );
 111         my $crlf = $header_obj->crlf;
 112         my $buf = $header_obj->as_string;
 113         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 114         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 115         $buf = "From mboxrd\@z Thu Jan  1 00:00:00 1970" . $crlf . $buf;
 116
 117         for (my $i = 0; $i < @append; $i += 2) {
 118                 my $k = $append[$i];
 119                 my $v = $append[$i + 1];
 120                 my @v = $header_obj->header_raw($k);
 121                 foreach (@v) {
 122                         if ($v eq $_) {
 123                                 $v = undef;
 124                                 last;
 125                         }
 126                 }
 127                 $buf .= "$k: $v$crlf" if defined $v;
 128         }
 129         $buf .= $crlf;
 130 }
 131
 132 sub msg_body ($) {
 133         my $bdy = $_[0]->{bdy} // return "\n";
 134         # mboxrd quoting style
 135         # https://en.wikipedia.org/wiki/Mbox#Modified_mbox
 136         # https://www.loc.gov/preservation/digital/formats/fdd/fdd000385.shtml
 137         # https://web.archive.org/http://www.qmail.org/man/man5/mbox.html
 138         $$bdy =~ s/^(>*From )/>$1/gm;
 139         $$bdy .= "\n";
 140 }
 141
 142 sub thread_cb {
 143         my ($ctx) = @_;
 144         my $msgs = $ctx->{msgs};
 145         while (1) {
 146                 if (my $smsg = shift @$msgs) {
 147                         return $smsg;
 148                 }
 149                 # refill result set
 150                 $ctx->{msgs} = $msgs = $ctx->{over}->get_thread($ctx->{mid},
 151                                                                 $ctx->{prev});
 152                 return unless @$msgs;
 153                 $ctx->{prev} = $msgs->[-1];
 154         }
 155 }
 156
 157 sub thread_mbox {
 158         my ($ctx, $over, $sfx) = @_;
 159         my $msgs = $ctx->{msgs} = $over->get_thread($ctx->{mid}, {});
 160         return [404, [qw(Content-Type text/plain)], []] if !@$msgs;
 161         $ctx->{prev} = $msgs->[-1];
 162         $ctx->{over} = $over; # bump refcnt
 163         require PublicInbox::MboxGz;
 164         PublicInbox::MboxGz::mbox_gz($ctx, \&thread_cb, $msgs->[0]->{subject});
 165 }
 166
 167 sub emit_range {
 168         my ($ctx, $range) = @_;
 169
 170         my $q;
 171         if ($range eq 'all') { # TODO: YYYY[-MM]
 172                 $q = '';
 173         } else {
 174                 return [404, [qw(Content-Type text/plain)], []];
 175         }
 176         mbox_all($ctx, { q => $q });
 177 }
 178
 179 sub all_ids_cb {
 180         my ($ctx) = @_;
 181         my $ids = $ctx->{ids};
 182         do {
 183                 while ((my $num = shift @$ids)) {
 184                         my $smsg = $ctx->{over}->get_art($num) or next;
 185                         return $smsg;
 186                 }
 187                 $ctx->{ids} = $ids = $ctx->{mm}->ids_after(\($ctx->{prev}));
 188         } while (@$ids);
 189 }
 190
 191 sub mbox_all_ids {
 192         my ($ctx) = @_;
 193         my $ibx = $ctx->{-inbox};
 194         my $prev = 0;
 195         my $mm = $ctx->{mm} = $ibx->mm;
 196         my $ids = $mm->ids_after(\$prev) or return
 197                 [404, [qw(Content-Type text/plain)], ["No results found\n"]];
 198         $ctx->{over} = $ibx->over or
 199                 return PublicInbox::WWW::need($ctx, 'Overview');
 200         $ctx->{ids} = $ids;
 201         $ctx->{prev} = $prev;
 202         require PublicInbox::MboxGz;
 203         PublicInbox::MboxGz::mbox_gz($ctx, \&all_ids_cb, 'all');
 204 }
 205
 206 sub results_cb {
 207         my ($ctx) = @_;
 208         my $over = $ctx->{-inbox}->over or return;
 209         while (1) {
 210                 while (defined(my $num = shift(@{$ctx->{ids}}))) {
 211                         my $smsg = $over->get_art($num) or next;
 212                         return $smsg;
 213                 }
 214                 # refill result set
 215                 my $srch = $ctx->{-inbox}->search(undef, $ctx) or return;
 216                 my $mset = $srch->query($ctx->{query}, $ctx->{qopts});
 217                 my $size = $mset->size or return;
 218                 $ctx->{qopts}->{offset} += $size;
 219                 $ctx->{ids} = $srch->mset_to_artnums($mset);
 220         }
 221 }
 222
 223 sub results_thread_cb {
 224         my ($ctx) = @_;
 225
 226         my $over = $ctx->{-inbox}->over or return;
 227         while (1) {
 228                 while (defined(my $num = shift(@{$ctx->{xids}}))) {
 229                         my $smsg = $over->get_art($num) or next;
 230                         return $smsg;
 231                 }
 232
 233                 # refills ctx->{xids}
 234                 next if $over->expand_thread($ctx);
 235
 236                 # refill result set
 237                 my $srch = $ctx->{-inbox}->search(undef, $ctx) or return;
 238                 my $mset = $srch->query($ctx->{query}, $ctx->{qopts});
 239                 my $size = $mset->size or return;
 240                 $ctx->{qopts}->{offset} += $size;
 241                 $ctx->{ids} = $srch->mset_to_artnums($mset);
 242         }
 243
 244 }
 245
 246 sub mbox_all {
 247         my ($ctx, $q) = @_;
 248         my $q_string = $q->{'q'};
 249         return mbox_all_ids($ctx) if $q_string !~ /\S/;
 250         my $srch = $ctx->{-inbox}->search or
 251                 return PublicInbox::WWW::need($ctx, 'Search');
 252         my $over = $ctx->{-inbox}->over or
 253                 return PublicInbox::WWW::need($ctx, 'Overview');
 254
 255         my $qopts = $ctx->{qopts} = { mset => 2 }; # order by docid
 256         $qopts->{thread} = 1 if $q->{t};
 257         my $mset = $srch->query($q_string, $qopts);
 258         $qopts->{offset} = $mset->size or
 259                         return [404, [qw(Content-Type text/plain)],
 260                                 ["No results found\n"]];
 261         $ctx->{query} = $q_string;
 262         $ctx->{ids} = $srch->mset_to_artnums($mset);
 263         require PublicInbox::MboxGz;
 264         my $fn;
 265         if ($q->{t} && $srch->has_threadid) {
 266                 $fn = 'results-thread-'.$q_string;
 267                 PublicInbox::MboxGz::mbox_gz($ctx, \&results_thread_cb, $fn);
 268         } else {
 269                 $fn = 'results-'.$q_string;
 270                 PublicInbox::MboxGz::mbox_gz($ctx, \&results_cb, $fn);
 271         }
 272 }
 273
 274 1;