lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 require PublicInbox::View;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compressed/;
  12
  13 use constant {
  14         TS => 0,
  15         # SCHEMA_VERSION history
  16         # 0 - initial
  17         # 1 - subject_path is lower-cased
  18         # 2 - subject_path is mid_compressed in the index, only
  19         SCHEMA_VERSION => 2,
  20         LANG => 'english',
  21         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  22 };
  23
  24 # setup prefixes
  25 my %bool_pfx_internal = (
  26         type => 'T', # "mail" or "ghost"
  27         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  28 );
  29
  30 my %bool_pfx_external = (
  31         path => 'XPATH',
  32         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  33         references => 'XREFS',
  34         inreplyto => 'XIRT',
  35 );
  36
  37 my %prob_prefix = (
  38         subject => 'S',
  39 );
  40
  41 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  42
  43 sub xpfx { $all_pfx{$_[0]} }
  44
  45 our %PFX2TERM_RMAP;
  46 while (my ($k, $v) = each %all_pfx) {
  47         next if $prob_prefix{$k};
  48         $PFX2TERM_RMAP{$v} = $k;
  49 }
  50
  51 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  52
  53 sub new {
  54         my ($class, $git_dir, $writable) = @_;
  55         # allow concurrent versions for easier rollback:
  56         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  57         my $db;
  58
  59         if ($writable) { # not used by the WWW interface
  60                 require Search::Xapian::WritableDatabase;
  61                 require File::Path;
  62                 File::Path::mkpath($dir);
  63                 $db = Search::Xapian::WritableDatabase->new($dir,
  64                                         Search::Xapian::DB_CREATE_OR_OPEN);
  65         } else {
  66                 $db = Search::Xapian::Database->new($dir);
  67         }
  68         bless { xdb => $db, git_dir => $git_dir }, $class;
  69 }
  70
  71 sub reopen { $_[0]->{xdb}->reopen }
  72
  73 sub add_message {
  74         my ($self, $mime) = @_; # mime = Email::MIME object
  75         my $db = $self->{xdb};
  76
  77         my $doc_id;
  78         my $mid = mid_clean($mime->header_obj->header_raw('Message-ID'));
  79         $mid = mid_compressed($mid);
  80         my $was_ghost = 0;
  81         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  82         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  83
  84         $db->begin_transaction;
  85         eval {
  86                 my $smsg = $self->lookup_message($mid);
  87                 my $doc;
  88
  89                 if ($smsg) {
  90                         $smsg->ensure_metadata;
  91                         # convert a ghost to a regular message
  92                         # it will also clobber any existing regular message
  93                         $smsg->mime($mime);
  94                         $doc = $smsg->{doc};
  95
  96                         my $type = xpfx('type');
  97                         eval {
  98                                 $doc->remove_term($type . 'ghost');
  99                                 $was_ghost = 1;
 100                         };
 101
 102                         # probably does not exist:
 103                         eval { $doc->remove_term($type . 'mail') };
 104                         $doc->add_term($type . 'mail');
 105                 }  else {
 106                         $smsg = PublicInbox::SearchMsg->new($mime);
 107                         $doc = $smsg->{doc};
 108                         $doc->add_term(xpfx('mid') . $mid);
 109                 }
 110
 111                 my $subj = $smsg->subject;
 112
 113                 if (length $subj) {
 114                         $doc->add_term(xpfx('subject') . $subj);
 115
 116                         my $path = subject_path($subj);
 117                         $doc->add_term(xpfx('path') . mid_compressed($path));
 118                 }
 119
 120                 my $from = $smsg->from_name;
 121                 my $date = $smsg->date;
 122                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 123                 $doc->add_value(PublicInbox::Search::TS, $ts);
 124
 125                 $doc->set_data($smsg->to_doc_data);
 126
 127                 my $tg = $self->term_generator;
 128
 129                 $tg->set_document($doc);
 130                 $tg->index_text($subj, 1, 'S') if $subj;
 131                 $tg->increase_termpos;
 132                 $tg->index_text($subj) if $subj;
 133                 $tg->increase_termpos;
 134
 135                 $tg->index_text($smsg->from->format);
 136                 $tg->increase_termpos;
 137
 138                 $mime->walk_parts(sub {
 139                         my ($part) = @_;
 140                         return if $part->subparts; # walk_parts already recurses
 141                         my $ct = $part->content_type || $ct_msg;
 142
 143                         # account for filter bugs...
 144                         $ct =~ m!\btext/plain\b!i or return;
 145
 146                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 147                         my (@orig, @quot);
 148                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 149                                 if ($l =~ /^\s*>/) {
 150                                         push @quot, $l;
 151                                 } else {
 152                                         push @orig, $l;
 153                                 }
 154                         }
 155                         if (@quot) {
 156                                 $tg->index_text(join("\n", @quot), 0);
 157                                 $tg->increase_termpos;
 158                         }
 159                         if (@orig) {
 160                                 $tg->index_text(join("\n", @orig));
 161                                 $tg->increase_termpos;
 162                         }
 163                 });
 164
 165                 if ($was_ghost) {
 166                         $doc_id = $smsg->doc_id;
 167                         $self->link_message($smsg, 0);
 168                         $db->replace_document($doc_id, $doc);
 169                 } else {
 170                         $self->link_message($smsg, 0);
 171                         $doc_id = $db->add_document($doc);
 172                 }
 173         };
 174
 175         if ($@) {
 176                 warn "failed to index message <$mid>: $@\n";
 177                 $db->cancel_transaction;
 178         } else {
 179                 $db->commit_transaction;
 180         }
 181         $doc_id;
 182 }
 183
 184 # returns deleted doc_id on success, undef on missing
 185 sub remove_message {
 186         my ($self, $mid) = @_;
 187         my $db = $self->{xdb};
 188         my $doc_id;
 189         $mid = mid_clean($mid);
 190         $mid = mid_compressed($mid);
 191
 192         $db->begin_transaction;
 193         eval {
 194                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 195                 $db->delete_document($doc_id) if defined $doc_id;
 196         };
 197
 198         if ($@) {
 199                 warn "failed to remove message <$mid>: $@\n";
 200                 $db->cancel_transaction;
 201         } else {
 202                 $db->commit_transaction;
 203         }
 204         $doc_id;
 205 }
 206
 207 # read-only
 208 sub query {
 209         my ($self, $query_string, $opts) = @_;
 210         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 211
 212         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 213         $self->do_enquire($query, $opts);
 214 }
 215
 216 sub get_subject_path {
 217         my ($self, $path, $opts) = @_;
 218         my $query = $self->qp->parse_query("path:".mid_compressed($path), 0);
 219         $self->do_enquire($query);
 220 }
 221
 222 # given a message ID, get followups to a message
 223 sub get_followups {
 224         my ($self, $mid, $opts) = @_;
 225         $mid = mid_clean($mid);
 226         $mid = mid_compressed($mid);
 227         my $qp = $self->qp;
 228         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 229         my $ref = $qp->parse_query("references:$mid", 0);
 230         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 231
 232         $self->do_enquire($query);
 233 }
 234
 235 sub get_thread {
 236         my ($self, $mid, $opts) = @_;
 237         my $smsg = eval { $self->lookup_message($mid) };
 238
 239         return { count => 0, msgs => [] } unless $smsg;
 240         my $qp = $self->qp;
 241         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 242         my $qsub = $qp->parse_query('path:'.mid_compressed($smsg->path));
 243         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 244         $self->do_enquire($query);
 245 }
 246
 247 # private subs below
 248
 249 sub do_enquire {
 250         my ($self, $query, $opts) = @_;
 251         my $enquire = $self->enquire;
 252
 253         $enquire->set_query($query);
 254         $enquire->set_sort_by_relevance_then_value(TS, 0);
 255         $opts ||= {};
 256         my $offset = $opts->{offset} || 0;
 257         my $limit = $opts->{limit} || 50;
 258         my $mset = $enquire->get_mset($offset, $limit);
 259         my @msgs = map {
 260                 PublicInbox::SearchMsg->load_doc($_->get_document);
 261         } $mset->items;
 262
 263         { count => $mset->get_matches_estimated, msgs => \@msgs }
 264 }
 265
 266 # read-write
 267 sub stemmer { Search::Xapian::Stem->new(LANG) }
 268
 269 # read-only
 270 sub qp {
 271         my ($self) = @_;
 272
 273         my $qp = $self->{query_parser};
 274         return $qp if $qp;
 275
 276         # new parser
 277         $qp = Search::Xapian::QueryParser->new;
 278         $qp->set_default_op(OP_AND);
 279         $qp->set_database($self->{xdb});
 280         $qp->set_stemmer($self->stemmer);
 281         $qp->set_stemming_strategy(STEM_SOME);
 282         $qp->add_valuerangeprocessor($self->ts_range_processor);
 283         $qp->add_valuerangeprocessor($self->date_range_processor);
 284
 285         while (my ($name, $prefix) = each %bool_pfx_external) {
 286                 $qp->add_boolean_prefix($name, $prefix);
 287         }
 288
 289         while (my ($name, $prefix) = each %prob_prefix) {
 290                 $qp->add_prefix($name, $prefix);
 291         }
 292
 293         $self->{query_parser} = $qp;
 294 }
 295
 296 sub term_generator { # write-only
 297         my ($self) = @_;
 298
 299         my $tg = $self->{term_generator};
 300         return $tg if $tg;
 301
 302         $tg = Search::Xapian::TermGenerator->new;
 303         $tg->set_stemmer($self->stemmer);
 304
 305         $self->{term_generator} = $tg;
 306 }
 307
 308 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 309
 310 # increments last_thread_id counter
 311 # returns a 64-bit integer represented as a hex string
 312 sub next_thread_id {
 313         my ($self) = @_;
 314         my $db = $self->{xdb};
 315         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 316
 317         $db->set_metadata('last_thread_id', ++$last_thread_id);
 318
 319         $last_thread_id;
 320 }
 321
 322 sub ts_range_processor {
 323         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 324 }
 325
 326 sub date_range_processor {
 327         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 328 }
 329
 330 sub link_message {
 331         my ($self, $smsg, $is_ghost) = @_;
 332
 333         if ($is_ghost) {
 334                 $smsg->ensure_metadata;
 335         } else {
 336                 $self->link_message_to_parents($smsg);
 337         }
 338 }
 339
 340 sub link_message_to_parents {
 341         my ($self, $smsg) = @_;
 342         my $doc = $smsg->{doc};
 343         my $mid = mid_compressed($smsg->mid);
 344         my $mime = $smsg->mime;
 345         my $refs = $mime->header_obj->header_raw('References');
 346         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 347         my $irt = $mime->header_obj->header_raw('In-Reply-To');
 348         if ($irt) {
 349                 if ($irt =~ /<([^>]+)>/) {
 350                         $irt = $1;
 351                 }
 352                 push @refs, $irt;
 353         }
 354
 355         my $tid;
 356         if (@refs) {
 357                 @refs = map { mid_compressed($_) } @refs;
 358                 my %uniq;
 359                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 360
 361                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 362
 363                 my $ref_pfx = xpfx('references');
 364
 365                 # first ref *should* be the thread root,
 366                 # but we can never trust clients to do the right thing
 367                 my $ref = shift @refs;
 368                 $doc->add_term($ref_pfx . $ref);
 369                 $tid = $self->_resolve_mid_to_tid($ref);
 370
 371                 # the rest of the refs should point to this tid:
 372                 foreach $ref (@refs) {
 373                         $doc->add_term($ref_pfx . $ref);
 374                         my $ptid = $self->_resolve_mid_to_tid($ref);
 375                         if ($tid ne $ptid) {
 376                                 $self->merge_threads($tid, $ptid);
 377                         }
 378                 }
 379         } else {
 380                 $tid = $self->next_thread_id;
 381         }
 382         $doc->add_term(xpfx('thread') . $tid);
 383 }
 384
 385 sub lookup_message {
 386         my ($self, $mid) = @_;
 387         $mid = mid_clean($mid);
 388         $mid = mid_compressed($mid);
 389
 390         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 391         my $smsg;
 392         if (defined $doc_id) {
 393                 # raises on error:
 394                 my $doc = $self->{xdb}->get_document($doc_id);
 395                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 396                 $smsg->doc_id($doc_id);
 397         }
 398         $smsg;
 399 }
 400
 401 sub find_unique_doc_id {
 402         my ($self, $term, $value) = @_;
 403
 404         my ($begin, $end) = $self->find_doc_ids($term, $value);
 405
 406         return undef if $begin->equal($end); # not found
 407
 408         my $rv = $begin->get_docid;
 409
 410         # sanity check
 411         $begin->inc;
 412         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 413         $rv;
 414 }
 415
 416 # returns begin and end PostingIterator
 417 sub find_doc_ids {
 418         my ($self, $term, $value) = @_;
 419
 420         $self->find_doc_ids_for_term(xpfx($term) . $value);
 421 }
 422
 423 # returns begin and end PostingIterator
 424 sub find_doc_ids_for_term {
 425         my ($self, $term) = @_;
 426         my $db = $self->{xdb};
 427
 428         ($db->postlist_begin($term), $db->postlist_end($term));
 429 }
 430
 431 # this will create a ghost as necessary
 432 sub _resolve_mid_to_tid {
 433         my ($self, $mid) = @_;
 434
 435         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 436         $smsg->thread_id;
 437 }
 438
 439 sub create_ghost {
 440         my ($self, $mid, $tid) = @_;
 441
 442         $mid = mid_compressed($mid);
 443         $tid = $self->next_thread_id unless defined $tid;
 444
 445         my $doc = Search::Xapian::Document->new;
 446         $doc->add_term(xpfx('mid') . $mid);
 447         $doc->add_term(xpfx('thread') . $tid);
 448         $doc->add_term(xpfx('type') . 'ghost');
 449
 450         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 451         $self->link_message($smsg, 1);
 452         $self->{xdb}->add_document($doc);
 453
 454         $smsg;
 455 }
 456
 457 sub merge_threads {
 458         my ($self, $winner_tid, $loser_tid) = @_;
 459         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 460         my $thread_pfx = xpfx('thread');
 461         my $db = $self->{xdb};
 462
 463         for (; $head != $tail; $head->inc) {
 464                 my $docid = $head->get_docid;
 465                 my $doc = $db->get_document($docid);
 466                 $doc->remove_term($thread_pfx . $loser_tid);
 467                 $doc->add_term($thread_pfx . $winner_tid);
 468                 $db->replace_document($docid, $doc);
 469         }
 470 }
 471
 472 # normalize subjects so they are suitable as pathnames for URLs
 473 sub subject_path {
 474         my $subj = pop;
 475
 476         $subj =~ s/\A\s+//;
 477         $subj =~ s/\s+\z//;
 478         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 479         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 480         lc($subj);
 481 }
 482
 483 sub do_cat_mail {
 484         my ($git, $blob) = @_;
 485         my $mime = eval {
 486                 my $str = $git->cat_file($blob);
 487                 Email::MIME->new($str);
 488         };
 489         $@ ? undef : $mime;
 490 }
 491
 492 sub index_blob {
 493         my ($self, $git, $blob) = @_;
 494         my $mime = do_cat_mail($git, $blob) or return;
 495         eval { $self->add_message($mime) };
 496         warn "W: index_blob $blob: $@\n" if $@;
 497 }
 498
 499 sub unindex_blob {
 500         my ($self, $git, $blob) = @_;
 501         my $mime = do_cat_mail($git, $blob) or return;
 502         my $mid = $mime->header_obj->header_raw('Message-ID');
 503         eval { $self->remove_message($mid) } if defined $mid;
 504         warn "W: unindex_blob $blob: $@\n" if $@;
 505 }
 506
 507 sub enquire {
 508         my ($self) = @_;
 509         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 510 }
 511
 512 # indexes all unindexed messages
 513 sub index_sync {
 514         my ($self, $git) = @_;
 515         my $db = $self->{xdb};
 516         my $latest = $db->get_metadata('last_commit');
 517         my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 518         $latest = undef;
 519
 520         my $hex = '[a-f0-9]';
 521         my $h40 = $hex .'{40}';
 522         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 523         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 524
 525         # get indexed messages
 526         my @cmd = ('git', "--git-dir=$git->{git_dir}", "log",
 527                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 528                     $range);
 529
 530         my $pid = open(my $log, '-|', @cmd) or
 531                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 532         my $last;
 533         while (my $line = <$log>) {
 534                 if ($line =~ /$addmsg/o) {
 535                         $self->index_blob($git, $1);
 536                 } elsif ($line =~ /$delmsg/o) {
 537                         $self->unindex_blob($git, $1);
 538                 } elsif ($line =~ /^commit ($h40)/o) {
 539                         my $commit = $1;
 540                         if (defined $latest) {
 541                                 $db->set_metadata('last_commit', $latest)
 542                         }
 543                         $latest = $commit;
 544                 }
 545         }
 546         close $log;
 547         $db->set_metadata('last_commit', $latest) if defined $latest;
 548 }
 549
 550 1;