lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 require PublicInbox::Git;
  22 use Compress::Zlib qw(compress);
  23
  24 use constant {
  25         BATCH_BYTES => 1_000_000,
  26         DEBUG => !!$ENV{DEBUG},
  27 };
  28
  29 my %GIT_ESC = (
  30         a => "\a",
  31         b => "\b",
  32         f => "\f",
  33         n => "\n",
  34         r => "\r",
  35         t => "\t",
  36         v => "\013",
  37 );
  38
  39 sub git_unquote ($) {
  40         my ($s) = @_;
  41         return $s unless ($s =~ /\A"(.*)"\z/);
  42         $s = $1;
  43         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  44         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  45         $s;
  46 }
  47
  48 sub new {
  49         my ($class, $ibx, $creat, $part) = @_;
  50         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  51         my $git_dir = $mainrepo;
  52         my ($altid, $git);
  53         my $version = 1;
  54         my $indexlevel = 'full';
  55         if (ref $ibx) {
  56                 $mainrepo = $ibx->{mainrepo};
  57                 $altid = $ibx->{altid};
  58                 $version = $ibx->{version} || 1;
  59                 if ($altid) {
  60                         require PublicInbox::AltId;
  61                         $altid = [ map {
  62                                 PublicInbox::AltId->new($ibx, $_);
  63                         } @$altid ];
  64                 }
  65         } else { # v1
  66                 $ibx = { mainrepo => $git_dir, version => 1 };
  67         }
  68         $ibx = PublicInbox::InboxWritable->new($ibx);
  69         require Search::Xapian::WritableDatabase;
  70         my $self = bless {
  71                 mainrepo => $mainrepo,
  72                 -inbox => $ibx,
  73                 git => $ibx->git,
  74                 -altid => $altid,
  75                 version => $version,
  76                 indexlevel => $indexlevel,
  77         }, $class;
  78         $ibx->umask_prepare;
  79         if ($version == 1) {
  80                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  81                 my $dir = $self->xdir;
  82                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  83         } elsif ($version == 2) {
  84                 defined $part or die "partition is required for v2\n";
  85                 # partition is a number
  86                 $self->{partition} = $part;
  87                 $self->{lock_path} = undef;
  88         } else {
  89                 die "unsupported inbox version=$version\n";
  90         }
  91         $self->{creat} = ($creat || 0) == 1;
  92         $self;
  93 }
  94
  95 sub _xdb_release {
  96         my ($self) = @_;
  97         my $xdb = delete $self->{xdb} or croak 'not acquired';
  98         $xdb->close;
  99         $self->lock_release if $self->{creat};
 100         undef;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         croak 'already acquired' if $self->{xdb};
 106         my $dir = $self->xdir;
 107         my $flag = Search::Xapian::DB_OPEN;
 108         if ($self->{creat}) {
 109                 require File::Path;
 110                 $self->lock_acquire;
 111                 File::Path::mkpath($dir);
 112                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 113         }
 114         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 115 }
 116
 117 sub add_val ($$$) {
 118         my ($doc, $col, $num) = @_;
 119         $num = Search::Xapian::sortable_serialise($num);
 120         $doc->add_value($col, $num);
 121 }
 122
 123 sub index_text ($$$$)
 124 {
 125         my ($self, $field, $n, $text) = @_;
 126         my $tg = $self->term_generator;
 127
 128         if ($self->{indexlevel} eq 'full') {
 129                 $tg->index_text($field, $n, $text);
 130                 $tg->increase_termpos;
 131         } else {
 132                 $tg->index_text_without_positions($field, $n, $text);
 133         }
 134 }
 135
 136 sub index_users ($$) {
 137         my ($self, $smsg) = @_;
 138
 139         my $from = $smsg->from;
 140         my $to = $smsg->to;
 141         my $cc = $smsg->cc;
 142
 143         $self->index_text($from, 1, 'A'); # A - author
 144         $self->index_text($to, 1, 'XTO') if $to ne '';
 145         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 146 }
 147
 148 sub index_diff_inc ($$$$) {
 149         my ($self, $text, $pfx, $xnq) = @_;
 150         if (@$xnq) {
 151                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 152                 @$xnq = ();
 153         }
 154         $self->index_text($text, 1, $pfx);
 155 }
 156
 157 sub index_old_diff_fn {
 158         my ($self, $seen, $fa, $fb, $xnq) = @_;
 159
 160         # no renames or space support for traditional diffs,
 161         # find the number of leading common paths to strip:
 162         my @fa = split('/', $fa);
 163         my @fb = split('/', $fb);
 164         while (scalar(@fa) && scalar(@fb)) {
 165                 $fa = join('/', @fa);
 166                 $fb = join('/', @fb);
 167                 if ($fa eq $fb) {
 168                         unless ($seen->{$fa}++) {
 169                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 170                         }
 171                         return 1;
 172                 }
 173                 shift @fa;
 174                 shift @fb;
 175         }
 176         0;
 177 }
 178
 179 sub index_diff ($$$) {
 180         my ($self, $lines, $doc) = @_;
 181         my %seen;
 182         my $in_diff;
 183         my @xnq;
 184         my $xnq = \@xnq;
 185         foreach (@$lines) {
 186                 if ($in_diff && s/^ //) { # diff context
 187                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 188                 } elsif (/^-- $/) { # email signature begins
 189                         $in_diff = undef;
 190                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 191                         my ($fa, $fb) = ($1, $2);
 192                         my $fn = (split('/', git_unquote($fa), 2))[1];
 193                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 194                         $fn = (split('/', git_unquote($fb), 2))[1];
 195                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 196                         $in_diff = 1;
 197                 # traditional diff:
 198                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 199                         my ($opt, $fa, $fb) = ($1, $2, $3);
 200                         push @xnq, $_;
 201                         # only support unified:
 202                         next unless $opt =~ /[uU]/;
 203                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 204                                                         $xnq);
 205                 } elsif (m!^--- ("?a/.+)!) {
 206                         my $fn = (split('/', git_unquote($1), 2))[1];
 207                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 208                         $in_diff = 1;
 209                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 210                         my $fn = (split('/', git_unquote($1), 2))[1];
 211                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 212                         $in_diff = 1;
 213                 } elsif (/^--- (\S+)/) {
 214                         $in_diff = $1;
 215                         push @xnq, $_;
 216                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 217                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 218                                                         $xnq);
 219                 } elsif ($in_diff && s/^\+//) { # diff added
 220                         $self->index_diff_inc($_, 'XDFB', $xnq);
 221                 } elsif ($in_diff && s/^-//) { # diff removed
 222                         $self->index_diff_inc($_, 'XDFA', $xnq);
 223                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 224                         my ($ba, $bb) = ($1, $2);
 225                         index_git_blob_id($doc, 'XDFPRE', $ba);
 226                         index_git_blob_id($doc, 'XDFPOST', $bb);
 227                         $in_diff = 1;
 228                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 229                         # traditional diff w/o -p
 230                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 231                         # hunk header context
 232                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 233                 # ignore the following lines:
 234                 } elsif (/^(?:dis)similarity index/ ||
 235                                 /^(?:old|new) mode/ ||
 236                                 /^(?:deleted|new) file mode/ ||
 237                                 /^(?:copy|rename) (?:from|to) / ||
 238                                 /^(?:dis)?similarity index / ||
 239                                 /^\\ No newline at end of file/ ||
 240                                 /^Binary files .* differ/) {
 241                         push @xnq, $_;
 242                 } elsif ($_ eq '') {
 243                         $in_diff = undef;
 244                 } else {
 245                         push @xnq, $_;
 246                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 247                         $in_diff = undef;
 248                 }
 249         }
 250
 251         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 252 }
 253
 254 sub index_body ($$$) {
 255         my ($self, $lines, $doc) = @_;
 256         my $txt = join("\n", @$lines);
 257         if ($doc) {
 258                 # does it look like a diff?
 259                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 260                         $txt = undef;
 261                         $self->index_diff($lines, $doc);
 262                 } else {
 263                         $self->index_text($txt, 1, 'XNQ');
 264                 }
 265         } else {
 266                 $self->index_text($txt, 0, 'XQUOT');
 267         }
 268         @$lines = ();
 269 }
 270
 271 sub add_message {
 272         # mime = Email::MIME object
 273         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 274         my $doc_id;
 275         my $mids = mids($mime->header_obj);
 276         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 277         unless (defined $num) { # v1
 278                 $self->_msgmap_init;
 279                 $num = index_mm($self, $mime);
 280         }
 281         eval {
 282                 my $smsg = PublicInbox::SearchMsg->new($mime);
 283                 my $doc = $smsg->{doc};
 284                 my $subj = $smsg->subject;
 285                 add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 286                 my @ds = gmtime($smsg->ds);
 287                 my $yyyymmdd = strftime('%Y%m%d', @ds);
 288                 add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 289                 my $dt = strftime('%Y%m%d%H%M%S', @ds);
 290                 add_val($doc, PublicInbox::Search::DT(), $dt);
 291
 292                 my $tg = $self->term_generator;
 293
 294                 $tg->set_document($doc);
 295                 $self->index_text($subj, 1, 'S') if $subj;
 296                 $self->index_users($smsg);
 297
 298                 msg_iter($mime, sub {
 299                         my ($part, $depth, @idx) = @{$_[0]};
 300                         my $ct = $part->content_type || 'text/plain';
 301                         my $fn = $part->filename;
 302                         if (defined $fn && $fn ne '') {
 303                                 $self->index_text($fn, 1, 'XFN');
 304                         }
 305
 306                         return if $ct =~ m!\btext/x?html\b!i;
 307
 308                         my $s = eval { $part->body_str };
 309                         if ($@) {
 310                                 if ($ct =~ m!\btext/plain\b!i) {
 311                                         # Try to assume UTF-8 because Alpine
 312                                         # seems to do wacky things and set
 313                                         # charset=X-UNKNOWN
 314                                         $part->charset_set('UTF-8');
 315                                         $s = eval { $part->body_str };
 316                                         $s = $part->body if $@;
 317                                 }
 318                         }
 319                         defined $s or return;
 320
 321                         my (@orig, @quot);
 322                         my $body = $part->body;
 323                         my @lines = split(/\n/, $body);
 324                         while (defined(my $l = shift @lines)) {
 325                                 if ($l =~ /^>/) {
 326                                         $self->index_body(\@orig, $doc) if @orig;
 327                                         push @quot, $l;
 328                                 } else {
 329                                         $self->index_body(\@quot, 0) if @quot;
 330                                         push @orig, $l;
 331                                 }
 332                         }
 333                         $self->index_body(\@quot, 0) if @quot;
 334                         $self->index_body(\@orig, $doc) if @orig;
 335                 });
 336
 337                 foreach my $mid (@$mids) {
 338                         $self->index_text($mid, 1, 'XM');
 339
 340                         # because too many Message-IDs are prefixed with
 341                         # "Pine.LNX."...
 342                         if ($mid =~ /\w{12,}/) {
 343                                 my @long = ($mid =~ /(\w{3,}+)/g);
 344                                 $self->index_text(join(' ', @long), 1, 'XM');
 345                         }
 346                 }
 347                 $smsg->{to} = $smsg->{cc} = '';
 348                 PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 349                 my $data = $smsg->to_doc_data($oid, $mid0);
 350                 $doc->set_data($data);
 351                 if (my $altid = $self->{-altid}) {
 352                         foreach my $alt (@$altid) {
 353                                 my $pfx = $alt->{xprefix};
 354                                 foreach my $mid (@$mids) {
 355                                         my $id = $alt->mid2alt($mid);
 356                                         next unless defined $id;
 357                                         $doc->add_boolean_term($pfx . $id);
 358                                 }
 359                         }
 360                 }
 361
 362                 if (my $over = $self->{over}) {
 363                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 364                 }
 365                 $doc->add_boolean_term('Q' . $_) foreach @$mids;
 366                 $self->{xdb}->replace_document($doc_id = $num, $doc);
 367         };
 368
 369         if ($@) {
 370                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 371                 return undef;
 372         }
 373         $doc_id;
 374 }
 375
 376 # returns begin and end PostingIterator
 377 sub find_doc_ids {
 378         my ($self, $termval) = @_;
 379         my $db = $self->{xdb};
 380
 381         ($db->postlist_begin($termval), $db->postlist_end($termval));
 382 }
 383
 384 sub batch_do {
 385         my ($self, $termval, $cb) = @_;
 386         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 387         while (1) {
 388                 my ($head, $tail) = $self->find_doc_ids($termval);
 389                 return if $head == $tail;
 390                 my @ids;
 391                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 392                         push @ids, $head->get_docid;
 393                 }
 394                 $cb->(\@ids);
 395         }
 396 }
 397
 398 sub remove_message {
 399         my ($self, $mid) = @_;
 400         my $db = $self->{xdb};
 401         my $called;
 402         $mid = mid_clean($mid);
 403         my $over = $self->{over};
 404
 405         eval {
 406                 batch_do($self, 'Q' . $mid, sub {
 407                         my ($ids) = @_;
 408                         $db->delete_document($_) for @$ids;
 409                         $over->delete_articles($ids) if $over;
 410                         $called = 1;
 411                 });
 412         };
 413         if ($@) {
 414                 warn "failed to remove message <$mid>: $@\n";
 415         } elsif (!$called) {
 416                 warn "cannot remove non-existent <$mid>\n";
 417         }
 418 }
 419
 420 # MID is a hint in V2
 421 sub remove_by_oid {
 422         my ($self, $oid, $mid) = @_;
 423         my $db = $self->{xdb};
 424
 425         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 426
 427         # XXX careful, we cannot use batch_do here since we conditionally
 428         # delete documents based on other factors, so we cannot call
 429         # find_doc_ids twice.
 430         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 431         return if $head == $tail;
 432
 433         # there is only ONE element in @delete unless we
 434         # have bugs in our v2writable deduplication check
 435         my @delete;
 436         for (; $head != $tail; $head->inc) {
 437                 my $docid = $head->get_docid;
 438                 my $doc = $db->get_document($docid);
 439                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 440                 $smsg->load_expand;
 441                 if ($smsg->{blob} eq $oid) {
 442                         push(@delete, $docid);
 443                 }
 444         }
 445         $db->delete_document($_) foreach @delete;
 446         scalar(@delete);
 447 }
 448
 449 sub term_generator { # write-only
 450         my ($self) = @_;
 451
 452         my $tg = $self->{term_generator};
 453         return $tg if $tg;
 454
 455         $tg = Search::Xapian::TermGenerator->new;
 456         $tg->set_stemmer($self->stemmer);
 457
 458         $self->{term_generator} = $tg;
 459 }
 460
 461 sub index_git_blob_id {
 462         my ($doc, $pfx, $objid) = @_;
 463
 464         my $len = length($objid);
 465         for (my $len = length($objid); $len >= 7; ) {
 466                 $doc->add_term($pfx.$objid);
 467                 $objid = substr($objid, 0, --$len);
 468         }
 469 }
 470
 471 sub unindex_blob {
 472         my ($self, $mime) = @_;
 473         my $mid = eval { mid_clean(mid_mime($mime)) };
 474         $self->remove_message($mid) if defined $mid;
 475 }
 476
 477 sub index_mm {
 478         my ($self, $mime) = @_;
 479         my $mid = mid_clean(mid_mime($mime));
 480         my $mm = $self->{mm};
 481         my $num;
 482
 483         if (defined $self->{regen_down}) {
 484                 $num = $mm->num_for($mid) and return $num;
 485
 486                 while (($num = $self->{regen_down}--) > 0) {
 487                         if ($mm->mid_set($num, $mid) != 0) {
 488                                 return $num;
 489                         }
 490                 }
 491         } elsif (defined $self->{regen_up}) {
 492                 $num = $mm->num_for($mid) and return $num;
 493
 494                 # this is to fixup old bugs due to add-remove-add
 495                 while (($num = ++$self->{regen_up})) {
 496                         if ($mm->mid_set($num, $mid) != 0) {
 497                                 return $num;
 498                         }
 499                 }
 500         }
 501
 502         $num = $mm->mid_insert($mid) and return $num;
 503
 504         # fallback to num_for since filters like RubyLang set the number
 505         $mm->num_for($mid);
 506 }
 507
 508 sub unindex_mm {
 509         my ($self, $mime) = @_;
 510         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 511 }
 512
 513 sub index_both {
 514         my ($self, $mime, $bytes, $blob) = @_;
 515         my $num = index_mm($self, $mime);
 516         add_message($self, $mime, $bytes, $num, $blob);
 517 }
 518
 519 sub unindex_both {
 520         my ($self, $mime) = @_;
 521         unindex_blob($self, $mime);
 522         unindex_mm($self, $mime);
 523 }
 524
 525 sub do_cat_mail {
 526         my ($git, $blob, $sizeref) = @_;
 527         my $mime = eval {
 528                 my $str = $git->cat_file($blob, $sizeref);
 529                 # fixup bugs from import:
 530                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 531                 PublicInbox::MIME->new($str);
 532         };
 533         $@ ? undef : $mime;
 534 }
 535
 536 sub index_sync {
 537         my ($self, $opts) = @_;
 538         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 539 }
 540
 541 sub batch_adjust ($$$$) {
 542         my ($max, $bytes, $batch_cb, $latest) = @_;
 543         $$max -= $bytes;
 544         if ($$max <= 0) {
 545                 $$max = BATCH_BYTES;
 546                 $batch_cb->($latest);
 547         }
 548 }
 549
 550 # only for v1
 551 sub read_log {
 552         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 553         my $hex = '[a-f0-9]';
 554         my $h40 = $hex .'{40}';
 555         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 556         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 557         my $git = $self->{git};
 558         my $latest;
 559         my $bytes;
 560         my $max = BATCH_BYTES;
 561         local $/ = "\n";
 562         my %D;
 563         my $line;
 564         my $newest;
 565         while (defined($line = <$log>)) {
 566                 if ($line =~ /$addmsg/o) {
 567                         my $blob = $1;
 568                         if (delete $D{$blob}) {
 569                                 if (defined $self->{regen_down}) {
 570                                         $self->{regen_down}--;
 571                                 }
 572                                 next;
 573                         }
 574                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 575                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 576                         $add_cb->($self, $mime, $bytes, $blob);
 577                 } elsif ($line =~ /$delmsg/o) {
 578                         my $blob = $1;
 579                         $D{$blob} = 1;
 580                 } elsif ($line =~ /^commit ($h40)/o) {
 581                         $latest = $1;
 582                         $newest ||= $latest;
 583                 }
 584         }
 585         # get the leftovers
 586         foreach my $blob (keys %D) {
 587                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 588                 $del_cb->($self, $mime);
 589         }
 590         $batch_cb->($latest, $newest);
 591 }
 592
 593 sub _msgmap_init {
 594         my ($self) = @_;
 595         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 596         $self->{mm} ||= eval {
 597                 require PublicInbox::Msgmap;
 598                 PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 599         };
 600 }
 601
 602 sub _git_log {
 603         my ($self, $range) = @_;
 604         my $git = $self->{git};
 605
 606         if (index($range, '..') < 0) {
 607                 my $regen_max = 0;
 608                 # can't use 'rev-list --count' if we use --diff-filter
 609                 my $fh = $git->popen(qw(log --pretty=tformat:%h
 610                                 --no-notes --no-color --no-renames
 611                                 --diff-filter=AM), $range);
 612                 ++$regen_max while <$fh>;
 613                 my (undef, $max) = $self->{mm}->minmax;
 614
 615                 if ($max && $max == $regen_max) {
 616                         # fix up old bugs in full indexes which caused messages to
 617                         # not appear in Msgmap
 618                         $self->{regen_up} = $max;
 619                 } else {
 620                         # normal regen is for for fresh data
 621                         $self->{regen_down} = $regen_max;
 622                 }
 623         }
 624
 625         $git->popen(qw/log --no-notes --no-color --no-renames
 626                                 --raw -r --no-abbrev/, $range);
 627 }
 628
 629 sub is_ancestor ($$$) {
 630         my ($git, $cur, $tip) = @_;
 631         return 0 unless $git->check($cur);
 632         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 633                 qw(merge-base --is-ancestor), $cur, $tip ];
 634         my $pid = spawn($cmd);
 635         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 636         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 637         $? == 0;
 638 }
 639
 640 sub need_update ($$$) {
 641         my ($self, $cur, $new) = @_;
 642         my $git = $self->{git};
 643         return 1 if $cur && !is_ancestor($git, $cur, $new);
 644         my $range = $cur eq '' ? $new : "$cur..$new";
 645         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 646         ($n eq '' || $n > 0);
 647 }
 648
 649 # indexes all unindexed messages (v1 only)
 650 sub _index_sync {
 651         my ($self, $opts) = @_;
 652         my $tip = $opts->{ref} || 'HEAD';
 653         my $reindex = $opts->{reindex};
 654         my ($mkey, $last_commit, $lx, $xlog);
 655         my $git = $self->{git};
 656         $git->batch_prepare;
 657
 658         my $xdb = $self->begin_txn_lazy;
 659         my $mm = _msgmap_init($self);
 660         do {
 661                 $xlog = undef;
 662                 $mkey = 'last_commit';
 663                 $last_commit = $xdb->get_metadata('last_commit');
 664                 $lx = $last_commit;
 665                 if ($reindex) {
 666                         $lx = '';
 667                         $mkey = undef if $last_commit ne '';
 668                 }
 669
 670                 # use last_commit from msgmap if it is older or unset
 671                 my $lm = $mm->last_commit || '';
 672                 if (!$lm || ($lm && $lx && is_ancestor($git, $lm, $lx))) {
 673                         $lx = $lm;
 674                 }
 675
 676                 $self->{over}->rollback_lazy;
 677                 $self->{over}->disconnect;
 678                 $git->cleanup;
 679                 delete $self->{txn};
 680                 $xdb->cancel_transaction;
 681                 $xdb = _xdb_release($self);
 682
 683                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 684                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 685                 $xlog = _git_log($self, $range);
 686
 687                 $xdb = $self->begin_txn_lazy;
 688         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 689
 690         my $dbh = $mm->{dbh} if $mm;
 691         my $cb = sub {
 692                 my ($commit, $newest) = @_;
 693                 if ($dbh) {
 694                         if ($newest) {
 695                                 my $cur = $mm->last_commit || '';
 696                                 if (need_update($self, $cur, $newest)) {
 697                                         $mm->last_commit($newest);
 698                                 }
 699                         }
 700                         $dbh->commit;
 701                 }
 702                 if ($mkey && $newest) {
 703                         my $cur = $xdb->get_metadata($mkey);
 704                         if (need_update($self, $cur, $newest)) {
 705                                 $xdb->set_metadata($mkey, $newest);
 706                         }
 707                 }
 708                 $self->commit_txn_lazy;
 709                 $git->cleanup;
 710                 $xdb = _xdb_release($self);
 711                 # let another process do some work... <
 712                 if (!$newest) {
 713                         $xdb = $self->begin_txn_lazy;
 714                         $dbh->begin_work if $dbh;
 715                 }
 716         };
 717
 718         $dbh->begin_work;
 719         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 720 }
 721
 722 sub DESTROY {
 723         # order matters for unlocking
 724         $_[0]->{xdb} = undef;
 725         $_[0]->{lockfh} = undef;
 726 }
 727
 728 # remote_* subs are only used by SearchIdxPart
 729 sub remote_commit {
 730         my ($self) = @_;
 731         if (my $w = $self->{w}) {
 732                 print $w "commit\n" or die "failed to write commit: $!";
 733         } else {
 734                 $self->commit_txn_lazy;
 735         }
 736 }
 737
 738 sub remote_close {
 739         my ($self) = @_;
 740         if (my $w = delete $self->{w}) {
 741                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 742                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 743                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 744                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 745                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 746         } else {
 747                 die "transaction in progress $self\n" if $self->{txn};
 748                 $self->_xdb_release if $self->{xdb};
 749         }
 750 }
 751
 752 sub remote_remove {
 753         my ($self, $oid, $mid) = @_;
 754         if (my $w = $self->{w}) {
 755                 # triggers remove_by_oid in a partition
 756                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 757         } else {
 758                 $self->begin_txn_lazy;
 759                 $self->remove_by_oid($oid, $mid);
 760         }
 761 }
 762
 763 sub begin_txn_lazy {
 764         my ($self) = @_;
 765         return if $self->{txn};
 766
 767         $self->{-inbox}->with_umask(sub {
 768                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 769                 $self->{over}->begin_lazy if $self->{over};
 770                 $xdb->begin_transaction;
 771                 $self->{txn} = 1;
 772                 $xdb;
 773         });
 774 }
 775
 776 sub commit_txn_lazy {
 777         my ($self) = @_;
 778         delete $self->{txn} or return;
 779         $self->{-inbox}->with_umask(sub {
 780                 $self->{xdb}->commit_transaction;
 781                 $self->{over}->commit_lazy if $self->{over};
 782         });
 783 }
 784
 785 sub worker_done {
 786         my ($self) = @_;
 787         die "$$ $0 xdb not released\n" if $self->{xdb};
 788         die "$$ $0 still in transaction\n" if $self->{txn};
 789 }
 790
 791 1;