lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  29
  30 # mic_for may prompt the user and store auth info, prepares mic_get
  31 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  32         my ($self, $url, $mic_args, $lei) = @_;
  33         require PublicInbox::URIimap;
  34         my $uri = PublicInbox::URIimap->new($url);
  35         require PublicInbox::GitCredential;
  36         my $cred = bless {
  37                 url => $url,
  38                 protocol => $uri->scheme,
  39                 host => $uri->host,
  40                 username => $uri->user,
  41                 password => $uri->password,
  42         }, 'PublicInbox::GitCredential';
  43         my $common = $mic_args->{uri_section($uri)} // {};
  44         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  45         my $host = $cred->{host};
  46         $host = '127.0.0.1' if $host eq '0';
  47         my $mic_arg = {
  48                 Port => $uri->port,
  49                 Server => $host,
  50                 Ssl => $uri->scheme eq 'imaps',
  51                 Keepalive => 1, # SO_KEEPALIVE
  52                 %$common, # may set Starttls, Compress, Debug ....
  53         };
  54         require PublicInbox::IMAPClient;
  55         my %socks;
  56         if ($lei && $lei->{socks5h}) {
  57                 my %opt = %{$lei->{socks5h}};
  58                 $opt{ConnectAddr} = delete $mic_arg->{Server};
  59                 $opt{ConnectPort} = delete $mic_arg->{Port};
  60                 $socks{Socket} = IO::Socket::Socks->new(%opt) or die
  61                         "E: <$url> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  62                 $self->{mic_socks5h} = \%opt;
  63         }
  64         my $mic = PublicInbox::IMAPClient->new(%$mic_arg, %socks) or
  65                 die "E: <$url> new: $@\n";
  66
  67         # default to using STARTTLS if it's available, but allow
  68         # it to be disabled since I usually connect to localhost
  69         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  70                         $mic->has_capability('STARTTLS') &&
  71                         $mic->can('starttls')) {
  72                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
  73         }
  74
  75         # do we even need credentials?
  76         if (!defined($cred->{username}) &&
  77                         $mic->has_capability('AUTH=ANONYMOUS')) {
  78                 $cred = undef;
  79         }
  80         if ($cred) {
  81                 $cred->check_netrc unless defined $cred->{password};
  82                 $cred->fill($lei); # may prompt user here
  83                 $mic->User($mic_arg->{User} = $cred->{username});
  84                 $mic->Password($mic_arg->{Password} = $cred->{password});
  85         } else { # AUTH=ANONYMOUS
  86                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
  87                 $mic_arg->{Authcallback} = 'auth_anon_cb';
  88                 $mic->Authcallback(\&auth_anon_cb);
  89         }
  90         my $err;
  91         if ($mic->login && $mic->IsAuthenticated) {
  92                 # success! keep IMAPClient->new arg in case we get disconnected
  93                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
  94         } else {
  95                 $err = "E: <$url> LOGIN: $@\n";
  96                 if ($cred && defined($cred->{password})) {
  97                         $err =~ s/\Q$cred->{password}\E/*******/g;
  98                 }
  99                 $mic = undef;
 100         }
 101         $cred->run($mic ? 'approve' : 'reject') if $cred;
 102         if ($err) {
 103                 $lei ? $lei->fail($err) : warn($err);
 104         }
 105         $mic;
 106 }
 107
 108 # Net::NNTP doesn't support CAPABILITIES, yet
 109 sub try_starttls ($) {
 110         my ($host) = @_;
 111         return if $host =~ /\.onion\z/s;
 112         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 113         return if $host eq '::1';
 114         1;
 115 }
 116
 117 sub nn_new ($$$) {
 118         my ($nn_arg, $nntp_opt, $uri) = @_;
 119         my $nn;
 120         if (defined $nn_arg->{ProxyAddr}) {
 121                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 122                 die "E: <$uri> $@\n" if $@;
 123         } else {
 124                 $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 125         }
 126
 127         # default to using STARTTLS if it's available, but allow
 128         # it to be disabled for localhost/VPN users
 129         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 130                 if (!defined($nntp_opt->{starttls}) &&
 131                                 try_starttls($nn_arg->{Host})) {
 132                         # soft fail by default
 133                         $nn->starttls or warn <<"";
 134 W: <$uri> STARTTLS tried and failed (not requested)
 135
 136                 } elsif ($nntp_opt->{starttls}) {
 137                         # hard fail if explicitly configured
 138                         $nn->starttls or die <<"";
 139 E: <$uri> STARTTLS requested and failed
 140
 141                 }
 142         } elsif ($nntp_opt->{starttls}) {
 143                 $nn->can('starttls') or
 144                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 145                 $nn->starttls or die <<"";
 146 E: <$uri> STARTTLS requested and failed
 147
 148         }
 149         $nn;
 150 }
 151
 152 sub nn_for ($$$$) { # nn = Net::NNTP
 153         my ($self, $uri, $nn_args, $lei) = @_;
 154         my $sec = uri_section($uri);
 155         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 156         my $host = $uri->host;
 157         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 158         $host = '127.0.0.1' if $host eq '0';
 159         my $cred;
 160         my ($u, $p);
 161         if (defined(my $ui = $uri->userinfo)) {
 162                 require PublicInbox::GitCredential;
 163                 $cred = bless {
 164                         url => $sec,
 165                         protocol => $uri->scheme,
 166                         host => $host,
 167                 }, 'PublicInbox::GitCredential';
 168                 ($u, $p) = split(/:/, $ui, 2);
 169                 ($cred->{username}, $cred->{password}) = ($u, $p);
 170                 $cred->check_netrc unless defined $p;
 171         }
 172         my $common = $nn_args->{$sec} // {};
 173         my $nn_arg = {
 174                 Port => $uri->port,
 175                 Host => $host,
 176                 SSL => $uri->secure, # snews == nntps
 177                 %$common, # may Debug ....
 178         };
 179         if ($lei && $lei->{socks5h}) {
 180                 require PublicInbox::NetNNTPSocks;
 181                 %$nn_arg = (%$nn_arg, %{$lei->{socks5h}});
 182         }
 183         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 184         if ($cred) {
 185                 $cred->fill($lei); # may prompt user here
 186                 if ($nn->authinfo($u, $p)) {
 187                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 188                 } else {
 189                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 190                         $nn = undef;
 191                 }
 192         }
 193
 194         if ($nntp_opt->{compress}) {
 195                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 196                 if ($nn->can('compress')) {
 197                         if ($nn->compress) {
 198                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 199                         } else {
 200                                 warn "W: <$uri> COMPRESS failed\n";
 201                         }
 202                 } else {
 203                         delete $nntp_opt->{compress};
 204                         warn <<"";
 205 W: <$uri> COMPRESS not supported by Net::NNTP
 206 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 207
 208                 }
 209         }
 210
 211         $self->{nn_arg}->{$sec} = $nn_arg;
 212         $cred->run($nn ? 'approve' : 'reject') if $cred;
 213         $nn;
 214 }
 215
 216 sub imap_uri {
 217         my ($url) = @_;
 218         require PublicInbox::URIimap;
 219         my $uri = PublicInbox::URIimap->new($url);
 220         $uri ? $uri->canonical : undef;
 221 }
 222
 223 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 224 sub nntp_uri {
 225         my ($url) = @_;
 226         require PublicInbox::URInntps;
 227         my $uri = PublicInbox::URInntps->new($url);
 228         $uri && $IS_NNTP{$uri->scheme} && $uri->group ? $uri->canonical : undef;
 229 }
 230
 231 sub cfg_intvl ($$$) {
 232         my ($cfg, $key, $url) = @_;
 233         my $v = $cfg->urlmatch($key, $url) // return;
 234         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 235         if (ref($v) eq 'ARRAY') {
 236                 $v = join(', ', @$v);
 237                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 238         } else {
 239                 warn "W: $key=$v is not a numeric value in seconds\n";
 240         }
 241 }
 242
 243 sub cfg_bool ($$$) {
 244         my ($cfg, $key, $url) = @_;
 245         my $orig = $cfg->urlmatch($key, $url) // return;
 246         my $bool = $cfg->git_bool($orig);
 247         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 248         $bool;
 249 }
 250
 251 # flesh out common IMAP-specific data structures
 252 sub imap_common_init ($;$) {
 253         my ($self, $lei) = @_;
 254         return unless $self->{imap_order};
 255         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 256         eval { require PublicInbox::IMAPClient } or
 257                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 258         ($lei || eval { require PublicInbox::IMAPTracker }) or
 259                 die "DBD::SQLite is required for IMAP\n:$@\n";
 260         require PublicInbox::URIimap;
 261         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 262         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 263         for my $uri (@{$self->{imap_order}}) {
 264                 my $sec = uri_section($uri);
 265                 for my $k (qw(Starttls Debug Compress)) {
 266                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 267                         $mic_args->{$sec}->{$k} = $bool;
 268                 }
 269                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 270                 $mic_args->{$sec}->{Timeout} = $to if $to;
 271                 for my $k (qw(pollInterval idleInterval)) {
 272                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 273                         $self->{imap_opt}->{$sec}->{$k} = $to;
 274                 }
 275                 my $k = 'imap.fetchBatchSize';
 276                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 277                 if ($bs =~ /\A([0-9]+)\z/) {
 278                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 279                 } else {
 280                         warn "$k=$bs is not an integer\n";
 281                 }
 282         }
 283         # make sure we can connect and cache the credentials in memory
 284         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 285         my $mics = {}; # schema://authority => IMAPClient obj
 286         for my $uri (@{$self->{imap_order}}) {
 287                 my $sec = uri_section($uri);
 288                 my $mic = $mics->{$sec} //=
 289                                 mic_for($self, "$sec/", $mic_args, $lei) //
 290                                 die "Unable to continue\n";
 291                 next unless $self->isa('PublicInbox::NetWriter');
 292                 my $dst = $uri->mailbox // next;
 293                 next if $mic->exists($dst); # already exists
 294                 $mic->create($dst) or die "CREATE $dst failed <$uri>: $@";
 295         }
 296         $mics;
 297 }
 298
 299 # flesh out common NNTP-specific data structures
 300 sub nntp_common_init ($;$) {
 301         my ($self, $lei) = @_;
 302         return unless $self->{nntp_order};
 303         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 304         eval { require Net::NNTP } or
 305                 die "Net::NNTP is required for NNTP:\n$@\n";
 306         ($lei || eval { require PublicInbox::IMAPTracker }) or
 307                 die "DBD::SQLite is required for NNTP\n:$@\n";
 308         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 309         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 310         for my $uri (@{$self->{nntp_order}}) {
 311                 my $sec = uri_section($uri);
 312
 313                 # Debug and Timeout are passed to Net::NNTP->new
 314                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 315                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 316                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 317                 $nn_args->{$sec}->{Timeout} = $to if $to;
 318
 319                 # Net::NNTP post-connect commands
 320                 for my $k (qw(starttls compress)) {
 321                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 322                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 323                 }
 324
 325                 # internal option
 326                 for my $k (qw(pollInterval)) {
 327                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 328                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 329                 }
 330         }
 331         # make sure we can connect and cache the credentials in memory
 332         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 333         my %nn; # schema://authority => Net::NNTP object
 334         for my $uri (@{$self->{nntp_order}}) {
 335                 my $sec = uri_section($uri);
 336                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 337         }
 338         \%nn; # for optional {nn_cached}
 339 }
 340
 341 sub add_url {
 342         my ($self, $arg) = @_;
 343         my $uri;
 344         if ($uri = imap_uri($arg)) {
 345                 push @{$self->{imap_order}}, $uri;
 346         } elsif ($uri = nntp_uri($arg)) {
 347                 push @{$self->{nntp_order}}, $uri;
 348         } else {
 349                 push @{$self->{unsupported_url}}, $arg;
 350         }
 351 }
 352
 353 sub errors {
 354         my ($self, $lei) = @_;
 355         if (my $u = $self->{unsupported_url}) {
 356                 return "Unsupported URL(s): @$u";
 357         }
 358         if ($self->{imap_order}) {
 359                 eval { require PublicInbox::IMAPClient } or
 360                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 361         }
 362         if ($self->{nntp_order}) {
 363                 eval { require Net::NNTP } or
 364                         die "Net::NNTP is required for NNTP:\n$@\n";
 365         }
 366         if ($lei && (($lei->{opt}->{proxy}//'') =~ m!\Asocks5h://
 367                                 (?: \[ ([^\]]+) \] | ([^:/]+) )
 368                                 (?::([0-9]+))?/?(?:,|\z)!ix)) {
 369                 my ($h, $p) = ($1 // $2, $3 + 0);
 370                 $h = '127.0.0.1' if $h eq '0';
 371                 eval { require IO::Socket::Socks } or die <<EOM;
 372 IO::Socket::Socks missing for socks5h://$h:$p
 373 EOM
 374                 $lei->{socks5h} = { ProxyAddr => $h, ProxyPort => $p };
 375         }
 376         undef;
 377 }
 378
 379 sub _imap_do_msg ($$$$$) {
 380         my ($self, $url, $uid, $raw, $flags) = @_;
 381         # our target audience expects LF-only, save storage
 382         $$raw =~ s/\r\n/\n/sg;
 383         my $kw = [];
 384         for my $f (split(/ /, $flags)) {
 385                 if (my $k = $IMAPflags2kw{$f}) {
 386                         push @$kw, $k;
 387                 } elsif ($f eq "\\Recent") { # not in JMAP
 388                 } elsif ($f eq "\\Deleted") { # not in JMAP
 389                         return;
 390                 } elsif ($self->{verbose}) {
 391                         warn "# unknown IMAP flag $f <$url/;UID=$uid>\n";
 392                 }
 393         }
 394         @$kw = sort @$kw; # for all UI/UX purposes
 395         my ($eml_cb, @args) = @{$self->{eml_each}};
 396         $eml_cb->($url, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 397 }
 398
 399 sub run_commit_cb ($) {
 400         my ($self) = @_;
 401         my $cmt_cb_args = $self->{on_commit} or return;
 402         my ($cb, @args) = @$cmt_cb_args;
 403         $cb->(@args);
 404 }
 405
 406 sub _itrk_last ($$;$) {
 407         my ($self, $uri, $r_uidval) = @_;
 408         return (undef, undef, $r_uidval) unless $self->{incremental};
 409         my ($itrk, $l_uid, $l_uidval);
 410         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 411                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 412                 my $x;
 413                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 414                                 $x->{'uid.max'} : undef;
 415                 # itrk remains undef, lei/store worker writes to
 416                 # mail_sync.sqlite3
 417         } else {
 418                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 419                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 420         }
 421         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 422 }
 423
 424 sub _imap_fetch_all ($$$) {
 425         my ($self, $mic, $orig_uri) = @_;
 426         my $sec = uri_section($orig_uri);
 427         my $mbx = $orig_uri->mailbox;
 428         $mic->Clear(1); # trim results history
 429         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 430         my ($r_uidval, $r_uidnext);
 431         for ($mic->Results) {
 432                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 433                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 434                 last if $r_uidval && $r_uidnext;
 435         }
 436         $r_uidval //= $mic->uidvalidity($mbx) //
 437                 return "E: $orig_uri cannot get UIDVALIDITY";
 438         $r_uidnext //= $mic->uidnext($mbx) //
 439                 return "E: $orig_uri cannot get UIDNEXT";
 440         my $expect = $orig_uri->uidvalidity // $r_uidval;
 441         return <<EOF if $expect != $r_uidval;
 442 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 443 EOF
 444
 445         my $uri = $orig_uri->clone;
 446         my ($itrk, $l_uid, $l_uidval) = _itrk_last($self, $uri, $r_uidval);
 447         return <<EOF if $l_uidval != $r_uidval;
 448 E: $uri UIDVALIDITY mismatch
 449 E: local=$l_uidval != remote=$r_uidval
 450 EOF
 451         $uri->uidvalidity($r_uidval);
 452         $l_uid //= 0;
 453         my $r_uid = $r_uidnext - 1;
 454         return <<EOF if $l_uid > $r_uid;
 455 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 456 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 457 EOF
 458         return if $l_uid >= $r_uid; # nothing to do
 459         $l_uid ||= 1;
 460         my ($mod, $shard) = @{$self->{shard_info} // []};
 461         unless ($self->{quiet}) {
 462                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 463                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 464         }
 465         $mic->Uid(1); # the default, we hope
 466         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 467         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 468         my $key = $req;
 469         $key =~ s/\.PEEK//;
 470         my ($uids, $batch);
 471         my $err;
 472         do {
 473                 # I wish "UID FETCH $START:*" could work, but:
 474                 # 1) servers do not need to return results in any order
 475                 # 2) Mail::IMAPClient doesn't offer a streaming API
 476                 unless ($uids = $mic->search("UID $l_uid:*")) {
 477                         return if $!{EINTR} && $self->{quit};
 478                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 479                 }
 480                 return if scalar(@$uids) == 0;
 481
 482                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 483                 # responses, so sort it ourselves.  Order matters so
 484                 # IMAPTracker can store the newest UID.
 485                 @$uids = sort { $a <=> $b } @$uids;
 486
 487                 # Did we actually get new messages?
 488                 return if $uids->[0] < $l_uid;
 489
 490                 $l_uid = $uids->[-1] + 1; # for next search
 491                 my $last_uid;
 492                 my $n = $self->{max_batch};
 493
 494                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 495                 while (scalar @$uids) {
 496                         my @batch = splice(@$uids, 0, $bs);
 497                         $batch = join(',', @batch);
 498                         local $0 = "UID:$batch $mbx $sec";
 499                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 500                         unless ($r) { # network error?
 501                                 last if $!{EINTR} && $self->{quit};
 502                                 $err = "E: $uri UID FETCH $batch error: $!";
 503                                 last;
 504                         }
 505                         for my $uid (@batch) {
 506                                 # messages get deleted, so holes appear
 507                                 my $per_uid = delete $r->{$uid} // next;
 508                                 my $raw = delete($per_uid->{$key}) // next;
 509                                 _imap_do_msg($self, $$uri, $uid, \$raw,
 510                                                 $per_uid->{FLAGS});
 511                                 $last_uid = $uid;
 512                                 last if $self->{quit};
 513                         }
 514                         last if $self->{quit};
 515                 }
 516                 run_commit_cb($self);
 517                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 518         } until ($err || $self->{quit});
 519         $err;
 520 }
 521
 522 # uses cached auth info prepared by mic_for
 523 sub mic_get {
 524         my ($self, $uri) = @_;
 525         my $sec = uri_section($uri);
 526         # see if caller saved result of imap_common_init
 527         my $cached = $self->{mics_cached};
 528         if ($cached) {
 529                 my $mic = $cached->{$sec};
 530                 return $mic if $mic && $mic->IsConnected;
 531                 delete $cached->{$sec};
 532         }
 533         my $mic_arg = $self->{mic_arg}->{$sec} or
 534                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 535         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 536                 if (ref($cb_name) ne 'CODE') {
 537                         $mic_arg->{Authcallback} = $self->can($cb_name);
 538                 }
 539         }
 540         my %socks;
 541         if (my $s5h = $self->{mic_socks5h}) {
 542                 $socks{Socket} = IO::Socket::Socks->new(%$s5h) or die
 543                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
 544         }
 545         my $mic = PublicInbox::IMAPClient->new(%$mic_arg, %socks);
 546         $cached //= {}; # invalid placeholder if no cache enabled
 547         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 548 }
 549
 550 sub imap_each {
 551         my ($self, $url, $eml_cb, @args) = @_;
 552         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 553         my $sec = uri_section($uri);
 554         local $0 = $uri->mailbox." $sec";
 555         my $mic = mic_get($self, $uri);
 556         my $err;
 557         if ($mic) {
 558                 local $self->{eml_each} = [ $eml_cb, @args ];
 559                 $err = _imap_fetch_all($self, $mic, $uri);
 560         } else {
 561                 $err = "E: <$uri> not connected: $!";
 562         }
 563         die $err if $err && $self->{-can_die};
 564         warn $err if $err;
 565         $mic;
 566 }
 567
 568 # may used cached auth info prepared by nn_for once
 569 sub nn_get {
 570         my ($self, $uri) = @_;
 571         my $sec = uri_section($uri);
 572         # see if caller saved result of nntp_common_init
 573         my $cached = $self->{nn_cached} // {};
 574         my $nn;
 575         $nn = delete($cached->{$sec}) and return $nn;
 576         my $nn_arg = $self->{nn_arg}->{$sec} or
 577                         die "BUG: no Net::NNTP->new arg for $sec";
 578         my $nntp_opt = $self->{nntp_opt}->{$sec};
 579         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 580         if (my $postconn = $nntp_opt->{-postconn}) {
 581                 for my $m_arg (@$postconn) {
 582                         my ($method, @args) = @$m_arg;
 583                         $nn->$method(@args) and next;
 584                         die "E: <$uri> $method failed\n";
 585                         return;
 586                 }
 587         }
 588         $nn;
 589 }
 590
 591 sub _nntp_fetch_all ($$$) {
 592         my ($self, $nn, $uri) = @_;
 593         my ($group, $num_a, $num_b) = $uri->group;
 594         my $sec = uri_section($uri);
 595         my ($nr, $beg, $end) = $nn->group($group);
 596         unless (defined($nr)) {
 597                 my $msg = ndump($nn->message);
 598                 return "E: GROUP $group <$sec> $msg";
 599         }
 600
 601         # IMAPTracker is also used for tracking NNTP, UID == article number
 602         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 603         # expensive.  So we assume newsgroups don't change:
 604         my ($itrk, $l_art) = _itrk_last($self, $uri);
 605
 606         # allow users to specify articles to refetch
 607         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 608         # nntp://example.com/inbox.foo/$num_a-$num_b
 609         $beg = $num_a if defined($num_a) && $num_a < $beg;
 610         $end = $num_b if defined($num_b) && $num_b < $end;
 611         if (defined $l_art) {
 612                 return if $l_art >= $end; # nothing to do
 613                 $beg = $l_art + 1;
 614         }
 615         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 616         unless ($self->{quiet}) {
 617                 warn "# $uri fetching ARTICLE $beg..$end\n";
 618         }
 619         my $n = $self->{max_batch};
 620         for ($beg..$end) {
 621                 last if $self->{quit};
 622                 $art = $_;
 623                 if (--$n < 0) {
 624                         run_commit_cb($self);
 625                         $itrk->update_last(0, $last_art) if $itrk;
 626                         $n = $self->{max_batch};
 627                 }
 628                 my $raw = $nn->article($art);
 629                 unless (defined($raw)) {
 630                         my $msg = ndump($nn->message);
 631                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 632                                 $err = "E: $msg";
 633                                 last;
 634                         } else { # probably just a deleted message (spam)
 635                                 warn "W: $msg";
 636                                 next;
 637                         }
 638                 }
 639                 $raw = join('', @$raw);
 640                 $raw =~ s/\r\n/\n/sg;
 641                 my ($eml_cb, @args) = @{$self->{eml_each}};
 642                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 643                 $last_art = $art;
 644         }
 645         run_commit_cb($self);
 646         $itrk->update_last(0, $last_art) if $itrk;
 647         $err;
 648 }
 649
 650 sub nntp_each {
 651         my ($self, $url, $eml_cb, @args) = @_;
 652         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 653         my $sec = uri_section($uri);
 654         local $0 = $uri->group ." $sec";
 655         my $nn = nn_get($self, $uri);
 656         return if $self->{quit};
 657         my $err;
 658         if ($nn) {
 659                 local $self->{eml_each} = [ $eml_cb, @args ];
 660                 $err = _nntp_fetch_all($self, $nn, $uri);
 661         } else {
 662                 $err = "E: <$uri> not connected: $!";
 663         }
 664         die $err if $err && $self->{-can_die};
 665         warn $err if $err;
 666         $nn;
 667 }
 668
 669 sub new { bless {}, shift };
 670
 671 1;