lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 our $BATCH_BYTES = defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000;
  27 use constant DEBUG => !!$ENV{DEBUG};
  28
  29 my $xapianlevels = qr/\A(?:full|medium)\z/;
  30
  31 sub new {
  32         my ($class, $ibx, $creat, $shard) = @_;
  33         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  34         my $levels = qr/\A(?:full|medium|basic)\z/;
  35         my $inboxdir = $ibx->{inboxdir};
  36         my $version = $ibx->version;
  37         my $indexlevel = 'full';
  38         my $altid = $ibx->{altid};
  39         if ($altid) {
  40                 require PublicInbox::AltId;
  41                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  42         }
  43         if ($ibx->{indexlevel}) {
  44                 if ($ibx->{indexlevel} =~ $levels) {
  45                         $indexlevel = $ibx->{indexlevel};
  46                 } else {
  47                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  48                 }
  49         }
  50         $ibx = PublicInbox::InboxWritable->new($ibx);
  51         my $self = bless {
  52                 inboxdir => $inboxdir,
  53                 -inbox => $ibx,
  54                 git => $ibx->git,
  55                 -altid => $altid,
  56                 ibx_ver => $version,
  57                 indexlevel => $indexlevel,
  58         }, $class;
  59         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  60         $ibx->umask_prepare;
  61         if ($version == 1) {
  62                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  63                 my $dir = $self->xdir;
  64                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  65                 $self->{index_max_size} = $ibx->{index_max_size};
  66         } elsif ($version == 2) {
  67                 defined $shard or die "shard is required for v2\n";
  68                 # shard is a number
  69                 $self->{shard} = $shard;
  70                 $self->{lock_path} = undef;
  71         } else {
  72                 die "unsupported inbox version=$version\n";
  73         }
  74         $self->{creat} = ($creat || 0) == 1;
  75         $self;
  76 }
  77
  78 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  79
  80 sub _xdb_release {
  81         my ($self) = @_;
  82         if (need_xapian($self)) {
  83                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  84                 $xdb->close;
  85         }
  86         $self->lock_release if $self->{creat};
  87         undef;
  88 }
  89
  90 sub load_xapian_writable () {
  91         return 1 if $X->{WritableDatabase};
  92         PublicInbox::Search::load_xapian() or return;
  93         my $xap = $PublicInbox::Search::Xap;
  94         for (qw(Document TermGenerator WritableDatabase)) {
  95                 $X->{$_} = $xap.'::'.$_;
  96         }
  97         eval 'require '.$X->{WritableDatabase} or die;
  98         *sortable_serialise = $xap.'::sortable_serialise';
  99         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 100         $DB_OPEN = eval($xap.'::DB_OPEN()');
 101         1;
 102 }
 103
 104 sub _xdb_acquire {
 105         my ($self) = @_;
 106         my $flag;
 107         my $dir = $self->xdir;
 108         if (need_xapian($self)) {
 109                 croak 'already acquired' if $self->{xdb};
 110                 load_xapian_writable();
 111                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 112         }
 113         if ($self->{creat}) {
 114                 require File::Path;
 115                 $self->lock_acquire;
 116
 117                 # don't create empty Xapian directories if we don't need Xapian
 118                 my $is_shard = defined($self->{shard});
 119                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 120                         File::Path::mkpath($dir);
 121                 }
 122         }
 123         return unless defined $flag;
 124         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 125         if ($@) {
 126                 die "Failed opening $dir: ", $@;
 127         }
 128         $self->{xdb} = $xdb;
 129 }
 130
 131 sub add_val ($$$) {
 132         my ($doc, $col, $num) = @_;
 133         $num = sortable_serialise($num);
 134         $doc->add_value($col, $num);
 135 }
 136
 137 sub term_generator ($) { # write-only
 138         my ($self) = @_;
 139
 140         $self->{term_generator} //= do {
 141                 my $tg = $X->{TermGenerator}->new;
 142                 $tg->set_stemmer($self->stemmer);
 143                 $tg;
 144         }
 145 }
 146
 147 sub index_text ($$$$) {
 148         my ($self, $text, $wdf_inc, $prefix) = @_;
 149         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 150
 151         if ($self->{indexlevel} eq 'full') {
 152                 $tg->index_text($text, $wdf_inc, $prefix);
 153                 $tg->increase_termpos;
 154         } else {
 155                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 156         }
 157 }
 158
 159 sub index_headers ($$) {
 160         my ($self, $smsg) = @_;
 161         my @x = (from => 'A', # Author
 162                 subject => 'S', to => 'XTO', cc => 'XCC');
 163         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 164                 my $val = $smsg->{$field};
 165                 index_text($self, $val, 1, $pfx) if $val ne '';
 166         }
 167 }
 168
 169 sub index_diff_inc ($$$$) {
 170         my ($self, $text, $pfx, $xnq) = @_;
 171         if (@$xnq) {
 172                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 173                 @$xnq = ();
 174         }
 175         index_text($self, $text, 1, $pfx);
 176 }
 177
 178 sub index_old_diff_fn {
 179         my ($self, $seen, $fa, $fb, $xnq) = @_;
 180
 181         # no renames or space support for traditional diffs,
 182         # find the number of leading common paths to strip:
 183         my @fa = split('/', $fa);
 184         my @fb = split('/', $fb);
 185         while (scalar(@fa) && scalar(@fb)) {
 186                 $fa = join('/', @fa);
 187                 $fb = join('/', @fb);
 188                 if ($fa eq $fb) {
 189                         unless ($seen->{$fa}++) {
 190                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 191                         }
 192                         return 1;
 193                 }
 194                 shift @fa;
 195                 shift @fb;
 196         }
 197         0;
 198 }
 199
 200 sub index_diff ($$$) {
 201         my ($self, $txt, $doc) = @_;
 202         my %seen;
 203         my $in_diff;
 204         my @xnq;
 205         my $xnq = \@xnq;
 206         foreach (split(/\n/, $txt)) {
 207                 if ($in_diff && s/^ //) { # diff context
 208                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 209                 } elsif (/^-- $/) { # email signature begins
 210                         $in_diff = undef;
 211                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 212                         # wait until "---" and "+++" to capture filenames
 213                         $in_diff = 1;
 214                 # traditional diff:
 215                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 216                         my ($opt, $fa, $fb) = ($1, $2, $3);
 217                         push @xnq, $_;
 218                         # only support unified:
 219                         next unless $opt =~ /[uU]/;
 220                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 221                                                         $xnq);
 222                 } elsif (m!^--- ("?[^/]+/.+)!) {
 223                         my $fn = $1;
 224                         $fn = (split('/', git_unquote($fn), 2))[1];
 225                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 226                         $in_diff = 1;
 227                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 228                         my $fn = $1;
 229                         $fn = (split('/', git_unquote($fn), 2))[1];
 230                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 231                         $in_diff = 1;
 232                 } elsif (/^--- (\S+)/) {
 233                         $in_diff = $1;
 234                         push @xnq, $_;
 235                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 236                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 237                                                         $1, $xnq);
 238                 } elsif ($in_diff && s/^\+//) { # diff added
 239                         index_diff_inc($self, $_, 'XDFB', $xnq);
 240                 } elsif ($in_diff && s/^-//) { # diff removed
 241                         index_diff_inc($self, $_, 'XDFA', $xnq);
 242                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 243                         my ($ba, $bb) = ($1, $2);
 244                         index_git_blob_id($doc, 'XDFPRE', $ba);
 245                         index_git_blob_id($doc, 'XDFPOST', $bb);
 246                         $in_diff = 1;
 247                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 248                         # traditional diff w/o -p
 249                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 250                         # hunk header context
 251                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 252                 # ignore the following lines:
 253                 } elsif (/^(?:dis)similarity index/ ||
 254                                 /^(?:old|new) mode/ ||
 255                                 /^(?:deleted|new) file mode/ ||
 256                                 /^(?:copy|rename) (?:from|to) / ||
 257                                 /^(?:dis)?similarity index / ||
 258                                 /^\\ No newline at end of file/ ||
 259                                 /^Binary files .* differ/) {
 260                         push @xnq, $_;
 261                 } elsif ($_ eq '') {
 262                         # possible to be in diff context, some mail may be
 263                         # stripped by MUA or even GNU diff(1).  "git apply"
 264                         # treats a bare "\n" as diff context, too
 265                 } else {
 266                         push @xnq, $_;
 267                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 268                         $in_diff = undef;
 269                 }
 270         }
 271
 272         index_text($self, join("\n", @xnq), 1, 'XNQ');
 273 }
 274
 275 sub index_xapian { # msg_iter callback
 276         my $part = $_[0]->[0]; # ignore $depth and $idx
 277         my ($self, $doc) = @{$_[1]};
 278         my $ct = $part->content_type || 'text/plain';
 279         my $fn = $part->filename;
 280         if (defined $fn && $fn ne '') {
 281                 index_text($self, $fn, 1, 'XFN');
 282         }
 283         if ($part->{is_submsg}) {
 284                 my $mids = mids_for_index($part);
 285                 index_ids($self, $doc, $part, $mids);
 286                 my $smsg = bless {}, 'PublicInbox::Smsg';
 287                 $smsg->populate($part);
 288                 index_headers($self, $smsg);
 289         }
 290
 291         my ($s, undef) = msg_part_text($part, $ct);
 292         defined $s or return;
 293         $_[0]->[0] = $part = undef; # free memory
 294
 295         # split off quoted and unquoted blocks:
 296         my @sections = PublicInbox::MsgIter::split_quotes($s);
 297         undef $s; # free memory
 298         for my $txt (@sections) {
 299                 if ($txt =~ /\A>/) {
 300                         index_text($self, $txt, 0, 'XQUOT');
 301                 } else {
 302                         # does it look like a diff?
 303                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 304                                 index_diff($self, $txt, $doc);
 305                         } else {
 306                                 index_text($self, $txt, 1, 'XNQ');
 307                         }
 308                 }
 309                 undef $txt; # free memory
 310         }
 311 }
 312
 313 sub index_ids ($$$$) {
 314         my ($self, $doc, $hdr, $mids) = @_;
 315         for my $mid (@$mids) {
 316                 index_text($self, $mid, 1, 'XM');
 317
 318                 # because too many Message-IDs are prefixed with
 319                 # "Pine.LNX."...
 320                 if ($mid =~ /\w{12,}/) {
 321                         my @long = ($mid =~ /(\w{3,}+)/g);
 322                         index_text($self, join(' ', @long), 1, 'XM');
 323                 }
 324         }
 325         $doc->add_boolean_term('Q' . $_) for @$mids;
 326         for my $l ($hdr->header_raw('List-Id')) {
 327                 $l =~ /<([^>]+)>/ or next;
 328                 my $lid = $1;
 329                 $doc->add_boolean_term('G' . $lid);
 330                 index_text($self, $lid, 1, 'XL'); # probabilistic
 331         }
 332 }
 333
 334 sub add_xapian ($$$$) {
 335         my ($self, $mime, $smsg, $mids) = @_;
 336         my $hdr = $mime->header_obj;
 337         my $doc = $X->{Document}->new;
 338         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 339         my @ds = gmtime($smsg->{ds});
 340         my $yyyymmdd = strftime('%Y%m%d', @ds);
 341         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 342         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 343         add_val($doc, PublicInbox::Search::DT(), $dt);
 344         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 345
 346         my $tg = term_generator($self);
 347         $tg->set_document($doc);
 348         index_headers($self, $smsg);
 349
 350         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 351         index_ids($self, $doc, $hdr, $mids);
 352         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 353         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 354         my $data = $smsg->to_doc_data;
 355         $doc->set_data($data);
 356         if (my $altid = $self->{-altid}) {
 357                 foreach my $alt (@$altid) {
 358                         my $pfx = $alt->{xprefix};
 359                         foreach my $mid (@$mids) {
 360                                 my $id = $alt->mid2alt($mid);
 361                                 next unless defined $id;
 362                                 $doc->add_boolean_term($pfx . $id);
 363                         }
 364                 }
 365         }
 366         $self->{xdb}->replace_document($smsg->{num}, $doc);
 367 }
 368
 369 sub _msgmap_init ($) {
 370         my ($self) = @_;
 371         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 372         $self->{mm} //= eval {
 373                 require PublicInbox::Msgmap;
 374                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 375         };
 376 }
 377
 378 sub add_message {
 379         # mime = PublicInbox::Eml or Email::MIME object
 380         my ($self, $mime, $smsg) = @_;
 381         my $hdr = $mime->header_obj;
 382         my $mids = mids_for_index($hdr);
 383         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 384         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 385         $smsg->{num} //= do { # v1
 386                 _msgmap_init($self);
 387                 index_mm($self, $mime);
 388         };
 389
 390         # v1 and tests only:
 391         $smsg->populate($hdr, $self);
 392         $smsg->{bytes} //= length($mime->as_string);
 393
 394         eval {
 395                 # order matters, overview stores every possible piece of
 396                 # data in doc_data (deflated).  Xapian only stores a subset
 397                 # of the fields which exist in over.sqlite3.  We may stop
 398                 # storing doc_data in Xapian sometime after we get multi-inbox
 399                 # search working.
 400                 if (my $over = $self->{over}) { # v1 only
 401                         $over->add_overview($mime, $smsg);
 402                 }
 403                 if (need_xapian($self)) {
 404                         add_xapian($self, $mime, $smsg, $mids);
 405                 }
 406         };
 407
 408         if ($@) {
 409                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 410                 return undef;
 411         }
 412         $smsg->{num};
 413 }
 414
 415 # returns begin and end PostingIterator
 416 sub find_doc_ids {
 417         my ($self, $termval) = @_;
 418         my $db = $self->{xdb};
 419
 420         ($db->postlist_begin($termval), $db->postlist_end($termval));
 421 }
 422
 423 # v1 only
 424 sub batch_do {
 425         my ($self, $termval, $cb) = @_;
 426         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 427         while (1) {
 428                 my ($head, $tail) = $self->find_doc_ids($termval);
 429                 return if $head == $tail;
 430                 my @ids;
 431                 for (; $head != $tail && @ids < $batch_size; $head++) {
 432                         push @ids, $head->get_docid;
 433                 }
 434                 $cb->(\@ids);
 435         }
 436 }
 437
 438 # v1 only, where $mid is unique
 439 sub remove_message {
 440         my ($self, $mid) = @_;
 441         $mid = mid_clean($mid);
 442
 443         if (my $over = $self->{over}) {
 444                 my $nr = eval { $over->remove_oid(undef, $mid) };
 445                 if ($@) {
 446                         warn "failed to remove <$mid> from overview: $@\n";
 447                 } elsif ($nr == 0) {
 448                         warn "<$mid> missing for removal from overview\n";
 449                 }
 450         }
 451         return unless need_xapian($self);
 452         my $db = $self->{xdb};
 453         my $nr = 0;
 454         eval {
 455                 batch_do($self, 'Q' . $mid, sub {
 456                         my ($ids) = @_;
 457                         $db->delete_document($_) for @$ids;
 458                         $nr += scalar @$ids;
 459                 });
 460         };
 461         if ($@) {
 462                 warn "failed to remove <$mid> from Xapian: $@\n";
 463         } elsif ($nr == 0) {
 464                 warn "<$mid> missing for removal from Xapian\n";
 465         }
 466 }
 467
 468 # MID is a hint in V2
 469 sub remove_by_oid {
 470         my ($self, $oid, $mid) = @_;
 471
 472         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 473
 474         return unless need_xapian($self);
 475         my $db = $self->{xdb};
 476
 477         # XXX careful, we cannot use batch_do here since we conditionally
 478         # delete documents based on other factors, so we cannot call
 479         # find_doc_ids twice.
 480         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 481         return if $head == $tail;
 482
 483         # there is only ONE element in @delete unless we
 484         # have bugs in our v2writable deduplication check
 485         my @delete;
 486         for (; $head != $tail; $head++) {
 487                 my $docid = $head->get_docid;
 488                 my $doc = $db->get_document($docid);
 489                 my $smsg = bless { mid => $mid }, 'PublicInbox::Smsg';
 490                 $smsg->load_expand($doc);
 491                 if ($smsg->{blob} eq $oid) {
 492                         push(@delete, $docid);
 493                 }
 494         }
 495         $db->delete_document($_) foreach @delete;
 496         scalar(@delete);
 497 }
 498
 499 sub index_git_blob_id {
 500         my ($doc, $pfx, $objid) = @_;
 501
 502         my $len = length($objid);
 503         for (my $len = length($objid); $len >= 7; ) {
 504                 $doc->add_term($pfx.$objid);
 505                 $objid = substr($objid, 0, --$len);
 506         }
 507 }
 508
 509 sub unindex_blob {
 510         my ($self, $mime) = @_;
 511         my $mid = eval { mid_mime($mime) };
 512         $self->remove_message($mid) if defined $mid;
 513 }
 514
 515 sub index_mm {
 516         my ($self, $mime) = @_;
 517         my $mid = mid_mime($mime);
 518         my $mm = $self->{mm};
 519         my $num;
 520
 521         if (defined $self->{regen_down}) {
 522                 $num = $mm->num_for($mid) and return $num;
 523
 524                 while (($num = $self->{regen_down}--) > 0) {
 525                         if ($mm->mid_set($num, $mid) != 0) {
 526                                 return $num;
 527                         }
 528                 }
 529         } elsif (defined $self->{regen_up}) {
 530                 $num = $mm->num_for($mid) and return $num;
 531
 532                 # this is to fixup old bugs due to add-remove-add
 533                 while (($num = ++$self->{regen_up})) {
 534                         if ($mm->mid_set($num, $mid) != 0) {
 535                                 return $num;
 536                         }
 537                 }
 538         }
 539
 540         $num = $mm->mid_insert($mid) and return $num;
 541
 542         # fallback to num_for since filters like RubyLang set the number
 543         $mm->num_for($mid);
 544 }
 545
 546 sub unindex_mm {
 547         my ($self, $mime) = @_;
 548         $self->{mm}->mid_delete(mid_mime($mime));
 549 }
 550
 551 sub index_both {
 552         my ($self, $mime, $smsg) = @_;
 553         my $num = index_mm($self, $mime);
 554         $smsg->{num} = $num;
 555         add_message($self, $mime, $smsg);
 556 }
 557
 558 sub unindex_both {
 559         my ($self, $mime) = @_;
 560         unindex_blob($self, $mime);
 561         unindex_mm($self, $mime);
 562 }
 563
 564 sub do_cat_mail {
 565         my ($git, $blob, $sizeref) = @_;
 566         my $str = $git->cat_file($blob, $sizeref) or
 567                 die "BUG: $blob not found in $git->{git_dir}";
 568         PublicInbox::Eml->new($str);
 569 }
 570
 571 # called by public-inbox-index
 572 sub index_sync {
 573         my ($self, $opts) = @_;
 574         delete $self->{lock_path} if $opts->{-skip_lock};
 575         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 576 }
 577
 578 sub batch_adjust ($$$$$) {
 579         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 580         $$max -= $bytes;
 581         if ($$max <= 0) {
 582                 $$max = $BATCH_BYTES;
 583                 $batch_cb->($nr, $latest);
 584         }
 585 }
 586
 587 sub too_big ($$$) {
 588         my ($self, $git, $oid) = @_;
 589         my $max_size = $self->{index_max_size} or return;
 590         my (undef, undef, $size) = $git->check($oid);
 591         die "E: bad $oid in $git->{git_dir}\n" if !defined($size);
 592         return if $size <= $max_size;
 593         warn "W: skipping $oid ($size > $max_size)\n";
 594         1;
 595 }
 596
 597 # only for v1
 598 sub read_log {
 599         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 600         my $hex = '[a-f0-9]';
 601         my $h40 = $hex .'{40}';
 602         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 603         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 604         my $git = $self->{git};
 605         my $latest;
 606         my $bytes;
 607         my $max = $BATCH_BYTES;
 608         local $/ = "\n";
 609         my %D;
 610         my $line;
 611         my $newest;
 612         my $nr = 0;
 613         while (defined($line = <$log>)) {
 614                 if ($line =~ /$addmsg/o) {
 615                         my $blob = $1;
 616                         if (delete $D{$blob}) {
 617                                 if (defined $self->{regen_down}) {
 618                                         my $num = $self->{regen_down}--;
 619                                         $self->{mm}->num_highwater($num);
 620                                 }
 621                                 next;
 622                         }
 623                         next if too_big($self, $git, $blob);
 624                         my $mime = do_cat_mail($git, $blob, \$bytes);
 625                         my $smsg = bless {}, 'PublicInbox::Smsg';
 626                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 627                         $smsg->{blob} = $blob;
 628                         $smsg->{bytes} = $bytes;
 629                         $add_cb->($self, $mime, $smsg);
 630                 } elsif ($line =~ /$delmsg/o) {
 631                         my $blob = $1;
 632                         $D{$blob} = 1 unless too_big($self, $git, $blob);
 633                 } elsif ($line =~ /^commit ($h40)/o) {
 634                         $latest = $1;
 635                         $newest ||= $latest;
 636                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 637                         $self->{autime} = $1;
 638                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 639                         $self->{cotime} = $1;
 640                 }
 641         }
 642         close($log) or die "git log failed: \$?=$?";
 643         # get the leftovers
 644         foreach my $blob (keys %D) {
 645                 my $mime = do_cat_mail($git, $blob, \$bytes);
 646                 $del_cb->($self, $mime);
 647         }
 648         delete @$self{qw(autime cotime)};
 649         $batch_cb->($nr, $latest, $newest);
 650 }
 651
 652 sub _git_log {
 653         my ($self, $opts, $range) = @_;
 654         my $git = $self->{git};
 655
 656         if (index($range, '..') < 0) {
 657                 # don't show annoying git errors to users who run -index
 658                 # on empty inboxes
 659                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 660                 if ($?) {
 661                         open my $fh, '<', '/dev/null' or
 662                                 die "failed to open /dev/null: $!\n";
 663                         return $fh;
 664                 }
 665         }
 666
 667         # Count the new files so they can be added newest to oldest
 668         # and still have numbers increasing from oldest to newest
 669         my $fcount = 0;
 670         my $pr = $opts->{-progress};
 671         $pr->("counting changes\n\t$range ... ") if $pr;
 672         # can't use 'rev-list --count' if we use --diff-filter
 673         my $fh = $git->popen(qw(log --pretty=tformat:%h
 674                              --no-notes --no-color --no-renames
 675                              --diff-filter=AM), $range);
 676         ++$fcount while <$fh>;
 677         close $fh or die "git log failed: \$?=$?";
 678         my $high = $self->{mm}->num_highwater;
 679         $pr->("$fcount\n") if $pr; # continue previous line
 680         $self->{ntodo} = $fcount;
 681
 682         if (index($range, '..') < 0) {
 683                 if ($high && $high == $fcount) {
 684                         # fix up old bugs in full indexes which caused messages to
 685                         # not appear in Msgmap
 686                         $self->{regen_up} = $high;
 687                 } else {
 688                         # normal regen is for for fresh data
 689                         $self->{regen_down} = $fcount;
 690                 }
 691         } else {
 692                 # Give oldest messages the smallest numbers
 693                 $self->{regen_down} = $high + $fcount;
 694         }
 695
 696         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 697                                 --raw -r --no-abbrev/, $range);
 698 }
 699
 700 # --is-ancestor requires git 1.8.0+
 701 sub is_ancestor ($$$) {
 702         my ($git, $cur, $tip) = @_;
 703         return 0 unless $git->check($cur);
 704         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 705                 qw(merge-base --is-ancestor), $cur, $tip ];
 706         my $pid = spawn($cmd);
 707         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 708         $? == 0;
 709 }
 710
 711 sub need_update ($$$) {
 712         my ($self, $cur, $new) = @_;
 713         my $git = $self->{git};
 714         return 1 if $cur && !is_ancestor($git, $cur, $new);
 715         my $range = $cur eq '' ? $new : "$cur..$new";
 716         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 717         ($n eq '' || $n > 0);
 718 }
 719
 720 # The last git commit we indexed with Xapian or SQLite (msgmap)
 721 # This needs to account for cases where Xapian or SQLite is
 722 # out-of-date with respect to the other.
 723 sub _last_x_commit {
 724         my ($self, $mm) = @_;
 725         my $lm = $mm->last_commit || '';
 726         my $lx = '';
 727         if (need_xapian($self)) {
 728                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 729         } else {
 730                 $lx = $lm;
 731         }
 732         # Use last_commit from msgmap if it is older or unset
 733         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 734                 $lx = $lm;
 735         }
 736         $lx;
 737 }
 738
 739 sub reindex_from ($$) {
 740         my ($reindex, $last_commit) = @_;
 741         return $last_commit unless $reindex;
 742         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 743 }
 744
 745 # indexes all unindexed messages (v1 only)
 746 sub _index_sync {
 747         my ($self, $opts) = @_;
 748         my $tip = $opts->{ref} || 'HEAD';
 749         my ($last_commit, $lx, $xlog);
 750         my $git = $self->{git};
 751         $git->batch_prepare;
 752         my $pr = $opts->{-progress};
 753
 754         my $xdb = $self->begin_txn_lazy;
 755         my $mm = _msgmap_init($self);
 756         do {
 757                 $xlog = undef; # stop previous git-log via SIGPIPE
 758                 $last_commit = _last_x_commit($self, $mm);
 759                 $lx = reindex_from($opts->{reindex}, $last_commit);
 760
 761                 $self->{over}->rollback_lazy;
 762                 $self->{over}->disconnect;
 763                 $git->cleanup;
 764                 delete $self->{txn};
 765                 $xdb->cancel_transaction if $xdb;
 766                 $xdb = _xdb_release($self);
 767
 768                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 769                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 770                 $xlog = _git_log($self, $opts, $range);
 771
 772                 $xdb = $self->begin_txn_lazy;
 773         } while (_last_x_commit($self, $mm) ne $last_commit);
 774
 775         my $dbh = $mm->{dbh} if $mm;
 776         my $cb = sub {
 777                 my ($nr, $commit, $newest) = @_;
 778                 if ($dbh) {
 779                         if ($newest) {
 780                                 my $cur = $mm->last_commit || '';
 781                                 if (need_update($self, $cur, $newest)) {
 782                                         $mm->last_commit($newest);
 783                                 }
 784                         }
 785                         $dbh->commit;
 786                 }
 787                 if ($newest && need_xapian($self)) {
 788                         my $cur = $xdb->get_metadata('last_commit');
 789                         if (need_update($self, $cur, $newest)) {
 790                                 $xdb->set_metadata('last_commit', $newest);
 791                         }
 792                 }
 793                 $self->commit_txn_lazy;
 794                 $git->cleanup;
 795                 $xdb = _xdb_release($self);
 796                 # let another process do some work... <
 797                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 798                 if (!$newest) {
 799                         $xdb = $self->begin_txn_lazy;
 800                         $dbh->begin_work if $dbh;
 801                 }
 802         };
 803
 804         $dbh->begin_work;
 805         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 806 }
 807
 808 sub DESTROY {
 809         # order matters for unlocking
 810         $_[0]->{xdb} = undef;
 811         $_[0]->{lockfh} = undef;
 812 }
 813
 814 # remote_* subs are only used by SearchIdxPart
 815 sub remote_commit {
 816         my ($self) = @_;
 817         if (my $w = $self->{w}) {
 818                 print $w "commit\n" or die "failed to write commit: $!";
 819         } else {
 820                 $self->commit_txn_lazy;
 821         }
 822 }
 823
 824 sub remote_close {
 825         my ($self) = @_;
 826         if (my $w = delete $self->{w}) {
 827                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 828                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 829                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 830                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 831                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 832         } else {
 833                 die "transaction in progress $self\n" if $self->{txn};
 834                 $self->_xdb_release if $self->{xdb};
 835         }
 836 }
 837
 838 sub remote_remove {
 839         my ($self, $oid, $mid) = @_;
 840         if (my $w = $self->{w}) {
 841                 # triggers remove_by_oid in a shard
 842                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 843         } else {
 844                 $self->begin_txn_lazy;
 845                 $self->remove_by_oid($oid, $mid);
 846         }
 847 }
 848
 849 sub begin_txn_lazy {
 850         my ($self) = @_;
 851         return if $self->{txn};
 852
 853         $self->{-inbox}->with_umask(sub {
 854                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 855                 $self->{over}->begin_lazy if $self->{over};
 856                 $xdb->begin_transaction if $xdb;
 857                 $self->{txn} = 1;
 858                 $xdb;
 859         });
 860 }
 861
 862 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 863 # This metadata is read by Admin::detect_indexlevel:
 864 sub set_indexlevel {
 865         my ($self) = @_;
 866
 867         if (!$self->{shard} && # undef or 0, not >0
 868                         delete($self->{-set_indexlevel_once})) {
 869                 my $xdb = $self->{xdb};
 870                 my $level = $xdb->get_metadata('indexlevel');
 871                 if (!$level || $level ne 'medium') {
 872                         $xdb->set_metadata('indexlevel', 'medium');
 873                 }
 874         }
 875 }
 876
 877 sub commit_txn_lazy {
 878         my ($self) = @_;
 879         delete $self->{txn} or return;
 880         $self->{-inbox}->with_umask(sub {
 881                 if (my $xdb = $self->{xdb}) {
 882                         set_indexlevel($self);
 883                         $xdb->commit_transaction;
 884                 }
 885                 $self->{over}->commit_lazy if $self->{over};
 886         });
 887 }
 888
 889 sub worker_done {
 890         my ($self) = @_;
 891         if (need_xapian($self)) {
 892                 die "$$ $0 xdb not released\n" if $self->{xdb};
 893         }
 894         die "$$ $0 still in transaction\n" if $self->{txn};
 895 }
 896
 897 1;