lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use base qw/Exporter/;
   9 use Search::Xapian qw/:standard/;
  10 require PublicInbox::View;
  11 use Email::MIME;
  12 use PublicInbox::MID qw/mid_clean mid_compressed/;
  13
  14 our @EXPORT = qw/xpfx/;
  15
  16 use constant {
  17         TS => 0,
  18         SCHEMA_VERSION => 0,
  19         LANG => 'english',
  20         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  21 };
  22
  23 # setup prefixes
  24 my %bool_pfx_internal = (
  25         type => 'T', # "mail" or "ghost"
  26         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  27 );
  28
  29 my %bool_pfx_external = (
  30         path => 'XPATH',
  31         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  32         references => 'XREFS',
  33         inreplyto => 'XIRT',
  34 );
  35
  36 my %prob_prefix = (
  37         subject => 'S',
  38 );
  39
  40 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  41
  42 sub xpfx { $all_pfx{$_[0]} }
  43
  44 our %PFX2TERM_RMAP;
  45 while (my ($k, $v) = each %all_pfx) {
  46         next if $prob_prefix{$k};
  47         $PFX2TERM_RMAP{$v} = $k;
  48 }
  49
  50 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  51
  52 sub new {
  53         my ($class, $git_dir, $writable) = @_;
  54         # allow concurrent versions for easier rollback:
  55         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  56         my $db;
  57
  58         if ($writable) { # not used by the WWW interface
  59                 require Search::Xapian::WritableDatabase;
  60                 require File::Path;
  61                 File::Path::mkpath($dir);
  62                 $db = Search::Xapian::WritableDatabase->new($dir,
  63                                         Search::Xapian::DB_CREATE_OR_OPEN);
  64         } else {
  65                 $db = Search::Xapian::Database->new($dir);
  66         }
  67         bless { xdb => $db, git_dir => $git_dir }, $class;
  68 }
  69
  70 sub reopen { $_[0]->{xdb}->reopen }
  71
  72 sub add_message {
  73         my ($self, $mime) = @_; # mime = Email::MIME object
  74         my $db = $self->{xdb};
  75
  76         my $doc_id;
  77         my $mid = mid_clean($mime->header('Message-ID'));
  78         $mid = mid_compressed($mid);
  79         my $was_ghost = 0;
  80         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  81         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  82
  83         $db->begin_transaction;
  84         eval {
  85                 my $smsg = $self->lookup_message($mid);
  86                 my $doc;
  87
  88                 if ($smsg) {
  89                         $smsg->ensure_metadata;
  90                         # convert a ghost to a regular message
  91                         # it will also clobber any existing regular message
  92                         $smsg->mime($mime);
  93                         $doc = $smsg->{doc};
  94
  95                         my $type = xpfx('type');
  96                         eval {
  97                                 $doc->remove_term($type . 'ghost');
  98                                 $was_ghost = 1;
  99                         };
 100
 101                         # probably does not exist:
 102                         eval { $doc->remove_term($type . 'mail') };
 103                         $doc->add_term($type . 'mail');
 104                 }  else {
 105                         $smsg = PublicInbox::SearchMsg->new($mime);
 106                         $doc = $smsg->{doc};
 107                         $doc->add_term(xpfx('mid') . $mid);
 108                 }
 109
 110                 my $subj = $smsg->subject;
 111
 112                 if (length $subj) {
 113                         $doc->add_term(xpfx('subject') . $subj);
 114
 115                         my $path = subject_path($subj);
 116                         $doc->add_term(xpfx('path') . $path);
 117                 }
 118
 119                 my $from = $smsg->from_name;
 120                 my $date = $smsg->date;
 121                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 122                 $doc->add_value(PublicInbox::Search::TS, $ts);
 123
 124                 $doc->set_data($smsg->to_doc_data);
 125
 126                 my $tg = $self->term_generator;
 127
 128                 $tg->set_document($doc);
 129                 $tg->index_text($subj, 1, 'S') if $subj;
 130                 $tg->increase_termpos;
 131                 $tg->index_text($subj) if $subj;
 132                 $tg->increase_termpos;
 133
 134                 $tg->index_text($smsg->from->format);
 135                 $tg->increase_termpos;
 136
 137                 $mime->walk_parts(sub {
 138                         my ($part) = @_;
 139                         return if $part->subparts; # walk_parts already recurses
 140                         my $ct = $part->content_type || $ct_msg;
 141
 142                         # account for filter bugs...
 143                         $ct =~ m!\btext/plain\b!i or return;
 144
 145                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 146                         my (@orig, @quot);
 147                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 148                                 if ($l =~ /^\s*>/) {
 149                                         push @quot, $l;
 150                                 } else {
 151                                         push @orig, $l;
 152                                 }
 153                         }
 154                         if (@quot) {
 155                                 $tg->index_text(join("\n", @quot), 0);
 156                                 $tg->increase_termpos;
 157                         }
 158                         if (@orig) {
 159                                 $tg->index_text(join("\n", @orig));
 160                                 $tg->increase_termpos;
 161                         }
 162                 });
 163
 164                 if ($was_ghost) {
 165                         $doc_id = $smsg->doc_id;
 166                         $self->link_message($smsg, 0);
 167                         $db->replace_document($doc_id, $doc);
 168                 } else {
 169                         $self->link_message($smsg, 0);
 170                         $doc_id = $db->add_document($doc);
 171                 }
 172         };
 173
 174         if ($@) {
 175                 warn "failed to index message <$mid>: $@\n";
 176                 $db->cancel_transaction;
 177         } else {
 178                 $db->commit_transaction;
 179         }
 180         $doc_id;
 181 }
 182
 183 # returns deleted doc_id on success, undef on missing
 184 sub remove_message {
 185         my ($self, $mid) = @_;
 186         my $db = $self->{xdb};
 187         my $doc_id;
 188         $mid = mid_clean($mid);
 189         $mid = mid_compressed($mid);
 190
 191         $db->begin_transaction;
 192         eval {
 193                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 194                 $db->delete_document($doc_id) if defined $doc_id;
 195         };
 196
 197         if ($@) {
 198                 warn "failed to remove message <$mid>: $@\n";
 199                 $db->cancel_transaction;
 200         } else {
 201                 $db->commit_transaction;
 202         }
 203         $doc_id;
 204 }
 205
 206 # read-only
 207 sub query {
 208         my ($self, $query_string, $opts) = @_;
 209         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 210
 211         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 212         $self->do_enquire($query, $opts);
 213 }
 214
 215 # given a message ID, get replies to a message
 216 sub get_replies {
 217         my ($self, $mid, $opts) = @_;
 218         $mid = mid_clean($mid);
 219         $mid = mid_compressed($mid);
 220         my $qp = $self->qp;
 221         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 222         my $ref = $qp->parse_query("references:$mid", 0);
 223         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 224
 225         $self->do_enquire($query);
 226 }
 227
 228 sub get_thread {
 229         my ($self, $mid, $opts) = @_;
 230         my $smsg = eval { $self->lookup_message($mid) };
 231
 232         return { count => 0, msgs => [] } unless $smsg;
 233         my $qp = $self->qp;
 234         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 235         my $qsub = $qp->parse_query('path:'.$smsg->path);
 236         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 237         $self->do_enquire($query);
 238 }
 239
 240 # private subs below
 241
 242 sub do_enquire {
 243         my ($self, $query, $opts) = @_;
 244         my $enquire = $self->enquire;
 245
 246         $enquire->set_query($query);
 247         $enquire->set_sort_by_relevance_then_value(TS, 0);
 248         $opts ||= {};
 249         my $offset = $opts->{offset} || 0;
 250         my $limit = $opts->{limit} || 50;
 251         my $mset = $enquire->get_mset($offset, $limit);
 252         my @msgs = map {
 253                 PublicInbox::SearchMsg->load_doc($_->get_document);
 254         } $mset->items;
 255
 256         { count => $mset->get_matches_estimated, msgs => \@msgs }
 257 }
 258
 259 # read-write
 260 sub stemmer { Search::Xapian::Stem->new(LANG) }
 261
 262 # read-only
 263 sub qp {
 264         my ($self) = @_;
 265
 266         my $qp = $self->{query_parser};
 267         return $qp if $qp;
 268
 269         # new parser
 270         $qp = Search::Xapian::QueryParser->new;
 271         $qp->set_default_op(OP_AND);
 272         $qp->set_database($self->{xdb});
 273         $qp->set_stemmer($self->stemmer);
 274         $qp->set_stemming_strategy(STEM_SOME);
 275         $qp->add_valuerangeprocessor($self->ts_range_processor);
 276         $qp->add_valuerangeprocessor($self->date_range_processor);
 277
 278         while (my ($name, $prefix) = each %bool_pfx_external) {
 279                 $qp->add_boolean_prefix($name, $prefix);
 280         }
 281
 282         while (my ($name, $prefix) = each %prob_prefix) {
 283                 $qp->add_prefix($name, $prefix);
 284         }
 285
 286         $self->{query_parser} = $qp;
 287 }
 288
 289 sub term_generator { # write-only
 290         my ($self) = @_;
 291
 292         my $tg = $self->{term_generator};
 293         return $tg if $tg;
 294
 295         $tg = Search::Xapian::TermGenerator->new;
 296         $tg->set_stemmer($self->stemmer);
 297
 298         $self->{term_generator} = $tg;
 299 }
 300
 301 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 302
 303 # increments last_thread_id counter
 304 # returns a 64-bit integer represented as a hex string
 305 sub next_thread_id {
 306         my ($self) = @_;
 307         my $db = $self->{xdb};
 308         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 309
 310         $db->set_metadata('last_thread_id', ++$last_thread_id);
 311
 312         $last_thread_id;
 313 }
 314
 315 sub ts_range_processor {
 316         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 317 }
 318
 319 sub date_range_processor {
 320         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 321 }
 322
 323 sub link_message {
 324         my ($self, $smsg, $is_ghost) = @_;
 325
 326         if ($is_ghost) {
 327                 $smsg->ensure_metadata;
 328         } else {
 329                 $self->link_message_to_parents($smsg);
 330         }
 331 }
 332
 333 sub link_message_to_parents {
 334         my ($self, $smsg) = @_;
 335         my $doc = $smsg->{doc};
 336         my $mid = mid_compressed($smsg->mid);
 337         my $mime = $smsg->mime;
 338         my $refs = $mime->header('References');
 339         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 340         my $irt = $mime->header('In-Reply-To');
 341         if ($irt) {
 342                 if ($irt =~ /<([^>]+)>/) {
 343                         $irt = $1;
 344                 }
 345                 push @refs, $irt;
 346         }
 347
 348         my $tid;
 349         if (@refs) {
 350                 @refs = map { mid_compressed($_) } @refs;
 351                 my %uniq;
 352                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 353
 354                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 355
 356                 my $ref_pfx = xpfx('references');
 357
 358                 # first ref *should* be the thread root,
 359                 # but we can never trust clients to do the right thing
 360                 my $ref = shift @refs;
 361                 $doc->add_term($ref_pfx . $ref);
 362                 $tid = $self->_resolve_mid_to_tid($ref);
 363
 364                 # the rest of the refs should point to this tid:
 365                 foreach $ref (@refs) {
 366                         $doc->add_term($ref_pfx . $ref);
 367                         my $ptid = $self->_resolve_mid_to_tid($ref);
 368                         if ($tid ne $ptid) {
 369                                 $self->merge_threads($tid, $ptid);
 370                         }
 371                 }
 372         } else {
 373                 $tid = $self->next_thread_id;
 374         }
 375         $doc->add_term(xpfx('thread') . $tid);
 376 }
 377
 378 sub lookup_message {
 379         my ($self, $mid) = @_;
 380         $mid = mid_clean($mid);
 381         $mid = mid_compressed($mid);
 382
 383         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 384         my $smsg;
 385         if (defined $doc_id) {
 386                 # raises on error:
 387                 my $doc = $self->{xdb}->get_document($doc_id);
 388                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 389                 $smsg->doc_id($doc_id);
 390         }
 391         $smsg;
 392 }
 393
 394 sub find_unique_doc_id {
 395         my ($self, $term, $value) = @_;
 396
 397         my ($begin, $end) = $self->find_doc_ids($term, $value);
 398
 399         return undef if $begin->equal($end); # not found
 400
 401         my $rv = $begin->get_docid;
 402
 403         # sanity check
 404         $begin->inc;
 405         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 406         $rv;
 407 }
 408
 409 # returns begin and end PostingIterator
 410 sub find_doc_ids {
 411         my ($self, $term, $value) = @_;
 412
 413         $self->find_doc_ids_for_term(xpfx($term) . $value);
 414 }
 415
 416 # returns begin and end PostingIterator
 417 sub find_doc_ids_for_term {
 418         my ($self, $term) = @_;
 419         my $db = $self->{xdb};
 420
 421         ($db->postlist_begin($term), $db->postlist_end($term));
 422 }
 423
 424 # this will create a ghost as necessary
 425 sub _resolve_mid_to_tid {
 426         my ($self, $mid) = @_;
 427
 428         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 429         $smsg->thread_id;
 430 }
 431
 432 sub create_ghost {
 433         my ($self, $mid, $tid) = @_;
 434
 435         $mid = mid_compressed($mid);
 436         $tid = $self->next_thread_id unless defined $tid;
 437
 438         my $doc = Search::Xapian::Document->new;
 439         $doc->add_term(xpfx('mid') . $mid);
 440         $doc->add_term(xpfx('thread') . $tid);
 441         $doc->add_term(xpfx('type') . 'ghost');
 442
 443         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 444         $self->link_message($smsg, 1);
 445         $self->{xdb}->add_document($doc);
 446
 447         $smsg;
 448 }
 449
 450 sub merge_threads {
 451         my ($self, $winner_tid, $loser_tid) = @_;
 452         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 453         my $thread_pfx = xpfx('thread');
 454         my $db = $self->{xdb};
 455
 456         for (; $head != $tail; $head->inc) {
 457                 my $docid = $head->get_docid;
 458                 my $doc = $db->get_document($docid);
 459                 $doc->remove_term($thread_pfx . $loser_tid);
 460                 $doc->add_term($thread_pfx . $winner_tid);
 461                 $db->replace_document($docid, $doc);
 462         }
 463 }
 464
 465 # normalize subjects so they are suitable as pathnames for URLs
 466 sub subject_path {
 467         my ($subj) = @_;
 468
 469         $subj =~ s/\A\s+//;
 470         $subj =~ s/\s+\z//;
 471         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 472         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 473         $subj;
 474 }
 475
 476 sub do_cat_mail {
 477         my ($git, $blob) = @_;
 478         my $mime = eval {
 479                 my $str = $git->cat_file($blob);
 480                 Email::MIME->new($str);
 481         };
 482         $@ ? undef : $mime;
 483 }
 484
 485 sub index_blob {
 486         my ($self, $git, $blob) = @_;
 487         my $mime = do_cat_mail($git, $blob) or return;
 488         eval { $self->add_message($mime) };
 489         warn "W: index_blob $blob: $@\n" if $@;
 490 }
 491
 492 sub unindex_blob {
 493         my ($self, $git, $blob) = @_;
 494         my $mime = do_cat_mail($git, $blob) or return;
 495         my $mid = $mime->header('Message-ID');
 496         eval { $self->remove_message($mid) } if defined $mid;
 497         warn "W: unindex_blob $blob: $@\n" if $@;
 498 }
 499
 500 sub enquire {
 501         my ($self) = @_;
 502         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 503 }
 504
 505 # indexes all unindexed messages
 506 sub index_sync {
 507         my ($self, $git) = @_;
 508         my $db = $self->{xdb};
 509         my $latest = $db->get_metadata('last_commit');
 510         my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 511         $latest = undef;
 512
 513         my $hex = '[a-f0-9]';
 514         my $h40 = $hex .'{40}';
 515         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 516         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 517
 518         # get indexed messages
 519         my @cmd = ('git', "--git-dir=$git->{git_dir}", "log",
 520                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 521                     $range);
 522
 523         my $pid = open(my $log, '-|', @cmd) or
 524                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 525         my $last;
 526         while (my $line = <$log>) {
 527                 if ($line =~ /$addmsg/o) {
 528                         $self->index_blob($git, $1);
 529                 } elsif ($line =~ /$delmsg/o) {
 530                         $self->unindex_blob($git, $1);
 531                 } elsif ($line =~ /^commit ($h40)/o) {
 532                         my $commit = $1;
 533                         if (defined $latest) {
 534                                 $db->set_metadata('last_commit', $latest)
 535                         }
 536                         $latest = $commit;
 537                 }
 538         }
 539         close $log;
 540         $db->set_metadata('last_commit', $latest) if defined $latest;
 541 }
 542
 543 1;