lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 use Email::MIME;
  15 use Data::Dumper qw(Dumper);
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use constant {
  19         r501 => '501 command syntax error',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24         long_response_limit => 0xffffffff,
  25 };
  26
  27 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  28
  29 my @OVERVIEW = qw(Subject From Date Message-ID References);
  30 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33
  34 # disable commands with easy DoS potential:
  35 # LISTGROUP could get pretty bad, too...
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $EXPTIMER;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $WEAKEN = {}; # string(nntpd) -> nntpd
  42 my $WEAKTIMER;
  43
  44 my $next_tick;
  45 my $nextq = [];
  46 sub next_tick () {
  47         $next_tick = undef;
  48         my $q = $nextq;
  49         $nextq = [];
  50         foreach my $nntp (@$q) {
  51                 # for request && response protocols, always finish writing
  52                 # before finishing reading:
  53                 if (my $long_cb = $nntp->{long_res}) {
  54                         $nntp->write($long_cb);
  55                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  56                         event_read($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub update_idle_time ($) {
  62         my ($self) = @_;
  63         my $tmp = $self->{sock} or return;
  64         $tmp = fileno($tmp);
  65         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  66 }
  67
  68 # reduce FD pressure by closing some "git cat-file --batch" processes
  69 # and unused FDs for msgmap and Xapian indices
  70 sub weaken_groups () {
  71         $WEAKTIMER = undef;
  72         foreach my $nntpd (values %$WEAKEN) {
  73                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  74         }
  75         $WEAKEN = {};
  76 }
  77
  78 sub expire_old () {
  79         my $now = now();
  80         my $exp = $EXPTIME;
  81         my $old = $now - $exp;
  82         my $next = $now + $exp;
  83         my $nr = 0;
  84         my %new;
  85         while (my ($fd, $v) = each %$EXPMAP) {
  86                 my ($idle_time, $nntp) = @$v;
  87                 if ($idle_time < $old) {
  88                         $nntp->close; # idempotent
  89                 } else {
  90                         my $nexp = $idle_time + $exp;
  91                         $next = $nexp if ($nexp < $next);
  92                         ++$nr;
  93                         $new{$fd} = $v;
  94                 }
  95         }
  96         $EXPMAP = \%new;
  97         if ($nr) {
  98                 $next -= $now;
  99                 $next = 0 if $next < 0;
 100                 $EXPTIMER = Danga::Socket->AddTimer($next, *expire_old);
 101                 weaken_groups();
 102         } else {
 103                 $EXPTIMER = undef;
 104                 # noop to kick outselves out of the loop ASAP so descriptors
 105                 # really get closed
 106                 Danga::Socket->AddTimer(0, sub {});
 107
 108                 # grace period for reaping resources
 109                 $WEAKTIMER ||= Danga::Socket->AddTimer(30, *weaken_groups);
 110         }
 111 }
 112
 113 sub new ($$$) {
 114         my ($class, $sock, $nntpd) = @_;
 115         my $self = fields::new($class);
 116         binmode $sock, ':utf8'; # RFC 3977
 117         $self->SUPER::new($sock);
 118         $self->{nntpd} = $nntpd;
 119         res($self, '201 server ready - post via email');
 120         $self->{rbuf} = '';
 121         $self->watch_read(1);
 122         update_idle_time($self);
 123         $WEAKEN->{"$nntpd"} = $nntpd;
 124         $EXPTIMER ||= Danga::Socket->AddTimer($EXPTIME, *expire_old);
 125         $self;
 126 }
 127
 128 sub args_ok ($$) {
 129         my ($cb, $argc) = @_;
 130         my $tot = prototype $cb;
 131         my ($nreq, undef) = split(';', $tot);
 132         $nreq = ($nreq =~ tr/$//) - 1;
 133         $tot = ($tot =~ tr/$//) - 1;
 134         ($argc <= $tot && $argc >= $nreq);
 135 }
 136
 137 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 138 sub process_line ($$) {
 139         my ($self, $l) = @_;
 140         my ($req, @args) = split(/\s+/, $l);
 141         $req = lc($req);
 142         $req = eval {
 143                 no strict 'refs';
 144                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 145         };
 146         return res($self, '500 command not recognized') unless $req;
 147         return res($self, r501) unless args_ok($req, scalar @args);
 148
 149         my $res = eval { $req->($self, @args) };
 150         my $err = $@;
 151         if ($err && !$self->{closed}) {
 152                 chomp($l = Dumper(\$l));
 153                 err($self, 'error from: %s (%s)', $l, $err);
 154                 $res = '503 program fault - command not performed';
 155         }
 156         return 0 unless defined $res;
 157         res($self, $res);
 158 }
 159
 160 sub cmd_mode ($$) {
 161         my ($self, $arg) = @_;
 162         $arg = uc $arg;
 163         return r501 unless $arg eq 'READER';
 164         '201 Posting prohibited';
 165 }
 166
 167 sub cmd_slave ($) { '202 slave status noted' }
 168
 169 sub cmd_xgtitle ($;$) {
 170         my ($self, $wildmat) = @_;
 171         more($self, '282 list of groups and descriptions follows');
 172         list_newsgroups($self, $wildmat);
 173         '.'
 174 }
 175
 176 sub list_overview_fmt ($) {
 177         my ($self) = @_;
 178         do_more($self, $OVERVIEW_FMT);
 179 }
 180
 181 sub list_headers ($;$) {
 182         my ($self) = @_;
 183         do_more($self, $LIST_HEADERS);
 184 }
 185
 186 sub list_active ($;$) {
 187         my ($self, $wildmat) = @_;
 188         wildmat2re($wildmat);
 189         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 190                 $ng->{name} =~ $wildmat or next;
 191                 group_line($self, $ng);
 192         }
 193 }
 194
 195 sub list_active_times ($;$) {
 196         my ($self, $wildmat) = @_;
 197         wildmat2re($wildmat);
 198         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 199                 $ng->{name} =~ $wildmat or next;
 200                 my $c = eval { $ng->mm->created_at } || time;
 201                 more($self, "$ng->{name} $c $ng->{address}");
 202         }
 203 }
 204
 205 sub list_newsgroups ($;$) {
 206         my ($self, $wildmat) = @_;
 207         wildmat2re($wildmat);
 208         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 209                 $ng->{name} =~ $wildmat or next;
 210                 my $d = $ng->description;
 211                 more($self, "$ng->{name} $d");
 212         }
 213 }
 214
 215 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 216 sub cmd_list ($;$$) {
 217         my ($self, @args) = @_;
 218         if (scalar @args) {
 219                 my $arg = shift @args;
 220                 $arg =~ tr/A-Z./a-z_/;
 221                 $arg = "list_$arg";
 222                 return r501 if $DISABLED{$arg};
 223
 224                 $arg = eval {
 225                         no strict 'refs';
 226                         *{$arg}{CODE};
 227                 };
 228                 return r501 unless $arg && args_ok($arg, scalar @args);
 229                 more($self, '215 information follows');
 230                 $arg->($self, @args);
 231         } else {
 232                 more($self, '215 list of newsgroups follows');
 233                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 234                         group_line($self, $ng);
 235                 }
 236         }
 237         '.'
 238 }
 239
 240 sub cmd_listgroup ($;$) {
 241         my ($self, $group) = @_;
 242         if (defined $group) {
 243                 my $res = cmd_group($self, $group);
 244                 return $res if ($res !~ /\A211 /);
 245                 more($self, $res);
 246         }
 247
 248         $self->{ng} or return '412 no newsgroup selected';
 249         long_response($self, 0, long_response_limit, sub {
 250                 my ($i) = @_;
 251                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 252                         my ($ary) = @_;
 253                         more($self, join("\r\n", @$ary));
 254                 });
 255
 256                 # -1 to adjust for implicit increment in long_response
 257                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 258         });
 259 }
 260
 261 sub parse_time ($$;$) {
 262         my ($date, $time, $gmt) = @_;
 263         use Time::Local qw();
 264         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 265         if (defined $gmt) {
 266                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 267                 $gmt = 1;
 268         }
 269         my @now = $gmt ? gmtime : localtime;
 270         my ($YYYY, $MM, $DD);
 271         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 272                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 273         } else { # legacy clients send YYMMDD
 274                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 275                 if ($YYYY > strftime('%y', @now)) {
 276                         my $cur_year = $now[5] + 1900;
 277                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 278                 }
 279         }
 280         if ($gmt) {
 281                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 282         } else {
 283                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 284         }
 285 }
 286
 287 sub group_line ($$) {
 288         my ($self, $ng) = @_;
 289         my ($min, $max) = $ng->mm->minmax;
 290         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 291 }
 292
 293 sub cmd_newgroups ($$$;$$) {
 294         my ($self, $date, $time, $gmt, $dists) = @_;
 295         my $ts = eval { parse_time($date, $time, $gmt) };
 296         return r501 if $@;
 297
 298         # TODO dists
 299         more($self, '231 list of new newsgroups follows');
 300         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 301                 my $c = eval { $ng->mm->created_at } || 0;
 302                 next unless $c > $ts;
 303                 group_line($self, $ng);
 304         }
 305         '.'
 306 }
 307
 308 sub wildmat2re (;$) {
 309         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 310         my %keep;
 311         my $salt = rand;
 312         use Digest::SHA qw(sha1_hex);
 313         my $tmp = $_[0];
 314
 315         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 316                 my $orig = $1;
 317                 my $key = sha1_hex($orig . $salt);
 318                 $orig =~ s/([^\w\-])+/\Q$1/g;
 319                 $keep{$key} = $orig;
 320                 $key
 321                 #gex;
 322         my %map = ('*' => '.*', '?' => '.' );
 323         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 324         if (scalar %keep) {
 325                 $tmp =~ s#([a-f0-9]{40})#
 326                         my $orig = $keep{$1};
 327                         defined $orig ? $orig : $1;
 328                         #ge;
 329         }
 330         $_[0] = qr/\A$tmp\z/;
 331 }
 332
 333 sub ngpat2re (;$) {
 334         return $_[0] = qr/\A\z/ unless defined $_[0];
 335         my %map = ('*' => '.*', ',' => '|');
 336         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 337         $_[0] = qr/\A(?:$_[0])\z/;
 338 }
 339
 340 sub cmd_newnews ($$$$;$$) {
 341         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 342         my $ts = eval { parse_time($date, $time, $gmt) };
 343         return r501 if $@;
 344         more($self, '230 list of new articles by message-id follows');
 345         my ($keep, $skip) = split('!', $newsgroups, 2);
 346         ngpat2re($keep);
 347         ngpat2re($skip);
 348         my @srch;
 349         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 350                 $ng->{name} =~ $keep or next;
 351                 $ng->{name} =~ $skip and next;
 352                 my $srch = $ng->search or next;
 353                 push @srch, $srch;
 354         };
 355         return '.' unless @srch;
 356
 357         $ts .= '..';
 358         my $opts = { asc => 1, limit => 1000, offset => 0 };
 359         long_response($self, 0, long_response_limit, sub {
 360                 my ($i) = @_;
 361                 my $srch = $srch[0];
 362                 my $res = $srch->query($ts, $opts);
 363                 my $msgs = $res->{msgs};
 364                 if (my $nr = scalar @$msgs) {
 365                         more($self, '<' .
 366                                 join(">\r\n<", map { $_->mid } @$msgs ).
 367                                 '>');
 368                         $opts->{offset} += $nr;
 369                 } else {
 370                         shift @srch;
 371                         if (@srch) { # continue onto next newsgroup
 372                                 $opts->{offset} = 0;
 373                         } else { # break out of the long response.
 374                                 $$i = long_response_limit;
 375                         }
 376                 }
 377         });
 378 }
 379
 380 sub cmd_group ($$) {
 381         my ($self, $group) = @_;
 382         my $no_such = '411 no such news group';
 383         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 384
 385         $self->{ng} = $ng;
 386         my ($min, $max) = $ng->mm->minmax;
 387         $min ||= 0;
 388         $max ||= 0;
 389         $self->{article} = $min;
 390         my $est_size = $max - $min;
 391         "211 $est_size $min $max $group";
 392 }
 393
 394 sub article_adj ($$) {
 395         my ($self, $off) = @_;
 396         my $ng = $self->{ng} or return '412 no newsgroup selected';
 397
 398         my $n = $self->{article};
 399         defined $n or return '420 no current article has been selected';
 400
 401         $n += $off;
 402         my $mid = $ng->mm->mid_for($n);
 403         unless ($mid) {
 404                 $n = $off > 0 ? 'next' : 'previous';
 405                 return "421 no $n article in this group";
 406         }
 407         $self->{article} = $n;
 408         "223 $n <$mid> article retrieved - request text separately";
 409 }
 410
 411 sub cmd_next ($) { article_adj($_[0], 1) }
 412 sub cmd_last ($) { article_adj($_[0], -1) }
 413
 414 # We want to encourage using email and CC-ing everybody involved to avoid
 415 # the single-point-of-failure a single server provides.
 416 sub cmd_post ($) {
 417         my ($self) = @_;
 418         my $ng = $self->{ng};
 419         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 420 }
 421
 422 sub cmd_quit ($) {
 423         my ($self) = @_;
 424         res($self, '205 closing connection - goodbye!');
 425         $self->close;
 426         undef;
 427 }
 428
 429 sub art_lookup ($$$) {
 430         my ($self, $art, $set_headers) = @_;
 431         my $ng = $self->{ng};
 432         my ($n, $mid);
 433         my $err;
 434         if (defined $art) {
 435                 if ($art =~ /\A\d+\z/o) {
 436                         $err = '423 no such article number in this group';
 437                         $n = int($art);
 438                         goto find_mid;
 439                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 440                         $mid = $1;
 441                         $err = r430;
 442                         $n = $ng->mm->num_for($mid) if $ng;
 443                         goto found if defined $n;
 444                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 445                                 $n = $g->mm->num_for($mid);
 446                                 if (defined $n) {
 447                                         $ng = $g;
 448                                         goto found;
 449                                 }
 450                         }
 451                         return $err;
 452                 } else {
 453                         return r501;
 454                 }
 455         } else {
 456                 $err = '420 no current article has been selected';
 457                 $n = $self->{article};
 458                 defined $n or return $err;
 459 find_mid:
 460                 $ng or return '412 no newsgroup has been selected';
 461                 $mid = $ng->mm->mid_for($n);
 462                 defined $mid or return $err;
 463         }
 464 found:
 465         my $o = 'HEAD:' . mid2path($mid);
 466         my $bytes;
 467         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 468         return $err unless $s;
 469         my $lines;
 470         if ($set_headers) {
 471                 $s->header_set('Newsgroups', $ng->{name});
 472                 $s->header_set('Xref', xref($ng, $n));
 473                 $lines = $s->body =~ tr!\n!\n!;
 474
 475                 # must be last
 476                 $s->body_set('') if ($set_headers == 2);
 477         }
 478         [ $n, $mid, $s, $bytes, $lines, $ng ];
 479 }
 480
 481 sub simple_body_write ($$) {
 482         my ($self, $s) = @_;
 483         my $body = $s->body;
 484         $s->body_set('');
 485         $body =~ s/^\./../smg;
 486         $body =~ s/(?<!\r)\n/\r\n/sg;
 487         do_more($self, $body);
 488         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 489         '.'
 490 }
 491
 492 sub set_art {
 493         my ($self, $art) = @_;
 494         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 495 }
 496
 497 sub cmd_article ($;$) {
 498         my ($self, $art) = @_;
 499         my $r = art_lookup($self, $art, 1);
 500         return $r unless ref $r;
 501         my ($n, $mid, $s) = @$r;
 502         set_art($self, $art);
 503         more($self, "220 $n <$mid> article retrieved - head and body follow");
 504         do_more($self, $s->header_obj->as_string);
 505         do_more($self, "\r\n");
 506         simple_body_write($self, $s);
 507 }
 508
 509 sub cmd_head ($;$) {
 510         my ($self, $art) = @_;
 511         my $r = art_lookup($self, $art, 2);
 512         return $r unless ref $r;
 513         my ($n, $mid, $s) = @$r;
 514         set_art($self, $art);
 515         more($self, "221 $n <$mid> article retrieved - head follows");
 516         do_more($self, $s->header_obj->as_string);
 517         '.'
 518 }
 519
 520 sub cmd_body ($;$) {
 521         my ($self, $art) = @_;
 522         my $r = art_lookup($self, $art, 0);
 523         return $r unless ref $r;
 524         my ($n, $mid, $s) = @$r;
 525         set_art($self, $art);
 526         more($self, "222 $n <$mid> article retrieved - body follows");
 527         simple_body_write($self, $s);
 528 }
 529
 530 sub cmd_stat ($;$) {
 531         my ($self, $art) = @_;
 532         my $r = art_lookup($self, $art, 0);
 533         return $r unless ref $r;
 534         my ($n, $mid, undef) = @$r;
 535         set_art($self, $art);
 536         "223 $n <$mid> article retrieved - request text separately";
 537 }
 538
 539 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 540
 541 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 542
 543 sub cmd_help ($) {
 544         my ($self) = @_;
 545         more($self, '100 help text follows');
 546         '.'
 547 }
 548
 549 sub get_range ($$) {
 550         my ($self, $range) = @_;
 551         my $ng = $self->{ng} or return '412 no news group has been selected';
 552         defined $range or return '420 No article(s) selected';
 553         my ($beg, $end);
 554         my ($min, $max) = $ng->mm->minmax;
 555         if ($range =~ /\A(\d+)\z/) {
 556                 $beg = $end = $1;
 557         } elsif ($range =~ /\A(\d+)-\z/) {
 558                 ($beg, $end) = ($1, $max);
 559         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 560                 ($beg, $end) = ($1, $2);
 561         } else {
 562                 return r501;
 563         }
 564         $beg = $min if ($beg < $min);
 565         $end = $max if ($end > $max);
 566         return '420 No article(s) selected' if ($beg > $end);
 567         [ $beg, $end ];
 568 }
 569
 570 sub long_response ($$$$) {
 571         my ($self, $beg, $end, $cb) = @_;
 572         die "BUG: nested long response" if $self->{long_res};
 573
 574         my $fd = $self->{fd};
 575         defined $fd or return;
 576         # make sure we disable reading during a long response,
 577         # clients should not be sending us stuff and making us do more
 578         # work while we are stream a response to them
 579         $self->watch_read(0);
 580         my $t0 = now();
 581         $self->{long_res} = sub {
 582                 # limit our own running time for fairness with other
 583                 # clients and to avoid buffering too much:
 584                 my $lim = 100;
 585
 586                 my $err;
 587                 do {
 588                         eval { $cb->(\$beg) };
 589                 } until (($err = $@) || $self->{closed} ||
 590                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 591
 592                 if ($err || $self->{closed}) {
 593                         $self->{long_res} = undef;
 594
 595                         if ($err) {
 596                                 err($self,
 597                                     "%s during long response[$fd] - %0.6f",
 598                                     $err, now() - $t0);
 599                         }
 600                         if ($self->{closed}) {
 601                                 out($self, " deferred[$fd] aborted - %0.6f",
 602                                            now() - $t0);
 603                         } else {
 604                                 update_idle_time($self);
 605                                 $self->watch_read(1);
 606                         }
 607                 } elsif (!$lim || $self->{write_buf_size}) {
 608                         # no recursion, schedule another call ASAP
 609                         # but only after all pending writes are done
 610                         update_idle_time($self);
 611
 612                         push @$nextq, $self;
 613                         $next_tick ||= Danga::Socket->AddTimer(0, *next_tick);
 614                 } else { # all done!
 615                         $self->{long_res} = undef;
 616                         $self->watch_read(1);
 617                         res($self, '.');
 618                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 619                 }
 620         };
 621         $self->{long_res}->(); # kick off!
 622         undef;
 623 }
 624
 625 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 626         my ($self, $xhdr, $range) = @_;
 627
 628         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 629                 my ($ng, $n) = mid_lookup($self, $1);
 630                 return r430 unless $n;
 631                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 632         } else { # numeric range
 633                 $range = $self->{article} unless defined $range;
 634                 my $r = get_range($self, $range);
 635                 return $r unless ref $r;
 636                 my $mm = $self->{ng}->mm;
 637                 my ($beg, $end) = @$r;
 638                 more($self, $xhdr ? r221 : r225);
 639                 long_response($self, $beg, $end, sub {
 640                         my ($i) = @_;
 641                         my $mid = $mm->mid_for($$i);
 642                         more($self, "$$i <$mid>") if defined $mid;
 643                 });
 644         }
 645 }
 646
 647 sub xref ($$) {
 648         my ($ng, $n) = @_;
 649         "$ng->{domain} $ng->{name}:$n"
 650 }
 651
 652 sub mid_lookup ($$) {
 653         my ($self, $mid) = @_;
 654         my $self_ng = $self->{ng};
 655         if ($self_ng) {
 656                 my $n = $self_ng->mm->num_for($mid);
 657                 return ($self_ng, $n) if defined $n;
 658         }
 659         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 660                 next if defined $self_ng && $ng eq $self_ng;
 661                 my $n = $ng->mm->num_for($mid);
 662                 return ($ng, $n) if defined $n;
 663         }
 664         (undef, undef);
 665 }
 666
 667 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 668         my ($self, $xhdr, $range) = @_;
 669
 670         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 671                 my ($ng, $n) = mid_lookup($self, $1);
 672                 return r430 unless $n;
 673                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 674         } else { # numeric range
 675                 $range = $self->{article} unless defined $range;
 676                 my $r = get_range($self, $range);
 677                 return $r unless ref $r;
 678                 my $ng = $self->{ng};
 679                 my $mm = $ng->mm;
 680                 my ($beg, $end) = @$r;
 681                 more($self, $xhdr ? r221 : r225);
 682                 long_response($self, $beg, $end, sub {
 683                         my ($i) = @_;
 684                         my $mid = $mm->mid_for($$i);
 685                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 686                 });
 687         }
 688 }
 689
 690 sub search_header_for {
 691         my ($srch, $mid, $field) = @_;
 692         my $smsg = $srch->lookup_message($mid) or return;
 693         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 694         $smsg->$field;
 695 }
 696
 697 sub hdr_searchmsg ($$$$) {
 698         my ($self, $xhdr, $field, $range) = @_;
 699         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 700                 my ($ng, $n) = mid_lookup($self, $1);
 701                 return r430 unless $n;
 702                 my $v = search_header_for($ng->search, $range, $field);
 703                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 704         } else { # numeric range
 705                 $range = $self->{article} unless defined $range;
 706                 my $srch = $self->{ng}->search;
 707                 my $mm = $self->{ng}->mm;
 708                 my $r = get_range($self, $range);
 709                 return $r unless ref $r;
 710                 my ($beg, $end) = @$r;
 711                 more($self, $xhdr ? r221 : r225);
 712                 my $off = 0;
 713                 long_response($self, $beg, $end, sub {
 714                         my ($i) = @_;
 715                         my $res = $srch->query_xover($beg, $end, $off);
 716                         my $msgs = $res->{msgs};
 717                         my $nr = scalar @$msgs or return;
 718                         $off += $nr;
 719                         my $tmp = '';
 720                         foreach my $s (@$msgs) {
 721                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 722                         }
 723                         do_more($self, $tmp);
 724                         # -1 to adjust for implicit increment in long_response
 725                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 726                 });
 727         }
 728 }
 729
 730 sub do_hdr ($$$;$) {
 731         my ($self, $xhdr, $header, $range) = @_;
 732         my $sub = lc $header;
 733         if ($sub eq 'message-id') {
 734                 hdr_message_id($self, $xhdr, $range);
 735         } elsif ($sub eq 'xref') {
 736                 hdr_xref($self, $xhdr, $range);
 737         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 738                                 bytes|lines)\z/x) {
 739                 hdr_searchmsg($self, $xhdr, $sub, $range);
 740         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 741                 hdr_searchmsg($self, $xhdr, $1, $range);
 742         } else {
 743                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 744         }
 745 }
 746
 747 # RFC 3977
 748 sub cmd_hdr ($$;$) {
 749         my ($self, $header, $range) = @_;
 750         do_hdr($self, 0, $header, $range);
 751 }
 752
 753 # RFC 2980
 754 sub cmd_xhdr ($$;$) {
 755         my ($self, $header, $range) = @_;
 756         do_hdr($self, 1, $header, $range);
 757 }
 758
 759 sub hdr_mid_prefix ($$$$$) {
 760         my ($self, $xhdr, $ng, $n, $mid) = @_;
 761         return $mid if $xhdr;
 762
 763         # HDR for RFC 3977 users
 764         if (my $self_ng = $self->{ng}) {
 765                 ($self_ng eq $ng) ? $n : '0';
 766         } else {
 767                 '0';
 768         }
 769 }
 770
 771 sub hdr_mid_response ($$$$$$) {
 772         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 773         my $res = '';
 774         if ($xhdr) {
 775                 $res .= r221 . "\r\n";
 776                 $res .= "$mid $v\r\n";
 777         } else {
 778                 $res .= r225 . "\r\n";
 779                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 780                 $res .= "$pfx $v\r\n";
 781         }
 782         res($self, $res .= '.');
 783         undef;
 784 }
 785
 786 sub cmd_xrover ($;$) {
 787         my ($self, $range) = @_;
 788         my $ng = $self->{ng} or return '412 no newsgroup selected';
 789         (defined $range && $range =~ /[<>]/) and
 790                 return '420 No article(s) selected'; # no message IDs
 791
 792         $range = $self->{article} unless defined $range;
 793         my $r = get_range($self, $range);
 794         return $r unless ref $r;
 795         my ($beg, $end) = @$r;
 796         my $mm = $ng->mm;
 797         my $srch = $ng->search;
 798         more($self, '224 Overview information follows');
 799         long_response($self, $beg, $end, sub {
 800                 my ($i) = @_;
 801                 my $mid = $mm->mid_for($$i) or return;
 802                 my $h = search_header_for($srch, $mid, 'references');
 803                 more($self, "$$i $h");
 804         });
 805 }
 806
 807 sub over_line ($$) {
 808         my ($num, $smsg) = @_;
 809         # n.b. field access and procedural calls can be
 810         # 10%-15% faster than OO method calls:
 811         join("\t", $num,
 812                 $smsg->{subject},
 813                 $smsg->{from},
 814                 PublicInbox::SearchMsg::date($smsg),
 815                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 816                 $smsg->{references},
 817                 PublicInbox::SearchMsg::bytes($smsg),
 818                 PublicInbox::SearchMsg::lines($smsg));
 819 }
 820
 821 sub cmd_over ($;$) {
 822         my ($self, $range) = @_;
 823         if ($range && $range =~ /\A<(.+)>\z/) {
 824                 my ($ng, $n) = mid_lookup($self, $1);
 825                 my $smsg = $ng->search->lookup_message($range) or
 826                         return '430 No article with that message-id';
 827                 more($self, '224 Overview information follows (multi-line)');
 828                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 829
 830                 # Only set article number column if it's the current group
 831                 my $self_ng = $self->{ng};
 832                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 833                 more($self, over_line($n, $smsg));
 834                 '.';
 835         } else {
 836                 cmd_xover($self, $range);
 837         }
 838 }
 839
 840 sub cmd_xover ($;$) {
 841         my ($self, $range) = @_;
 842         $range = $self->{article} unless defined $range;
 843         my $r = get_range($self, $range);
 844         return $r unless ref $r;
 845         my ($beg, $end) = @$r;
 846         more($self, "224 Overview information follows for $beg to $end");
 847         my $srch = $self->{ng}->search;
 848         my $off = 0;
 849         long_response($self, $beg, $end, sub {
 850                 my ($i) = @_;
 851                 my $res = $srch->query_xover($beg, $end, $off);
 852                 my $msgs = $res->{msgs};
 853                 my $nr = scalar @$msgs or return;
 854                 $off += $nr;
 855
 856                 # OVERVIEW.FMT
 857                 more($self, join("\r\n", map {
 858                         over_line(PublicInbox::SearchMsg::num($_), $_);
 859                         } @$msgs));
 860
 861                 # -1 to adjust for implicit increment in long_response
 862                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 863         });
 864 }
 865
 866 sub cmd_xpath ($$) {
 867         my ($self, $mid) = @_;
 868         return r501 unless $mid =~ /\A<(.+)>\z/;
 869         $mid = $1;
 870         my @paths;
 871         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 872                 my $n = $ng->mm->num_for($mid);
 873                 push @paths, "$ng->{name}/$n" if defined $n;
 874         }
 875         return '430 no such article on server' unless @paths;
 876         '223 '.join(' ', @paths);
 877 }
 878
 879 sub res ($$) {
 880         my ($self, $line) = @_;
 881         do_write($self, $line . "\r\n");
 882 }
 883
 884 sub more ($$) {
 885         my ($self, $line) = @_;
 886         do_more($self, $line . "\r\n");
 887 }
 888
 889 sub do_write ($$) {
 890         my ($self, $data) = @_;
 891         my $done = $self->write($data);
 892         die if $self->{closed};
 893
 894         # Do not watch for readability if we have data in the queue,
 895         # instead re-enable watching for readability when we can
 896         $self->watch_read(0) if (!$done || $self->{long_res});
 897
 898         $done;
 899 }
 900
 901 sub err ($$;@) {
 902         my ($self, $fmt, @args) = @_;
 903         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 904 }
 905
 906 sub out ($$;@) {
 907         my ($self, $fmt, @args) = @_;
 908         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 909 }
 910
 911 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 912
 913 sub do_more ($$) {
 914         my ($self, $data) = @_;
 915         if (MSG_MORE && !$self->{write_buf_size}) {
 916                 my $n = send($self->{sock}, $data, MSG_MORE);
 917                 if (defined $n) {
 918                         my $dlen = length($data);
 919                         return 1 if $n == $dlen; # all done!
 920                         $data = substr($data, $n, $dlen - $n);
 921                 }
 922         }
 923         do_write($self, $data);
 924 }
 925
 926 # callbacks for Danga::Socket
 927
 928 sub event_hup { $_[0]->close }
 929 sub event_err { $_[0]->close }
 930
 931 sub event_write {
 932         my ($self) = @_;
 933         update_idle_time($self);
 934         # only continue watching for readability when we are done writing:
 935         if ($self->write(undef) == 1 && !$self->{long_res}) {
 936                 $self->watch_read(1);
 937         }
 938 }
 939
 940 sub event_read {
 941         my ($self) = @_;
 942         use constant LINE_MAX => 512; # RFC 977 section 2.3
 943         my $r = 1;
 944
 945         my $buf = $self->read(LINE_MAX) or return $self->close;
 946         $self->{rbuf} .= $$buf;
 947         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 948                 my $line = $1;
 949                 my $t0 = now();
 950                 my $fd = $self->{fd};
 951                 $r = eval { process_line($self, $line) };
 952                 my $d = $self->{long_res} ?
 953                         " deferred[$fd]" : '';
 954                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 955         }
 956
 957         return $self->close if $r < 0;
 958         my $len = length($self->{rbuf});
 959         return $self->close if ($len >= LINE_MAX);
 960         update_idle_time($self);
 961 }
 962
 963 sub watch_read {
 964         my ($self, $bool) = @_;
 965         my $rv = $self->SUPER::watch_read($bool);
 966         if ($bool && $self->{rbuf} ne '') {
 967                 # Force another read if there is a pipelined request.
 968                 # We don't know if the socket has anything for us to read,
 969                 # and we must double-check again by the time the timer fires
 970                 # in case we really did dispatch a read event and started
 971                 # another long response.
 972                 push @$nextq, $self;
 973                 $next_tick ||= Danga::Socket->AddTimer(0, *next_tick);
 974         }
 975         $rv;
 976 }
 977
 978 # for graceful shutdown in PublicInbox::Daemon:
 979 sub busy () {
 980         my ($self) = @_;
 981         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 982 }
 983
 984 1;