lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 require PublicInbox::Git;
  22 use Compress::Zlib qw(compress);
  23
  24 use constant {
  25         BATCH_BYTES => 1_000_000,
  26         DEBUG => !!$ENV{DEBUG},
  27 };
  28
  29 my %GIT_ESC = (
  30         a => "\a",
  31         b => "\b",
  32         f => "\f",
  33         n => "\n",
  34         r => "\r",
  35         t => "\t",
  36         v => "\013",
  37 );
  38
  39 sub git_unquote ($) {
  40         my ($s) = @_;
  41         return $s unless ($s =~ /\A"(.*)"\z/);
  42         $s = $1;
  43         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  44         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  45         $s;
  46 }
  47
  48 sub new {
  49         my ($class, $ibx, $creat, $part) = @_;
  50         my $levels = qr/\A(?:full|medium|basic)\z/;
  51         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  52         my $git_dir = $mainrepo;
  53         my ($altid, $git);
  54         my $version = 1;
  55         my $indexlevel = 'full';
  56         if (ref $ibx) {
  57                 $mainrepo = $ibx->{mainrepo};
  58                 $altid = $ibx->{altid};
  59                 $version = $ibx->{version} || 1;
  60                 if ($altid) {
  61                         require PublicInbox::AltId;
  62                         $altid = [ map {
  63                                 PublicInbox::AltId->new($ibx, $_);
  64                         } @$altid ];
  65                 }
  66                 if ($ibx->{indexlevel}) {
  67                         if ($ibx->{indexlevel} =~ $levels) {
  68                                 $indexlevel = $ibx->{indexlevel};
  69                         } else {
  70                                 die("Invalid indexlevel $ibx->{indexlevel}\n");
  71                         }
  72                 }
  73         } else { # v1
  74                 $ibx = { mainrepo => $git_dir, version => 1 };
  75         }
  76         $ibx = PublicInbox::InboxWritable->new($ibx);
  77         require Search::Xapian::WritableDatabase;
  78         my $self = bless {
  79                 mainrepo => $mainrepo,
  80                 -inbox => $ibx,
  81                 git => $ibx->git,
  82                 -altid => $altid,
  83                 version => $version,
  84                 indexlevel => $indexlevel,
  85         }, $class;
  86         $ibx->umask_prepare;
  87         if ($version == 1) {
  88                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  89                 my $dir = $self->xdir;
  90                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  91         } elsif ($version == 2) {
  92                 defined $part or die "partition is required for v2\n";
  93                 # partition is a number
  94                 $self->{partition} = $part;
  95                 $self->{lock_path} = undef;
  96         } else {
  97                 die "unsupported inbox version=$version\n";
  98         }
  99         $self->{creat} = ($creat || 0) == 1;
 100         $self;
 101 }
 102
 103 sub _xdb_release {
 104         my ($self) = @_;
 105         my $xdb = delete $self->{xdb} or croak 'not acquired';
 106         $xdb->close;
 107         $self->lock_release if $self->{creat};
 108         undef;
 109 }
 110
 111 sub _xdb_acquire {
 112         my ($self) = @_;
 113         croak 'already acquired' if $self->{xdb};
 114         my $dir = $self->xdir;
 115         my $flag = Search::Xapian::DB_OPEN;
 116         if ($self->{creat}) {
 117                 require File::Path;
 118                 $self->lock_acquire;
 119                 File::Path::mkpath($dir);
 120                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 121         }
 122         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 123 }
 124
 125 sub add_val ($$$) {
 126         my ($doc, $col, $num) = @_;
 127         $num = Search::Xapian::sortable_serialise($num);
 128         $doc->add_value($col, $num);
 129 }
 130
 131 sub index_text ($$$$)
 132 {
 133         my ($self, $field, $n, $text) = @_;
 134         my $tg = $self->term_generator;
 135
 136         if ($self->{indexlevel} eq 'full') {
 137                 $tg->index_text($field, $n, $text);
 138                 $tg->increase_termpos;
 139         } else {
 140                 $tg->index_text_without_positions($field, $n, $text);
 141         }
 142 }
 143
 144 sub index_users ($$) {
 145         my ($self, $smsg) = @_;
 146
 147         my $from = $smsg->from;
 148         my $to = $smsg->to;
 149         my $cc = $smsg->cc;
 150
 151         $self->index_text($from, 1, 'A'); # A - author
 152         $self->index_text($to, 1, 'XTO') if $to ne '';
 153         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 154 }
 155
 156 sub index_diff_inc ($$$$) {
 157         my ($self, $text, $pfx, $xnq) = @_;
 158         if (@$xnq) {
 159                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 160                 @$xnq = ();
 161         }
 162         $self->index_text($text, 1, $pfx);
 163 }
 164
 165 sub index_old_diff_fn {
 166         my ($self, $seen, $fa, $fb, $xnq) = @_;
 167
 168         # no renames or space support for traditional diffs,
 169         # find the number of leading common paths to strip:
 170         my @fa = split('/', $fa);
 171         my @fb = split('/', $fb);
 172         while (scalar(@fa) && scalar(@fb)) {
 173                 $fa = join('/', @fa);
 174                 $fb = join('/', @fb);
 175                 if ($fa eq $fb) {
 176                         unless ($seen->{$fa}++) {
 177                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 178                         }
 179                         return 1;
 180                 }
 181                 shift @fa;
 182                 shift @fb;
 183         }
 184         0;
 185 }
 186
 187 sub index_diff ($$$) {
 188         my ($self, $lines, $doc) = @_;
 189         my %seen;
 190         my $in_diff;
 191         my @xnq;
 192         my $xnq = \@xnq;
 193         foreach (@$lines) {
 194                 if ($in_diff && s/^ //) { # diff context
 195                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 196                 } elsif (/^-- $/) { # email signature begins
 197                         $in_diff = undef;
 198                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 199                         my ($fa, $fb) = ($1, $2);
 200                         my $fn = (split('/', git_unquote($fa), 2))[1];
 201                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 202                         $fn = (split('/', git_unquote($fb), 2))[1];
 203                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 204                         $in_diff = 1;
 205                 # traditional diff:
 206                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 207                         my ($opt, $fa, $fb) = ($1, $2, $3);
 208                         push @xnq, $_;
 209                         # only support unified:
 210                         next unless $opt =~ /[uU]/;
 211                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 212                                                         $xnq);
 213                 } elsif (m!^--- ("?a/.+)!) {
 214                         my $fn = (split('/', git_unquote($1), 2))[1];
 215                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 216                         $in_diff = 1;
 217                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 218                         my $fn = (split('/', git_unquote($1), 2))[1];
 219                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 220                         $in_diff = 1;
 221                 } elsif (/^--- (\S+)/) {
 222                         $in_diff = $1;
 223                         push @xnq, $_;
 224                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 225                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 226                                                         $xnq);
 227                 } elsif ($in_diff && s/^\+//) { # diff added
 228                         $self->index_diff_inc($_, 'XDFB', $xnq);
 229                 } elsif ($in_diff && s/^-//) { # diff removed
 230                         $self->index_diff_inc($_, 'XDFA', $xnq);
 231                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 232                         my ($ba, $bb) = ($1, $2);
 233                         index_git_blob_id($doc, 'XDFPRE', $ba);
 234                         index_git_blob_id($doc, 'XDFPOST', $bb);
 235                         $in_diff = 1;
 236                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 237                         # traditional diff w/o -p
 238                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 239                         # hunk header context
 240                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 241                 # ignore the following lines:
 242                 } elsif (/^(?:dis)similarity index/ ||
 243                                 /^(?:old|new) mode/ ||
 244                                 /^(?:deleted|new) file mode/ ||
 245                                 /^(?:copy|rename) (?:from|to) / ||
 246                                 /^(?:dis)?similarity index / ||
 247                                 /^\\ No newline at end of file/ ||
 248                                 /^Binary files .* differ/) {
 249                         push @xnq, $_;
 250                 } elsif ($_ eq '') {
 251                         $in_diff = undef;
 252                 } else {
 253                         push @xnq, $_;
 254                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 255                         $in_diff = undef;
 256                 }
 257         }
 258
 259         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 260 }
 261
 262 sub index_body ($$$) {
 263         my ($self, $lines, $doc) = @_;
 264         my $txt = join("\n", @$lines);
 265         if ($doc) {
 266                 # does it look like a diff?
 267                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 268                         $txt = undef;
 269                         $self->index_diff($lines, $doc);
 270                 } else {
 271                         $self->index_text($txt, 1, 'XNQ');
 272                 }
 273         } else {
 274                 $self->index_text($txt, 0, 'XQUOT');
 275         }
 276         @$lines = ();
 277 }
 278
 279 sub add_xapian ($$$$$) {
 280         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 281         my $smsg = PublicInbox::SearchMsg->new($mime);
 282         my $doc = $smsg->{doc};
 283         my $subj = $smsg->subject;
 284         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 285         my @ds = gmtime($smsg->ds);
 286         my $yyyymmdd = strftime('%Y%m%d', @ds);
 287         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 288         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 289         add_val($doc, PublicInbox::Search::DT(), $dt);
 290
 291         my $tg = $self->term_generator;
 292
 293         $tg->set_document($doc);
 294         $self->index_text($subj, 1, 'S') if $subj;
 295         $self->index_users($smsg);
 296
 297         msg_iter($mime, sub {
 298                 my ($part, $depth, @idx) = @{$_[0]};
 299                 my $ct = $part->content_type || 'text/plain';
 300                 my $fn = $part->filename;
 301                 if (defined $fn && $fn ne '') {
 302                         $self->index_text($fn, 1, 'XFN');
 303                 }
 304
 305                 return if $ct =~ m!\btext/x?html\b!i;
 306
 307                 my $s = eval { $part->body_str };
 308                 if ($@) {
 309                         if ($ct =~ m!\btext/plain\b!i) {
 310                                 # Try to assume UTF-8 because Alpine
 311                                 # seems to do wacky things and set
 312                                 # charset=X-UNKNOWN
 313                                 $part->charset_set('UTF-8');
 314                                 $s = eval { $part->body_str };
 315                                 $s = $part->body if $@;
 316                         }
 317                 }
 318                 defined $s or return;
 319
 320                 my (@orig, @quot);
 321                 my $body = $part->body;
 322                 my @lines = split(/\n/, $body);
 323                 while (defined(my $l = shift @lines)) {
 324                         if ($l =~ /^>/) {
 325                                 $self->index_body(\@orig, $doc) if @orig;
 326                                 push @quot, $l;
 327                         } else {
 328                                 $self->index_body(\@quot, 0) if @quot;
 329                                 push @orig, $l;
 330                         }
 331                 }
 332                 $self->index_body(\@quot, 0) if @quot;
 333                 $self->index_body(\@orig, $doc) if @orig;
 334         });
 335
 336         foreach my $mid (@$mids) {
 337                 $self->index_text($mid, 1, 'XM');
 338
 339                 # because too many Message-IDs are prefixed with
 340                 # "Pine.LNX."...
 341                 if ($mid =~ /\w{12,}/) {
 342                         my @long = ($mid =~ /(\w{3,}+)/g);
 343                         $self->index_text(join(' ', @long), 1, 'XM');
 344                 }
 345         }
 346         $smsg->{to} = $smsg->{cc} = '';
 347         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 348         my $data = $smsg->to_doc_data($oid, $mid0);
 349         $doc->set_data($data);
 350         if (my $altid = $self->{-altid}) {
 351                 foreach my $alt (@$altid) {
 352                         my $pfx = $alt->{xprefix};
 353                         foreach my $mid (@$mids) {
 354                                 my $id = $alt->mid2alt($mid);
 355                                 next unless defined $id;
 356                                 $doc->add_boolean_term($pfx . $id);
 357                         }
 358                 }
 359         }
 360         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 361         $self->{xdb}->replace_document($num, $doc);
 362 }
 363
 364 sub add_message {
 365         # mime = Email::MIME object
 366         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 367         my $xapianlevels = qr/\A(?:full|medium)\z/;
 368         my $mids = mids($mime->header_obj);
 369         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 370         unless (defined $num) { # v1
 371                 $self->_msgmap_init;
 372                 $num = index_mm($self, $mime);
 373         }
 374         eval {
 375                 if ($self->{indexlevel} =~ $xapianlevels) {
 376                         $self->add_xapian($mime, $num, $oid, $mids, $mid0)
 377                 }
 378                 if (my $over = $self->{over}) {
 379                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 380                 }
 381         };
 382
 383         if ($@) {
 384                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 385                 return undef;
 386         }
 387         $num;
 388 }
 389
 390 # returns begin and end PostingIterator
 391 sub find_doc_ids {
 392         my ($self, $termval) = @_;
 393         my $db = $self->{xdb};
 394
 395         ($db->postlist_begin($termval), $db->postlist_end($termval));
 396 }
 397
 398 sub batch_do {
 399         my ($self, $termval, $cb) = @_;
 400         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 401         while (1) {
 402                 my ($head, $tail) = $self->find_doc_ids($termval);
 403                 return if $head == $tail;
 404                 my @ids;
 405                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 406                         push @ids, $head->get_docid;
 407                 }
 408                 $cb->(\@ids);
 409         }
 410 }
 411
 412 sub remove_message {
 413         my ($self, $mid) = @_;
 414         my $db = $self->{xdb};
 415         my $called;
 416         $mid = mid_clean($mid);
 417         my $over = $self->{over};
 418
 419         eval {
 420                 batch_do($self, 'Q' . $mid, sub {
 421                         my ($ids) = @_;
 422                         $db->delete_document($_) for @$ids;
 423                         $over->delete_articles($ids) if $over;
 424                         $called = 1;
 425                 });
 426         };
 427         if ($@) {
 428                 warn "failed to remove message <$mid>: $@\n";
 429         } elsif (!$called) {
 430                 warn "cannot remove non-existent <$mid>\n";
 431         }
 432 }
 433
 434 # MID is a hint in V2
 435 sub remove_by_oid {
 436         my ($self, $oid, $mid) = @_;
 437         my $db = $self->{xdb};
 438
 439         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 440
 441         # XXX careful, we cannot use batch_do here since we conditionally
 442         # delete documents based on other factors, so we cannot call
 443         # find_doc_ids twice.
 444         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 445         return if $head == $tail;
 446
 447         # there is only ONE element in @delete unless we
 448         # have bugs in our v2writable deduplication check
 449         my @delete;
 450         for (; $head != $tail; $head->inc) {
 451                 my $docid = $head->get_docid;
 452                 my $doc = $db->get_document($docid);
 453                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 454                 $smsg->load_expand;
 455                 if ($smsg->{blob} eq $oid) {
 456                         push(@delete, $docid);
 457                 }
 458         }
 459         $db->delete_document($_) foreach @delete;
 460         scalar(@delete);
 461 }
 462
 463 sub term_generator { # write-only
 464         my ($self) = @_;
 465
 466         my $tg = $self->{term_generator};
 467         return $tg if $tg;
 468
 469         $tg = Search::Xapian::TermGenerator->new;
 470         $tg->set_stemmer($self->stemmer);
 471
 472         $self->{term_generator} = $tg;
 473 }
 474
 475 sub index_git_blob_id {
 476         my ($doc, $pfx, $objid) = @_;
 477
 478         my $len = length($objid);
 479         for (my $len = length($objid); $len >= 7; ) {
 480                 $doc->add_term($pfx.$objid);
 481                 $objid = substr($objid, 0, --$len);
 482         }
 483 }
 484
 485 sub unindex_blob {
 486         my ($self, $mime) = @_;
 487         my $mid = eval { mid_clean(mid_mime($mime)) };
 488         $self->remove_message($mid) if defined $mid;
 489 }
 490
 491 sub index_mm {
 492         my ($self, $mime) = @_;
 493         my $mid = mid_clean(mid_mime($mime));
 494         my $mm = $self->{mm};
 495         my $num;
 496
 497         if (defined $self->{regen_down}) {
 498                 $num = $mm->num_for($mid) and return $num;
 499
 500                 while (($num = $self->{regen_down}--) > 0) {
 501                         if ($mm->mid_set($num, $mid) != 0) {
 502                                 return $num;
 503                         }
 504                 }
 505         } elsif (defined $self->{regen_up}) {
 506                 $num = $mm->num_for($mid) and return $num;
 507
 508                 # this is to fixup old bugs due to add-remove-add
 509                 while (($num = ++$self->{regen_up})) {
 510                         if ($mm->mid_set($num, $mid) != 0) {
 511                                 return $num;
 512                         }
 513                 }
 514         }
 515
 516         $num = $mm->mid_insert($mid) and return $num;
 517
 518         # fallback to num_for since filters like RubyLang set the number
 519         $mm->num_for($mid);
 520 }
 521
 522 sub unindex_mm {
 523         my ($self, $mime) = @_;
 524         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 525 }
 526
 527 sub index_both {
 528         my ($self, $mime, $bytes, $blob) = @_;
 529         my $num = index_mm($self, $mime);
 530         add_message($self, $mime, $bytes, $num, $blob);
 531 }
 532
 533 sub unindex_both {
 534         my ($self, $mime) = @_;
 535         unindex_blob($self, $mime);
 536         unindex_mm($self, $mime);
 537 }
 538
 539 sub do_cat_mail {
 540         my ($git, $blob, $sizeref) = @_;
 541         my $mime = eval {
 542                 my $str = $git->cat_file($blob, $sizeref);
 543                 # fixup bugs from import:
 544                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 545                 PublicInbox::MIME->new($str);
 546         };
 547         $@ ? undef : $mime;
 548 }
 549
 550 sub index_sync {
 551         my ($self, $opts) = @_;
 552         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 553 }
 554
 555 sub batch_adjust ($$$$) {
 556         my ($max, $bytes, $batch_cb, $latest) = @_;
 557         $$max -= $bytes;
 558         if ($$max <= 0) {
 559                 $$max = BATCH_BYTES;
 560                 $batch_cb->($latest);
 561         }
 562 }
 563
 564 # only for v1
 565 sub read_log {
 566         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 567         my $hex = '[a-f0-9]';
 568         my $h40 = $hex .'{40}';
 569         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 570         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 571         my $git = $self->{git};
 572         my $latest;
 573         my $bytes;
 574         my $max = BATCH_BYTES;
 575         local $/ = "\n";
 576         my %D;
 577         my $line;
 578         my $newest;
 579         while (defined($line = <$log>)) {
 580                 if ($line =~ /$addmsg/o) {
 581                         my $blob = $1;
 582                         if (delete $D{$blob}) {
 583                                 if (defined $self->{regen_down}) {
 584                                         $self->{regen_down}--;
 585                                 }
 586                                 next;
 587                         }
 588                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 589                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 590                         $add_cb->($self, $mime, $bytes, $blob);
 591                 } elsif ($line =~ /$delmsg/o) {
 592                         my $blob = $1;
 593                         $D{$blob} = 1;
 594                 } elsif ($line =~ /^commit ($h40)/o) {
 595                         $latest = $1;
 596                         $newest ||= $latest;
 597                 }
 598         }
 599         # get the leftovers
 600         foreach my $blob (keys %D) {
 601                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 602                 $del_cb->($self, $mime);
 603         }
 604         $batch_cb->($latest, $newest);
 605 }
 606
 607 sub _msgmap_init {
 608         my ($self) = @_;
 609         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 610         $self->{mm} ||= eval {
 611                 require PublicInbox::Msgmap;
 612                 PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 613         };
 614 }
 615
 616 sub _git_log {
 617         my ($self, $range) = @_;
 618         my $git = $self->{git};
 619
 620         if (index($range, '..') < 0) {
 621                 my $regen_max = 0;
 622                 # can't use 'rev-list --count' if we use --diff-filter
 623                 my $fh = $git->popen(qw(log --pretty=tformat:%h
 624                                 --no-notes --no-color --no-renames
 625                                 --diff-filter=AM), $range);
 626                 ++$regen_max while <$fh>;
 627                 my (undef, $max) = $self->{mm}->minmax;
 628
 629                 if ($max && $max == $regen_max) {
 630                         # fix up old bugs in full indexes which caused messages to
 631                         # not appear in Msgmap
 632                         $self->{regen_up} = $max;
 633                 } else {
 634                         # normal regen is for for fresh data
 635                         $self->{regen_down} = $regen_max;
 636                 }
 637         }
 638
 639         $git->popen(qw/log --no-notes --no-color --no-renames
 640                                 --raw -r --no-abbrev/, $range);
 641 }
 642
 643 sub is_ancestor ($$$) {
 644         my ($git, $cur, $tip) = @_;
 645         return 0 unless $git->check($cur);
 646         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 647                 qw(merge-base --is-ancestor), $cur, $tip ];
 648         my $pid = spawn($cmd);
 649         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 650         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 651         $? == 0;
 652 }
 653
 654 sub need_update ($$$) {
 655         my ($self, $cur, $new) = @_;
 656         my $git = $self->{git};
 657         return 1 if $cur && !is_ancestor($git, $cur, $new);
 658         my $range = $cur eq '' ? $new : "$cur..$new";
 659         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 660         ($n eq '' || $n > 0);
 661 }
 662
 663 # indexes all unindexed messages (v1 only)
 664 sub _index_sync {
 665         my ($self, $opts) = @_;
 666         my $tip = $opts->{ref} || 'HEAD';
 667         my $reindex = $opts->{reindex};
 668         my ($mkey, $last_commit, $lx, $xlog);
 669         my $git = $self->{git};
 670         $git->batch_prepare;
 671
 672         my $xdb = $self->begin_txn_lazy;
 673         my $mm = _msgmap_init($self);
 674         do {
 675                 $xlog = undef;
 676                 $mkey = 'last_commit';
 677                 $last_commit = $xdb->get_metadata('last_commit');
 678                 $lx = $last_commit;
 679                 if ($reindex) {
 680                         $lx = '';
 681                         $mkey = undef if $last_commit ne '';
 682                 }
 683
 684                 # use last_commit from msgmap if it is older or unset
 685                 my $lm = $mm->last_commit || '';
 686                 if (!$lm || ($lm && $lx && is_ancestor($git, $lm, $lx))) {
 687                         $lx = $lm;
 688                 }
 689
 690                 $self->{over}->rollback_lazy;
 691                 $self->{over}->disconnect;
 692                 $git->cleanup;
 693                 delete $self->{txn};
 694                 $xdb->cancel_transaction;
 695                 $xdb = _xdb_release($self);
 696
 697                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 698                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 699                 $xlog = _git_log($self, $range);
 700
 701                 $xdb = $self->begin_txn_lazy;
 702         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 703
 704         my $dbh = $mm->{dbh} if $mm;
 705         my $cb = sub {
 706                 my ($commit, $newest) = @_;
 707                 if ($dbh) {
 708                         if ($newest) {
 709                                 my $cur = $mm->last_commit || '';
 710                                 if (need_update($self, $cur, $newest)) {
 711                                         $mm->last_commit($newest);
 712                                 }
 713                         }
 714                         $dbh->commit;
 715                 }
 716                 if ($mkey && $newest) {
 717                         my $cur = $xdb->get_metadata($mkey);
 718                         if (need_update($self, $cur, $newest)) {
 719                                 $xdb->set_metadata($mkey, $newest);
 720                         }
 721                 }
 722                 $self->commit_txn_lazy;
 723                 $git->cleanup;
 724                 $xdb = _xdb_release($self);
 725                 # let another process do some work... <
 726                 if (!$newest) {
 727                         $xdb = $self->begin_txn_lazy;
 728                         $dbh->begin_work if $dbh;
 729                 }
 730         };
 731
 732         $dbh->begin_work;
 733         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 734 }
 735
 736 sub DESTROY {
 737         # order matters for unlocking
 738         $_[0]->{xdb} = undef;
 739         $_[0]->{lockfh} = undef;
 740 }
 741
 742 # remote_* subs are only used by SearchIdxPart
 743 sub remote_commit {
 744         my ($self) = @_;
 745         if (my $w = $self->{w}) {
 746                 print $w "commit\n" or die "failed to write commit: $!";
 747         } else {
 748                 $self->commit_txn_lazy;
 749         }
 750 }
 751
 752 sub remote_close {
 753         my ($self) = @_;
 754         if (my $w = delete $self->{w}) {
 755                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 756                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 757                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 758                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 759                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 760         } else {
 761                 die "transaction in progress $self\n" if $self->{txn};
 762                 $self->_xdb_release if $self->{xdb};
 763         }
 764 }
 765
 766 sub remote_remove {
 767         my ($self, $oid, $mid) = @_;
 768         if (my $w = $self->{w}) {
 769                 # triggers remove_by_oid in a partition
 770                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 771         } else {
 772                 $self->begin_txn_lazy;
 773                 $self->remove_by_oid($oid, $mid);
 774         }
 775 }
 776
 777 sub begin_txn_lazy {
 778         my ($self) = @_;
 779         return if $self->{txn};
 780
 781         $self->{-inbox}->with_umask(sub {
 782                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 783                 $self->{over}->begin_lazy if $self->{over};
 784                 $xdb->begin_transaction;
 785                 $self->{txn} = 1;
 786                 $xdb;
 787         });
 788 }
 789
 790 sub commit_txn_lazy {
 791         my ($self) = @_;
 792         delete $self->{txn} or return;
 793         $self->{-inbox}->with_umask(sub {
 794                 $self->{xdb}->commit_transaction;
 795                 $self->{over}->commit_lazy if $self->{over};
 796         });
 797 }
 798
 799 sub worker_done {
 800         my ($self) = @_;
 801         die "$$ $0 xdb not released\n" if $self->{xdb};
 802         die "$$ $0 still in transaction\n" if $self->{txn};
 803 }
 804
 805 1;