lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 use Email::MIME;
  15 use Data::Dumper qw(Dumper);
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use constant {
  19         r501 => '501 command syntax error',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24         long_response_limit => 0xffffffff,
  25 };
  26
  27 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  28
  29 my @OVERVIEW = qw(Subject From Date Message-ID References);
  30 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33
  34 # disable commands with easy DoS potential:
  35 # LISTGROUP could get pretty bad, too...
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $EXPTIMER;
  40 our $EXPTIME = 180; # 3 minutes
  41
  42 sub update_idle_time ($) {
  43         my ($self) = @_;
  44         my $tmp = $self->{sock} or return;
  45         $tmp = fileno($tmp);
  46         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  47 }
  48
  49 sub expire_old () {
  50         my $now = now();
  51         my $exp = $EXPTIME;
  52         my $old = $now - $exp;
  53         my $next = $now + $exp;
  54         my $nr = 0;
  55         my %new;
  56         while (my ($fd, $v) = each %$EXPMAP) {
  57                 my ($idle_time, $nntp) = @$v;
  58                 if ($idle_time < $old) {
  59                         $nntp->close; # idempotent
  60                 } else {
  61                         my $nexp = $idle_time + $exp;
  62                         $next = $nexp if ($nexp < $next);
  63                         ++$nr;
  64                         $new{$fd} = $v;
  65                 }
  66         }
  67         $EXPMAP = \%new;
  68         if ($nr) {
  69                 $next -= $now;
  70                 $next = 0 if $next < 0;
  71                 $EXPTIMER = Danga::Socket->AddTimer($next, *expire_old);
  72         } else {
  73                 $EXPTIMER = undef;
  74                 # noop to kick outselves out of the loop so descriptors
  75                 # really get closed
  76                 Danga::Socket->AddTimer(0, sub {});
  77         }
  78 }
  79
  80 sub new ($$$) {
  81         my ($class, $sock, $nntpd) = @_;
  82         my $self = fields::new($class);
  83         binmode $sock, ':utf8'; # RFC 3977
  84         $self->SUPER::new($sock);
  85         $self->{nntpd} = $nntpd;
  86         res($self, '201 server ready - post via email');
  87         $self->{rbuf} = '';
  88         $self->watch_read(1);
  89         update_idle_time($self);
  90         $EXPTIMER ||= Danga::Socket->AddTimer($EXPTIME, *expire_old);
  91         $self;
  92 }
  93
  94 sub args_ok ($$) {
  95         my ($cb, $argc) = @_;
  96         my $tot = prototype $cb;
  97         my ($nreq, undef) = split(';', $tot);
  98         $nreq = ($nreq =~ tr/$//) - 1;
  99         $tot = ($tot =~ tr/$//) - 1;
 100         ($argc <= $tot && $argc >= $nreq);
 101 }
 102
 103 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 104 sub process_line ($$) {
 105         my ($self, $l) = @_;
 106         my ($req, @args) = split(/\s+/, $l);
 107         $req = lc($req);
 108         $req = eval {
 109                 no strict 'refs';
 110                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 111         };
 112         return res($self, '500 command not recognized') unless $req;
 113         return res($self, r501) unless args_ok($req, scalar @args);
 114
 115         my $res = eval { $req->($self, @args) };
 116         my $err = $@;
 117         if ($err && !$self->{closed}) {
 118                 chomp($l = Dumper(\$l));
 119                 err($self, 'error from: %s (%s)', $l, $err);
 120                 $res = '503 program fault - command not performed';
 121         }
 122         return 0 unless defined $res;
 123         res($self, $res);
 124 }
 125
 126 sub cmd_mode ($$) {
 127         my ($self, $arg) = @_;
 128         $arg = uc $arg;
 129         return r501 unless $arg eq 'READER';
 130         '201 Posting prohibited';
 131 }
 132
 133 sub cmd_slave ($) { '202 slave status noted' }
 134
 135 sub cmd_xgtitle ($;$) {
 136         my ($self, $wildmat) = @_;
 137         more($self, '282 list of groups and descriptions follows');
 138         list_newsgroups($self, $wildmat);
 139         '.'
 140 }
 141
 142 sub list_overview_fmt ($) {
 143         my ($self) = @_;
 144         do_more($self, $OVERVIEW_FMT);
 145 }
 146
 147 sub list_headers ($;$) {
 148         my ($self) = @_;
 149         do_more($self, $LIST_HEADERS);
 150 }
 151
 152 sub list_active ($;$) {
 153         my ($self, $wildmat) = @_;
 154         wildmat2re($wildmat);
 155         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 156                 $ng->{name} =~ $wildmat or next;
 157                 group_line($self, $ng);
 158         }
 159 }
 160
 161 sub list_active_times ($;$) {
 162         my ($self, $wildmat) = @_;
 163         wildmat2re($wildmat);
 164         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 165                 $ng->{name} =~ $wildmat or next;
 166                 my $c = eval { $ng->mm->created_at } || time;
 167                 more($self, "$ng->{name} $c $ng->{address}");
 168         }
 169 }
 170
 171 sub list_newsgroups ($;$) {
 172         my ($self, $wildmat) = @_;
 173         wildmat2re($wildmat);
 174         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 175                 $ng->{name} =~ $wildmat or next;
 176                 my $d = $ng->description;
 177                 more($self, "$ng->{name} $d");
 178         }
 179 }
 180
 181 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 182 sub cmd_list ($;$$) {
 183         my ($self, @args) = @_;
 184         if (scalar @args) {
 185                 my $arg = shift @args;
 186                 $arg =~ tr/A-Z./a-z_/;
 187                 $arg = "list_$arg";
 188                 return r501 if $DISABLED{$arg};
 189
 190                 $arg = eval {
 191                         no strict 'refs';
 192                         *{$arg}{CODE};
 193                 };
 194                 return r501 unless $arg && args_ok($arg, scalar @args);
 195                 more($self, '215 information follows');
 196                 $arg->($self, @args);
 197         } else {
 198                 more($self, '215 list of newsgroups follows');
 199                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 200                         group_line($self, $ng);
 201                 }
 202         }
 203         '.'
 204 }
 205
 206 sub cmd_listgroup ($;$) {
 207         my ($self, $group) = @_;
 208         if (defined $group) {
 209                 my $res = cmd_group($self, $group);
 210                 return $res if ($res !~ /\A211 /);
 211                 more($self, $res);
 212         }
 213
 214         $self->{ng} or return '412 no newsgroup selected';
 215         long_response($self, 0, long_response_limit, sub {
 216                 my ($i) = @_;
 217                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 218                         my ($ary) = @_;
 219                         more($self, join("\r\n", @$ary));
 220                 });
 221
 222                 # -1 to adjust for implicit increment in long_response
 223                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 224         });
 225 }
 226
 227 sub parse_time ($$;$) {
 228         my ($date, $time, $gmt) = @_;
 229         use Time::Local qw();
 230         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 231         if (defined $gmt) {
 232                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 233                 $gmt = 1;
 234         }
 235         my @now = $gmt ? gmtime : localtime;
 236         my ($YYYY, $MM, $DD);
 237         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 238                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 239         } else { # legacy clients send YYMMDD
 240                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 241                 if ($YYYY > strftime('%y', @now)) {
 242                         my $cur_year = $now[5] + 1900;
 243                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 244                 }
 245         }
 246         if ($gmt) {
 247                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 248         } else {
 249                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 250         }
 251 }
 252
 253 sub group_line ($$) {
 254         my ($self, $ng) = @_;
 255         my ($min, $max) = $ng->mm->minmax;
 256         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 257 }
 258
 259 sub cmd_newgroups ($$$;$$) {
 260         my ($self, $date, $time, $gmt, $dists) = @_;
 261         my $ts = eval { parse_time($date, $time, $gmt) };
 262         return r501 if $@;
 263
 264         # TODO dists
 265         more($self, '231 list of new newsgroups follows');
 266         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 267                 my $c = eval { $ng->mm->created_at } || 0;
 268                 next unless $c > $ts;
 269                 group_line($self, $ng);
 270         }
 271         '.'
 272 }
 273
 274 sub wildmat2re (;$) {
 275         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 276         my %keep;
 277         my $salt = rand;
 278         use Digest::SHA qw(sha1_hex);
 279         my $tmp = $_[0];
 280
 281         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 282                 my $orig = $1;
 283                 my $key = sha1_hex($orig . $salt);
 284                 $orig =~ s/([^\w\-])+/\Q$1/g;
 285                 $keep{$key} = $orig;
 286                 $key
 287                 #gex;
 288         my %map = ('*' => '.*', '?' => '.' );
 289         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 290         if (scalar %keep) {
 291                 $tmp =~ s#([a-f0-9]{40})#
 292                         my $orig = $keep{$1};
 293                         defined $orig ? $orig : $1;
 294                         #ge;
 295         }
 296         $_[0] = qr/\A$tmp\z/;
 297 }
 298
 299 sub ngpat2re (;$) {
 300         return $_[0] = qr/\A\z/ unless defined $_[0];
 301         my %map = ('*' => '.*', ',' => '|');
 302         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 303         $_[0] = qr/\A(?:$_[0])\z/;
 304 }
 305
 306 sub cmd_newnews ($$$$;$$) {
 307         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 308         my $ts = eval { parse_time($date, $time, $gmt) };
 309         return r501 if $@;
 310         more($self, '230 list of new articles by message-id follows');
 311         my ($keep, $skip) = split('!', $newsgroups, 2);
 312         ngpat2re($keep);
 313         ngpat2re($skip);
 314         my @srch;
 315         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 316                 $ng->{name} =~ $keep or next;
 317                 $ng->{name} =~ $skip and next;
 318                 my $srch = $ng->search or next;
 319                 push @srch, $srch;
 320         };
 321         return '.' unless @srch;
 322
 323         $ts .= '..';
 324         my $opts = { asc => 1, limit => 1000, offset => 0 };
 325         long_response($self, 0, long_response_limit, sub {
 326                 my ($i) = @_;
 327                 my $srch = $srch[0];
 328                 my $res = $srch->query($ts, $opts);
 329                 my $msgs = $res->{msgs};
 330                 if (my $nr = scalar @$msgs) {
 331                         more($self, '<' .
 332                                 join(">\r\n<", map { $_->mid } @$msgs ).
 333                                 '>');
 334                         $opts->{offset} += $nr;
 335                 } else {
 336                         shift @srch;
 337                         if (@srch) { # continue onto next newsgroup
 338                                 $opts->{offset} = 0;
 339                         } else { # break out of the long response.
 340                                 $$i = long_response_limit;
 341                         }
 342                 }
 343         });
 344 }
 345
 346 sub cmd_group ($$) {
 347         my ($self, $group) = @_;
 348         my $no_such = '411 no such news group';
 349         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 350
 351         $self->{ng} = $ng;
 352         my ($min, $max) = $ng->mm->minmax;
 353         $min ||= 0;
 354         $max ||= 0;
 355         $self->{article} = $min;
 356         my $est_size = $max - $min;
 357         "211 $est_size $min $max $group";
 358 }
 359
 360 sub article_adj ($$) {
 361         my ($self, $off) = @_;
 362         my $ng = $self->{ng} or return '412 no newsgroup selected';
 363
 364         my $n = $self->{article};
 365         defined $n or return '420 no current article has been selected';
 366
 367         $n += $off;
 368         my $mid = $ng->mm->mid_for($n);
 369         unless ($mid) {
 370                 $n = $off > 0 ? 'next' : 'previous';
 371                 return "421 no $n article in this group";
 372         }
 373         $self->{article} = $n;
 374         "223 $n <$mid> article retrieved - request text separately";
 375 }
 376
 377 sub cmd_next ($) { article_adj($_[0], 1) }
 378 sub cmd_last ($) { article_adj($_[0], -1) }
 379
 380 # We want to encourage using email and CC-ing everybody involved to avoid
 381 # the single-point-of-failure a single server provides.
 382 sub cmd_post ($) {
 383         my ($self) = @_;
 384         my $ng = $self->{ng};
 385         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 386 }
 387
 388 sub cmd_quit ($) {
 389         my ($self) = @_;
 390         res($self, '205 closing connection - goodbye!');
 391         $self->close;
 392         undef;
 393 }
 394
 395 sub art_lookup ($$$) {
 396         my ($self, $art, $set_headers) = @_;
 397         my $ng = $self->{ng};
 398         my ($n, $mid);
 399         my $err;
 400         if (defined $art) {
 401                 if ($art =~ /\A\d+\z/o) {
 402                         $err = '423 no such article number in this group';
 403                         $n = int($art);
 404                         goto find_mid;
 405                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 406                         $mid = $1;
 407                         $err = r430;
 408                         $n = $ng->mm->num_for($mid) if $ng;
 409                         goto found if defined $n;
 410                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 411                                 $n = $g->mm->num_for($mid);
 412                                 if (defined $n) {
 413                                         $ng = $g;
 414                                         goto found;
 415                                 }
 416                         }
 417                         return $err;
 418                 } else {
 419                         return r501;
 420                 }
 421         } else {
 422                 $err = '420 no current article has been selected';
 423                 $n = $self->{article};
 424                 defined $n or return $err;
 425 find_mid:
 426                 $ng or return '412 no newsgroup has been selected';
 427                 $mid = $ng->mm->mid_for($n);
 428                 defined $mid or return $err;
 429         }
 430 found:
 431         my $o = 'HEAD:' . mid2path($mid);
 432         my $bytes;
 433         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 434         return $err unless $s;
 435         my $lines;
 436         if ($set_headers) {
 437                 $s->header_set('Newsgroups', $ng->{name});
 438                 $s->header_set('Xref', xref($ng, $n));
 439                 $lines = $s->body =~ tr!\n!\n!;
 440
 441                 # must be last
 442                 $s->body_set('') if ($set_headers == 2);
 443         }
 444         [ $n, $mid, $s, $bytes, $lines, $ng ];
 445 }
 446
 447 sub simple_body_write ($$) {
 448         my ($self, $s) = @_;
 449         my $body = $s->body;
 450         $s->body_set('');
 451         $body =~ s/^\./../smg;
 452         $body =~ s/(?<!\r)\n/\r\n/sg;
 453         do_more($self, $body);
 454         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 455         '.'
 456 }
 457
 458 sub set_art {
 459         my ($self, $art) = @_;
 460         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 461 }
 462
 463 sub cmd_article ($;$) {
 464         my ($self, $art) = @_;
 465         my $r = art_lookup($self, $art, 1);
 466         return $r unless ref $r;
 467         my ($n, $mid, $s) = @$r;
 468         set_art($self, $art);
 469         more($self, "220 $n <$mid> article retrieved - head and body follow");
 470         do_more($self, $s->header_obj->as_string);
 471         do_more($self, "\r\n");
 472         simple_body_write($self, $s);
 473 }
 474
 475 sub cmd_head ($;$) {
 476         my ($self, $art) = @_;
 477         my $r = art_lookup($self, $art, 2);
 478         return $r unless ref $r;
 479         my ($n, $mid, $s) = @$r;
 480         set_art($self, $art);
 481         more($self, "221 $n <$mid> article retrieved - head follows");
 482         do_more($self, $s->header_obj->as_string);
 483         '.'
 484 }
 485
 486 sub cmd_body ($;$) {
 487         my ($self, $art) = @_;
 488         my $r = art_lookup($self, $art, 0);
 489         return $r unless ref $r;
 490         my ($n, $mid, $s) = @$r;
 491         set_art($self, $art);
 492         more($self, "222 $n <$mid> article retrieved - body follows");
 493         simple_body_write($self, $s);
 494 }
 495
 496 sub cmd_stat ($;$) {
 497         my ($self, $art) = @_;
 498         my $r = art_lookup($self, $art, 0);
 499         return $r unless ref $r;
 500         my ($n, $mid, undef) = @$r;
 501         set_art($self, $art);
 502         "223 $n <$mid> article retrieved - request text separately";
 503 }
 504
 505 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 506
 507 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 508
 509 sub cmd_help ($) {
 510         my ($self) = @_;
 511         more($self, '100 help text follows');
 512         '.'
 513 }
 514
 515 sub get_range ($$) {
 516         my ($self, $range) = @_;
 517         my $ng = $self->{ng} or return '412 no news group has been selected';
 518         defined $range or return '420 No article(s) selected';
 519         my ($beg, $end);
 520         my ($min, $max) = $ng->mm->minmax;
 521         if ($range =~ /\A(\d+)\z/) {
 522                 $beg = $end = $1;
 523         } elsif ($range =~ /\A(\d+)-\z/) {
 524                 ($beg, $end) = ($1, $max);
 525         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 526                 ($beg, $end) = ($1, $2);
 527         } else {
 528                 return r501;
 529         }
 530         $beg = $min if ($beg < $min);
 531         $end = $max if ($end > $max);
 532         return '420 No article(s) selected' if ($beg > $end);
 533         [ $beg, $end ];
 534 }
 535
 536 sub long_response ($$$$) {
 537         my ($self, $beg, $end, $cb) = @_;
 538         die "BUG: nested long response" if $self->{long_res};
 539
 540         my $fd = $self->{fd};
 541         defined $fd or return;
 542         # make sure we disable reading during a long response,
 543         # clients should not be sending us stuff and making us do more
 544         # work while we are stream a response to them
 545         $self->watch_read(0);
 546         my $t0 = now();
 547         $self->{long_res} = sub {
 548                 # limit our own running time for fairness with other
 549                 # clients and to avoid buffering too much:
 550                 my $lim = 100;
 551
 552                 my $err;
 553                 do {
 554                         eval { $cb->(\$beg) };
 555                 } until (($err = $@) || $self->{closed} ||
 556                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 557
 558                 if ($err || $self->{closed}) {
 559                         $self->{long_res} = undef;
 560
 561                         if ($err) {
 562                                 err($self,
 563                                     "%s during long response[$fd] - %0.6f",
 564                                     $err, now() - $t0);
 565                         }
 566                         if ($self->{closed}) {
 567                                 out($self, " deferred[$fd] aborted - %0.6f",
 568                                            now() - $t0);
 569                         } else {
 570                                 update_idle_time($self);
 571                                 $self->watch_read(1);
 572                         }
 573                 } elsif (!$lim || $self->{write_buf_size}) {
 574                         # no recursion, schedule another call ASAP
 575                         # but only after all pending writes are done
 576                         update_idle_time($self);
 577                         Danga::Socket->AddTimer(0, sub {
 578                                 $self->write($self->{long_res});
 579                         });
 580                 } else { # all done!
 581                         $self->{long_res} = undef;
 582                         $self->watch_read(1);
 583                         res($self, '.');
 584                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 585                 }
 586         };
 587         $self->{long_res}->(); # kick off!
 588         undef;
 589 }
 590
 591 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 592         my ($self, $xhdr, $range) = @_;
 593
 594         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 595                 my ($ng, $n) = mid_lookup($self, $1);
 596                 return r430 unless $n;
 597                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 598         } else { # numeric range
 599                 $range = $self->{article} unless defined $range;
 600                 my $r = get_range($self, $range);
 601                 return $r unless ref $r;
 602                 my $mm = $self->{ng}->mm;
 603                 my ($beg, $end) = @$r;
 604                 more($self, $xhdr ? r221 : r225);
 605                 long_response($self, $beg, $end, sub {
 606                         my ($i) = @_;
 607                         my $mid = $mm->mid_for($$i);
 608                         more($self, "$$i <$mid>") if defined $mid;
 609                 });
 610         }
 611 }
 612
 613 sub xref ($$) {
 614         my ($ng, $n) = @_;
 615         "$ng->{domain} $ng->{name}:$n"
 616 }
 617
 618 sub mid_lookup ($$) {
 619         my ($self, $mid) = @_;
 620         my $self_ng = $self->{ng};
 621         if ($self_ng) {
 622                 my $n = $self_ng->mm->num_for($mid);
 623                 return ($self_ng, $n) if defined $n;
 624         }
 625         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 626                 next if defined $self_ng && $ng eq $self_ng;
 627                 my $n = $ng->mm->num_for($mid);
 628                 return ($ng, $n) if defined $n;
 629         }
 630         (undef, undef);
 631 }
 632
 633 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 634         my ($self, $xhdr, $range) = @_;
 635
 636         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 637                 my ($ng, $n) = mid_lookup($self, $1);
 638                 return r430 unless $n;
 639                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 640         } else { # numeric range
 641                 $range = $self->{article} unless defined $range;
 642                 my $r = get_range($self, $range);
 643                 return $r unless ref $r;
 644                 my $ng = $self->{ng};
 645                 my $mm = $ng->mm;
 646                 my ($beg, $end) = @$r;
 647                 more($self, $xhdr ? r221 : r225);
 648                 long_response($self, $beg, $end, sub {
 649                         my ($i) = @_;
 650                         my $mid = $mm->mid_for($$i);
 651                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 652                 });
 653         }
 654 }
 655
 656 sub search_header_for {
 657         my ($srch, $mid, $field) = @_;
 658         my $smsg = $srch->lookup_message($mid) or return;
 659         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 660         $smsg->$field;
 661 }
 662
 663 sub hdr_searchmsg ($$$$) {
 664         my ($self, $xhdr, $field, $range) = @_;
 665         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 666                 my ($ng, $n) = mid_lookup($self, $1);
 667                 return r430 unless $n;
 668                 my $v = search_header_for($ng->search, $range, $field);
 669                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 670         } else { # numeric range
 671                 $range = $self->{article} unless defined $range;
 672                 my $srch = $self->{ng}->search;
 673                 my $mm = $self->{ng}->mm;
 674                 my $r = get_range($self, $range);
 675                 return $r unless ref $r;
 676                 my ($beg, $end) = @$r;
 677                 more($self, $xhdr ? r221 : r225);
 678                 my $off = 0;
 679                 long_response($self, $beg, $end, sub {
 680                         my ($i) = @_;
 681                         my $res = $srch->query_xover($beg, $end, $off);
 682                         my $msgs = $res->{msgs};
 683                         my $nr = scalar @$msgs or return;
 684                         $off += $nr;
 685                         my $tmp = '';
 686                         foreach my $s (@$msgs) {
 687                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 688                         }
 689                         do_more($self, $tmp);
 690                         # -1 to adjust for implicit increment in long_response
 691                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 692                 });
 693         }
 694 }
 695
 696 sub do_hdr ($$$;$) {
 697         my ($self, $xhdr, $header, $range) = @_;
 698         my $sub = lc $header;
 699         if ($sub eq 'message-id') {
 700                 hdr_message_id($self, $xhdr, $range);
 701         } elsif ($sub eq 'xref') {
 702                 hdr_xref($self, $xhdr, $range);
 703         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 704                                 bytes|lines)\z/x) {
 705                 hdr_searchmsg($self, $xhdr, $sub, $range);
 706         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 707                 hdr_searchmsg($self, $xhdr, $1, $range);
 708         } else {
 709                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 710         }
 711 }
 712
 713 # RFC 3977
 714 sub cmd_hdr ($$;$) {
 715         my ($self, $header, $range) = @_;
 716         do_hdr($self, 0, $header, $range);
 717 }
 718
 719 # RFC 2980
 720 sub cmd_xhdr ($$;$) {
 721         my ($self, $header, $range) = @_;
 722         do_hdr($self, 1, $header, $range);
 723 }
 724
 725 sub hdr_mid_prefix ($$$$$) {
 726         my ($self, $xhdr, $ng, $n, $mid) = @_;
 727         return $mid if $xhdr;
 728
 729         # HDR for RFC 3977 users
 730         if (my $self_ng = $self->{ng}) {
 731                 ($self_ng eq $ng) ? $n : '0';
 732         } else {
 733                 '0';
 734         }
 735 }
 736
 737 sub hdr_mid_response ($$$$$$) {
 738         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 739         my $res = '';
 740         if ($xhdr) {
 741                 $res .= r221 . "\r\n";
 742                 $res .= "$mid $v\r\n";
 743         } else {
 744                 $res .= r225 . "\r\n";
 745                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 746                 $res .= "$pfx $v\r\n";
 747         }
 748         res($self, $res .= '.');
 749         undef;
 750 }
 751
 752 sub cmd_xrover ($;$) {
 753         my ($self, $range) = @_;
 754         my $ng = $self->{ng} or return '412 no newsgroup selected';
 755         (defined $range && $range =~ /[<>]/) and
 756                 return '420 No article(s) selected'; # no message IDs
 757
 758         $range = $self->{article} unless defined $range;
 759         my $r = get_range($self, $range);
 760         return $r unless ref $r;
 761         my ($beg, $end) = @$r;
 762         my $mm = $ng->mm;
 763         my $srch = $ng->search;
 764         more($self, '224 Overview information follows');
 765         long_response($self, $beg, $end, sub {
 766                 my ($i) = @_;
 767                 my $mid = $mm->mid_for($$i) or return;
 768                 my $h = search_header_for($srch, $mid, 'references');
 769                 more($self, "$$i $h");
 770         });
 771 }
 772
 773 sub over_line ($$) {
 774         my ($num, $smsg) = @_;
 775         # n.b. field access and procedural calls can be
 776         # 10%-15% faster than OO method calls:
 777         join("\t", $num,
 778                 $smsg->{subject},
 779                 $smsg->{from},
 780                 PublicInbox::SearchMsg::date($smsg),
 781                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 782                 $smsg->{references},
 783                 PublicInbox::SearchMsg::bytes($smsg),
 784                 PublicInbox::SearchMsg::lines($smsg));
 785 }
 786
 787 sub cmd_over ($;$) {
 788         my ($self, $range) = @_;
 789         if ($range && $range =~ /\A<(.+)>\z/) {
 790                 my ($ng, $n) = mid_lookup($self, $1);
 791                 my $smsg = $ng->search->lookup_message($range) or
 792                         return '430 No article with that message-id';
 793                 more($self, '224 Overview information follows (multi-line)');
 794                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 795
 796                 # Only set article number column if it's the current group
 797                 my $self_ng = $self->{ng};
 798                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 799                 more($self, over_line($n, $smsg));
 800                 '.';
 801         } else {
 802                 cmd_xover($self, $range);
 803         }
 804 }
 805
 806 sub cmd_xover ($;$) {
 807         my ($self, $range) = @_;
 808         $range = $self->{article} unless defined $range;
 809         my $r = get_range($self, $range);
 810         return $r unless ref $r;
 811         my ($beg, $end) = @$r;
 812         more($self, "224 Overview information follows for $beg to $end");
 813         my $srch = $self->{ng}->search;
 814         my $off = 0;
 815         long_response($self, $beg, $end, sub {
 816                 my ($i) = @_;
 817                 my $res = $srch->query_xover($beg, $end, $off);
 818                 my $msgs = $res->{msgs};
 819                 my $nr = scalar @$msgs or return;
 820                 $off += $nr;
 821
 822                 # OVERVIEW.FMT
 823                 more($self, join("\r\n", map {
 824                         over_line(PublicInbox::SearchMsg::num($_), $_);
 825                         } @$msgs));
 826
 827                 # -1 to adjust for implicit increment in long_response
 828                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 829         });
 830 }
 831
 832 sub cmd_xpath ($$) {
 833         my ($self, $mid) = @_;
 834         return r501 unless $mid =~ /\A<(.+)>\z/;
 835         $mid = $1;
 836         my @paths;
 837         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 838                 my $n = $ng->mm->num_for($mid);
 839                 push @paths, "$ng->{name}/$n" if defined $n;
 840         }
 841         return '430 no such article on server' unless @paths;
 842         '223 '.join(' ', @paths);
 843 }
 844
 845 sub res ($$) {
 846         my ($self, $line) = @_;
 847         do_write($self, $line . "\r\n");
 848 }
 849
 850 sub more ($$) {
 851         my ($self, $line) = @_;
 852         do_more($self, $line . "\r\n");
 853 }
 854
 855 sub do_write ($$) {
 856         my ($self, $data) = @_;
 857         my $done = $self->write($data);
 858         die if $self->{closed};
 859
 860         # Do not watch for readability if we have data in the queue,
 861         # instead re-enable watching for readability when we can
 862         $self->watch_read(0) if (!$done || $self->{long_res});
 863
 864         $done;
 865 }
 866
 867 sub err ($$;@) {
 868         my ($self, $fmt, @args) = @_;
 869         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 870 }
 871
 872 sub out ($$;@) {
 873         my ($self, $fmt, @args) = @_;
 874         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 875 }
 876
 877 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 878
 879 sub do_more ($$) {
 880         my ($self, $data) = @_;
 881         if (MSG_MORE && !$self->{write_buf_size}) {
 882                 my $n = send($self->{sock}, $data, MSG_MORE);
 883                 if (defined $n) {
 884                         my $dlen = length($data);
 885                         return 1 if $n == $dlen; # all done!
 886                         $data = substr($data, $n, $dlen - $n);
 887                 }
 888         }
 889         do_write($self, $data);
 890 }
 891
 892 # callbacks for Danga::Socket
 893
 894 sub event_hup { $_[0]->close }
 895 sub event_err { $_[0]->close }
 896
 897 sub event_write {
 898         my ($self) = @_;
 899         update_idle_time($self);
 900         # only continue watching for readability when we are done writing:
 901         if ($self->write(undef) == 1 && !$self->{long_res}) {
 902                 $self->watch_read(1);
 903         }
 904 }
 905
 906 sub event_read {
 907         my ($self) = @_;
 908         use constant LINE_MAX => 512; # RFC 977 section 2.3
 909         my $r = 1;
 910
 911         my $buf = $self->read(LINE_MAX) or return $self->close;
 912         $self->{rbuf} .= $$buf;
 913         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 914                 my $line = $1;
 915                 my $t0 = now();
 916                 my $fd = $self->{fd};
 917                 $r = eval { process_line($self, $line) };
 918                 my $d = $self->{long_res} ?
 919                         " deferred[$fd]" : '';
 920                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 921         }
 922
 923         return $self->close if $r < 0;
 924         my $len = length($self->{rbuf});
 925         return $self->close if ($len >= LINE_MAX);
 926         update_idle_time($self);
 927 }
 928
 929 sub watch_read {
 930         my ($self, $bool) = @_;
 931         my $rv = $self->SUPER::watch_read($bool);
 932         if ($bool && $self->{rbuf} ne '') {
 933                 # Force another read if there is a pipelined request.
 934                 # We don't know if the socket has anything for us to read,
 935                 # and we must double-check again by the time the timer fires
 936                 # in case we really did dispatch a read event and started
 937                 # another long response.
 938                 Danga::Socket->AddTimer(0, sub {
 939                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 940                                 event_read($self);
 941                         }
 942                 });
 943         }
 944         $rv;
 945 }
 946
 947 # for graceful shutdown in PublicInbox::Daemon:
 948 sub busy () {
 949         my ($self) = @_;
 950         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 951 }
 952
 953 1;