lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 # for IO::Socket::Socks
  39                 return { ProxyAddr => $h, ProxyPort => $p };
  40         }
  41         die "$val not understood (only socks5h:// is supported)\n";
  42 }
  43
  44 sub mic_new ($$$$) {
  45         my ($self, $mic_arg, $sec, $uri) = @_;
  46         my %mic_arg = %$mic_arg;
  47         my $sa = $self->{cfg_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  48         if ($sa) {
  49                 # this `require' needed for worker[1..Inf], since socks_args
  50                 # only got called in worker[0]
  51                 require IO::Socket::Socks;
  52
  53                 my %opt = %$sa;
  54                 $opt{SocksDebug} = 1 if $mic_arg{Debug};
  55                 $opt{ConnectAddr} = delete $mic_arg{Server};
  56                 $opt{ConnectPort} = delete $mic_arg{Port};
  57                 $mic_arg{Socket} = IO::Socket::Socks->new(%opt) or die
  58                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  59         }
  60         PublicInbox::IMAPClient->new(%mic_arg, Keepalive => 1);
  61 }
  62
  63 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  64
  65 sub onion_hint ($$) {
  66         my ($lei, $uri) = @_;
  67         $uri->host =~ /\.onion\z/i or return "\n";
  68         my $t = $uri->isa('PublicInbox::URIimap') ? 'imap' : 'nntp';
  69         my $url = uri_section($uri);
  70         my $set_cfg = 'lei config';
  71         if (!$lei) { # public-inbox-watch
  72                 my $f = $ENV{PI_CONFIG} || '~/.public-inbox/config';
  73                 $set_cfg = "git config -f $f";
  74         }
  75         <<EOM
  76
  77 Assuming you have Tor configured and running locally on port 9050,
  78 try configuring a socks5h:// proxy:
  79
  80         url=$url
  81         $set_cfg $t.\$url.proxy socks5h://127.0.0.1:9050
  82
  83 ...before retrying your current command
  84 EOM
  85 }
  86
  87 # mic_for may prompt the user and store auth info, prepares mic_get
  88 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  89         my ($self, $uri, $mic_common, $lei) = @_;
  90         require PublicInbox::GitCredential;
  91         my $cred = bless {
  92                 url => "$uri",
  93                 protocol => $uri->scheme,
  94                 host => $uri->host,
  95                 username => $uri->user,
  96                 password => $uri->password,
  97         }, 'PublicInbox::GitCredential';
  98         my $sec = uri_section($uri);
  99         my $common = $mic_common->{$sec} // {};
 100         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 101         my $host = $cred->{host};
 102         $host = '127.0.0.1' if $host eq '0';
 103         my $mic_arg = {
 104                 Port => $uri->port,
 105                 Server => $host,
 106                 Ssl => $uri->scheme eq 'imaps',
 107                 %$common, # may set Starttls, Compress, Debug ....
 108         };
 109         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
 110         require PublicInbox::IMAPClient;
 111         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
 112                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 113
 114         # default to using STARTTLS if it's available, but allow
 115         # it to be disabled since I usually connect to localhost
 116         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 117                         $mic->has_capability('STARTTLS') &&
 118                         $mic->can('starttls')) {
 119                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
 120         }
 121
 122         # do we even need credentials?
 123         if (!defined($cred->{username}) &&
 124                         $mic->has_capability('AUTH=ANONYMOUS')) {
 125                 $cred = undef;
 126         }
 127         if ($cred) {
 128                 my $p = $cred->{password} // $cred->check_netrc($lei);
 129                 $cred->fill($lei) unless defined($p); # may prompt user here
 130                 $mic->User($mic_arg->{User} = $cred->{username});
 131                 $mic->Password($mic_arg->{Password} = $cred->{password});
 132         } else { # AUTH=ANONYMOUS
 133                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 134                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 135                 $mic->Authcallback(\&auth_anon_cb);
 136         }
 137         my $err;
 138         if ($mic->login && $mic->IsAuthenticated) {
 139                 # success! keep IMAPClient->new arg in case we get disconnected
 140                 $self->{net_arg}->{$sec} = $mic_arg;
 141                 if ($cred) {
 142                         $uri->user($cred->{username}) if !defined($uri->user);
 143                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 144                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 145                 }
 146         } else {
 147                 $err = "E: <$uri> LOGIN: $@\n";
 148                 if ($cred && defined($cred->{password})) {
 149                         $err =~ s/\Q$cred->{password}\E/*******/g;
 150                 }
 151                 $mic = undef;
 152         }
 153         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 154         if ($err) {
 155                 $lei ? $lei->fail($err) : warn($err);
 156         }
 157         $mic;
 158 }
 159
 160 # Net::NNTP doesn't support CAPABILITIES, yet
 161 sub try_starttls ($) {
 162         my ($host) = @_;
 163         return if $host =~ /\.onion\z/s;
 164         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 165         return if $host eq '::1';
 166         1;
 167 }
 168
 169 sub nn_new ($$$) {
 170         my ($nn_arg, $nntp_cfg, $uri) = @_;
 171         my $nn;
 172         if (defined $nn_arg->{ProxyAddr}) {
 173                 require PublicInbox::NetNNTPSocks;
 174                 $nn_arg->{SocksDebug} = 1 if $nn_arg->{Debug};
 175                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 176                 die "E: <$uri> $@\n" if $@;
 177         } else {
 178                 $nn = Net::NNTP->new(%$nn_arg) or return;
 179         }
 180
 181         # default to using STARTTLS if it's available, but allow
 182         # it to be disabled for localhost/VPN users
 183         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 184                 if (!defined($nntp_cfg->{starttls}) &&
 185                                 try_starttls($nn_arg->{Host})) {
 186                         # soft fail by default
 187                         $nn->starttls or warn <<"";
 188 W: <$uri> STARTTLS tried and failed (not requested)
 189
 190                 } elsif ($nntp_cfg->{starttls}) {
 191                         # hard fail if explicitly configured
 192                         $nn->starttls or die <<"";
 193 E: <$uri> STARTTLS requested and failed
 194
 195                 }
 196         } elsif ($nntp_cfg->{starttls}) {
 197                 $nn->can('starttls') or
 198                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 199                 $nn->starttls or die <<"";
 200 E: <$uri> STARTTLS requested and failed
 201
 202         }
 203         $nn;
 204 }
 205
 206 sub nn_for ($$$$) { # nn = Net::NNTP
 207         my ($self, $uri, $nn_common, $lei) = @_;
 208         my $sec = uri_section($uri);
 209         my $nntp_cfg = $self->{cfg_opt}->{$sec} //= {};
 210         my $host = $uri->host;
 211         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 212         $host = '127.0.0.1' if $host eq '0';
 213         my $cred;
 214         my ($u, $p);
 215         if (defined(my $ui = $uri->userinfo)) {
 216                 require PublicInbox::GitCredential;
 217                 $cred = bless {
 218                         url => $sec,
 219                         protocol => $uri->scheme,
 220                         host => $host,
 221                 }, 'PublicInbox::GitCredential';
 222                 ($u, $p) = split(/:/, $ui, 2);
 223                 ($cred->{username}, $cred->{password}) = ($u, $p);
 224                 $p //= $cred->check_netrc($lei);
 225         }
 226         my $common = $nn_common->{$sec} // {};
 227         my $nn_arg = {
 228                 Port => $uri->port,
 229                 Host => $host,
 230                 %$common, # may Debug ....
 231         };
 232         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 233         my $sa = $self->{-proxy_cli};
 234         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 235         my $nn = nn_new($nn_arg, $nntp_cfg, $uri) or
 236                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 237         if ($cred) {
 238                 $cred->fill($lei) unless defined($p); # may prompt user here
 239                 if ($nn->authinfo($u, $p)) {
 240                         push @{$nntp_cfg->{-postconn}}, [ 'authinfo', $u, $p ];
 241                 } else {
 242                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 243                         $nn = undef;
 244                 }
 245         }
 246
 247         if ($nntp_cfg->{compress}) {
 248                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 249                 if ($nn->can('compress')) {
 250                         if ($nn->compress) {
 251                                 push @{$nntp_cfg->{-postconn}}, [ 'compress' ];
 252                         } else {
 253                                 warn "W: <$uri> COMPRESS failed\n";
 254                         }
 255                 } else {
 256                         delete $nntp_cfg->{compress};
 257                         warn <<"";
 258 W: <$uri> COMPRESS not supported by Net::NNTP
 259 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 260
 261                 }
 262         }
 263
 264         $self->{net_arg}->{$sec} = $nn_arg;
 265         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 266         $nn;
 267 }
 268
 269 sub imap_uri {
 270         my ($url, $ls_ok) = @_;
 271         require PublicInbox::URIimap;
 272         my $uri = PublicInbox::URIimap->new($url);
 273         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 274 }
 275
 276 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 277 sub nntp_uri {
 278         my ($url, $ls_ok) = @_;
 279         require PublicInbox::URInntps;
 280         my $uri = PublicInbox::URInntps->new($url);
 281         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 282                 $uri->canonical : undef;
 283 }
 284
 285 sub cfg_intvl ($$$) {
 286         my ($cfg, $key, $url) = @_;
 287         my $v = $cfg->urlmatch($key, $url) // return;
 288         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 289         if (ref($v) eq 'ARRAY') {
 290                 $v = join(', ', @$v);
 291                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 292         } else {
 293                 warn "W: $key=$v is not a numeric value in seconds\n";
 294         }
 295 }
 296
 297 sub cfg_bool ($$$) {
 298         my ($cfg, $key, $url) = @_;
 299         my $orig = $cfg->urlmatch($key, $url) // return;
 300         my $bool = $cfg->git_bool($orig);
 301         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 302         $bool;
 303 }
 304
 305 # flesh out common IMAP-specific data structures
 306 sub imap_common_init ($;$) {
 307         my ($self, $lei) = @_;
 308         return unless $self->{imap_order};
 309         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 310         eval { require PublicInbox::IMAPClient } or
 311                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 312         ($lei || eval { require PublicInbox::IMAPTracker }) or
 313                 die "DBD::SQLite is required for IMAP\n:$@\n";
 314         require PublicInbox::URIimap;
 315         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 316         my $mic_common = {}; # scheme://authority => Mail:IMAPClient arg
 317         for my $uri (@{$self->{imap_order}}) {
 318                 my $sec = uri_section($uri);
 319
 320                 # knobs directly for Mail::IMAPClient->new
 321                 for my $k (qw(Starttls Debug Compress Ignoresizeerrors)) {
 322                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 323                         $mic_common->{$sec}->{$k} = $bool;
 324                 }
 325                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 326                 $mic_common->{$sec}->{Timeout} = $to if $to;
 327
 328                 # knobs we use ourselves:
 329                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 330                 $self->{cfg_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 331                 for my $k (qw(pollInterval idleInterval)) {
 332                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 333                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 334                 }
 335                 my $k = 'imap.fetchBatchSize';
 336                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 337                 if ($bs =~ /\A([0-9]+)\z/) {
 338                         $self->{cfg_opt}->{$sec}->{batch_size} = $bs;
 339                 } else {
 340                         warn "$k=$bs is not an integer\n";
 341                 }
 342         }
 343         # make sure we can connect and cache the credentials in memory
 344         my $mics = {}; # schema://authority => IMAPClient obj
 345         for my $orig_uri (@{$self->{imap_order}}) {
 346                 my $sec = uri_section($orig_uri);
 347                 my $uri = PublicInbox::URIimap->new("$sec/");
 348                 my $mic = $mics->{$sec} //=
 349                                 mic_for($self, $uri, $mic_common, $lei) //
 350                                 die "Unable to continue\n";
 351                 next unless $self->isa('PublicInbox::NetWriter');
 352                 my $dst = $orig_uri->mailbox // next;
 353                 next if $mic->exists($dst); # already exists
 354                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 355         }
 356         $mics;
 357 }
 358
 359 # flesh out common NNTP-specific data structures
 360 sub nntp_common_init ($;$) {
 361         my ($self, $lei) = @_;
 362         return unless $self->{nntp_order};
 363         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 364         eval { require Net::NNTP } or
 365                 die "Net::NNTP is required for NNTP:\n$@\n";
 366         ($lei || eval { require PublicInbox::IMAPTracker }) or
 367                 die "DBD::SQLite is required for NNTP\n:$@\n";
 368         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 369         my $nn_common = {}; # scheme://authority => Net::NNTP->new arg
 370         for my $uri (@{$self->{nntp_order}}) {
 371                 my $sec = uri_section($uri);
 372                 my $args = $nn_common->{$sec} //= {};
 373
 374                 # Debug and Timeout are passed to Net::NNTP->new
 375                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 376                 $args->{Debug} = $v if defined $v;
 377                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 378                 $args->{Timeout} = $to if $to;
 379                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 380                 %$args = (%$args, %$sa) if $sa;
 381
 382                 # Net::NNTP post-connect commands
 383                 for my $k (qw(starttls compress)) {
 384                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 385                         $self->{cfg_opt}->{$sec}->{$k} = $v;
 386                 }
 387
 388                 # -watch internal option
 389                 for my $k (qw(pollInterval)) {
 390                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 391                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 392                 }
 393         }
 394         # make sure we can connect and cache the credentials in memory
 395         my %nn; # schema://authority => Net::NNTP object
 396         for my $uri (@{$self->{nntp_order}}) {
 397                 my $sec = uri_section($uri);
 398                 $nn{$sec} //= nn_for($self, $uri, $nn_common, $lei);
 399         }
 400         \%nn; # for optional {nn_cached}
 401 }
 402
 403 sub add_url {
 404         my ($self, $arg, $ls_ok) = @_;
 405         my $uri;
 406         if ($uri = imap_uri($arg, $ls_ok)) {
 407                 $_[1] = $$uri; # canonicalized
 408                 push @{$self->{imap_order}}, $uri;
 409         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 410                 $_[1] = $$uri; # canonicalized
 411                 push @{$self->{nntp_order}}, $uri;
 412         } else {
 413                 push @{$self->{unsupported_url}}, $arg;
 414         }
 415 }
 416
 417 sub errors {
 418         my ($self, $lei) = @_;
 419         if (my $u = $self->{unsupported_url}) {
 420                 return "Unsupported URL(s): @$u";
 421         }
 422         if ($self->{imap_order}) {
 423                 eval { require PublicInbox::IMAPClient } or
 424                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 425         }
 426         if ($self->{nntp_order}) {
 427                 eval { require Net::NNTP } or
 428                         die "Net::NNTP is required for NNTP:\n$@\n";
 429         }
 430         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 431         $self->{-proxy_cli} = $sa if $sa;
 432         undef;
 433 }
 434
 435 sub flags2kw ($$$$) {
 436         my ($self, $uri, $uid, $flags) = @_;
 437         my $kw = [];
 438         for my $f (split(/ /, $flags)) {
 439                 if (my $k = $IMAPflags2kw{$f}) {
 440                         push @$kw, $k;
 441                 } elsif ($f eq "\\Recent") { # not in JMAP
 442                 } elsif ($f eq "\\Deleted") { # not in JMAP
 443                         return;
 444                 } elsif ($self->{verbose}) {
 445                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 446                 }
 447         }
 448         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 449         $kw;
 450 }
 451
 452 sub _imap_do_msg ($$$$$) {
 453         my ($self, $uri, $uid, $raw, $flags) = @_;
 454         # our target audience expects LF-only, save storage
 455         $$raw =~ s/\r\n/\n/sg;
 456         my $kw = defined($flags) ?
 457                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 458         my ($eml_cb, @args) = @{$self->{eml_each}};
 459         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 460 }
 461
 462 sub run_commit_cb ($) {
 463         my ($self) = @_;
 464         my $cmt_cb_args = $self->{on_commit} or return;
 465         my ($cb, @args) = @$cmt_cb_args;
 466         $cb->(@args);
 467 }
 468
 469 sub itrk_last ($$;$$) {
 470         my ($self, $uri, $r_uidval, $mic) = @_;
 471         return (undef, undef, $r_uidval) unless $self->{incremental};
 472         my ($itrk, $l_uid, $l_uidval);
 473         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 474                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 475                 if ($mic) {
 476                         my $auth = $mic->Authmechanism // '';
 477                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 478                         my $user = $mic->User;
 479                         $uri->user($user) if defined($user);
 480                 }
 481                 my $x;
 482                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 483                                 $x->{'uid.max'} : undef;
 484                 # itrk remains undef, lei/store worker writes to
 485                 # mail_sync.sqlite3
 486         } else {
 487                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 488                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 489         }
 490         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 491 }
 492
 493 # import flags of already-seen messages
 494 sub each_old_flags ($$$$) {
 495         my ($self, $mic, $uri, $l_uid) = @_;
 496         $l_uid ||= 1;
 497         my $sec = uri_section($uri);
 498         my $bs = ($self->{cfg_opt}->{$sec}->{batch_size} // 1) * 10000;
 499         my ($eml_cb, @args) = @{$self->{eml_each}};
 500         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 501         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 502                 my $end = $n + $bs;
 503                 $end = $l_uid if $end > $l_uid;
 504                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 505                 if (!$r) {
 506                         return if $!{EINTR} && $self->{quit};
 507                         return "E: $uri UID FETCH $n:$end error: $!";
 508                 }
 509                 while (my ($uid, $per_uid) = each %$r) {
 510                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 511                                 // next;
 512                         # LeiImport->input_net_cb
 513                         $eml_cb->($uri, $uid, $kw, undef, @args);
 514                 }
 515         }
 516 }
 517
 518 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 519 # messages are meaningful
 520 sub perm_fl_ok ($) {
 521         my ($perm_fl) = @_;
 522         return if !defined($perm_fl);
 523         for my $f (split(/[ \t]+/, $perm_fl)) {
 524                 return 1 if $IMAPflags2kw{$f};
 525         }
 526         undef;
 527 }
 528
 529 # may be overridden in NetWriter or Watch
 530 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 531
 532 sub _imap_fetch_all ($$$) {
 533         my ($self, $mic, $orig_uri) = @_;
 534         my $sec = uri_section($orig_uri);
 535         my $mbx = $orig_uri->mailbox;
 536         $mic->Clear(1); # trim results history
 537
 538         # we need to check for mailbox writability to see if we care about
 539         # FLAGS from already-imported messages.
 540         my $cmd = $self->folder_select;
 541         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 542
 543         my ($r_uidval, $r_uidnext, $perm_fl);
 544         for ($mic->Results) {
 545                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 546                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 547                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 548         }
 549         $r_uidval //= $mic->uidvalidity($mbx) //
 550                 return "E: $orig_uri cannot get UIDVALIDITY";
 551         $r_uidnext //= $mic->uidnext($mbx) //
 552                 return "E: $orig_uri cannot get UIDNEXT";
 553         my $expect = $orig_uri->uidvalidity // $r_uidval;
 554         return <<EOF if $expect != $r_uidval;
 555 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 556 EOF
 557
 558         my $uri = $orig_uri->clone;
 559         my $single_uid = $uri->uid;
 560         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 561         if (defined($single_uid)) {
 562                 $itrk = $l_uid = undef;
 563                 $uri->uid(undef); # for eml_cb
 564         }
 565         return <<EOF if $l_uidval != $r_uidval;
 566 E: $uri UIDVALIDITY mismatch
 567 E: local=$l_uidval != remote=$r_uidval
 568 EOF
 569         $uri->uidvalidity($r_uidval);
 570         $l_uid //= 0;
 571         my $r_uid = $r_uidnext - 1;
 572         return <<EOF if $l_uid > $r_uid;
 573 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 574 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 575 EOF
 576         $mic->Uid(1); # the default, we hope
 577         my $err;
 578         my $use_fl = perm_fl_ok($perm_fl);
 579         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 580                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 581                 return $err if $err;
 582         }
 583         return if $l_uid >= $r_uid; # nothing to do
 584         $l_uid ||= 1;
 585         my ($mod, $shard) = @{$self->{shard_info} // []};
 586         unless ($self->{quiet}) {
 587                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 588                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 589         }
 590         my $bs = $self->{cfg_opt}->{$sec}->{batch_size} // 1;
 591         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 592         my $key = $req;
 593         $key =~ s/\.PEEK//;
 594         my ($uids, $batch);
 595         do {
 596                 # I wish "UID FETCH $START:*" could work, but:
 597                 # 1) servers do not need to return results in any order
 598                 # 2) Mail::IMAPClient doesn't offer a streaming API
 599                 if (defined $single_uid) {
 600                         $uids = [ $single_uid ];
 601                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 602                         return if $!{EINTR} && $self->{quit};
 603                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 604                 }
 605                 return if scalar(@$uids) == 0;
 606
 607                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 608                 # responses, so sort it ourselves.  Order matters so
 609                 # IMAPTracker can store the newest UID.
 610                 @$uids = sort { $a <=> $b } @$uids;
 611
 612                 # Did we actually get new messages?
 613                 return if $uids->[0] < $l_uid;
 614
 615                 $l_uid = $uids->[-1] + 1; # for next search
 616                 my $last_uid;
 617                 my $n = $self->{max_batch};
 618
 619                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 620                 while (scalar @$uids) {
 621                         my @batch = splice(@$uids, 0, $bs);
 622                         $batch = join(',', @batch);
 623                         local $0 = "UID:$batch $mbx $sec";
 624                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 625                         unless ($r) { # network error?
 626                                 last if $!{EINTR} && $self->{quit};
 627                                 $err = "E: $uri UID FETCH $batch error: $!";
 628                                 last;
 629                         }
 630                         for my $uid (@batch) {
 631                                 # messages get deleted, so holes appear
 632                                 my $per_uid = delete $r->{$uid} // next;
 633                                 my $raw = delete($per_uid->{$key}) // next;
 634                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 635                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 636                                 $last_uid = $uid;
 637                                 last if $self->{quit};
 638                         }
 639                         last if $self->{quit};
 640                 }
 641                 run_commit_cb($self);
 642                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 643         } until ($err || $self->{quit} || defined($single_uid));
 644         $err;
 645 }
 646
 647 # uses cached auth info prepared by mic_for
 648 sub mic_get {
 649         my ($self, $uri) = @_;
 650         my $sec = uri_section($uri);
 651         # see if caller saved result of imap_common_init
 652         my $cached = $self->{mics_cached};
 653         if ($cached) {
 654                 my $mic = $cached->{$sec};
 655                 return $mic if $mic && $mic->IsConnected;
 656                 delete $cached->{$sec};
 657         }
 658         my $mic_arg = $self->{net_arg}->{$sec} or
 659                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 660         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 661                 if (ref($cb_name) ne 'CODE') {
 662                         $mic_arg->{Authcallback} = $self->can($cb_name);
 663                 }
 664         }
 665         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 666         $cached //= {}; # invalid placeholder if no cache enabled
 667         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 668 }
 669
 670 sub imap_each {
 671         my ($self, $url, $eml_cb, @args) = @_;
 672         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 673         my $sec = uri_section($uri);
 674         local $0 = $uri->mailbox." $sec";
 675         my $mic = mic_get($self, $uri);
 676         my $err;
 677         if ($mic) {
 678                 local $self->{eml_each} = [ $eml_cb, @args ];
 679                 $err = _imap_fetch_all($self, $mic, $uri);
 680         } else {
 681                 $err = "E: <$uri> not connected: $!";
 682         }
 683         die $err if $err && $self->{-can_die};
 684         warn $err if $err;
 685         $mic;
 686 }
 687
 688 # may used cached auth info prepared by nn_for once
 689 sub nn_get {
 690         my ($self, $uri) = @_;
 691         my $sec = uri_section($uri);
 692         # see if caller saved result of nntp_common_init
 693         my $cached = $self->{nn_cached} // {};
 694         my $nn;
 695         $nn = delete($cached->{$sec}) and return $nn;
 696         my $nn_arg = $self->{net_arg}->{$sec} or
 697                         die "BUG: no Net::NNTP->new arg for $sec";
 698         my $nntp_cfg = $self->{cfg_opt}->{$sec};
 699         $nn = nn_new($nn_arg, $nntp_cfg, $uri) or return;
 700         if (my $postconn = $nntp_cfg->{-postconn}) {
 701                 for my $m_arg (@$postconn) {
 702                         my ($method, @args) = @$m_arg;
 703                         $nn->$method(@args) and next;
 704                         die "E: <$uri> $method failed\n";
 705                         return;
 706                 }
 707         }
 708         $nn;
 709 }
 710
 711 sub _nntp_fetch_all ($$$) {
 712         my ($self, $nn, $uri) = @_;
 713         my ($group, $num_a, $num_b) = $uri->group;
 714         my $sec = uri_section($uri);
 715         my ($nr, $beg, $end) = $nn->group($group);
 716         unless (defined($nr)) {
 717                 my $msg = ndump($nn->message);
 718                 return "E: GROUP $group <$sec> $msg";
 719         }
 720
 721         # IMAPTracker is also used for tracking NNTP, UID == article number
 722         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 723         # expensive.  So we assume newsgroups don't change:
 724         my ($itrk, $l_art) = itrk_last($self, $uri);
 725
 726         # allow users to specify articles to refetch
 727         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 728         # nntp://example.com/inbox.foo/$num_a-$num_b
 729         $beg = $num_a if defined($num_a) && $num_a < $beg;
 730         $end = $num_b if defined($num_b) && $num_b < $end;
 731         if (defined $l_art) {
 732                 return if $l_art >= $end; # nothing to do
 733                 $beg = $l_art + 1;
 734         }
 735         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 736         unless ($self->{quiet}) {
 737                 warn "# $uri fetching ARTICLE $beg..$end\n";
 738         }
 739         my $n = $self->{max_batch};
 740         for ($beg..$end) {
 741                 last if $self->{quit};
 742                 $art = $_;
 743                 if (--$n < 0) {
 744                         run_commit_cb($self);
 745                         $itrk->update_last(0, $last_art) if $itrk;
 746                         $n = $self->{max_batch};
 747                 }
 748                 my $raw = $nn->article($art);
 749                 unless (defined($raw)) {
 750                         my $msg = ndump($nn->message);
 751                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 752                                 $err = "E: $msg";
 753                                 last;
 754                         } else { # probably just a deleted message (spam)
 755                                 warn "W: $msg";
 756                                 next;
 757                         }
 758                 }
 759                 $raw = join('', @$raw);
 760                 $raw =~ s/\r\n/\n/sg;
 761                 my ($eml_cb, @args) = @{$self->{eml_each}};
 762                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 763                 $last_art = $art;
 764         }
 765         run_commit_cb($self);
 766         $itrk->update_last(0, $last_art) if $itrk;
 767         $err;
 768 }
 769
 770 sub nntp_each {
 771         my ($self, $url, $eml_cb, @args) = @_;
 772         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 773         my $sec = uri_section($uri);
 774         local $0 = $uri->group ." $sec";
 775         my $nn = nn_get($self, $uri);
 776         return if $self->{quit};
 777         my $err;
 778         if ($nn) {
 779                 local $self->{eml_each} = [ $eml_cb, @args ];
 780                 $err = _nntp_fetch_all($self, $nn, $uri);
 781         } else {
 782                 $err = "E: <$uri> not connected: $!";
 783         }
 784         die $err if $err && $self->{-can_die};
 785         warn $err if $err;
 786         $nn;
 787 }
 788
 789 sub new { bless {}, shift };
 790
 791 # updates $uri with UIDVALIDITY
 792 sub mic_for_folder {
 793         my ($self, $uri) = @_;
 794         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 795         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 796         $mic->$m($uri->mailbox) or return;
 797         my $uidval;
 798         for ($mic->Results) {
 799                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 800                 $uidval = $1;
 801                 last;
 802         }
 803         $uidval //= $mic->uidvalidity($uri->mailbox) or
 804                 die "E: failed to get uidvalidity from <$uri>: $@";
 805         $uri->uidvalidity($uidval);
 806         $mic;
 807 }
 808
 809
 810 1;