lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean id_compress/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  12 use constant {
  13         PERM_UMASK => 0,
  14         OLD_PERM_GROUP => 1,
  15         OLD_PERM_EVERYBODY => 2,
  16         PERM_GROUP => 0660,
  17         PERM_EVERYBODY => 0664,
  18 };
  19
  20 sub new {
  21         my ($class, $git_dir, $writable) = @_;
  22         my $dir = $class->xdir($git_dir);
  23         require Search::Xapian::WritableDatabase;
  24         my $flag = Search::Xapian::DB_OPEN;
  25         my $self = bless { git_dir => $git_dir }, $class;
  26         my $perm = $self->_git_config_perm;
  27         my $umask = _umask_for($perm);
  28         $self->{umask} = $umask;
  29         $self->{xdb} = $self->with_umask(sub {
  30                 if ($writable == 1) {
  31                         require File::Path;
  32                         File::Path::mkpath($dir);
  33                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  34                 }
  35                 Search::Xapian::WritableDatabase->new($dir, $flag);
  36         });
  37         $self;
  38 }
  39
  40 sub add_val {
  41         my ($doc, $col, $num) = @_;
  42         $num = Search::Xapian::sortable_serialise($num);
  43         $doc->add_value($col, $num);
  44 }
  45
  46 sub add_message {
  47         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  48         my $db = $self->{xdb};
  49
  50         my $doc_id;
  51         my $mid = mid_clean($mime->header('Message-ID'));
  52         my $was_ghost = 0;
  53         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  54
  55         eval {
  56                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
  57                 my $smsg = $self->lookup_message($mid);
  58                 my $doc;
  59
  60                 if ($smsg) {
  61                         $smsg->ensure_metadata;
  62                         # convert a ghost to a regular message
  63                         # it will also clobber any existing regular message
  64                         $smsg->mime($mime);
  65                         $doc = $smsg->{doc};
  66
  67                         my $type = xpfx('type');
  68                         eval {
  69                                 $doc->remove_term($type . 'ghost');
  70                                 $was_ghost = 1;
  71                         };
  72
  73                         # probably does not exist:
  74                         eval { $doc->remove_term($type . 'mail') };
  75                         $doc->add_term($type . 'mail');
  76                 }  else {
  77                         $smsg = PublicInbox::SearchMsg->new($mime);
  78                         $doc = $smsg->{doc};
  79                         $doc->add_term(xpfx('mid') . $mid);
  80                 }
  81
  82                 my $subj = $smsg->subject;
  83
  84                 if ($subj ne '') {
  85                         my $path = $self->subject_path($subj);
  86                         $doc->add_term(xpfx('path') . id_compress($path));
  87                 }
  88
  89                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
  90
  91                 defined($num) and
  92                         add_val($doc, &PublicInbox::Search::NUM, $num);
  93
  94                 defined($bytes) and
  95                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
  96
  97                 add_val($doc, &PublicInbox::Search::LINES,
  98                                 $mime->body_raw =~ tr!\n!\n!);
  99
 100                 my $tg = $self->term_generator;
 101
 102                 $tg->set_document($doc);
 103                 $tg->index_text($subj, 1, 'S') if $subj;
 104                 $tg->increase_termpos;
 105                 $tg->index_text($subj) if $subj;
 106                 $tg->increase_termpos;
 107
 108                 $tg->index_text($smsg->from);
 109                 $tg->increase_termpos;
 110
 111                 $mime->walk_parts(sub {
 112                         my ($part) = @_;
 113                         return if $part->subparts; # walk_parts already recurses
 114                         my $ct = $part->content_type || $ct_msg;
 115
 116                         # account for filter bugs...
 117                         $ct =~ m!\btext/plain\b!i or return;
 118
 119                         my (@orig, @quot);
 120                         my $body = $part->body;
 121                         $part->body_set('');
 122                         my @lines = split(/\n/, $body);
 123                         while (defined(my $l = shift @lines)) {
 124                                 if ($l =~ /^\s*>/) {
 125                                         push @quot, $l;
 126                                 } else {
 127                                         push @orig, $l;
 128                                 }
 129                         }
 130                         if (@quot) {
 131                                 $tg->index_text(join("\n", @quot), 0);
 132                                 @quot = ();
 133                                 $tg->increase_termpos;
 134                         }
 135                         if (@orig) {
 136                                 $tg->index_text(join("\n", @orig));
 137                                 @orig = ();
 138                                 $tg->increase_termpos;
 139                         }
 140                 });
 141
 142                 if ($was_ghost) {
 143                         $doc_id = $smsg->doc_id;
 144                         $self->link_message($smsg, 0);
 145                         $doc->set_data($smsg->to_doc_data);
 146                         $db->replace_document($doc_id, $doc);
 147                 } else {
 148                         $self->link_message($smsg, 0);
 149                         $doc->set_data($smsg->to_doc_data);
 150                         $doc_id = $db->add_document($doc);
 151                 }
 152         };
 153
 154         if ($@) {
 155                 warn "failed to index message <$mid>: $@\n";
 156                 return undef;
 157         }
 158         $doc_id;
 159 }
 160
 161 # returns deleted doc_id on success, undef on missing
 162 sub remove_message {
 163         my ($self, $mid) = @_;
 164         my $db = $self->{xdb};
 165         my $doc_id;
 166         $mid = mid_clean($mid);
 167
 168         eval {
 169                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 170                 $db->delete_document($doc_id) if defined $doc_id;
 171         };
 172
 173         if ($@) {
 174                 warn "failed to remove message <$mid>: $@\n";
 175                 return undef;
 176         }
 177         $doc_id;
 178 }
 179
 180 sub term_generator { # write-only
 181         my ($self) = @_;
 182
 183         my $tg = $self->{term_generator};
 184         return $tg if $tg;
 185
 186         $tg = Search::Xapian::TermGenerator->new;
 187         $tg->set_stemmer($self->stemmer);
 188
 189         $self->{term_generator} = $tg;
 190 }
 191
 192 # increments last_thread_id counter
 193 # returns a 64-bit integer represented as a hex string
 194 sub next_thread_id {
 195         my ($self) = @_;
 196         my $db = $self->{xdb};
 197         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 198
 199         $db->set_metadata('last_thread_id', ++$last_thread_id);
 200
 201         $last_thread_id;
 202 }
 203
 204 sub link_message {
 205         my ($self, $smsg, $is_ghost) = @_;
 206
 207         if ($is_ghost) {
 208                 $smsg->ensure_metadata;
 209         } else {
 210                 $self->link_message_to_parents($smsg);
 211         }
 212 }
 213
 214 sub link_message_to_parents {
 215         my ($self, $smsg) = @_;
 216         my $doc = $smsg->{doc};
 217         my $mid = $smsg->mid;
 218         my $mime = $smsg->mime;
 219         my $refs = $mime->header('References');
 220         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 221         if (my $irt = $mime->header('In-Reply-To')) {
 222                 # last References should be $irt
 223                 # we will de-dupe later
 224                 push @refs, mid_clean($irt);
 225         }
 226
 227         my $tid;
 228         if (@refs) {
 229                 my %uniq = ($mid => 1);
 230                 my @orig_refs = @refs;
 231                 @refs = ();
 232
 233                 # prevent circular references via References: here:
 234                 foreach my $ref (@orig_refs) {
 235                         if (length($ref) > MAX_MID_SIZE) {
 236                                 warn "References: <$ref> too long, ignoring\n";
 237                         }
 238                         next if $uniq{$ref};
 239                         $uniq{$ref} = 1;
 240                         push @refs, $ref;
 241                 }
 242         }
 243         if (@refs) {
 244                 $smsg->{references} = '<'.join('> <', @refs).'>';
 245
 246                 # first ref *should* be the thread root,
 247                 # but we can never trust clients to do the right thing
 248                 my $ref = shift @refs;
 249                 $tid = $self->_resolve_mid_to_tid($ref);
 250
 251                 # the rest of the refs should point to this tid:
 252                 foreach $ref (@refs) {
 253                         my $ptid = $self->_resolve_mid_to_tid($ref);
 254                         if ($tid ne $ptid) {
 255                                 $self->merge_threads($tid, $ptid);
 256                         }
 257                 }
 258         } else {
 259                 $tid = $self->next_thread_id;
 260         }
 261         $doc->add_term(xpfx('thread') . $tid);
 262 }
 263
 264 sub index_blob {
 265         my ($self, $git, $mime, $bytes, $num) = @_;
 266         $self->add_message($mime, $bytes, $num);
 267 }
 268
 269 sub unindex_blob {
 270         my ($self, $git, $mime) = @_;
 271         my $mid = mid_clean($mime->header('Message-ID'));
 272         $self->remove_message($mid) if defined $mid;
 273 }
 274
 275 sub index_mm {
 276         my ($self, $git, $mime) = @_;
 277         $self->{mm}->mid_insert(mid_clean($mime->header('Message-ID')));
 278 }
 279
 280 sub unindex_mm {
 281         my ($self, $git, $mime) = @_;
 282         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 283 }
 284
 285 sub index_mm2 {
 286         my ($self, $git, $mime, $bytes) = @_;
 287         my $num = $self->{mm}->num_for(mid_clean($mime->header('Message-ID')));
 288         index_blob($self, $git, $mime, $bytes, $num);
 289 }
 290
 291 sub unindex_mm2 {
 292         my ($self, $git, $mime) = @_;
 293         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 294         unindex_blob($self, $git, $mime);
 295 }
 296
 297 sub index_both {
 298         my ($self, $git, $mime, $bytes) = @_;
 299         my $num = index_mm($self, $git, $mime);
 300         index_blob($self, $git, $mime, $bytes, $num);
 301 }
 302
 303 sub unindex_both {
 304         my ($self, $git, $mime) = @_;
 305         unindex_blob($self, $git, $mime);
 306         unindex_mm($self, $git, $mime);
 307 }
 308
 309 sub do_cat_mail {
 310         my ($git, $blob, $sizeref) = @_;
 311         my $mime = eval {
 312                 my $str = $git->cat_file($blob, $sizeref);
 313                 Email::MIME->new($str);
 314         };
 315         $@ ? undef : $mime;
 316 }
 317
 318 sub index_sync {
 319         my ($self, $head) = @_;
 320         $self->with_umask(sub { $self->_index_sync($head) });
 321 }
 322
 323 sub rlog {
 324         my ($self, $range, $add_cb, $del_cb) = @_;
 325         my $hex = '[a-f0-9]';
 326         my $h40 = $hex .'{40}';
 327         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 328         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 329         my $git_dir = $self->{git_dir};
 330         require PublicInbox::GitCatFile;
 331         my $git = PublicInbox::GitCatFile->new($git_dir);
 332         my @cmd = ('git', "--git-dir=$git_dir", "log",
 333                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 334                     $range);
 335         my $latest;
 336         my $bytes;
 337         my $pid = open(my $log, '-|', @cmd) or
 338                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 339         while (my $line = <$log>) {
 340                 if ($line =~ /$addmsg/o) {
 341                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 342                         $add_cb->($self, $git, $mime, $bytes);
 343                 } elsif ($line =~ /$delmsg/o) {
 344                         my $mime = do_cat_mail($git, $1) or next;
 345                         $del_cb->($self, $git, $mime);
 346                 } elsif ($line =~ /^commit ($h40)/o) {
 347                         $latest = $1;
 348                 }
 349         }
 350         close $log;
 351         $latest;
 352 }
 353
 354 # indexes all unindexed messages
 355 sub _index_sync {
 356         my ($self, $head) = @_;
 357         my $db = $self->{xdb};
 358         $head ||= 'HEAD';
 359         my $mm = $self->{mm} = eval {
 360                 require PublicInbox::Msgmap;
 361                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 362         };
 363
 364         $db->begin_transaction;
 365         my $lx = $db->get_metadata('last_commit');
 366         my $range = $lx eq '' ? $head : "$lx..$head";
 367         if ($mm) {
 368                 $mm->{dbh}->begin_work;
 369                 my $lm = $mm->last_commit || '';
 370                 if ($lm eq $lx) {
 371                         # Common case is the indexes are synced,
 372                         # we only need to run git-log once:
 373                         $lx = $self->rlog($range, *index_both, *unindex_both);
 374                         $mm->{dbh}->commit;
 375                         if (defined $lx) {
 376                                 $db->set_metadata('last_commit', $lx);
 377                                 $mm->last_commit($lx);
 378                         }
 379                 } else {
 380                         # dumb case, msgmap and xapian are out-of-sync
 381                         # do not care for performance:
 382                         my $r = $lm eq '' ? $head : "$lm..$head";
 383                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 384                         $mm->{dbh}->commit;
 385                         $mm->last_commit($lm) if defined $lm;
 386
 387                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 388                         $db->set_metadata('last_commit', $lx) if defined $lx;
 389                 }
 390         } else {
 391                 # user didn't install DBD::SQLite and DBI
 392                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 393                 $db->set_metadata('last_commit', $lx) if defined $lx;
 394         }
 395         if ($@) {
 396                 $db->cancel_transaction;
 397                 $mm->{dbh}->rollback if $mm;
 398         } else {
 399                 $db->commit_transaction;
 400         }
 401 }
 402
 403 # this will create a ghost as necessary
 404 sub _resolve_mid_to_tid {
 405         my ($self, $mid) = @_;
 406
 407         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 408         $smsg->thread_id;
 409 }
 410
 411 sub create_ghost {
 412         my ($self, $mid, $tid) = @_;
 413
 414         $tid = $self->next_thread_id unless defined $tid;
 415
 416         my $doc = Search::Xapian::Document->new;
 417         $doc->add_term(xpfx('mid') . $mid);
 418         $doc->add_term(xpfx('thread') . $tid);
 419         $doc->add_term(xpfx('type') . 'ghost');
 420
 421         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 422         $self->link_message($smsg, 1);
 423         $self->{xdb}->add_document($doc);
 424
 425         $smsg;
 426 }
 427
 428 sub merge_threads {
 429         my ($self, $winner_tid, $loser_tid) = @_;
 430         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 431         my $thread_pfx = xpfx('thread');
 432         my $db = $self->{xdb};
 433
 434         for (; $head != $tail; $head->inc) {
 435                 my $docid = $head->get_docid;
 436                 my $doc = $db->get_document($docid);
 437                 $doc->remove_term($thread_pfx . $loser_tid);
 438                 $doc->add_term($thread_pfx . $winner_tid);
 439                 $db->replace_document($docid, $doc);
 440         }
 441 }
 442
 443 sub _read_git_config_perm {
 444         my ($self) = @_;
 445         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 446                    qw(config core.sharedRepository));
 447         my $pid = open(my $fh, '-|', @cmd) or
 448                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 449         my $perm = <$fh>;
 450         close $fh;
 451         chomp $perm if defined $perm;
 452         $perm;
 453 }
 454
 455 sub _git_config_perm {
 456         my $self = shift;
 457         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 458         return PERM_GROUP if (!defined($perm) || $perm eq '');
 459         return PERM_UMASK if ($perm eq 'umask');
 460         return PERM_GROUP if ($perm eq 'group');
 461         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 462                 return PERM_EVERYBODY;
 463         }
 464         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 465         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 466
 467         my $i = oct($perm);
 468         return PERM_UMASK if ($i == PERM_UMASK);
 469         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 470         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 471
 472         if (($i & 0600) != 0600) {
 473                 die "core.sharedRepository mode invalid: ".
 474                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 475         }
 476         ($i & 0666);
 477 }
 478
 479 sub _umask_for {
 480         my ($perm) = @_; # _git_config_perm return value
 481         my $rv = $perm;
 482         return umask if $rv == 0;
 483
 484         # set +x bit if +r or +w were set
 485         $rv |= 0100 if ($rv & 0600);
 486         $rv |= 0010 if ($rv & 0060);
 487         $rv |= 0001 if ($rv & 0006);
 488         (~$rv & 0777);
 489 }
 490
 491 sub with_umask {
 492         my ($self, $cb) = @_;
 493         my $old = umask $self->{umask};
 494         my $rv = eval { $cb->() };
 495         my $err = $@;
 496         umask $old;
 497         die $err if $@;
 498         $rv;
 499 }
 500
 501 1;