lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27
  28 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  29 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  30 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  31                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  32
  33 # disable commands with easy DoS potential:
  34 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  35
  36 my $EXPMAP; # fd -> [ idle_time, $self ]
  37 my $expt;
  38 our $EXPTIME = 180; # 3 minutes
  39 my $nextt;
  40
  41 my $nextq = [];
  42 sub next_tick () {
  43         $nextt = undef;
  44         my $q = $nextq;
  45         $nextq = [];
  46         foreach my $nntp (@$q) {
  47                 # for request && response protocols, always finish writing
  48                 # before finishing reading:
  49                 if (my $long_cb = $nntp->{long_res}) {
  50                         $nntp->write($long_cb);
  51                 } else {
  52                         # pipelined request, we bypassed socket-readiness
  53                         # checks to get here:
  54                         event_step($nntp);
  55
  56                         # maybe there's more pipelined data, or we'll have
  57                         # to register it for socket-readiness notifications
  58                         if (!$nntp->{long_res} && $nntp->{sock}) {
  59                                 check_read($nntp);
  60                         }
  61                 }
  62         }
  63 }
  64
  65 sub update_idle_time ($) {
  66         my ($self) = @_;
  67         my $sock = $self->{sock} or return;
  68         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  69 }
  70
  71 sub expire_old () {
  72         my $now = now();
  73         my $exp = $EXPTIME;
  74         my $old = $now - $exp;
  75         my $nr = 0;
  76         my %new;
  77         while (my ($fd, $v) = each %$EXPMAP) {
  78                 my ($idle_time, $nntp) = @$v;
  79                 if ($idle_time < $old) {
  80                         $nntp->close; # idempotent
  81                 } else {
  82                         ++$nr;
  83                         $new{$fd} = $v;
  84                 }
  85         }
  86         $EXPMAP = \%new;
  87         if ($nr) {
  88                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  89         } else {
  90                 $expt = undef;
  91                 # noop to kick outselves out of the loop ASAP so descriptors
  92                 # really get closed
  93                 PublicInbox::EvCleanup::asap(sub {});
  94         }
  95 }
  96
  97 sub new ($$$) {
  98         my ($class, $sock, $nntpd) = @_;
  99         my $self = fields::new($class);
 100         $self->SUPER::new($sock, PublicInbox::DS::EPOLLIN());
 101         $self->{nntpd} = $nntpd;
 102         res($self, '201 ' . $nntpd->{servername} . ' ready - post via email');
 103         $self->{rbuf} = '';
 104         update_idle_time($self);
 105         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 106         $self;
 107 }
 108
 109 sub args_ok ($$) {
 110         my ($cb, $argc) = @_;
 111         my $tot = prototype $cb;
 112         my ($nreq, undef) = split(';', $tot);
 113         $nreq = ($nreq =~ tr/$//) - 1;
 114         $tot = ($tot =~ tr/$//) - 1;
 115         ($argc <= $tot && $argc >= $nreq);
 116 }
 117
 118 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 119 sub process_line ($$) {
 120         my ($self, $l) = @_;
 121         my ($req, @args) = split(/[ \t]/, $l);
 122         return 1 unless defined($req); # skip blank line
 123         $req = lc($req);
 124         $req = eval {
 125                 no strict 'refs';
 126                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 127         };
 128         return res($self, '500 command not recognized') unless $req;
 129         return res($self, r501) unless args_ok($req, scalar @args);
 130
 131         my $res = eval { $req->($self, @args) };
 132         my $err = $@;
 133         if ($err && $self->{sock}) {
 134                 local $/ = "\n";
 135                 chomp($l);
 136                 err($self, 'error from: %s (%s)', $l, $err);
 137                 $res = '503 program fault - command not performed';
 138         }
 139         return 0 unless defined $res;
 140         res($self, $res);
 141 }
 142
 143 sub cmd_mode ($$) {
 144         my ($self, $arg) = @_;
 145         $arg = uc $arg;
 146         return r501 unless $arg eq 'READER';
 147         '201 Posting prohibited';
 148 }
 149
 150 sub cmd_slave ($) { '202 slave status noted' }
 151
 152 sub cmd_xgtitle ($;$) {
 153         my ($self, $wildmat) = @_;
 154         more($self, '282 list of groups and descriptions follows');
 155         list_newsgroups($self, $wildmat);
 156         '.'
 157 }
 158
 159 sub list_overview_fmt ($) {
 160         my ($self) = @_;
 161         msg_more($self, $OVERVIEW_FMT);
 162 }
 163
 164 sub list_headers ($;$) {
 165         my ($self) = @_;
 166         msg_more($self, $LIST_HEADERS);
 167 }
 168
 169 sub list_active ($;$) {
 170         my ($self, $wildmat) = @_;
 171         wildmat2re($wildmat);
 172         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 173                 $ng->{newsgroup} =~ $wildmat or next;
 174                 group_line($self, $ng);
 175         }
 176 }
 177
 178 sub list_active_times ($;$) {
 179         my ($self, $wildmat) = @_;
 180         wildmat2re($wildmat);
 181         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 182                 $ng->{newsgroup} =~ $wildmat or next;
 183                 my $c = eval { $ng->mm->created_at } || time;
 184                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 185         }
 186 }
 187
 188 sub list_newsgroups ($;$) {
 189         my ($self, $wildmat) = @_;
 190         wildmat2re($wildmat);
 191         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 192                 $ng->{newsgroup} =~ $wildmat or next;
 193                 my $d = $ng->description;
 194                 more($self, "$ng->{newsgroup} $d");
 195         }
 196 }
 197
 198 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 199 sub cmd_list ($;$$) {
 200         my ($self, @args) = @_;
 201         if (scalar @args) {
 202                 my $arg = shift @args;
 203                 $arg =~ tr/A-Z./a-z_/;
 204                 $arg = "list_$arg";
 205                 return r501 if $DISABLED{$arg};
 206
 207                 $arg = eval {
 208                         no strict 'refs';
 209                         *{$arg}{CODE};
 210                 };
 211                 return r501 unless $arg && args_ok($arg, scalar @args);
 212                 more($self, '215 information follows');
 213                 $arg->($self, @args);
 214         } else {
 215                 more($self, '215 list of newsgroups follows');
 216                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 217                         group_line($self, $ng);
 218                 }
 219         }
 220         '.'
 221 }
 222
 223 sub cmd_listgroup ($;$) {
 224         my ($self, $group) = @_;
 225         if (defined $group) {
 226                 my $res = cmd_group($self, $group);
 227                 return $res if ($res !~ /\A211 /);
 228                 more($self, $res);
 229         }
 230
 231         $self->{ng} or return '412 no newsgroup selected';
 232         my $n = 0;
 233         long_response($self, sub {
 234                 my $ary = $self->{ng}->mm->ids_after(\$n);
 235                 scalar @$ary or return;
 236                 more($self, join("\r\n", @$ary));
 237                 1;
 238         });
 239 }
 240
 241 sub parse_time ($$;$) {
 242         my ($date, $time, $gmt) = @_;
 243         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 244         if (defined $gmt) {
 245                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 246                 $gmt = 1;
 247         }
 248         my @now = $gmt ? gmtime : localtime;
 249         my ($YYYY, $MM, $DD);
 250         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 251                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 252         } else { # legacy clients send YYMMDD
 253                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 254                 my $cur_year = $now[5] + 1900;
 255                 if ($YYYY > $cur_year) {
 256                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 257                 }
 258         }
 259         if ($gmt) {
 260                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 261         } else {
 262                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 263         }
 264 }
 265
 266 sub group_line ($$) {
 267         my ($self, $ng) = @_;
 268         my ($min, $max) = $ng->mm->minmax;
 269         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 270 }
 271
 272 sub cmd_newgroups ($$$;$$) {
 273         my ($self, $date, $time, $gmt, $dists) = @_;
 274         my $ts = eval { parse_time($date, $time, $gmt) };
 275         return r501 if $@;
 276
 277         # TODO dists
 278         more($self, '231 list of new newsgroups follows');
 279         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 280                 my $c = eval { $ng->mm->created_at } || 0;
 281                 next unless $c > $ts;
 282                 group_line($self, $ng);
 283         }
 284         '.'
 285 }
 286
 287 sub wildmat2re (;$) {
 288         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 289         my %keep;
 290         my $salt = rand;
 291         my $tmp = $_[0];
 292
 293         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 294                 my $orig = $1;
 295                 my $key = sha1_hex($orig . $salt);
 296                 $orig =~ s/([^\w\-])+/\Q$1/g;
 297                 $keep{$key} = $orig;
 298                 $key
 299                 #gex;
 300         my %map = ('*' => '.*', '?' => '.' );
 301         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 302         if (scalar %keep) {
 303                 $tmp =~ s#([a-f0-9]{40})#
 304                         my $orig = $keep{$1};
 305                         defined $orig ? $orig : $1;
 306                         #ge;
 307         }
 308         $_[0] = qr/\A$tmp\z/;
 309 }
 310
 311 sub ngpat2re (;$) {
 312         return $_[0] = qr/\A\z/ unless defined $_[0];
 313         my %map = ('*' => '.*', ',' => '|');
 314         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 315         $_[0] = qr/\A(?:$_[0])\z/;
 316 }
 317
 318 sub cmd_newnews ($$$$;$$) {
 319         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 320         my $ts = eval { parse_time($date, $time, $gmt) };
 321         return r501 if $@;
 322         more($self, '230 list of new articles by message-id follows');
 323         my ($keep, $skip) = split('!', $newsgroups, 2);
 324         ngpat2re($keep);
 325         ngpat2re($skip);
 326         my @over;
 327         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 328                 $ng->{newsgroup} =~ $keep or next;
 329                 $ng->{newsgroup} =~ $skip and next;
 330                 my $over = $ng->over or next;
 331                 push @over, $over;
 332         };
 333         return '.' unless @over;
 334
 335         my $prev = 0;
 336         long_response($self, sub {
 337                 my $over = $over[0];
 338                 my $msgs = $over->query_ts($ts, $prev);
 339                 if (scalar @$msgs) {
 340                         more($self, '<' .
 341                                 join(">\r\n<", map { $_->mid } @$msgs ).
 342                                 '>');
 343                         $prev = $msgs->[-1]->{num};
 344                 } else {
 345                         shift @over;
 346                         if (@over) { # continue onto next newsgroup
 347                                 $prev = 0;
 348                                 return 1;
 349                         } else { # break out of the long response.
 350                                 return;
 351                         }
 352                 }
 353         });
 354 }
 355
 356 sub cmd_group ($$) {
 357         my ($self, $group) = @_;
 358         my $no_such = '411 no such news group';
 359         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 360
 361         $self->{ng} = $ng;
 362         my ($min, $max) = $ng->mm->minmax;
 363         $min ||= 0;
 364         $max ||= 0;
 365         $self->{article} = $min;
 366         my $est_size = $max - $min;
 367         "211 $est_size $min $max $group";
 368 }
 369
 370 sub article_adj ($$) {
 371         my ($self, $off) = @_;
 372         my $ng = $self->{ng} or return '412 no newsgroup selected';
 373
 374         my $n = $self->{article};
 375         defined $n or return '420 no current article has been selected';
 376
 377         $n += $off;
 378         my $mid = $ng->mm->mid_for($n);
 379         unless ($mid) {
 380                 $n = $off > 0 ? 'next' : 'previous';
 381                 return "421 no $n article in this group";
 382         }
 383         $self->{article} = $n;
 384         "223 $n <$mid> article retrieved - request text separately";
 385 }
 386
 387 sub cmd_next ($) { article_adj($_[0], 1) }
 388 sub cmd_last ($) { article_adj($_[0], -1) }
 389
 390 # We want to encourage using email and CC-ing everybody involved to avoid
 391 # the single-point-of-failure a single server provides.
 392 sub cmd_post ($) {
 393         my ($self) = @_;
 394         my $ng = $self->{ng};
 395         $ng ? "440 mailto:$ng->{-primary_address} to post"
 396                 : '440 posting not allowed'
 397 }
 398
 399 sub cmd_quit ($) {
 400         my ($self) = @_;
 401         res($self, '205 closing connection - goodbye!');
 402         $self->close;
 403         undef;
 404 }
 405
 406 sub header_append ($$$) {
 407         my ($hdr, $k, $v) = @_;
 408         my @v = $hdr->header($k);
 409         foreach (@v) {
 410                 return if $v eq $_;
 411         }
 412         $hdr->header_set($k, @v, $v);
 413 }
 414
 415 sub xref ($$$$) {
 416         my ($self, $ng, $n, $mid) = @_;
 417         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 418
 419         # num_for is pretty cheap and sometimes we'll lookup the existence
 420         # of an article without getting even the OVER info.  In other words,
 421         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 422         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 423         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 424                 next if $ng eq $other;
 425                 my $num = eval { $other->mm->num_for($mid) } or next;
 426                 $ret .= " $other->{newsgroup}:$num";
 427         }
 428         $ret;
 429 }
 430
 431 sub set_nntp_headers ($$$$$) {
 432         my ($self, $hdr, $ng, $n, $mid) = @_;
 433
 434         # why? leafnode requires a Path: header for some inexplicable
 435         # reason.  We'll fake the shortest one possible.
 436         $hdr->header_set('Path', 'y');
 437
 438         # leafnode (and maybe other NNTP clients) have trouble dealing
 439         # with v2 messages which have multiple Message-IDs (either due
 440         # to our own content-based dedupe or buggy git-send-email versions).
 441         my @mids = $hdr->header('Message-ID');
 442         if (scalar(@mids) > 1) {
 443                 my $mid0 = "<$mid>";
 444                 $hdr->header_set('Message-ID', $mid0);
 445                 my @alt = $hdr->header('X-Alt-Message-ID');
 446                 my %seen = map { $_ => 1 } (@alt, $mid0);
 447                 foreach my $m (@mids) {
 448                         next if $seen{$m}++;
 449                         push @alt, $m;
 450                 }
 451                 $hdr->header_set('X-Alt-Message-ID', @alt);
 452         }
 453
 454         # clobber some
 455         my $xref = xref($self, $ng, $n, $mid);
 456         $hdr->header_set('Xref', $xref);
 457         $xref =~ s/:[0-9]+//g;
 458         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 459         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 460         if (my $url = $ng->base_url) {
 461                 $mid = mid_escape($mid);
 462                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 463                 header_append($hdr, 'List-Archive', "<$url>");
 464         }
 465 }
 466
 467 sub art_lookup ($$$) {
 468         my ($self, $art, $set_headers) = @_;
 469         my $ng = $self->{ng};
 470         my ($n, $mid);
 471         my $err;
 472         if (defined $art) {
 473                 if ($art =~ /\A[0-9]+\z/) {
 474                         $err = '423 no such article number in this group';
 475                         $n = int($art);
 476                         goto find_mid;
 477                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 478                         $mid = $1;
 479                         $err = r430;
 480                         $n = $ng->mm->num_for($mid) if $ng;
 481                         goto found if defined $n;
 482                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 483                                 $n = $g->mm->num_for($mid);
 484                                 if (defined $n) {
 485                                         $ng = $g;
 486                                         goto found;
 487                                 }
 488                         }
 489                         return $err;
 490                 } else {
 491                         return r501;
 492                 }
 493         } else {
 494                 $err = '420 no current article has been selected';
 495                 $n = $self->{article};
 496                 defined $n or return $err;
 497 find_mid:
 498                 $ng or return '412 no newsgroup has been selected';
 499                 $mid = $ng->mm->mid_for($n);
 500                 defined $mid or return $err;
 501         }
 502 found:
 503         my $smsg = $ng->over->get_art($n) or return $err;
 504         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 505         my $s = Email::Simple->new($msg);
 506         if ($set_headers) {
 507                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 508
 509                 # must be last
 510                 $s->body_set('') if ($set_headers == 2);
 511         }
 512         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 513 }
 514
 515 sub simple_body_write ($$) {
 516         my ($self, $s) = @_;
 517         my $body = $s->body;
 518         $s->body_set('');
 519         $body =~ s/^\./../smg;
 520         $body =~ s/(?<!\r)\n/\r\n/sg;
 521         msg_more($self, $body);
 522         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 523         '.'
 524 }
 525
 526 sub set_art {
 527         my ($self, $art) = @_;
 528         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 529 }
 530
 531 sub _header ($) {
 532         my $hdr = $_[0]->header_obj->as_string;
 533         utf8::encode($hdr);
 534         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 535
 536         # for leafnode compatibility, we need to ensure Message-ID headers
 537         # are only a single line.  We can't subclass Email::Simple::Header
 538         # and override _default_fold_at in here, either; since that won't
 539         # affect messages already in the archive.
 540         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 541
 542         $hdr
 543 }
 544
 545 sub cmd_article ($;$) {
 546         my ($self, $art) = @_;
 547         my $r = art_lookup($self, $art, 1);
 548         return $r unless ref $r;
 549         my ($n, $mid, $s) = @$r;
 550         set_art($self, $art);
 551         more($self, "220 $n <$mid> article retrieved - head and body follow");
 552         msg_more($self, _header($s));
 553         msg_more($self, "\r\n");
 554         simple_body_write($self, $s);
 555 }
 556
 557 sub cmd_head ($;$) {
 558         my ($self, $art) = @_;
 559         my $r = art_lookup($self, $art, 2);
 560         return $r unless ref $r;
 561         my ($n, $mid, $s) = @$r;
 562         set_art($self, $art);
 563         more($self, "221 $n <$mid> article retrieved - head follows");
 564         msg_more($self, _header($s));
 565         '.'
 566 }
 567
 568 sub cmd_body ($;$) {
 569         my ($self, $art) = @_;
 570         my $r = art_lookup($self, $art, 0);
 571         return $r unless ref $r;
 572         my ($n, $mid, $s) = @$r;
 573         set_art($self, $art);
 574         more($self, "222 $n <$mid> article retrieved - body follows");
 575         simple_body_write($self, $s);
 576 }
 577
 578 sub cmd_stat ($;$) {
 579         my ($self, $art) = @_;
 580         my $r = art_lookup($self, $art, 0);
 581         return $r unless ref $r;
 582         my ($n, $mid, undef) = @$r;
 583         set_art($self, $art);
 584         "223 $n <$mid> article retrieved - request text separately";
 585 }
 586
 587 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 588
 589 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 590
 591 sub cmd_help ($) {
 592         my ($self) = @_;
 593         more($self, '100 help text follows');
 594         '.'
 595 }
 596
 597 sub get_range ($$) {
 598         my ($self, $range) = @_;
 599         my $ng = $self->{ng} or return '412 no news group has been selected';
 600         defined $range or return '420 No article(s) selected';
 601         my ($beg, $end);
 602         my ($min, $max) = $ng->mm->minmax;
 603         if ($range =~ /\A([0-9]+)\z/) {
 604                 $beg = $end = $1;
 605         } elsif ($range =~ /\A([0-9]+)-\z/) {
 606                 ($beg, $end) = ($1, $max);
 607         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 608                 ($beg, $end) = ($1, $2);
 609         } else {
 610                 return r501;
 611         }
 612         $beg = $min if ($beg < $min);
 613         $end = $max if ($end > $max);
 614         return '420 No article(s) selected' if ($beg > $end);
 615         [ $beg, $end ];
 616 }
 617
 618 sub long_response ($$) {
 619         my ($self, $cb) = @_;
 620         die "BUG: nested long response" if $self->{long_res};
 621
 622         my $fd = fileno($self->{sock});
 623         defined $fd or return;
 624         # make sure we disable reading during a long response,
 625         # clients should not be sending us stuff and making us do more
 626         # work while we are stream a response to them
 627         $self->watch_read(0);
 628         my $t0 = now();
 629         $self->{long_res} = sub {
 630                 my $more = eval { $cb->() };
 631                 if ($@ || !$self->{sock}) {
 632                         $self->{long_res} = undef;
 633
 634                         if ($@) {
 635                                 err($self,
 636                                     "%s during long response[$fd] - %0.6f",
 637                                     $@, now() - $t0);
 638                         }
 639                         if ($self->{sock}) {
 640                                 update_idle_time($self);
 641                                 check_read($self);
 642                         } else {
 643                                 out($self, " deferred[$fd] aborted - %0.6f",
 644                                            now() - $t0);
 645                         }
 646                 } elsif ($more) { # $self->{wbuf}:
 647                         # no recursion, schedule another call ASAP
 648                         # but only after all pending writes are done
 649                         update_idle_time($self);
 650
 651                         push @$nextq, $self;
 652                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 653                 } else { # all done!
 654                         $self->{long_res} = undef;
 655                         check_read($self);
 656                         res($self, '.');
 657                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 658                 }
 659         };
 660         $self->{long_res}->(); # kick off!
 661         undef;
 662 }
 663
 664 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 665         my ($self, $xhdr, $range) = @_;
 666
 667         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 668                 my ($ng, $n) = mid_lookup($self, $1);
 669                 return r430 unless $n;
 670                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 671         } else { # numeric range
 672                 $range = $self->{article} unless defined $range;
 673                 my $r = get_range($self, $range);
 674                 return $r unless ref $r;
 675                 my $mm = $self->{ng}->mm;
 676                 my ($beg, $end) = @$r;
 677                 more($self, $xhdr ? r221 : r225);
 678                 long_response($self, sub {
 679                         my $r = $mm->msg_range(\$beg, $end);
 680                         @$r or return;
 681                         more($self, join("\r\n", map {
 682                                 "$_->[0] <$_->[1]>"
 683                         } @$r));
 684                         1;
 685                 });
 686         }
 687 }
 688
 689 sub mid_lookup ($$) {
 690         my ($self, $mid) = @_;
 691         my $self_ng = $self->{ng};
 692         if ($self_ng) {
 693                 my $n = $self_ng->mm->num_for($mid);
 694                 return ($self_ng, $n) if defined $n;
 695         }
 696         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 697                 next if defined $self_ng && $ng eq $self_ng;
 698                 my $n = $ng->mm->num_for($mid);
 699                 return ($ng, $n) if defined $n;
 700         }
 701         (undef, undef);
 702 }
 703
 704 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 705         my ($self, $xhdr, $range) = @_;
 706
 707         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 708                 my $mid = $1;
 709                 my ($ng, $n) = mid_lookup($self, $mid);
 710                 return r430 unless $n;
 711                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 712                                 xref($self, $ng, $n, $mid));
 713         } else { # numeric range
 714                 $range = $self->{article} unless defined $range;
 715                 my $r = get_range($self, $range);
 716                 return $r unless ref $r;
 717                 my $ng = $self->{ng};
 718                 my $mm = $ng->mm;
 719                 my ($beg, $end) = @$r;
 720                 more($self, $xhdr ? r221 : r225);
 721                 long_response($self, sub {
 722                         my $r = $mm->msg_range(\$beg, $end);
 723                         @$r or return;
 724                         more($self, join("\r\n", map {
 725                                 my $num = $_->[0];
 726                                 "$num ".xref($self, $ng, $num, $_->[1]);
 727                         } @$r));
 728                         1;
 729                 });
 730         }
 731 }
 732
 733 sub over_header_for {
 734         my ($over, $num, $field) = @_;
 735         my $smsg = $over->get_art($num) or return;
 736         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 737         $smsg->{$field};
 738 }
 739
 740 sub hdr_searchmsg ($$$$) {
 741         my ($self, $xhdr, $field, $range) = @_;
 742         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 743                 my ($ng, $n) = mid_lookup($self, $1);
 744                 return r430 unless defined $n;
 745                 my $v = over_header_for($ng->over, $n, $field);
 746                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 747         } else { # numeric range
 748                 $range = $self->{article} unless defined $range;
 749                 my $over = $self->{ng}->over;
 750                 my $mm = $self->{ng}->mm;
 751                 my $r = get_range($self, $range);
 752                 return $r unless ref $r;
 753                 my ($beg, $end) = @$r;
 754                 more($self, $xhdr ? r221 : r225);
 755                 my $cur = $beg;
 756                 long_response($self, sub {
 757                         my $msgs = $over->query_xover($cur, $end);
 758                         my $nr = scalar @$msgs or return;
 759                         my $tmp = '';
 760                         foreach my $s (@$msgs) {
 761                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 762                         }
 763                         utf8::encode($tmp);
 764                         msg_more($self, $tmp);
 765                         $cur = $msgs->[-1]->{num} + 1;
 766                 });
 767         }
 768 }
 769
 770 sub do_hdr ($$$;$) {
 771         my ($self, $xhdr, $header, $range) = @_;
 772         my $sub = lc $header;
 773         if ($sub eq 'message-id') {
 774                 hdr_message_id($self, $xhdr, $range);
 775         } elsif ($sub eq 'xref') {
 776                 hdr_xref($self, $xhdr, $range);
 777         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 778                                 bytes|lines)\z/x) {
 779                 hdr_searchmsg($self, $xhdr, $sub, $range);
 780         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 781                 hdr_searchmsg($self, $xhdr, $1, $range);
 782         } else {
 783                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 784         }
 785 }
 786
 787 # RFC 3977
 788 sub cmd_hdr ($$;$) {
 789         my ($self, $header, $range) = @_;
 790         do_hdr($self, 0, $header, $range);
 791 }
 792
 793 # RFC 2980
 794 sub cmd_xhdr ($$;$) {
 795         my ($self, $header, $range) = @_;
 796         do_hdr($self, 1, $header, $range);
 797 }
 798
 799 sub hdr_mid_prefix ($$$$$) {
 800         my ($self, $xhdr, $ng, $n, $mid) = @_;
 801         return $mid if $xhdr;
 802
 803         # HDR for RFC 3977 users
 804         if (my $self_ng = $self->{ng}) {
 805                 ($self_ng eq $ng) ? $n : '0';
 806         } else {
 807                 '0';
 808         }
 809 }
 810
 811 sub hdr_mid_response ($$$$$$) {
 812         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 813         my $res = '';
 814         if ($xhdr) {
 815                 $res .= r221 . "\r\n";
 816                 $res .= "$mid $v\r\n";
 817         } else {
 818                 $res .= r225 . "\r\n";
 819                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 820                 $res .= "$pfx $v\r\n";
 821         }
 822         res($self, $res .= '.');
 823         undef;
 824 }
 825
 826 sub cmd_xrover ($;$) {
 827         my ($self, $range) = @_;
 828         my $ng = $self->{ng} or return '412 no newsgroup selected';
 829         (defined $range && $range =~ /[<>]/) and
 830                 return '420 No article(s) selected'; # no message IDs
 831
 832         $range = $self->{article} unless defined $range;
 833         my $r = get_range($self, $range);
 834         return $r unless ref $r;
 835         my ($beg, $end) = @$r;
 836         my $mm = $ng->mm;
 837         my $over = $ng->over;
 838         more($self, '224 Overview information follows');
 839
 840         long_response($self, sub {
 841                 my $h = over_header_for($over, $beg, 'references');
 842                 more($self, "$beg $h") if defined($h);
 843                 $beg++ < $end;
 844         });
 845 }
 846
 847 sub over_line ($$$$) {
 848         my ($self, $ng, $num, $smsg) = @_;
 849         # n.b. field access and procedural calls can be
 850         # 10%-15% faster than OO method calls:
 851         my $s = join("\t", $num,
 852                 $smsg->{subject},
 853                 $smsg->{from},
 854                 PublicInbox::SearchMsg::date($smsg),
 855                 "<$smsg->{mid}>",
 856                 $smsg->{references},
 857                 $smsg->{bytes},
 858                 $smsg->{lines},
 859                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 860         utf8::encode($s);
 861         $s
 862 }
 863
 864 sub cmd_over ($;$) {
 865         my ($self, $range) = @_;
 866         if ($range && $range =~ /\A<(.+)>\z/) {
 867                 my ($ng, $n) = mid_lookup($self, $1);
 868                 defined $n or return r430;
 869                 my $smsg = $ng->over->get_art($n) or return r430;
 870                 more($self, '224 Overview information follows (multi-line)');
 871
 872                 # Only set article number column if it's the current group
 873                 my $self_ng = $self->{ng};
 874                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 875                 more($self, over_line($self, $ng, $n, $smsg));
 876                 '.';
 877         } else {
 878                 cmd_xover($self, $range);
 879         }
 880 }
 881
 882 sub cmd_xover ($;$) {
 883         my ($self, $range) = @_;
 884         $range = $self->{article} unless defined $range;
 885         my $r = get_range($self, $range);
 886         return $r unless ref $r;
 887         my ($beg, $end) = @$r;
 888         more($self, "224 Overview information follows for $beg to $end");
 889         my $over = $self->{ng}->over;
 890         my $cur = $beg;
 891         long_response($self, sub {
 892                 my $msgs = $over->query_xover($cur, $end);
 893                 my $nr = scalar @$msgs or return;
 894
 895                 # OVERVIEW.FMT
 896                 more($self, join("\r\n", map {
 897                         over_line($self, $self->{ng}, $_->{num}, $_);
 898                         } @$msgs));
 899                 $cur = $msgs->[-1]->{num} + 1;
 900         });
 901 }
 902
 903 sub cmd_xpath ($$) {
 904         my ($self, $mid) = @_;
 905         return r501 unless $mid =~ /\A<(.+)>\z/;
 906         $mid = $1;
 907         my @paths;
 908         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 909                 my $n = $ng->mm->num_for($mid);
 910                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 911         }
 912         return '430 no such article on server' unless @paths;
 913         '223 '.join(' ', @paths);
 914 }
 915
 916 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 917
 918 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 919
 920 sub do_write ($$) {
 921         my $self = $_[0];
 922         my $done = $self->write(\($_[1]));
 923         return 0 unless $self->{sock};
 924
 925         # Do not watch for readability if we have data in the queue,
 926         # instead re-enable watching for readability when we can
 927         $self->watch_read(0) if (!$done || $self->{long_res});
 928
 929         $done;
 930 }
 931
 932 sub err ($$;@) {
 933         my ($self, $fmt, @args) = @_;
 934         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 935 }
 936
 937 sub out ($$;@) {
 938         my ($self, $fmt, @args) = @_;
 939         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 940 }
 941
 942 sub event_step {
 943         my ($self) = @_;
 944
 945         return unless $self->flush_write && $self->{sock};
 946         return if $self->{long_res};
 947
 948         update_idle_time($self);
 949         # only read more requests if we've drained the write buffer,
 950         # otherwise we can be buffering infinitely w/o backpressure
 951
 952         use constant LINE_MAX => 512; # RFC 977 section 2.3
 953         my $rbuf = \($self->{rbuf});
 954         my $r;
 955
 956         if (index($$rbuf, "\n") < 0) {
 957                 my $off = length($$rbuf);
 958                 $r = sysread($self->{sock}, $$rbuf, LINE_MAX, $off);
 959                 unless (defined $r) {
 960                         return if $!{EAGAIN};
 961                         return $self->close;
 962                 }
 963                 return $self->close if $r == 0;
 964         }
 965         $r = 1;
 966         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 967                 my $line = $1;
 968                 return $self->close if $line =~ /[[:cntrl:]]/s;
 969                 my $t0 = now();
 970                 my $fd = fileno($self->{sock});
 971                 $r = eval { process_line($self, $line) };
 972                 my $d = $self->{long_res} ?
 973                         " deferred[$fd]" : '';
 974                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 975         }
 976
 977         return $self->close if $r < 0;
 978         my $len = length($$rbuf);
 979         return $self->close if ($len >= LINE_MAX);
 980         update_idle_time($self);
 981 }
 982
 983 sub check_read {
 984         my ($self) = @_;
 985         if (index($self->{rbuf}, "\n") >= 0) {
 986                 # Force another read if there is a pipelined request.
 987                 # We don't know if the socket has anything for us to read,
 988                 # and we must double-check again by the time the timer fires
 989                 # in case we really did dispatch a read event and started
 990                 # another long response.
 991                 push @$nextq, $self;
 992                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 993         } else {
 994                 # no pipelined requests available, let the kernel know
 995                 # to wake us up if there's more
 996                 $self->watch_read(1); # PublicInbox::DS::watch_read
 997         }
 998 }
 999
1000 sub not_idle_long ($$) {
1001         my ($self, $now) = @_;
1002         my $sock = $self->{sock} or return;
1003         my $ary = $EXPMAP->{fileno($sock)} or return;
1004         my $exp_at = $ary->[0] + $EXPTIME;
1005         $exp_at > $now;
1006 }
1007
1008 # for graceful shutdown in PublicInbox::Daemon:
1009 sub busy {
1010         my ($self, $now) = @_;
1011         ($self->{rbuf} ne '' || $self->{long_res} ||
1012                 $self->{wbuf} || not_idle_long($self, $now));
1013 }
1014
1015 1;