lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compressed/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant {
  12         PERM_UMASK => 0,
  13         OLD_PERM_GROUP => 1,
  14         OLD_PERM_EVERYBODY => 2,
  15         PERM_GROUP => 0660,
  16         PERM_EVERYBODY => 0664,
  17 };
  18
  19 sub new {
  20         my ($class, $git_dir, $writable) = @_;
  21         my $dir = $class->xdir($git_dir);
  22         require Search::Xapian::WritableDatabase;
  23         my $flag = Search::Xapian::DB_OPEN;
  24         if ($writable == 1) {
  25                 require File::Path;
  26                 File::Path::mkpath($dir);
  27                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  28         }
  29         my $self = bless { git_dir => $git_dir }, $class;
  30         my $umask = _umask_for($self->_git_config_perm);
  31         my $old_umask = umask $umask;
  32         my $db = eval { Search::Xapian::WritableDatabase->new($dir, $flag) };
  33         my $err = $@;
  34         umask $old_umask;
  35         die $err if $err;
  36         $self->{xdb} = $db;
  37         $self;
  38 }
  39
  40 sub add_message {
  41         my ($self, $mime) = @_; # mime = Email::MIME object
  42         my $db = $self->{xdb};
  43
  44         my $doc_id;
  45         my $mid_orig = mid_clean($mime->header_obj->header('Message-ID'));
  46         my $mid = mid_compressed($mid_orig);
  47         my $was_ghost = 0;
  48         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  49
  50         eval {
  51                 my $smsg = $self->lookup_message($mid);
  52                 my $doc;
  53
  54                 if ($smsg) {
  55                         $smsg->ensure_metadata;
  56                         # convert a ghost to a regular message
  57                         # it will also clobber any existing regular message
  58                         $smsg->mime($mime);
  59                         $doc = $smsg->{doc};
  60
  61                         my $type = xpfx('type');
  62                         eval {
  63                                 $doc->remove_term($type . 'ghost');
  64                                 $was_ghost = 1;
  65                         };
  66
  67                         # probably does not exist:
  68                         eval { $doc->remove_term($type . 'mail') };
  69                         $doc->add_term($type . 'mail');
  70                 }  else {
  71                         $smsg = PublicInbox::SearchMsg->new($mime);
  72                         $doc = $smsg->{doc};
  73                         $doc->add_term(xpfx('mid') . $mid);
  74                 }
  75
  76                 my $subj = $smsg->subject;
  77
  78                 if (length $subj) {
  79                         $doc->add_term(xpfx('subject') . $subj);
  80
  81                         my $path = $self->subject_path($subj);
  82                         $doc->add_term(xpfx('path') . mid_compressed($path));
  83                 }
  84
  85                 my $from = $smsg->from_name;
  86                 my $date = $smsg->date;
  87                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
  88                 $doc->add_value(PublicInbox::Search::TS, $ts);
  89
  90                 my $tg = $self->term_generator;
  91
  92                 $tg->set_document($doc);
  93                 $tg->index_text($subj, 1, 'S') if $subj;
  94                 $tg->increase_termpos;
  95                 $tg->index_text($subj) if $subj;
  96                 $tg->increase_termpos;
  97
  98                 $tg->index_text($smsg->from->format);
  99                 $tg->increase_termpos;
 100
 101                 $mime->walk_parts(sub {
 102                         my ($part) = @_;
 103                         return if $part->subparts; # walk_parts already recurses
 104                         my $ct = $part->content_type || $ct_msg;
 105
 106                         # account for filter bugs...
 107                         $ct =~ m!\btext/plain\b!i or return;
 108
 109                         my (@orig, @quot);
 110                         my $body = $part->body;
 111                         $part->body_set('');
 112                         my @lines = split(/\n/, $body);
 113                         while (defined(my $l = shift @lines)) {
 114                                 if ($l =~ /^\s*>/) {
 115                                         push @quot, $l;
 116                                 } else {
 117                                         push @orig, $l;
 118                                 }
 119                         }
 120                         if (@quot) {
 121                                 $tg->index_text(join("\n", @quot), 0);
 122                                 @quot = ();
 123                                 $tg->increase_termpos;
 124                         }
 125                         if (@orig) {
 126                                 $tg->index_text(join("\n", @orig));
 127                                 @orig = ();
 128                                 $tg->increase_termpos;
 129                         }
 130                 });
 131
 132                 if ($was_ghost) {
 133                         $doc_id = $smsg->doc_id;
 134                         $self->link_message($smsg, 0);
 135                         $doc->set_data($smsg->to_doc_data);
 136                         $db->replace_document($doc_id, $doc);
 137                 } else {
 138                         $self->link_message($smsg, 0);
 139                         $doc->set_data($smsg->to_doc_data);
 140                         $doc_id = $db->add_document($doc);
 141                 }
 142         };
 143
 144         if ($@) {
 145                 warn "failed to index message <$mid_orig>: $@\n";
 146                 return undef;
 147         }
 148         $doc_id;
 149 }
 150
 151 # returns deleted doc_id on success, undef on missing
 152 sub remove_message {
 153         my ($self, $mid_orig) = @_;
 154         my $db = $self->{xdb};
 155         my $doc_id;
 156         $mid_orig = mid_clean($mid_orig);
 157         my $mid = mid_compressed($mid_orig);
 158
 159         eval {
 160                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 161                 $db->delete_document($doc_id) if defined $doc_id;
 162         };
 163
 164         if ($@) {
 165                 warn "failed to remove message <$mid_orig>: $@\n";
 166                 return undef;
 167         }
 168         $doc_id;
 169 }
 170
 171 sub term_generator { # write-only
 172         my ($self) = @_;
 173
 174         my $tg = $self->{term_generator};
 175         return $tg if $tg;
 176
 177         $tg = Search::Xapian::TermGenerator->new;
 178         $tg->set_stemmer($self->stemmer);
 179
 180         $self->{term_generator} = $tg;
 181 }
 182
 183 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 184
 185 # increments last_thread_id counter
 186 # returns a 64-bit integer represented as a hex string
 187 sub next_thread_id {
 188         my ($self) = @_;
 189         my $db = $self->{xdb};
 190         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 191
 192         $db->set_metadata('last_thread_id', ++$last_thread_id);
 193
 194         $last_thread_id;
 195 }
 196
 197 sub link_message {
 198         my ($self, $smsg, $is_ghost) = @_;
 199
 200         if ($is_ghost) {
 201                 $smsg->ensure_metadata;
 202         } else {
 203                 $self->link_message_to_parents($smsg);
 204         }
 205 }
 206
 207 sub link_message_to_parents {
 208         my ($self, $smsg) = @_;
 209         my $doc = $smsg->{doc};
 210         my $mid = mid_compressed($smsg->mid);
 211         my $mime = $smsg->mime;
 212         my $refs = $mime->header_obj->header('References');
 213         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 214         my $irt = $mime->header_obj->header('In-Reply-To');
 215         if ($irt) {
 216                 $irt = mid_compressed(mid_clean($irt));
 217
 218                 # maybe some crazies will try to make a circular reference:
 219                 if ($irt eq $mid) {
 220                         $irt = undef;
 221                 } else {
 222                         # last References should be $irt
 223                         # we will de-dupe later
 224                         push @refs, $irt;
 225                 }
 226         }
 227
 228         my $tid;
 229         if (@refs) {
 230                 my @crefs = map { mid_compressed($_) } @refs;
 231                 my %uniq = ($mid => 1);
 232
 233                 # prevent circular references via References: here:
 234                 @refs = ();
 235                 foreach my $ref (@crefs) {
 236                         next if $uniq{$ref};
 237                         $uniq{$ref} = 1;
 238                         push @refs, $ref;
 239                 }
 240         }
 241         if (@refs) {
 242                 $doc->add_term(xpfx('inreplyto') . $irt) if defined $irt;
 243                 $smsg->{references_sorted} = '<'.join('><', @refs).'>';
 244
 245                 my $ref_pfx = xpfx('references');
 246
 247                 # first ref *should* be the thread root,
 248                 # but we can never trust clients to do the right thing
 249                 my $ref = shift @refs;
 250                 $doc->add_term($ref_pfx . $ref);
 251                 $tid = $self->_resolve_mid_to_tid($ref);
 252
 253                 # the rest of the refs should point to this tid:
 254                 foreach $ref (@refs) {
 255                         $doc->add_term($ref_pfx . $ref);
 256                         my $ptid = $self->_resolve_mid_to_tid($ref);
 257                         if ($tid ne $ptid) {
 258                                 $self->merge_threads($tid, $ptid);
 259                         }
 260                 }
 261         } else {
 262                 $tid = $self->next_thread_id;
 263         }
 264         $doc->add_term(xpfx('thread') . $tid);
 265 }
 266
 267 sub index_blob {
 268         my ($self, $git, $blob) = @_;
 269         my $mime = do_cat_mail($git, $blob) or return;
 270         eval { $self->add_message($mime) };
 271         warn "W: index_blob $blob: $@\n" if $@;
 272 }
 273
 274 sub unindex_blob {
 275         my ($self, $git, $blob) = @_;
 276         my $mime = do_cat_mail($git, $blob) or return;
 277         my $mid = $mime->header_obj->header('Message-ID');
 278         eval { $self->remove_message($mid) } if defined $mid;
 279         warn "W: unindex_blob $blob: $@\n" if $@;
 280 }
 281
 282 sub do_cat_mail {
 283         my ($git, $blob) = @_;
 284         my $mime = eval {
 285                 my $str = $git->cat_file($blob);
 286                 Email::MIME->new($str);
 287         };
 288         $@ ? undef : $mime;
 289 }
 290
 291 # indexes all unindexed messages
 292 sub index_sync {
 293         my ($self, $head) = @_;
 294         require PublicInbox::GitCatFile;
 295         my $db = $self->{xdb};
 296         my $hex = '[a-f0-9]';
 297         my $h40 = $hex .'{40}';
 298         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 299         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 300         $head ||= 'HEAD';
 301
 302         $db->begin_transaction;
 303         eval {
 304                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 305
 306                 my $latest = $db->get_metadata('last_commit');
 307                 my $range = length $latest ? "$latest..$head" : $head;
 308                 $latest = undef;
 309
 310                 # get indexed messages
 311                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 312                             qw/--reverse --no-notes --no-color --raw -r
 313                                --no-abbrev/, $range);
 314                 my $pid = open(my $log, '-|', @cmd) or
 315                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 316
 317                 while (my $line = <$log>) {
 318                         if ($line =~ /$addmsg/o) {
 319                                 $self->index_blob($git, $1);
 320                         } elsif ($line =~ /$delmsg/o) {
 321                                 $self->unindex_blob($git, $1);
 322                         } elsif ($line =~ /^commit ($h40)/o) {
 323                                 $latest = $1;
 324                         }
 325                 }
 326                 close $log;
 327                 $db->set_metadata('last_commit', $latest) if defined $latest;
 328         };
 329         if ($@) {
 330                 warn "indexing failed: $@\n";
 331                 $db->cancel_transaction;
 332         } else {
 333                 $db->commit_transaction;
 334         }
 335 }
 336
 337 # this will create a ghost as necessary
 338 sub _resolve_mid_to_tid {
 339         my ($self, $mid) = @_;
 340
 341         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 342         $smsg->thread_id;
 343 }
 344
 345 sub create_ghost {
 346         my ($self, $mid, $tid) = @_;
 347
 348         $mid = mid_compressed($mid);
 349         $tid = $self->next_thread_id unless defined $tid;
 350
 351         my $doc = Search::Xapian::Document->new;
 352         $doc->add_term(xpfx('mid') . $mid);
 353         $doc->add_term(xpfx('thread') . $tid);
 354         $doc->add_term(xpfx('type') . 'ghost');
 355
 356         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 357         $self->link_message($smsg, 1);
 358         $self->{xdb}->add_document($doc);
 359
 360         $smsg;
 361 }
 362
 363 sub merge_threads {
 364         my ($self, $winner_tid, $loser_tid) = @_;
 365         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 366         my $thread_pfx = xpfx('thread');
 367         my $db = $self->{xdb};
 368
 369         for (; $head != $tail; $head->inc) {
 370                 my $docid = $head->get_docid;
 371                 my $doc = $db->get_document($docid);
 372                 $doc->remove_term($thread_pfx . $loser_tid);
 373                 $doc->add_term($thread_pfx . $winner_tid);
 374                 $db->replace_document($docid, $doc);
 375         }
 376 }
 377
 378 sub _read_git_config_perm {
 379         my ($self) = @_;
 380         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 381                    qw(config core.sharedRepository));
 382         my $pid = open(my $fh, '-|', @cmd) or
 383                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 384         my $perm = <$fh>;
 385         close $fh;
 386         chomp $perm if defined $perm;
 387         $perm;
 388 }
 389
 390 sub _git_config_perm {
 391         my $self = shift;
 392         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 393         return PERM_GROUP if (!defined($perm) || !length($perm));
 394         return PERM_UMASK if ($perm eq 'umask');
 395         return PERM_GROUP if ($perm eq 'group');
 396         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 397                 return PERM_EVERYBODY;
 398         }
 399         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 400         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 401
 402         my $i = oct($perm);
 403         return PERM_UMASK if ($i == PERM_UMASK);
 404         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 405         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 406
 407         if (($i & 0600) != 0600) {
 408                 die "core.sharedRepository mode invalid: ".
 409                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 410         }
 411         ($i & 0666);
 412 }
 413
 414 sub _umask_for {
 415         my ($perm) = @_; # _git_config_perm return value
 416         my $rv = $perm;
 417         return umask if $rv == 0;
 418
 419         # set +x bit if +r or +w were set
 420         $rv |= 0100 if ($rv & 0600);
 421         $rv |= 0010 if ($rv & 0060);
 422         $rv |= 0001 if ($rv & 0006);
 423         (~$rv & 0777);
 424 }
 425
 426 1;