lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 # for IO::Socket::Socks
  39                 return { ProxyAddr => $h, ProxyPort => $p };
  40         }
  41         die "$val not understood (only socks5h:// is supported)\n";
  42 }
  43
  44 sub mic_new ($$$$) {
  45         my ($self, $mic_arg, $sec, $uri) = @_;
  46         my %mic_arg = (%$mic_arg, Keepalive => 1);
  47         my $sa = $self->{cfg_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  48         if ($sa) {
  49                 # this `require' needed for worker[1..Inf], since socks_args
  50                 # only got called in worker[0]
  51                 require IO::Socket::Socks;
  52                 my %opt = (%$sa, Keepalive => 1);
  53                 $opt{SocksDebug} = 1 if $mic_arg{Debug};
  54                 $opt{ConnectAddr} = delete $mic_arg{Server};
  55                 $opt{ConnectPort} = delete $mic_arg{Port};
  56                 my $s = IO::Socket::Socks->new(%opt) or die
  57                         "E: <$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  58                 if ($mic_arg->{Ssl}) { # for imaps://
  59                         require IO::Socket::SSL;
  60                         $s = IO::Socket::SSL->start_SSL($s) or die
  61                                 "E: <$uri> ".(IO::Socket::SSL->errstr // '');
  62                 }
  63                 $mic_arg{Socket} = $s;
  64         }
  65         PublicInbox::IMAPClient->new(%mic_arg);
  66 }
  67
  68 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  69
  70 sub onion_hint ($$) {
  71         my ($lei, $uri) = @_;
  72         $uri->host =~ /\.onion\z/i or return "\n";
  73         my $t = $uri->isa('PublicInbox::URIimap') ? 'imap' : 'nntp';
  74         my $url = uri_section($uri);
  75         my $set_cfg = 'lei config';
  76         if (!$lei) { # public-inbox-watch
  77                 my $f = $ENV{PI_CONFIG} || '~/.public-inbox/config';
  78                 $set_cfg = "git config -f $f";
  79         }
  80         <<EOM
  81
  82 Assuming you have Tor configured and running locally on port 9050,
  83 try configuring a socks5h:// proxy:
  84
  85         url=$url
  86         $set_cfg $t.\$url.proxy socks5h://127.0.0.1:9050
  87
  88 ...before retrying your current command
  89 EOM
  90 }
  91
  92 # mic_for may prompt the user and store auth info, prepares mic_get
  93 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  94         my ($self, $uri, $mic_common, $lei) = @_;
  95         require PublicInbox::GitCredential;
  96         my $cred = bless {
  97                 url => "$uri",
  98                 protocol => $uri->scheme,
  99                 host => $uri->host,
 100                 username => $uri->user,
 101                 password => $uri->password,
 102         }, 'PublicInbox::GitCredential';
 103         my $sec = uri_section($uri);
 104         my $common = $mic_common->{$sec} // {};
 105         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 106         my $host = $cred->{host};
 107         $host = '127.0.0.1' if $host eq '0';
 108         my $mic_arg = {
 109                 Port => $uri->port,
 110                 Server => $host,
 111                 %$common, # may set Starttls, Compress, Debug ....
 112         };
 113         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
 114         require PublicInbox::IMAPClient;
 115         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 116         ($mic && $mic->IsConnected) or
 117                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 118
 119         # default to using STARTTLS if it's available, but allow
 120         # it to be disabled since I usually connect to localhost
 121         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 122                         $mic->has_capability('STARTTLS') &&
 123                         $mic->can('starttls')) {
 124                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
 125         }
 126
 127         # do we even need credentials?
 128         if (!defined($cred->{username}) &&
 129                         $mic->has_capability('AUTH=ANONYMOUS')) {
 130                 $cred = undef;
 131         }
 132         if ($cred) {
 133                 my $p = $cred->{password} // $cred->check_netrc($lei);
 134                 $cred->fill($lei) unless defined($p); # may prompt user here
 135                 $mic->User($mic_arg->{User} = $cred->{username});
 136                 $mic->Password($mic_arg->{Password} = $cred->{password});
 137         } else { # AUTH=ANONYMOUS
 138                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 139                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 140                 $mic->Authcallback(\&auth_anon_cb);
 141         }
 142         my $err;
 143         if ($mic->login && $mic->IsAuthenticated) {
 144                 # success! keep IMAPClient->new arg in case we get disconnected
 145                 $self->{net_arg}->{$sec} = $mic_arg;
 146                 if ($cred) {
 147                         $uri->user($cred->{username}) if !defined($uri->user);
 148                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 149                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 150                 }
 151         } else {
 152                 $err = "E: <$uri> LOGIN: $@\n";
 153                 if ($cred && defined($cred->{password})) {
 154                         $err =~ s/\Q$cred->{password}\E/*******/g;
 155                 }
 156                 $mic = undef;
 157         }
 158         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 159         if ($err) {
 160                 $lei ? $lei->fail($err) : warn($err);
 161         }
 162         $mic;
 163 }
 164
 165 # Net::NNTP doesn't support CAPABILITIES, yet
 166 sub try_starttls ($) {
 167         my ($host) = @_;
 168         return if $host =~ /\.onion\z/s;
 169         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 170         return if $host eq '::1';
 171         1;
 172 }
 173
 174 sub nn_new ($$$) {
 175         my ($nn_arg, $nntp_cfg, $uri) = @_;
 176         my $nn;
 177         if (defined $nn_arg->{ProxyAddr}) {
 178                 require PublicInbox::NetNNTPSocks;
 179                 $nn_arg->{SocksDebug} = 1 if $nn_arg->{Debug};
 180                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 181                 die "E: <$uri> $@\n" if $@;
 182         } else {
 183                 $nn = Net::NNTP->new(%$nn_arg) or return;
 184         }
 185
 186         # default to using STARTTLS if it's available, but allow
 187         # it to be disabled for localhost/VPN users
 188         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 189                 if (!defined($nntp_cfg->{starttls}) &&
 190                                 try_starttls($nn_arg->{Host})) {
 191                         # soft fail by default
 192                         $nn->starttls or warn <<"";
 193 W: <$uri> STARTTLS tried and failed (not requested)
 194
 195                 } elsif ($nntp_cfg->{starttls}) {
 196                         # hard fail if explicitly configured
 197                         $nn->starttls or die <<"";
 198 E: <$uri> STARTTLS requested and failed
 199
 200                 }
 201         } elsif ($nntp_cfg->{starttls}) {
 202                 $nn->can('starttls') or
 203                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 204                 $nn->starttls or die <<"";
 205 E: <$uri> STARTTLS requested and failed
 206
 207         }
 208         $nn;
 209 }
 210
 211 sub nn_for ($$$$) { # nn = Net::NNTP
 212         my ($self, $uri, $nn_common, $lei) = @_;
 213         my $sec = uri_section($uri);
 214         my $nntp_cfg = $self->{cfg_opt}->{$sec} //= {};
 215         my $host = $uri->host;
 216         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 217         $host = '127.0.0.1' if $host eq '0';
 218         my $cred;
 219         my ($u, $p);
 220         if (defined(my $ui = $uri->userinfo)) {
 221                 require PublicInbox::GitCredential;
 222                 $cred = bless {
 223                         url => $sec,
 224                         protocol => $uri->scheme,
 225                         host => $host,
 226                 }, 'PublicInbox::GitCredential';
 227                 ($u, $p) = split(/:/, $ui, 2);
 228                 ($cred->{username}, $cred->{password}) = ($u, $p);
 229                 $p //= $cred->check_netrc($lei);
 230         }
 231         my $common = $nn_common->{$sec} // {};
 232         my $nn_arg = {
 233                 Port => $uri->port,
 234                 Host => $host,
 235                 %$common, # may Debug ....
 236         };
 237         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 238         my $sa = $self->{-proxy_cli};
 239         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 240         my $nn = nn_new($nn_arg, $nntp_cfg, $uri) or
 241                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 242         if ($cred) {
 243                 $cred->fill($lei) unless defined($p); # may prompt user here
 244                 if ($nn->authinfo($u, $p)) {
 245                         push @{$nntp_cfg->{-postconn}}, [ 'authinfo', $u, $p ];
 246                 } else {
 247                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 248                         $nn = undef;
 249                 }
 250         }
 251
 252         if ($nntp_cfg->{compress}) {
 253                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 254                 if ($nn->can('compress')) {
 255                         if ($nn->compress) {
 256                                 push @{$nntp_cfg->{-postconn}}, [ 'compress' ];
 257                         } else {
 258                                 warn "W: <$uri> COMPRESS failed\n";
 259                         }
 260                 } else {
 261                         delete $nntp_cfg->{compress};
 262                         warn <<"";
 263 W: <$uri> COMPRESS not supported by Net::NNTP
 264 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 265
 266                 }
 267         }
 268
 269         $self->{net_arg}->{$sec} = $nn_arg;
 270         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 271         $nn;
 272 }
 273
 274 sub imap_uri {
 275         my ($url, $ls_ok) = @_;
 276         require PublicInbox::URIimap;
 277         my $uri = PublicInbox::URIimap->new($url);
 278         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 279 }
 280
 281 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 282 sub nntp_uri {
 283         my ($url, $ls_ok) = @_;
 284         require PublicInbox::URInntps;
 285         my $uri = PublicInbox::URInntps->new($url);
 286         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 287                 $uri->canonical : undef;
 288 }
 289
 290 sub cfg_intvl ($$$) {
 291         my ($cfg, $key, $url) = @_;
 292         my $v = $cfg->urlmatch($key, $url) // return;
 293         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 294         if (ref($v) eq 'ARRAY') {
 295                 $v = join(', ', @$v);
 296                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 297         } else {
 298                 warn "W: $key=$v is not a numeric value in seconds\n";
 299         }
 300 }
 301
 302 sub cfg_bool ($$$) {
 303         my ($cfg, $key, $url) = @_;
 304         my $orig = $cfg->urlmatch($key, $url) // return;
 305         my $bool = $cfg->git_bool($orig);
 306         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 307         $bool;
 308 }
 309
 310 # flesh out common IMAP-specific data structures
 311 sub imap_common_init ($;$) {
 312         my ($self, $lei) = @_;
 313         return unless $self->{imap_order};
 314         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 315         eval { require PublicInbox::IMAPClient } or
 316                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 317         ($lei || eval { require PublicInbox::IMAPTracker }) or
 318                 die "DBD::SQLite is required for IMAP\n:$@\n";
 319         require PublicInbox::URIimap;
 320         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 321         my $mic_common = {}; # scheme://authority => Mail:IMAPClient arg
 322         for my $uri (@{$self->{imap_order}}) {
 323                 my $sec = uri_section($uri);
 324
 325                 # knobs directly for Mail::IMAPClient->new
 326                 for my $k (qw(Starttls Debug Compress Ignoresizeerrors)) {
 327                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 328                         $mic_common->{$sec}->{$k} = $bool;
 329                 }
 330                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 331                 $mic_common->{$sec}->{Timeout} = $to if $to;
 332
 333                 # knobs we use ourselves:
 334                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 335                 $self->{cfg_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 336                 for my $k (qw(pollInterval idleInterval)) {
 337                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 338                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 339                 }
 340                 my $k = 'imap.fetchBatchSize';
 341                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 342                 if ($bs =~ /\A([0-9]+)\z/) {
 343                         $self->{cfg_opt}->{$sec}->{batch_size} = $bs;
 344                 } else {
 345                         warn "$k=$bs is not an integer\n";
 346                 }
 347         }
 348         # make sure we can connect and cache the credentials in memory
 349         my $mics = {}; # schema://authority => IMAPClient obj
 350         for my $orig_uri (@{$self->{imap_order}}) {
 351                 my $sec = uri_section($orig_uri);
 352                 my $uri = PublicInbox::URIimap->new("$sec/");
 353                 my $mic = $mics->{$sec} //=
 354                                 mic_for($self, $uri, $mic_common, $lei) //
 355                                 die "Unable to continue\n";
 356                 next unless $self->isa('PublicInbox::NetWriter');
 357                 my $dst = $orig_uri->mailbox // next;
 358                 next if $mic->exists($dst); # already exists
 359                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 360         }
 361         $mics;
 362 }
 363
 364 # flesh out common NNTP-specific data structures
 365 sub nntp_common_init ($;$) {
 366         my ($self, $lei) = @_;
 367         return unless $self->{nntp_order};
 368         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 369         eval { require Net::NNTP } or
 370                 die "Net::NNTP is required for NNTP:\n$@\n";
 371         ($lei || eval { require PublicInbox::IMAPTracker }) or
 372                 die "DBD::SQLite is required for NNTP\n:$@\n";
 373         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 374         my $nn_common = {}; # scheme://authority => Net::NNTP->new arg
 375         for my $uri (@{$self->{nntp_order}}) {
 376                 my $sec = uri_section($uri);
 377                 my $args = $nn_common->{$sec} //= {};
 378
 379                 # Debug and Timeout are passed to Net::NNTP->new
 380                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 381                 $args->{Debug} = $v if defined $v;
 382                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 383                 $args->{Timeout} = $to if $to;
 384                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 385                 %$args = (%$args, %$sa) if $sa;
 386
 387                 # Net::NNTP post-connect commands
 388                 for my $k (qw(starttls compress)) {
 389                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 390                         $self->{cfg_opt}->{$sec}->{$k} = $v;
 391                 }
 392
 393                 # -watch internal option
 394                 for my $k (qw(pollInterval)) {
 395                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 396                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 397                 }
 398         }
 399         # make sure we can connect and cache the credentials in memory
 400         my %nn; # schema://authority => Net::NNTP object
 401         for my $uri (@{$self->{nntp_order}}) {
 402                 my $sec = uri_section($uri);
 403                 $nn{$sec} //= nn_for($self, $uri, $nn_common, $lei);
 404         }
 405         \%nn; # for optional {nn_cached}
 406 }
 407
 408 sub add_url {
 409         my ($self, $arg, $ls_ok) = @_;
 410         my $uri;
 411         if ($uri = imap_uri($arg, $ls_ok)) {
 412                 $_[1] = $$uri; # canonicalized
 413                 push @{$self->{imap_order}}, $uri;
 414         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 415                 $_[1] = $$uri; # canonicalized
 416                 push @{$self->{nntp_order}}, $uri;
 417         } else {
 418                 push @{$self->{unsupported_url}}, $arg;
 419         }
 420 }
 421
 422 sub errors {
 423         my ($self, $lei) = @_;
 424         if (my $u = $self->{unsupported_url}) {
 425                 return "Unsupported URL(s): @$u";
 426         }
 427         if ($self->{imap_order}) {
 428                 eval { require PublicInbox::IMAPClient } or
 429                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 430         }
 431         if ($self->{nntp_order}) {
 432                 eval { require Net::NNTP } or
 433                         die "Net::NNTP is required for NNTP:\n$@\n";
 434         }
 435         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 436         $self->{-proxy_cli} = $sa if $sa;
 437         undef;
 438 }
 439
 440 sub flags2kw ($$$$) {
 441         my ($self, $uri, $uid, $flags) = @_;
 442         my $kw = [];
 443         for my $f (split(/ /, $flags)) {
 444                 if (my $k = $IMAPflags2kw{$f}) {
 445                         push @$kw, $k;
 446                 } elsif ($f eq "\\Recent") { # not in JMAP
 447                 } elsif ($f eq "\\Deleted") { # not in JMAP
 448                         return;
 449                 } elsif ($self->{verbose}) {
 450                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 451                 }
 452         }
 453         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 454         $kw;
 455 }
 456
 457 sub _imap_do_msg ($$$$$) {
 458         my ($self, $uri, $uid, $raw, $flags) = @_;
 459         # our target audience expects LF-only, save storage
 460         $$raw =~ s/\r\n/\n/sg;
 461         my $kw = defined($flags) ?
 462                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 463         my ($eml_cb, @args) = @{$self->{eml_each}};
 464         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 465 }
 466
 467 sub run_commit_cb ($) {
 468         my ($self) = @_;
 469         my $cmt_cb_args = $self->{on_commit} or return;
 470         my ($cb, @args) = @$cmt_cb_args;
 471         $cb->(@args);
 472 }
 473
 474 sub itrk_last ($$;$$) {
 475         my ($self, $uri, $r_uidval, $mic) = @_;
 476         return (undef, undef, $r_uidval) unless $self->{incremental};
 477         my ($itrk, $l_uid, $l_uidval);
 478         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 479                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 480                 if ($mic) {
 481                         my $auth = $mic->Authmechanism // '';
 482                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 483                         my $user = $mic->User;
 484                         $uri->user($user) if defined($user);
 485                 }
 486                 my $x;
 487                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 488                                 $x->{'uid.max'} : undef;
 489                 # itrk remains undef, lei/store worker writes to
 490                 # mail_sync.sqlite3
 491         } else {
 492                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 493                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 494         }
 495         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 496 }
 497
 498 # import flags of already-seen messages
 499 sub each_old_flags ($$$$) {
 500         my ($self, $mic, $uri, $l_uid) = @_;
 501         $l_uid ||= 1;
 502         my $sec = uri_section($uri);
 503         my $bs = ($self->{cfg_opt}->{$sec}->{batch_size} // 1) * 10000;
 504         my ($eml_cb, @args) = @{$self->{eml_each}};
 505         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 506         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 507                 my $end = $n + $bs;
 508                 $end = $l_uid if $end > $l_uid;
 509                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 510                 if (!$r) {
 511                         return if $!{EINTR} && $self->{quit};
 512                         return "E: $uri UID FETCH $n:$end error: $!";
 513                 }
 514                 while (my ($uid, $per_uid) = each %$r) {
 515                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 516                                 // next;
 517                         # LeiImport->input_net_cb
 518                         $eml_cb->($uri, $uid, $kw, undef, @args);
 519                 }
 520         }
 521 }
 522
 523 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 524 # messages are meaningful
 525 sub perm_fl_ok ($) {
 526         my ($perm_fl) = @_;
 527         return if !defined($perm_fl);
 528         for my $f (split(/[ \t]+/, $perm_fl)) {
 529                 return 1 if $IMAPflags2kw{$f};
 530         }
 531         undef;
 532 }
 533
 534 # may be overridden in NetWriter or Watch
 535 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 536
 537 sub _imap_fetch_all ($$$) {
 538         my ($self, $mic, $orig_uri) = @_;
 539         my $sec = uri_section($orig_uri);
 540         my $mbx = $orig_uri->mailbox;
 541         $mic->Clear(1); # trim results history
 542
 543         # we need to check for mailbox writability to see if we care about
 544         # FLAGS from already-imported messages.
 545         my $cmd = $self->folder_select;
 546         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 547
 548         my ($r_uidval, $r_uidnext, $perm_fl);
 549         for ($mic->Results) {
 550                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 551                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 552                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 553         }
 554         $r_uidval //= $mic->uidvalidity($mbx) //
 555                 return "E: $orig_uri cannot get UIDVALIDITY";
 556         $r_uidnext //= $mic->uidnext($mbx) //
 557                 return "E: $orig_uri cannot get UIDNEXT";
 558         my $expect = $orig_uri->uidvalidity // $r_uidval;
 559         return <<EOF if $expect != $r_uidval;
 560 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 561 EOF
 562
 563         my $uri = $orig_uri->clone;
 564         my $single_uid = $uri->uid;
 565         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 566         if (defined($single_uid)) {
 567                 $itrk = $l_uid = undef;
 568                 $uri->uid(undef); # for eml_cb
 569         }
 570         return <<EOF if $l_uidval != $r_uidval;
 571 E: $uri UIDVALIDITY mismatch
 572 E: local=$l_uidval != remote=$r_uidval
 573 EOF
 574         $uri->uidvalidity($r_uidval);
 575         $l_uid //= 0;
 576         my $r_uid = $r_uidnext - 1;
 577         return <<EOF if $l_uid > $r_uid;
 578 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 579 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 580 EOF
 581         $mic->Uid(1); # the default, we hope
 582         my $err;
 583         my $use_fl = perm_fl_ok($perm_fl);
 584         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 585                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 586                 return $err if $err;
 587         }
 588         return if $l_uid >= $r_uid; # nothing to do
 589         $l_uid ||= 1;
 590         my ($mod, $shard) = @{$self->{shard_info} // []};
 591         unless ($self->{quiet}) {
 592                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 593                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 594         }
 595         my $bs = $self->{cfg_opt}->{$sec}->{batch_size} // 1;
 596         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 597         my $key = $req;
 598         $key =~ s/\.PEEK//;
 599         my ($uids, $batch);
 600         do {
 601                 # I wish "UID FETCH $START:*" could work, but:
 602                 # 1) servers do not need to return results in any order
 603                 # 2) Mail::IMAPClient doesn't offer a streaming API
 604                 if (defined $single_uid) {
 605                         $uids = [ $single_uid ];
 606                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 607                         return if $!{EINTR} && $self->{quit};
 608                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 609                 }
 610                 return if scalar(@$uids) == 0;
 611
 612                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 613                 # responses, so sort it ourselves.  Order matters so
 614                 # IMAPTracker can store the newest UID.
 615                 @$uids = sort { $a <=> $b } @$uids;
 616
 617                 # Did we actually get new messages?
 618                 return if $uids->[0] < $l_uid;
 619
 620                 $l_uid = $uids->[-1] + 1; # for next search
 621                 my $last_uid;
 622                 my $n = $self->{max_batch};
 623
 624                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 625                 while (scalar @$uids) {
 626                         my @batch = splice(@$uids, 0, $bs);
 627                         $batch = join(',', @batch);
 628                         local $0 = "UID:$batch $mbx $sec";
 629                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 630                         unless ($r) { # network error?
 631                                 last if $!{EINTR} && $self->{quit};
 632                                 $err = "E: $uri UID FETCH $batch error: $!";
 633                                 last;
 634                         }
 635                         for my $uid (@batch) {
 636                                 # messages get deleted, so holes appear
 637                                 my $per_uid = delete $r->{$uid} // next;
 638                                 my $raw = delete($per_uid->{$key}) // next;
 639                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 640                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 641                                 $last_uid = $uid;
 642                                 last if $self->{quit};
 643                         }
 644                         last if $self->{quit};
 645                 }
 646                 run_commit_cb($self);
 647                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 648         } until ($err || $self->{quit} || defined($single_uid));
 649         $err;
 650 }
 651
 652 # uses cached auth info prepared by mic_for
 653 sub mic_get {
 654         my ($self, $uri) = @_;
 655         my $sec = uri_section($uri);
 656         # see if caller saved result of imap_common_init
 657         my $cached = $self->{mics_cached};
 658         if ($cached) {
 659                 my $mic = $cached->{$sec};
 660                 return $mic if $mic && $mic->IsConnected;
 661                 delete $cached->{$sec};
 662         }
 663         my $mic_arg = $self->{net_arg}->{$sec} or
 664                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 665         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 666                 if (ref($cb_name) ne 'CODE') {
 667                         $mic_arg->{Authcallback} = $self->can($cb_name);
 668                 }
 669         }
 670         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 671         $cached //= {}; # invalid placeholder if no cache enabled
 672         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 673 }
 674
 675 sub imap_each {
 676         my ($self, $url, $eml_cb, @args) = @_;
 677         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 678         my $sec = uri_section($uri);
 679         local $0 = $uri->mailbox." $sec";
 680         my $mic = mic_get($self, $uri);
 681         my $err;
 682         if ($mic) {
 683                 local $self->{eml_each} = [ $eml_cb, @args ];
 684                 $err = _imap_fetch_all($self, $mic, $uri);
 685         } else {
 686                 $err = "E: <$uri> not connected: $!";
 687         }
 688         die $err if $err && $self->{-can_die};
 689         warn $err if $err;
 690         $mic;
 691 }
 692
 693 # may used cached auth info prepared by nn_for once
 694 sub nn_get {
 695         my ($self, $uri) = @_;
 696         my $sec = uri_section($uri);
 697         # see if caller saved result of nntp_common_init
 698         my $cached = $self->{nn_cached} // {};
 699         my $nn;
 700         $nn = delete($cached->{$sec}) and return $nn;
 701         my $nn_arg = $self->{net_arg}->{$sec} or
 702                         die "BUG: no Net::NNTP->new arg for $sec";
 703         my $nntp_cfg = $self->{cfg_opt}->{$sec};
 704         $nn = nn_new($nn_arg, $nntp_cfg, $uri) or return;
 705         if (my $postconn = $nntp_cfg->{-postconn}) {
 706                 for my $m_arg (@$postconn) {
 707                         my ($method, @args) = @$m_arg;
 708                         $nn->$method(@args) and next;
 709                         die "E: <$uri> $method failed\n";
 710                         return;
 711                 }
 712         }
 713         $nn;
 714 }
 715
 716 sub _nntp_fetch_all ($$$) {
 717         my ($self, $nn, $uri) = @_;
 718         my ($group, $num_a, $num_b) = $uri->group;
 719         my $sec = uri_section($uri);
 720         my ($nr, $beg, $end) = $nn->group($group);
 721         unless (defined($nr)) {
 722                 my $msg = ndump($nn->message);
 723                 return "E: GROUP $group <$sec> $msg";
 724         }
 725
 726         # IMAPTracker is also used for tracking NNTP, UID == article number
 727         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 728         # expensive.  So we assume newsgroups don't change:
 729         my ($itrk, $l_art) = itrk_last($self, $uri);
 730
 731         # allow users to specify articles to refetch
 732         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 733         # nntp://example.com/inbox.foo/$num_a-$num_b
 734         $beg = $num_a if defined($num_a) && $num_a < $beg;
 735         $end = $num_b if defined($num_b) && $num_b < $end;
 736         if (defined $l_art) {
 737                 return if $l_art >= $end; # nothing to do
 738                 $beg = $l_art + 1;
 739         }
 740         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 741         unless ($self->{quiet}) {
 742                 warn "# $uri fetching ARTICLE $beg..$end\n";
 743         }
 744         my $n = $self->{max_batch};
 745         for ($beg..$end) {
 746                 last if $self->{quit};
 747                 $art = $_;
 748                 if (--$n < 0) {
 749                         run_commit_cb($self);
 750                         $itrk->update_last(0, $last_art) if $itrk;
 751                         $n = $self->{max_batch};
 752                 }
 753                 my $raw = $nn->article($art);
 754                 unless (defined($raw)) {
 755                         my $msg = ndump($nn->message);
 756                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 757                                 $err = "E: $msg";
 758                                 last;
 759                         } else { # probably just a deleted message (spam)
 760                                 warn "W: $msg";
 761                                 next;
 762                         }
 763                 }
 764                 $raw = join('', @$raw);
 765                 $raw =~ s/\r\n/\n/sg;
 766                 my ($eml_cb, @args) = @{$self->{eml_each}};
 767                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 768                 $last_art = $art;
 769         }
 770         run_commit_cb($self);
 771         $itrk->update_last(0, $last_art) if $itrk;
 772         $err;
 773 }
 774
 775 sub nntp_each {
 776         my ($self, $url, $eml_cb, @args) = @_;
 777         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 778         my $sec = uri_section($uri);
 779         local $0 = $uri->group ." $sec";
 780         my $nn = nn_get($self, $uri);
 781         return if $self->{quit};
 782         my $err;
 783         if ($nn) {
 784                 local $self->{eml_each} = [ $eml_cb, @args ];
 785                 $err = _nntp_fetch_all($self, $nn, $uri);
 786         } else {
 787                 $err = "E: <$uri> not connected: $!";
 788         }
 789         die $err if $err && $self->{-can_die};
 790         warn $err if $err;
 791         $nn;
 792 }
 793
 794 sub new { bless {}, shift };
 795
 796 # updates $uri with UIDVALIDITY
 797 sub mic_for_folder {
 798         my ($self, $uri) = @_;
 799         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 800         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 801         $mic->$m($uri->mailbox) or return;
 802         my $uidval;
 803         for ($mic->Results) {
 804                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 805                 $uidval = $1;
 806                 last;
 807         }
 808         $uidval //= $mic->uidvalidity($uri->mailbox) or
 809                 die "E: failed to get uidvalidity from <$uri>: $@";
 810         $uri->uidvalidity($uidval);
 811         $mic;
 812 }
 813
 814
 815 1;