lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: GPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchMsg;
   5 use strict;
   6 use warnings;
   7 use Search::Xapian;
   8 use Email::Address qw//;
   9 use Email::Simple qw//;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean mid_compress/;
  13 use Encode qw/find_encoding/;
  14 my $enc_utf8 = find_encoding('UTF-8');
  15 our $PFX2TERM_RE = undef;
  16
  17 sub new {
  18         my ($class, $mime) = @_;
  19         my $doc = Search::Xapian::Document->new;
  20         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  21
  22         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  23 }
  24
  25 sub wrap {
  26         my ($class, $doc, $mid) = @_;
  27         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  28 }
  29
  30 sub load_doc {
  31         my ($class, $doc) = @_;
  32         my $data = $doc->get_data;
  33         $data = $enc_utf8->decode($data);
  34         my ($mid, $subj, $from, $date, $refs) = split(/\n/, $data);
  35         bless {
  36                 doc => $doc,
  37                 mid => $mid,
  38                 subject => $subj,
  39                 date => $date,
  40                 from_name => $from,
  41                 references_sorted => $refs,
  42         }, $class;
  43 }
  44
  45 sub subject {
  46         my ($self) = @_;
  47         my $subj = $self->{subject};
  48         return $subj if defined $subj;
  49         $subj = $self->{mime}->header('Subject');
  50         $subj = '' unless defined $subj;
  51         $subj =~ tr/\n/ /;
  52         $self->{subject} = $subj;
  53 }
  54
  55 sub from {
  56         my ($self) = @_;
  57         my $from = $self->mime->header('From') || '';
  58         my @from;
  59
  60         if ($from) {
  61                 $from =~ tr/\n/ /;
  62                 @from = Email::Address->parse($from);
  63                 $self->{from} = $from[0];
  64                 $from = $from[0]->name;
  65         }
  66         $self->{from_name} = $from;
  67         $self->{from};
  68 }
  69
  70 sub from_name {
  71         my ($self) = @_;
  72         my $from_name = $self->{from_name};
  73         return $from_name if defined $from_name;
  74         $self->from;
  75         $self->{from_name};
  76 }
  77
  78 sub ts {
  79         my ($self) = @_;
  80         my $ts = $self->{ts};
  81         return $ts if $ts;
  82         $self->{ts} = eval {
  83                 str2time($self->date || $self->mime->header('Date'))
  84         } || 0;
  85 }
  86
  87 sub date {
  88         my ($self) = @_;
  89         my $date = $self->{date};
  90         return $date if $date;
  91         my $ts = eval { str2time($self->mime->header('Date')) };
  92         $self->{date} = POSIX::strftime('%Y-%m-%d %H:%M', gmtime($ts));
  93 }
  94
  95 sub to_doc_data {
  96         my ($self) = @_;
  97         $self->mid . "\n" .
  98         PublicInbox::Search::subject_summary($self->subject) . "\n" .
  99         $self->from_name . "\n".
 100         $self->date . "\n" .
 101         $self->references_sorted;
 102 }
 103
 104 sub references_sorted {
 105         my ($self) = @_;
 106         my $x = $self->{references_sorted};
 107         defined $x ? $x : '';
 108 }
 109
 110 sub ensure_metadata {
 111         my ($self) = @_;
 112         my $doc = $self->{doc};
 113         my $i = $doc->termlist_begin;
 114         my $end = $doc->termlist_end;
 115
 116         unless (defined $PFX2TERM_RE) {
 117                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 118                 $PFX2TERM_RE = qr/\A($or)/;
 119         }
 120
 121         for (; $i != $end; $i->inc) {
 122                 my $val = $i->get_termname;
 123
 124                 if ($val =~ s/$PFX2TERM_RE//o) {
 125                         my $field = $PublicInbox::Search::PFX2TERM_RMAP{$1};
 126                         $self->{$field} = $val;
 127                 }
 128         }
 129 }
 130
 131 # for threading only
 132 sub mini_mime {
 133         my ($self) = @_;
 134         $self->ensure_metadata;
 135         my @h = (
 136                 Subject => $self->subject,
 137                 'X-PI-From' => $self->from_name,
 138                 'X-PI-Date' => $self->date,
 139                 'X-PI-TS' => $self->ts,
 140                 'Message-ID' => "<$self->{mid}>",
 141         );
 142
 143         my $refs = $self->{references_sorted};
 144         my $mime = Email::MIME->create(header_str => \@h);
 145         $mime->header_set('References', $refs) if (defined $refs);
 146         $mime;
 147 }
 148
 149 sub mid {
 150         my ($self, $mid) = @_;
 151
 152         if (defined $mid) {
 153                 $self->{mid} = $mid;
 154         } else {
 155                 $self->ensure_metadata; # needed for ghosts
 156                 $self->{mid} ||= $self->_extract_mid;
 157         }
 158 }
 159
 160 sub _extract_mid {
 161         my ($self) = @_;
 162
 163         my $mid = $self->mime->header('Message-ID');
 164         $mid ? mid_compress(mid_clean($mid)) : $mid;
 165 }
 166
 167 sub mime {
 168         my ($self, $mime) = @_;
 169         if (defined $mime) {
 170                 $self->{mime} = $mime;
 171         } else {
 172                 # TODO load from git
 173                 $self->{mime};
 174         }
 175 }
 176
 177 sub doc_id {
 178         my ($self, $doc_id) = @_;
 179         if (defined $doc_id) {
 180                 $self->{doc_id} = $doc_id;
 181         } else {
 182                 # TODO load from xapian
 183                 $self->{doc_id};
 184         }
 185 }
 186
 187 sub thread_id {
 188         my ($self) = @_;
 189         my $tid = $self->{thread};
 190         return $tid if defined $tid;
 191         $self->ensure_metadata;
 192         $self->{thread};
 193 }
 194
 195 sub path {
 196         my ($self) = @_;
 197         my $path = $self->{path};
 198         return $path if defined $path;
 199         $self->ensure_metadata;
 200         $self->{path};
 201 }
 202
 203 1;