lib/PublicInbox/PktOp.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # op dispatch socket, reads a message, runs a sub
   5 # There may be multiple producers, but (for now) only one consumer
   6 # Used for lei_xsearch and maybe other things
   7 # "command" => [ $sub, @fixed_operands ]
   8 package PublicInbox::PktOp;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS Exporter);
  12 use Errno qw(EAGAIN EINTR);
  13 use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
  14 use Socket qw(AF_UNIX MSG_EOR SOCK_SEQPACKET);
  15 use PublicInbox::IPC qw(ipc_freeze ipc_thaw);
  16 our @EXPORT_OK = qw(pkt_do);
  17
  18 sub new {
  19         my ($cls, $r) = @_;
  20         my $self = bless { sock => $r }, $cls;
  21         $r->blocking(0);
  22         $self->SUPER::new($r, EPOLLIN|EPOLLET);
  23 }
  24
  25 # returns a blessed object as the consumer, and a GLOB/IO for the producer
  26 sub pair {
  27         my ($cls) = @_;
  28         my ($c, $p);
  29         socketpair($c, $p, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
  30         (new($cls, $c), $p);
  31 }
  32
  33 sub pkt_do { # for the producer to trigger event_step in consumer
  34         my ($producer, $cmd, @args) = @_;
  35         send($producer, @args ? "$cmd\0".ipc_freeze(\@args) : $cmd, MSG_EOR);
  36 }
  37
  38 sub event_step {
  39         my ($self) = @_;
  40         my $c = $self->{sock};
  41         my $msg;
  42         while (1) {
  43                 my $n = recv($c, $msg, 4096, 0);
  44                 unless (defined $n) {
  45                         return if $! == EAGAIN;
  46                         next if $! == EINTR;
  47                         $self->close;
  48                         die "recv: $!";
  49                 }
  50                 my ($cmd, @pargs);
  51                 if (index($msg, "\0") > 0) {
  52                         ($cmd, my $pargs) = split(/\0/, $msg, 2);
  53                         @pargs = @{ipc_thaw($pargs)};
  54                 } else {
  55                         # for compatibility with the script/lei in client mode,
  56                         # it doesn't load Sereal||Storable for startup speed
  57                         ($cmd, @pargs) = split(/ /, $msg);
  58                 }
  59                 my $op = $self->{ops}->{$cmd //= $msg};
  60                 die "BUG: unknown message: `$cmd'" unless $op;
  61                 my ($sub, @args) = @$op;
  62                 $sub->(@args, @pargs);
  63                 return $self->close if $msg eq ''; # close on EOF
  64         }
  65 }
  66
  67 # call this when we're ready to wait on events
  68 sub op_wait_event {
  69         my ($self, $ops) = @_;
  70         $self->{ops} = $ops;
  71 }
  72
  73 1;