lib/PublicInbox/Msgmap.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # bidirectional Message-ID <-> Article Number mapping
   4 package PublicInbox::Msgmap;
   5 use strict;
   6 use warnings;
   7 use fields qw(dbh mid_insert mid_for num_for);
   8 use DBI;
   9 use DBD::SQLite;
  10
  11 sub new {
  12         my ($class, $git_dir, $writable) = @_;
  13         my $d = "$git_dir/public-inbox";
  14         if ($writable && !-d $d && !mkdir $d) {
  15                 my $err = $!;
  16                 -d $d or die "$d not created: $err";
  17         }
  18         my $f = "$d/msgmap.sqlite3";
  19         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  20                 AutoCommit => 1,
  21                 RaiseError => 1,
  22                 PrintError => 0,
  23                 sqlite_use_immediate_transaction => 1,
  24         });
  25         $dbh->do('PRAGMA case_sensitive_like = ON');
  26
  27         $writable and create_tables($dbh);
  28         my $self = fields::new($class);
  29         $self->{dbh} = $dbh;
  30         $self;
  31 }
  32
  33 # accessor
  34 sub last_commit {
  35         my ($self, $commit) = @_;
  36         my $dbh = $self->{dbh};
  37         my $prev;
  38         use constant {
  39                 key => 'last_commit',
  40                 meta_select => 'SELECT val FROM meta WHERE key = ? LIMIT 1',
  41                 meta_update => 'UPDATE meta SET val = ? WHERE key = ? LIMIT 1',
  42                 meta_insert => 'INSERT INTO meta (key,val) VALUES (?,?)',
  43         };
  44
  45         defined $commit or
  46                 return $dbh->selectrow_array(meta_select, undef, key);
  47
  48         $dbh->begin_work;
  49         eval {
  50                 $prev = $dbh->selectrow_array(meta_select, undef, key);
  51
  52                 if (defined $prev) {
  53                         $dbh->do(meta_update, undef, $commit, key);
  54                 } else {
  55                         $dbh->do(meta_insert, undef, key, $commit);
  56                 }
  57                 $dbh->commit;
  58         };
  59         return $prev unless $@;
  60
  61         $dbh->rollback;
  62         die $@;
  63 }
  64
  65 sub mid_insert {
  66         my ($self, $mid) = @_;
  67         my $dbh = $self->{dbh};
  68         use constant MID_INSERT => 'INSERT INTO msgmap (mid) VALUES (?)';
  69         my $sth = $self->{mid_insert} ||= $dbh->prepare(MID_INSERT);
  70         $sth->bind_param(1, $mid);
  71         $sth->execute;
  72         $dbh->last_insert_id(undef, undef, 'msgmap', 'num');
  73 }
  74
  75 use constant MID_FOR => 'SELECT mid FROM msgmap WHERE num = ? LIMIT 1';
  76 sub mid_for {
  77         my ($self, $num) = @_;
  78         my $dbh = $self->{dbh};
  79         my $sth = $self->{mid_for} ||= $dbh->prepare(MID_FOR);
  80         $sth->bind_param(1, $num);
  81         $sth->execute;
  82         $sth->fetchrow_array;
  83 }
  84
  85 sub num_for {
  86         my ($self, $mid) = @_;
  87         my $dbh = $self->{dbh};
  88         use constant NUM_FOR => 'SELECT num FROM msgmap WHERE mid = ? LIMIT 1';
  89         my $sth = $self->{num_for} ||= $dbh->prepare(NUM_FOR);
  90         $sth->bind_param(1, $mid);
  91         $sth->execute;
  92         $sth->fetchrow_array;
  93 }
  94
  95 sub mid_prefixes {
  96         my ($self, $pfx, $limit) = @_;
  97
  98         die "No prefix given" unless (defined $pfx && $pfx ne '');
  99         $pfx =~ s/([%_])/\\$1/g;
 100         $pfx .= '%';
 101
 102         $limit ||= 100;
 103         $limit += 0; # force to integer
 104         $limit ||= 100;
 105
 106         $self->{dbh}->selectcol_arrayref('SELECT mid FROM msgmap ' .
 107                                          'WHERE mid LIKE ? ESCAPE ? ' .
 108                                          "ORDER BY num DESC LIMIT $limit",
 109                                          undef, $pfx, '\\');
 110 }
 111
 112 sub mid_delete {
 113         my ($self, $mid) = @_;
 114         my $dbh = $self->{dbh};
 115         use constant MID_DELETE => 'DELETE FROM msgmap WHERE mid = ?';
 116         my $sth = $dbh->prepare(MID_DELETE);
 117         $sth->bind_param(1, $mid);
 118         $sth->execute;
 119 }
 120
 121 sub create_tables {
 122         my ($dbh) = @_;
 123         my $e;
 124
 125         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM msgmap;') };
 126         defined $e or $dbh->do('CREATE TABLE msgmap (' .
 127                         'num INTEGER PRIMARY KEY AUTOINCREMENT, '.
 128                         'mid VARCHAR(1000) NOT NULL, ' .
 129                         'UNIQUE (mid) )');
 130
 131         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM meta') };
 132         defined $e or $dbh->do('CREATE TABLE meta (' .
 133                         'key VARCHAR(32) PRIMARY KEY, '.
 134                         'val VARCHAR(255) NOT NULL)');
 135 }
 136
 137 1;