lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak carp);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(log2stack is_ancestor check_size prepare_stack
  26         index_text term_generator add_val is_bad_blob);
  27 my $X = \%PublicInbox::Search::X;
  28 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  29 our $DB_NO_SYNC = 0;
  30 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  31 use constant DEBUG => !!$ENV{DEBUG};
  32
  33 my $xapianlevels = qr/\A(?:full|medium)\z/;
  34 my $hex = '[a-f0-9]';
  35 my $OID = $hex .'{40,}';
  36 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  37
  38 sub new {
  39         my ($class, $ibx, $creat, $shard) = @_;
  40         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  41         my $inboxdir = $ibx->{inboxdir};
  42         my $version = $ibx->version;
  43         my $indexlevel = 'full';
  44         my $altid = $ibx->{altid};
  45         if ($altid) {
  46                 require PublicInbox::AltId;
  47                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  48         }
  49         if ($ibx->{indexlevel}) {
  50                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  51                         $indexlevel = $ibx->{indexlevel};
  52                 } else {
  53                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  54                 }
  55         }
  56         $ibx = PublicInbox::InboxWritable->new($ibx);
  57         my $self = PublicInbox::Search->new($ibx);
  58         bless $self, $class;
  59         $self->{ibx} = $ibx;
  60         $self->{-altid} = $altid;
  61         $self->{indexlevel} = $indexlevel;
  62         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  63         if ($ibx->{-skip_docdata}) {
  64                 $self->{-set_skip_docdata_once} = 1;
  65                 $self->{-skip_docdata} = 1;
  66         }
  67         if ($version == 1) {
  68                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  69                 my $dir = $self->xdir;
  70                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  71                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  72         } elsif ($version == 2) {
  73                 defined $shard or die "shard is required for v2\n";
  74                 # shard is a number
  75                 $self->{shard} = $shard;
  76                 $self->{lock_path} = undef;
  77         } else {
  78                 die "unsupported inbox version=$version\n";
  79         }
  80         $self->{creat} = ($creat || 0) == 1;
  81         $self;
  82 }
  83
  84 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  85
  86 sub idx_release {
  87         my ($self, $wake) = @_;
  88         if (need_xapian($self)) {
  89                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  90                 $xdb->close;
  91         }
  92         $self->lock_release($wake) if $self->{creat};
  93         undef;
  94 }
  95
  96 sub load_xapian_writable () {
  97         return 1 if $X->{WritableDatabase};
  98         PublicInbox::Search::load_xapian() or return;
  99         my $xap = $PublicInbox::Search::Xap;
 100         for (qw(Document TermGenerator WritableDatabase)) {
 101                 $X->{$_} = $xap.'::'.$_;
 102         }
 103         eval 'require '.$X->{WritableDatabase} or die;
 104         *sortable_serialise = $xap.'::sortable_serialise';
 105         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 106         $DB_OPEN = eval($xap.'::DB_OPEN()');
 107         my $ver = (eval($xap.'::major_version()') << 16) |
 108                 (eval($xap.'::minor_version()') << 8);
 109         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 110         1;
 111 }
 112
 113 sub idx_acquire {
 114         my ($self) = @_;
 115         my $flag;
 116         my $dir = $self->xdir;
 117         if (need_xapian($self)) {
 118                 croak 'already acquired' if $self->{xdb};
 119                 load_xapian_writable();
 120                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 121         }
 122         if ($self->{creat}) {
 123                 require File::Path;
 124                 $self->lock_acquire;
 125
 126                 # don't create empty Xapian directories if we don't need Xapian
 127                 my $is_shard = defined($self->{shard});
 128                 if (!-d $dir && (!$is_shard ||
 129                                 ($is_shard && need_xapian($self)))) {
 130                         File::Path::mkpath($dir);
 131                         nodatacow_dir($dir);
 132                         $self->{-set_has_threadid_once} = 1;
 133                 }
 134         }
 135         return unless defined $flag;
 136         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 137         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 138         croak "Failed opening $dir: $@" if $@;
 139         $self->{xdb} = $xdb;
 140 }
 141
 142 sub add_val ($$$) {
 143         my ($doc, $col, $num) = @_;
 144         $num = sortable_serialise($num);
 145         $doc->add_value($col, $num);
 146 }
 147
 148 sub term_generator ($) { # write-only
 149         my ($self) = @_;
 150
 151         $self->{term_generator} //= do {
 152                 my $tg = $X->{TermGenerator}->new;
 153                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 154                 $tg;
 155         }
 156 }
 157
 158 sub index_text ($$$$) {
 159         my ($self, $text, $wdf_inc, $prefix) = @_;
 160         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 161
 162         if ($self->{indexlevel} eq 'full') {
 163                 $tg->index_text($text, $wdf_inc, $prefix);
 164                 $tg->increase_termpos;
 165         } else {
 166                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 167         }
 168 }
 169
 170 sub index_headers ($$) {
 171         my ($self, $smsg) = @_;
 172         my @x = (from => 'A', # Author
 173                 subject => 'S', to => 'XTO', cc => 'XCC');
 174         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 175                 my $val = $smsg->{$field};
 176                 index_text($self, $val, 1, $pfx) if $val ne '';
 177         }
 178 }
 179
 180 sub index_diff_inc ($$$$) {
 181         my ($self, $text, $pfx, $xnq) = @_;
 182         if (@$xnq) {
 183                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 184                 @$xnq = ();
 185         }
 186         index_text($self, $text, 1, $pfx);
 187 }
 188
 189 sub index_old_diff_fn {
 190         my ($self, $seen, $fa, $fb, $xnq) = @_;
 191
 192         # no renames or space support for traditional diffs,
 193         # find the number of leading common paths to strip:
 194         my @fa = split('/', $fa);
 195         my @fb = split('/', $fb);
 196         while (scalar(@fa) && scalar(@fb)) {
 197                 $fa = join('/', @fa);
 198                 $fb = join('/', @fb);
 199                 if ($fa eq $fb) {
 200                         unless ($seen->{$fa}++) {
 201                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 202                         }
 203                         return 1;
 204                 }
 205                 shift @fa;
 206                 shift @fb;
 207         }
 208         0;
 209 }
 210
 211 sub index_diff ($$$) {
 212         my ($self, $txt, $doc) = @_;
 213         my %seen;
 214         my $in_diff;
 215         my @xnq;
 216         my $xnq = \@xnq;
 217         foreach (split(/\n/, $txt)) {
 218                 if ($in_diff && s/^ //) { # diff context
 219                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 220                 } elsif (/^-- $/) { # email signature begins
 221                         $in_diff = undef;
 222                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 223                         # wait until "---" and "+++" to capture filenames
 224                         $in_diff = 1;
 225                 # traditional diff:
 226                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 227                         my ($opt, $fa, $fb) = ($1, $2, $3);
 228                         push @xnq, $_;
 229                         # only support unified:
 230                         next unless $opt =~ /[uU]/;
 231                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 232                                                         $xnq);
 233                 } elsif (m!^--- ("?[^/]+/.+)!) {
 234                         my $fn = $1;
 235                         $fn = (split('/', git_unquote($fn), 2))[1];
 236                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 237                         $in_diff = 1;
 238                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 239                         my $fn = $1;
 240                         $fn = (split('/', git_unquote($fn), 2))[1];
 241                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 242                         $in_diff = 1;
 243                 } elsif (/^--- (\S+)/) {
 244                         $in_diff = $1;
 245                         push @xnq, $_;
 246                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 247                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 248                                                         $1, $xnq);
 249                 } elsif ($in_diff && s/^\+//) { # diff added
 250                         index_diff_inc($self, $_, 'XDFB', $xnq);
 251                 } elsif ($in_diff && s/^-//) { # diff removed
 252                         index_diff_inc($self, $_, 'XDFA', $xnq);
 253                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 254                         my ($ba, $bb) = ($1, $2);
 255                         index_git_blob_id($doc, 'XDFPRE', $ba);
 256                         index_git_blob_id($doc, 'XDFPOST', $bb);
 257                         $in_diff = 1;
 258                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 259                         # traditional diff w/o -p
 260                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 261                         # hunk header context
 262                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 263                 # ignore the following lines:
 264                 } elsif (/^(?:dis)similarity index/ ||
 265                                 /^(?:old|new) mode/ ||
 266                                 /^(?:deleted|new) file mode/ ||
 267                                 /^(?:copy|rename) (?:from|to) / ||
 268                                 /^(?:dis)?similarity index / ||
 269                                 /^\\ No newline at end of file/ ||
 270                                 /^Binary files .* differ/) {
 271                         push @xnq, $_;
 272                 } elsif ($_ eq '') {
 273                         # possible to be in diff context, some mail may be
 274                         # stripped by MUA or even GNU diff(1).  "git apply"
 275                         # treats a bare "\n" as diff context, too
 276                 } else {
 277                         push @xnq, $_;
 278                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 279                         $in_diff = undef;
 280                 }
 281         }
 282
 283         index_text($self, join("\n", @xnq), 1, 'XNQ');
 284 }
 285
 286 sub index_xapian { # msg_iter callback
 287         my $part = $_[0]->[0]; # ignore $depth and $idx
 288         my ($self, $doc) = @{$_[1]};
 289         my $ct = $part->content_type || 'text/plain';
 290         my $fn = $part->filename;
 291         if (defined $fn && $fn ne '') {
 292                 index_text($self, $fn, 1, 'XFN');
 293         }
 294         if ($part->{is_submsg}) {
 295                 my $mids = mids_for_index($part);
 296                 index_ids($self, $doc, $part, $mids);
 297                 my $smsg = bless {}, 'PublicInbox::Smsg';
 298                 $smsg->populate($part);
 299                 index_headers($self, $smsg);
 300         }
 301
 302         my ($s, undef) = msg_part_text($part, $ct);
 303         defined $s or return;
 304         $_[0]->[0] = $part = undef; # free memory
 305
 306         # split off quoted and unquoted blocks:
 307         my @sections = PublicInbox::MsgIter::split_quotes($s);
 308         undef $s; # free memory
 309         for my $txt (@sections) {
 310                 if ($txt =~ /\A>/) {
 311                         index_text($self, $txt, 0, 'XQUOT');
 312                 } else {
 313                         # does it look like a diff?
 314                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 315                                 index_diff($self, $txt, $doc);
 316                         } else {
 317                                 index_text($self, $txt, 1, 'XNQ');
 318                         }
 319                 }
 320                 undef $txt; # free memory
 321         }
 322 }
 323
 324 sub index_list_id ($$$) {
 325         my ($self, $doc, $hdr) = @_;
 326         for my $l ($hdr->header_raw('List-Id')) {
 327                 $l =~ /<([^>]+)>/ or next;
 328                 my $lid = lc $1;
 329                 $doc->add_boolean_term('G' . $lid);
 330                 index_text($self, $lid, 1, 'XL'); # probabilistic
 331         }
 332 }
 333
 334 sub index_ids ($$$$) {
 335         my ($self, $doc, $hdr, $mids) = @_;
 336         for my $mid (@$mids) {
 337                 index_text($self, $mid, 1, 'XM');
 338
 339                 # because too many Message-IDs are prefixed with
 340                 # "Pine.LNX."...
 341                 if ($mid =~ /\w{12,}/) {
 342                         my @long = ($mid =~ /(\w{3,}+)/g);
 343                         index_text($self, join(' ', @long), 1, 'XM');
 344                 }
 345         }
 346         $doc->add_boolean_term('Q' . $_) for @$mids;
 347         index_list_id($self, $doc, $hdr);
 348 }
 349
 350 sub eml2doc ($$$;$) {
 351         my ($self, $eml, $smsg, $mids) = @_;
 352         $mids //= mids_for_index($eml);
 353         my $doc = $X->{Document}->new;
 354         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 355         my @ds = gmtime($smsg->{ds});
 356         my $yyyymmdd = strftime('%Y%m%d', @ds);
 357         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 358         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 359         add_val($doc, PublicInbox::Search::DT(), $dt);
 360         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 361         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 362         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 363
 364         my $tg = term_generator($self);
 365         $tg->set_document($doc);
 366         index_headers($self, $smsg);
 367
 368         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 369                 $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 370         }
 371         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 372         index_ids($self, $doc, $eml, $mids);
 373
 374         # by default, we maintain compatibility with v1.5.0 and earlier
 375         # by writing to docdata.glass, users who never exect to downgrade can
 376         # use --skip-docdata
 377         if (!$self->{-skip_docdata}) {
 378                 # WWW doesn't need {to} or {cc}, only NNTP
 379                 $smsg->{to} = $smsg->{cc} = '';
 380                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 381                 my $data = $smsg->to_doc_data;
 382                 $doc->set_data($data);
 383         }
 384
 385         if (my $altid = $self->{-altid}) {
 386                 foreach my $alt (@$altid) {
 387                         my $pfx = $alt->{xprefix};
 388                         foreach my $mid (@$mids) {
 389                                 my $id = $alt->mid2alt($mid);
 390                                 next unless defined $id;
 391                                 $doc->add_boolean_term($pfx . $id);
 392                         }
 393                 }
 394         }
 395         $doc;
 396 }
 397
 398 sub add_xapian ($$$$) {
 399         my ($self, $eml, $smsg, $mids) = @_;
 400         my $doc = eml2doc($self, $eml, $smsg, $mids);
 401         $self->{xdb}->replace_document($smsg->{num}, $doc);
 402 }
 403
 404 sub _msgmap_init ($) {
 405         my ($self) = @_;
 406         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx}->version != 1;
 407         $self->{mm} //= eval {
 408                 require PublicInbox::Msgmap;
 409                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 410                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 411         };
 412 }
 413
 414 sub add_message {
 415         # mime = PublicInbox::Eml or Email::MIME object
 416         my ($self, $mime, $smsg, $sync) = @_;
 417         begin_txn_lazy($self);
 418         my $mids = mids_for_index($mime);
 419         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 420         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 421         $smsg->{num} //= do { # v1
 422                 _msgmap_init($self);
 423                 index_mm($self, $mime, $smsg->{blob}, $sync);
 424         };
 425
 426         # v1 and tests only:
 427         $smsg->populate($mime, $sync);
 428         $smsg->{bytes} //= length($mime->as_string);
 429
 430         eval {
 431                 # order matters, overview stores every possible piece of
 432                 # data in doc_data (deflated).  Xapian only stores a subset
 433                 # of the fields which exist in over.sqlite3.  We may stop
 434                 # storing doc_data in Xapian sometime after we get multi-inbox
 435                 # search working.
 436                 if (my $oidx = $self->{oidx}) { # v1 only
 437                         $oidx->add_overview($mime, $smsg);
 438                 }
 439                 if (need_xapian($self)) {
 440                         add_xapian($self, $mime, $smsg, $mids);
 441                 }
 442         };
 443
 444         if ($@) {
 445                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 446                 return undef;
 447         }
 448         $smsg->{num};
 449 }
 450
 451 sub _get_doc ($$) {
 452         my ($self, $docid) = @_;
 453         my $doc = eval { $self->{xdb}->get_document($docid) };
 454         $doc // do {
 455                 warn "E: $@\n" if $@;
 456                 warn "E: #$docid missing in Xapian\n";
 457                 undef;
 458         }
 459 }
 460
 461 sub add_eidx_info {
 462         my ($self, $docid, $eidx_key, $eml) = @_;
 463         begin_txn_lazy($self);
 464         my $doc = _get_doc($self, $docid) or return;
 465         term_generator($self)->set_document($doc);
 466         $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 467         index_list_id($self, $doc, $eml);
 468         $self->{xdb}->replace_document($docid, $doc);
 469 }
 470
 471 sub remove_eidx_info {
 472         my ($self, $docid, $eidx_key, $eml) = @_;
 473         begin_txn_lazy($self);
 474         my $doc = _get_doc($self, $docid) or return;
 475         eval { $doc->remove_term('O'.$eidx_key) };
 476         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 477         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 478                 $l =~ /<([^>]+)>/ or next;
 479                 my $lid = lc $1;
 480                 eval { $doc->remove_term('G' . $lid) };
 481                 warn "W: ->remove_term G$lid: $@\n" if $@;
 482
 483                 # nb: we don't remove the XL probabilistic terms
 484                 # since terms may overlap if cross-posted.
 485                 #
 486                 # IOW, a message which has both <foo.example.com>
 487                 # and <bar.example.com> would have overlapping
 488                 # "XLexample" and "XLcom" as terms and which we
 489                 # wouldn't know if they're safe to remove if we just
 490                 # unindex <foo.example.com> while preserving
 491                 # <bar.example.com>.
 492                 #
 493                 # In any case, this entire sub is will likely never
 494                 # be needed and users using the "l:" prefix are probably
 495                 # rarer.
 496         }
 497         $self->{xdb}->replace_document($docid, $doc);
 498 }
 499
 500 sub set_keywords {
 501         my ($self, $docid, @kw) = @_;
 502         begin_txn_lazy($self);
 503         my $doc = _get_doc($self, $docid) or return;
 504         my %keep = map { $_ => 1 } @kw;
 505         my %add = %keep;
 506         my @rm;
 507         my $end = $doc->termlist_end;
 508         for (my $cur = $doc->termlist_begin; $cur != $end; $cur++) {
 509                 $cur->skip_to('K');
 510                 last if $cur == $end;
 511                 my $kw = $cur->get_termname;
 512                 $kw =~ s/\AK//s or next;
 513                 $keep{$kw} ? delete($add{$kw}) : push(@rm, $kw);
 514         }
 515         return unless (scalar(@rm) + scalar(keys %add));
 516         $doc->remove_term('K'.$_) for @rm;
 517         $doc->add_boolean_term('K'.$_) for (keys %add);
 518         $self->{xdb}->replace_document($docid, $doc);
 519 }
 520
 521 sub add_keywords {
 522         my ($self, $docid, @kw) = @_;
 523         begin_txn_lazy($self);
 524         my $doc = _get_doc($self, $docid) or return;
 525         $doc->add_boolean_term('K'.$_) for @kw;
 526         $self->{xdb}->replace_document($docid, $doc);
 527 }
 528
 529 sub remove_keywords {
 530         my ($self, $docid, @kw) = @_;
 531         begin_txn_lazy($self);
 532         my $doc = _get_doc($self, $docid) or return;
 533         my $replace;
 534         eval {
 535                 $doc->remove_term('K'.$_);
 536                 $replace = 1
 537         } for @kw;
 538         $self->{xdb}->replace_document($docid, $doc) if $replace;
 539 }
 540
 541 sub smsg_from_doc ($) {
 542         my ($doc) = @_;
 543         my $data = $doc->get_data or return;
 544         my $smsg = bless {}, 'PublicInbox::Smsg';
 545         $smsg->{ts} = int_val($doc, PublicInbox::Search::TS());
 546         my $dt = int_val($doc, PublicInbox::Search::DT());
 547         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 548         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 549         $smsg->load_from_data($data);
 550         $smsg;
 551 }
 552
 553 sub xdb_remove {
 554         my ($self, @docids) = @_;
 555         $self->begin_txn_lazy;
 556         my $xdb = $self->{xdb} or return;
 557         for my $docid (@docids) {
 558                 eval { $xdb->delete_document($docid) };
 559                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 560         }
 561 }
 562
 563 sub index_git_blob_id {
 564         my ($doc, $pfx, $objid) = @_;
 565
 566         my $len = length($objid);
 567         for (my $len = length($objid); $len >= 7; ) {
 568                 $doc->add_term($pfx.$objid);
 569                 $objid = substr($objid, 0, --$len);
 570         }
 571 }
 572
 573 # v1 only
 574 sub unindex_eml {
 575         my ($self, $oid, $eml) = @_;
 576         my $mids = mids($eml);
 577         my $nr = 0;
 578         my %tmp;
 579         for my $mid (@$mids) {
 580                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 581                 $nr += scalar @removed;
 582                 $tmp{$_}++ for @removed;
 583         }
 584         if (!$nr) {
 585                 my $m = join('> <', @$mids);
 586                 warn "W: <$m> missing for removal from overview\n";
 587         }
 588         while (my ($num, $nr) = each %tmp) {
 589                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 590         }
 591         if ($nr) {
 592                 $self->{mm}->num_delete($_) for (keys %tmp);
 593         } else { # just in case msgmap and over.sqlite3 become desynched:
 594                 $self->{mm}->mid_delete($mids->[0]);
 595         }
 596         xdb_remove($self, keys %tmp) if need_xapian($self);
 597 }
 598
 599 sub index_mm {
 600         my ($self, $mime, $oid, $sync) = @_;
 601         my $mids = mids($mime);
 602         my $mm = $self->{mm};
 603         if ($sync->{reindex}) {
 604                 my $oidx = $self->{oidx};
 605                 for my $mid (@$mids) {
 606                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 607                         return $num if defined $num;
 608                 }
 609                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 610         } else {
 611                 # fallback to num_for since filters like RubyLang set the number
 612                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 613         }
 614 }
 615
 616 sub is_bad_blob ($$$$) {
 617         my ($oid, $type, $size, $expect_oid) = @_;
 618         if ($type ne 'blob') {
 619                 carp "W: $expect_oid is not a blob (type=$type)";
 620                 return 1;
 621         }
 622         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 623         $size == 0 ? 1 : 0; # size == 0 means purged
 624 }
 625
 626 sub index_both { # git->cat_async callback
 627         my ($bref, $oid, $type, $size, $sync) = @_;
 628         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 629         my ($nr, $max) = @$sync{qw(nr max)};
 630         ++$$nr;
 631         $$max -= $size;
 632         my $smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 633         $smsg->set_bytes($$bref, $size);
 634         my $self = $sync->{sidx};
 635         local $self->{current_info} = "$self->{current_info}: $oid";
 636         my $eml = PublicInbox::Eml->new($bref);
 637         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 638                 die "E: could not generate NNTP article number for $oid";
 639         add_message($self, $eml, $smsg, $sync);
 640         ++$self->{nidx};
 641         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 642         ${$sync->{latest_cmt}} = $cur_cmt;
 643 }
 644
 645 sub unindex_both { # git->cat_async callback
 646         my ($bref, $oid, $type, $size, $sync) = @_;
 647         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 648         my $self = $sync->{sidx};
 649         local $self->{current_info} = "$self->{current_info}: $oid";
 650         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 651         # may be undef if leftover
 652         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 653                 ${$sync->{latest_cmt}} = $cur_cmt;
 654         }
 655         ++$self->{nidx};
 656 }
 657
 658 sub with_umask {
 659         my $self = shift;
 660         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 661 }
 662
 663 # called by public-inbox-index
 664 sub index_sync {
 665         my ($self, $opt) = @_;
 666         delete $self->{lock_path} if $opt->{-skip_lock};
 667         $self->with_umask(\&_index_sync, $self, $opt);
 668         if ($opt->{reindex} && !$opt->{quit}) {
 669                 my %again = %$opt;
 670                 delete @again{qw(rethread reindex)};
 671                 index_sync($self, \%again);
 672                 $opt->{quit} = $again{quit}; # propagate to caller
 673         }
 674 }
 675
 676 sub check_size { # check_async cb for -index --max-size=...
 677         my ($oid, $type, $size, $arg, $git) = @_;
 678         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 679         if ($size <= $arg->{max_size}) {
 680                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 681         } else {
 682                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 683         }
 684 }
 685
 686 sub v1_checkpoint ($$;$) {
 687         my ($self, $sync, $stk) = @_;
 688         $self->{ibx}->git->async_wait_all;
 689
 690         # $newest may be undef
 691         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 692         if (defined($newest)) {
 693                 my $cur = $self->{mm}->last_commit || '';
 694                 if (need_update($self, $cur, $newest)) {
 695                         $self->{mm}->last_commit($newest);
 696                 }
 697         }
 698         ${$sync->{max}} = $self->{batch_bytes};
 699
 700         $self->{mm}->{dbh}->commit;
 701         my $xdb = need_xapian($self) ? $self->{xdb} : undef;
 702         if ($newest && $xdb) {
 703                 my $cur = $xdb->get_metadata('last_commit');
 704                 if (need_update($self, $cur, $newest)) {
 705                         $xdb->set_metadata('last_commit', $newest);
 706                 }
 707         }
 708         if ($stk) { # all done if $stk is passed
 709                 # let SearchView know a full --reindex was done so it can
 710                 # generate ->has_threadid-dependent links
 711                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 712                         my $n = $xdb->get_metadata('has_threadid');
 713                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 714                 }
 715                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 716         }
 717         commit_txn_lazy($self);
 718         $sync->{ibx}->git->cleanup;
 719         my $nr = ${$sync->{nr}};
 720         idx_release($self, $nr);
 721         # let another process do some work...
 722         if (my $pr = $sync->{-opt}->{-progress}) {
 723                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 724         }
 725         if (!$stk && !$sync->{quit}) { # more to come
 726                 begin_txn_lazy($self);
 727                 $self->{mm}->{dbh}->begin_work;
 728         }
 729 }
 730
 731 # only for v1
 732 sub process_stack {
 733         my ($self, $sync, $stk) = @_;
 734         my $git = $sync->{ibx}->git;
 735         my $max = $self->{batch_bytes};
 736         my $nr = 0;
 737         $sync->{nr} = \$nr;
 738         $sync->{max} = \$max;
 739         $sync->{sidx} = $self;
 740         $sync->{latest_cmt} = \(my $latest_cmt);
 741
 742         $self->{mm}->{dbh}->begin_work;
 743         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 744                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 745                 for my $oid (@leftovers) {
 746                         last if $sync->{quit};
 747                         $oid = unpack('H*', $oid);
 748                         $git->cat_async($oid, \&unindex_both, $sync);
 749                 }
 750         }
 751         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 752                 $sync->{index_oid} = \&index_both;
 753         }
 754         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 755                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 756                 last if $sync->{quit};
 757                 if ($f eq 'm') {
 758                         $arg->{autime} = $at;
 759                         $arg->{cotime} = $ct;
 760                         if ($sync->{max_size}) {
 761                                 $git->check_async($oid, \&check_size, $arg);
 762                         } else {
 763                                 $git->cat_async($oid, \&index_both, $arg);
 764                         }
 765                         v1_checkpoint($self, $sync) if $max <= 0;
 766                 } elsif ($f eq 'd') {
 767                         $git->cat_async($oid, \&unindex_both, $arg);
 768                 }
 769         }
 770         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 771 }
 772
 773 sub log2stack ($$$) {
 774         my ($sync, $git, $range) = @_;
 775         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 776         my ($add, $del);
 777         if ($sync->{ibx}->version == 1) {
 778                 my $path = $hex.'{2}/'.$hex.'{38}';
 779                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 780                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 781         } else {
 782                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 783                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 784         }
 785
 786         # Count the new files so they can be added newest to oldest
 787         # and still have numbers increasing from oldest to newest
 788         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 789                                 --no-notes --no-color --no-renames --no-abbrev),
 790                                 $range);
 791         my ($at, $ct, $stk, $cmt);
 792         while (<$fh>) {
 793                 return if $sync->{quit};
 794                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 795                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 796                         $stk //= PublicInbox::IdxStack->new($cmt);
 797                 } elsif (/$del/) {
 798                         my $oid = $1;
 799                         if ($D) { # reindex case
 800                                 $D->{pack('H*', $oid)}++;
 801                         } else { # non-reindex case:
 802                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 803                         }
 804                 } elsif (/$add/) {
 805                         my $oid = $1;
 806                         if ($D) {
 807                                 my $oid_bin = pack('H*', $oid);
 808                                 my $nr = --$D->{$oid_bin};
 809                                 delete($D->{$oid_bin}) if $nr <= 0;
 810                                 # nr < 0 (-1) means it never existed
 811                                 next if $nr >= 0;
 812                         }
 813                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 814                 }
 815         }
 816         close $fh or die "git log failed: \$?=$?";
 817         $stk //= PublicInbox::IdxStack->new;
 818         $stk->read_prepare;
 819 }
 820
 821 sub prepare_stack ($$) {
 822         my ($sync, $range) = @_;
 823         my $git = $sync->{ibx}->git;
 824
 825         if (index($range, '..') < 0) {
 826                 # don't show annoying git errors to users who run -index
 827                 # on empty inboxes
 828                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 829                 return PublicInbox::IdxStack->new->read_prepare if $?;
 830         }
 831         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 832         log2stack($sync, $git, $range);
 833 }
 834
 835 # --is-ancestor requires git 1.8.0+
 836 sub is_ancestor ($$$) {
 837         my ($git, $cur, $tip) = @_;
 838         return 0 unless $git->check($cur);
 839         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 840                 qw(merge-base --is-ancestor), $cur, $tip ];
 841         my $pid = spawn($cmd);
 842         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 843         $? == 0;
 844 }
 845
 846 sub need_update ($$$) {
 847         my ($self, $cur, $new) = @_;
 848         my $git = $self->{ibx}->git;
 849         return 1 if $cur && !is_ancestor($git, $cur, $new);
 850         my $range = $cur eq '' ? $new : "$cur..$new";
 851         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 852         ($n eq '' || $n > 0);
 853 }
 854
 855 # The last git commit we indexed with Xapian or SQLite (msgmap)
 856 # This needs to account for cases where Xapian or SQLite is
 857 # out-of-date with respect to the other.
 858 sub _last_x_commit {
 859         my ($self, $mm) = @_;
 860         my $lm = $mm->last_commit || '';
 861         my $lx = '';
 862         if (need_xapian($self)) {
 863                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 864         } else {
 865                 $lx = $lm;
 866         }
 867         # Use last_commit from msgmap if it is older or unset
 868         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 869                 $lx = $lm;
 870         }
 871         $lx;
 872 }
 873
 874 sub reindex_from ($$) {
 875         my ($reindex, $last_commit) = @_;
 876         return $last_commit unless $reindex;
 877         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 878 }
 879
 880 sub quit_cb ($) {
 881         my ($sync) = @_;
 882         sub {
 883                 # we set {-opt}->{quit} too, so ->index_sync callers
 884                 # can abort multi-inbox loops this way
 885                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
 886                 warn "gracefully quitting\n";
 887         }
 888 }
 889
 890 # indexes all unindexed messages (v1 only)
 891 sub _index_sync {
 892         my ($self, $opt) = @_;
 893         my $tip = $opt->{ref} || 'HEAD';
 894         my $ibx = $self->{ibx};
 895         local $self->{current_info} = "$ibx->{inboxdir}";
 896         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 897         $ibx->git->batch_prepare;
 898         my $pr = $opt->{-progress};
 899         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
 900         my $quit = quit_cb($sync);
 901         local $SIG{QUIT} = $quit;
 902         local $SIG{INT} = $quit;
 903         local $SIG{TERM} = $quit;
 904         my $xdb = $self->begin_txn_lazy;
 905         $self->{oidx}->rethread_prepare($opt);
 906         my $mm = _msgmap_init($self);
 907         if ($sync->{reindex}) {
 908                 my $last = $mm->last_commit;
 909                 if ($last) {
 910                         $tip = $last;
 911                 } else {
 912                         # somebody just blindly added --reindex when indexing
 913                         # for the first time, allow it:
 914                         undef $sync->{reindex};
 915                 }
 916         }
 917         my $last_commit = _last_x_commit($self, $mm);
 918         my $lx = reindex_from($sync->{reindex}, $last_commit);
 919         my $range = $lx eq '' ? $tip : "$lx..$tip";
 920         $pr->("counting changes\n\t$range ... ") if $pr;
 921         my $stk = prepare_stack($sync, $range);
 922         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 923         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 924         process_stack($self, $sync, $stk) if !$sync->{quit};
 925 }
 926
 927 sub DESTROY {
 928         # order matters for unlocking
 929         $_[0]->{xdb} = undef;
 930         $_[0]->{lockfh} = undef;
 931 }
 932
 933 sub _begin_txn {
 934         my ($self) = @_;
 935         my $xdb = $self->{xdb} || idx_acquire($self);
 936         $self->{oidx}->begin_lazy if $self->{oidx};
 937         $xdb->begin_transaction if $xdb;
 938         $self->{txn} = 1;
 939         $xdb;
 940 }
 941
 942 sub begin_txn_lazy {
 943         my ($self) = @_;
 944         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
 945 }
 946
 947 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 948 # This metadata is read by Admin::detect_indexlevel:
 949 sub set_metadata_once {
 950         my ($self) = @_;
 951
 952         return if $self->{shard}; # only continue if undef or 0, not >0
 953         my $xdb = $self->{xdb};
 954
 955         if (delete($self->{-set_has_threadid_once})) {
 956                 $xdb->set_metadata('has_threadid', '1');
 957         }
 958         if (delete($self->{-set_indexlevel_once})) {
 959                 my $level = $xdb->get_metadata('indexlevel');
 960                 if (!$level || $level ne 'medium') {
 961                         $xdb->set_metadata('indexlevel', 'medium');
 962                 }
 963         }
 964         if (delete($self->{-set_skip_docdata_once})) {
 965                 $xdb->get_metadata('skip_docdata') or
 966                         $xdb->set_metadata('skip_docdata', '1');
 967         }
 968 }
 969
 970 sub _commit_txn {
 971         my ($self) = @_;
 972         if (my $eidx = $self->{eidx}) {
 973                 $eidx->git->async_wait_all;
 974                 $eidx->{transact_bytes} = 0;
 975         }
 976         if (my $xdb = $self->{xdb}) {
 977                 set_metadata_once($self);
 978                 $xdb->commit_transaction;
 979         }
 980         $self->{oidx}->commit_lazy if $self->{oidx};
 981 }
 982
 983 sub commit_txn_lazy {
 984         my ($self) = @_;
 985         delete($self->{txn}) and
 986                 $self->with_umask(\&_commit_txn, $self);
 987 }
 988
 989 sub eidx_shard_new {
 990         my ($class, $eidx, $shard) = @_;
 991         my $self = bless {
 992                 eidx => $eidx,
 993                 xpfx => $eidx->{xpfx},
 994                 indexlevel => $eidx->{indexlevel},
 995                 -skip_docdata => 1,
 996                 shard => $shard,
 997                 creat => 1,
 998         }, $class;
 999         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
1000         $self;
1001 }
1002
1003 # ensure there's no stale Xapian docs by treating $over as canonical
1004 sub over_check {
1005         my ($self, $over) = @_;
1006         begin_txn_lazy($self);
1007         my $sth = $over->dbh->prepare(<<'');
1008 SELECT COUNT(*) FROM over WHERE num = ?
1009
1010         my $xdb = $self->{xdb};
1011         my $cur = $xdb->postlist_begin('');
1012         my $end = $xdb->postlist_end('');
1013         my $xdir = $self->xdir;
1014         for (; $cur != $end; $cur++) {
1015                 my $docid = $cur->get_docid;
1016                 $sth->execute($docid);
1017                 my $x = $sth->fetchrow_array;
1018                 next if $x > 0;
1019                 warn "I: removing $xdir #$docid, not in `over'\n";
1020                 $xdb->delete_document($docid);
1021         }
1022 }
1023
1024 1;