lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchIdx;
   5 use strict;
   6 use warnings;
   7 use base qw(PublicInbox::Search);
   8 use PublicInbox::MID qw/mid_clean mid_compress/;
   9 *xpfx = *PublicInbox::Search::xpfx;
  10
  11 use constant {
  12         PERM_UMASK => 0,
  13         OLD_PERM_GROUP => 1,
  14         OLD_PERM_EVERYBODY => 2,
  15         PERM_GROUP => 0660,
  16         PERM_EVERYBODY => 0664,
  17 };
  18
  19 sub new {
  20         my ($class, $git_dir, $writable) = @_;
  21         my $dir = $class->xdir($git_dir);
  22         require Search::Xapian::WritableDatabase;
  23         my $flag = Search::Xapian::DB_OPEN;
  24         my $self = bless { git_dir => $git_dir }, $class;
  25         my $perm = $self->_git_config_perm;
  26         my $umask = _umask_for($perm);
  27         $self->{umask} = $umask;
  28         $self->{xdb} = $self->with_umask(sub {
  29                 if ($writable == 1) {
  30                         require File::Path;
  31                         File::Path::mkpath($dir);
  32                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  33                 }
  34                 Search::Xapian::WritableDatabase->new($dir, $flag);
  35         });
  36         $self;
  37 }
  38
  39 sub add_message {
  40         my ($self, $mime) = @_; # mime = Email::MIME object
  41         my $db = $self->{xdb};
  42
  43         my $doc_id;
  44         my $mid = mid_clean($mime->header('Message-ID'));
  45         my $was_ghost = 0;
  46         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  47
  48         eval {
  49                 my $smsg = $self->lookup_message($mid);
  50                 my $doc;
  51
  52                 if ($smsg) {
  53                         $smsg->ensure_metadata;
  54                         # convert a ghost to a regular message
  55                         # it will also clobber any existing regular message
  56                         $smsg->mime($mime);
  57                         $doc = $smsg->{doc};
  58
  59                         my $type = xpfx('type');
  60                         eval {
  61                                 $doc->remove_term($type . 'ghost');
  62                                 $was_ghost = 1;
  63                         };
  64
  65                         # probably does not exist:
  66                         eval { $doc->remove_term($type . 'mail') };
  67                         $doc->add_term($type . 'mail');
  68                 }  else {
  69                         $smsg = PublicInbox::SearchMsg->new($mime);
  70                         $doc = $smsg->{doc};
  71                         $doc->add_term(xpfx('mid') . $mid);
  72                 }
  73
  74                 my $subj = $smsg->subject;
  75
  76                 if ($subj ne '') {
  77                         $doc->add_term(xpfx('subject') . $subj);
  78
  79                         my $path = $self->subject_path($subj);
  80                         $doc->add_term(xpfx('path') . mid_compress($path));
  81                 }
  82
  83                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
  84                 $doc->add_value(PublicInbox::Search::TS, $ts);
  85
  86                 my $tg = $self->term_generator;
  87
  88                 $tg->set_document($doc);
  89                 $tg->index_text($subj, 1, 'S') if $subj;
  90                 $tg->increase_termpos;
  91                 $tg->index_text($subj) if $subj;
  92                 $tg->increase_termpos;
  93
  94                 $tg->index_text($smsg->from->format);
  95                 $tg->increase_termpos;
  96
  97                 $mime->walk_parts(sub {
  98                         my ($part) = @_;
  99                         return if $part->subparts; # walk_parts already recurses
 100                         my $ct = $part->content_type || $ct_msg;
 101
 102                         # account for filter bugs...
 103                         $ct =~ m!\btext/plain\b!i or return;
 104
 105                         my (@orig, @quot);
 106                         my $body = $part->body;
 107                         $part->body_set('');
 108                         my @lines = split(/\n/, $body);
 109                         while (defined(my $l = shift @lines)) {
 110                                 if ($l =~ /^\s*>/) {
 111                                         push @quot, $l;
 112                                 } else {
 113                                         push @orig, $l;
 114                                 }
 115                         }
 116                         if (@quot) {
 117                                 $tg->index_text(join("\n", @quot), 0);
 118                                 @quot = ();
 119                                 $tg->increase_termpos;
 120                         }
 121                         if (@orig) {
 122                                 $tg->index_text(join("\n", @orig));
 123                                 @orig = ();
 124                                 $tg->increase_termpos;
 125                         }
 126                 });
 127
 128                 if ($was_ghost) {
 129                         $doc_id = $smsg->doc_id;
 130                         $self->link_message($smsg, 0);
 131                         $doc->set_data($smsg->to_doc_data);
 132                         $db->replace_document($doc_id, $doc);
 133                 } else {
 134                         $self->link_message($smsg, 0);
 135                         $doc->set_data($smsg->to_doc_data);
 136                         $doc_id = $db->add_document($doc);
 137                 }
 138         };
 139
 140         if ($@) {
 141                 warn "failed to index message <$mid>: $@\n";
 142                 return undef;
 143         }
 144         $doc_id;
 145 }
 146
 147 # returns deleted doc_id on success, undef on missing
 148 sub remove_message {
 149         my ($self, $mid) = @_;
 150         my $db = $self->{xdb};
 151         my $doc_id;
 152         $mid = mid_clean($mid);
 153
 154         eval {
 155                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 156                 $db->delete_document($doc_id) if defined $doc_id;
 157         };
 158
 159         if ($@) {
 160                 warn "failed to remove message <$mid>: $@\n";
 161                 return undef;
 162         }
 163         $doc_id;
 164 }
 165
 166 sub term_generator { # write-only
 167         my ($self) = @_;
 168
 169         my $tg = $self->{term_generator};
 170         return $tg if $tg;
 171
 172         $tg = Search::Xapian::TermGenerator->new;
 173         $tg->set_stemmer($self->stemmer);
 174
 175         $self->{term_generator} = $tg;
 176 }
 177
 178 # increments last_thread_id counter
 179 # returns a 64-bit integer represented as a hex string
 180 sub next_thread_id {
 181         my ($self) = @_;
 182         my $db = $self->{xdb};
 183         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 184
 185         $db->set_metadata('last_thread_id', ++$last_thread_id);
 186
 187         $last_thread_id;
 188 }
 189
 190 sub link_message {
 191         my ($self, $smsg, $is_ghost) = @_;
 192
 193         if ($is_ghost) {
 194                 $smsg->ensure_metadata;
 195         } else {
 196                 $self->link_message_to_parents($smsg);
 197         }
 198 }
 199
 200 sub link_message_to_parents {
 201         my ($self, $smsg) = @_;
 202         my $doc = $smsg->{doc};
 203         my $mid = $smsg->mid;
 204         my $mime = $smsg->mime;
 205         my $refs = $mime->header('References');
 206         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 207         if (my $irt = $mime->header('In-Reply-To')) {
 208                 # last References should be $irt
 209                 # we will de-dupe later
 210                 push @refs, mid_clean($irt);
 211         }
 212
 213         my $tid;
 214         if (@refs) {
 215                 my %uniq = ($mid => 1);
 216                 my @orig_refs = @refs;
 217                 @refs = ();
 218
 219                 # prevent circular references via References: here:
 220                 foreach my $ref (@orig_refs) {
 221                         next if $uniq{$ref};
 222                         $uniq{$ref} = 1;
 223                         push @refs, $ref;
 224                 }
 225         }
 226         if (@refs) {
 227                 $smsg->{references_sorted} = '<'.join('><', @refs).'>';
 228
 229                 # first ref *should* be the thread root,
 230                 # but we can never trust clients to do the right thing
 231                 my $ref = shift @refs;
 232                 $tid = $self->_resolve_mid_to_tid($ref);
 233
 234                 # the rest of the refs should point to this tid:
 235                 foreach $ref (@refs) {
 236                         my $ptid = $self->_resolve_mid_to_tid($ref);
 237                         if ($tid ne $ptid) {
 238                                 $self->merge_threads($tid, $ptid);
 239                         }
 240                 }
 241         } else {
 242                 $tid = $self->next_thread_id;
 243         }
 244         $doc->add_term(xpfx('thread') . $tid);
 245 }
 246
 247 sub index_blob {
 248         my ($self, $git, $mime) = @_;
 249         $self->add_message($mime);
 250 }
 251
 252 sub unindex_blob {
 253         my ($self, $git, $mime) = @_;
 254         my $mid = mid_clean($mime->header('Message-ID'));
 255         $self->remove_message($mid) if defined $mid;
 256 }
 257
 258 sub index_mm {
 259         my ($self, $git, $mime) = @_;
 260         $self->{mm}->mid_insert(mid_clean($mime->header('Message-ID')));
 261 }
 262
 263 sub unindex_mm {
 264         my ($self, $git, $mime) = @_;
 265         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 266 }
 267
 268 sub index_both {
 269         my ($self, $git, $mime) = @_;
 270         index_blob($self, $git, $mime);
 271         index_mm($self, $git, $mime);
 272 }
 273
 274 sub unindex_both {
 275         my ($self, $git, $mime) = @_;
 276         unindex_blob($self, $git, $mime);
 277         unindex_mm($self, $git, $mime);
 278 }
 279
 280 sub do_cat_mail {
 281         my ($git, $blob) = @_;
 282         my $mime = eval {
 283                 my $str = $git->cat_file($blob);
 284                 Email::MIME->new($str);
 285         };
 286         $@ ? undef : $mime;
 287 }
 288
 289 sub index_sync {
 290         my ($self, $head) = @_;
 291         $self->with_umask(sub { $self->_index_sync($head) });
 292 }
 293
 294 sub rlog {
 295         my ($self, $range, $add_cb, $del_cb) = @_;
 296         my $hex = '[a-f0-9]';
 297         my $h40 = $hex .'{40}';
 298         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 299         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 300         my $git_dir = $self->{git_dir};
 301         require PublicInbox::GitCatFile;
 302         my $git = PublicInbox::GitCatFile->new($git_dir);
 303         my @cmd = ('git', "--git-dir=$git_dir", "log",
 304                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 305                     $range);
 306         my $latest;
 307         my $pid = open(my $log, '-|', @cmd) or
 308                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 309         while (my $line = <$log>) {
 310                 if ($line =~ /$addmsg/o) {
 311                         my $mime = do_cat_mail($git, $1) or next;
 312                         $add_cb->($self, $git, $mime);
 313                 } elsif ($line =~ /$delmsg/o) {
 314                         my $mime = do_cat_mail($git, $1) or next;
 315                         $del_cb->($self, $git, $mime);
 316                 } elsif ($line =~ /^commit ($h40)/o) {
 317                         $latest = $1;
 318                 }
 319         }
 320         close $log;
 321         $latest;
 322 }
 323
 324 # indexes all unindexed messages
 325 sub _index_sync {
 326         my ($self, $head) = @_;
 327         my $db = $self->{xdb};
 328         $head ||= 'HEAD';
 329         my $mm = $self->{mm} = eval {
 330                 require PublicInbox::Msgmap;
 331                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 332         };
 333
 334         $db->begin_transaction;
 335         my $lx = $db->get_metadata('last_commit');
 336         my $range = $lx eq '' ? $head : "$lx..$head";
 337         if ($mm) {
 338                 $mm->{dbh}->begin_work;
 339                 my $lm = $mm->last_commit || '';
 340                 if ($lm eq $lx) {
 341                         # Common case is the indexes are synced,
 342                         # we only need to run git-log once:
 343                         $lx = $self->rlog($range, *index_both, *unindex_both);
 344                         $mm->{dbh}->commit;
 345                         if (defined $lx) {
 346                                 $db->set_metadata('last_commit', $lx);
 347                                 $mm->last_commit($lx);
 348                         }
 349                 } else {
 350                         # dumb case, msgmap and xapian are out-of-sync
 351                         # do not care for performance:
 352                         my $r = $lm eq '' ? $head : "$lm..$head";
 353                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 354                         $mm->{dbh}->commit;
 355                         $mm->last_commit($lm) if defined $lm;
 356
 357                         goto xapian_only;
 358                 }
 359         } else {
 360                 # user didn't install DBD::SQLite and DBI
 361 xapian_only:
 362                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 363                 $db->set_metadata('last_commit', $lx) if defined $lx;
 364         }
 365         if ($@) {
 366                 $db->cancel_transaction;
 367                 $mm->{dbh}->rollback if $mm;
 368         } else {
 369                 $db->commit_transaction;
 370         }
 371 }
 372
 373 # this will create a ghost as necessary
 374 sub _resolve_mid_to_tid {
 375         my ($self, $mid) = @_;
 376
 377         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 378         $smsg->thread_id;
 379 }
 380
 381 sub create_ghost {
 382         my ($self, $mid, $tid) = @_;
 383
 384         $tid = $self->next_thread_id unless defined $tid;
 385
 386         my $doc = Search::Xapian::Document->new;
 387         $doc->add_term(xpfx('mid') . $mid);
 388         $doc->add_term(xpfx('thread') . $tid);
 389         $doc->add_term(xpfx('type') . 'ghost');
 390
 391         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 392         $self->link_message($smsg, 1);
 393         $self->{xdb}->add_document($doc);
 394
 395         $smsg;
 396 }
 397
 398 sub merge_threads {
 399         my ($self, $winner_tid, $loser_tid) = @_;
 400         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 401         my $thread_pfx = xpfx('thread');
 402         my $db = $self->{xdb};
 403
 404         for (; $head != $tail; $head->inc) {
 405                 my $docid = $head->get_docid;
 406                 my $doc = $db->get_document($docid);
 407                 $doc->remove_term($thread_pfx . $loser_tid);
 408                 $doc->add_term($thread_pfx . $winner_tid);
 409                 $db->replace_document($docid, $doc);
 410         }
 411 }
 412
 413 sub _read_git_config_perm {
 414         my ($self) = @_;
 415         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 416                    qw(config core.sharedRepository));
 417         my $pid = open(my $fh, '-|', @cmd) or
 418                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 419         my $perm = <$fh>;
 420         close $fh;
 421         chomp $perm if defined $perm;
 422         $perm;
 423 }
 424
 425 sub _git_config_perm {
 426         my $self = shift;
 427         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 428         return PERM_GROUP if (!defined($perm) || $perm eq '');
 429         return PERM_UMASK if ($perm eq 'umask');
 430         return PERM_GROUP if ($perm eq 'group');
 431         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 432                 return PERM_EVERYBODY;
 433         }
 434         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 435         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 436
 437         my $i = oct($perm);
 438         return PERM_UMASK if ($i == PERM_UMASK);
 439         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 440         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 441
 442         if (($i & 0600) != 0600) {
 443                 die "core.sharedRepository mode invalid: ".
 444                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 445         }
 446         ($i & 0666);
 447 }
 448
 449 sub _umask_for {
 450         my ($perm) = @_; # _git_config_perm return value
 451         my $rv = $perm;
 452         return umask if $rv == 0;
 453
 454         # set +x bit if +r or +w were set
 455         $rv |= 0100 if ($rv & 0600);
 456         $rv |= 0010 if ($rv & 0060);
 457         $rv |= 0001 if ($rv & 0006);
 458         (~$rv & 0777);
 459 }
 460
 461 sub with_umask {
 462         my ($self, $cb) = @_;
 463         my $old = umask $self->{umask};
 464         my $rv = eval { $cb->() };
 465         my $err = $@;
 466         umask $old;
 467         die $err if $@;
 468         $rv;
 469 }
 470
 471 1;