lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_mime/;
  10 use PublicInbox::Address;
  11 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  12 use Time::Local qw(timegm);
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         my $doc = Search::Xapian::Document->new;
  17         bless { doc => $doc, mime => $mime }, $class;
  18 }
  19
  20 sub wrap {
  21         my ($class, $doc, $mid) = @_;
  22         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  23 }
  24
  25 sub get {
  26         my ($class, $head, $db, $mid) = @_;
  27         my $doc_id = $head->get_docid;
  28         my $doc = $db->get_document($doc_id);
  29         load_expand(wrap($class, $doc, $mid))
  30 }
  31
  32 sub get_val ($$) {
  33         my ($doc, $col) = @_;
  34         Search::Xapian::sortable_unserialise($doc->get_value($col));
  35 }
  36
  37 sub to_doc_data {
  38         my ($self, $oid, $mid0) = @_;
  39         $oid = '' unless defined $oid;
  40         join("\n",
  41                 $self->subject,
  42                 $self->from,
  43                 $self->references,
  44                 $self->to,
  45                 $self->cc,
  46                 $oid,
  47                 $mid0,
  48                 $self->{bytes} || '',
  49                 $self->{lines} || ''
  50         );
  51 }
  52
  53 sub load_from_data ($$) {
  54         my ($self) = $_[0]; # data = $_[1]
  55         (
  56                 $self->{subject},
  57                 $self->{from},
  58                 $self->{references},
  59
  60                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  61                 # some NNTP clients will use that for message displays.
  62                 $self->{to},
  63                 $self->{cc},
  64
  65                 $self->{blob},
  66                 $self->{mid},
  67                 $self->{bytes},
  68                 $self->{lines}
  69         ) = split(/\n/, $_[1]);
  70 }
  71
  72 sub load_expand {
  73         my ($self) = @_;
  74         my $doc = $self->{doc};
  75         my $data = $doc->get_data or return;
  76         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  77         my $dt = get_val($doc, PublicInbox::Search::DT());
  78         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  79         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  80         utf8::decode($data);
  81         load_from_data($self, $data);
  82         $self;
  83 }
  84
  85 sub load_doc {
  86         my ($class, $doc) = @_;
  87         my $self = bless { doc => $doc }, $class;
  88         $self->load_expand;
  89 }
  90
  91 # :bytes and :lines metadata in RFC 3977
  92 sub bytes ($) { $_[0]->{bytes} }
  93 sub lines ($) { $_[0]->{lines} }
  94
  95 sub __hdr ($$) {
  96         my ($self, $field) = @_;
  97         my $val = $self->{$field};
  98         return $val if defined $val;
  99
 100         my $mime = $self->{mime} or return;
 101         $val = $mime->header($field);
 102         $val = '' unless defined $val;
 103         $val =~ tr/\t\n/  /;
 104         $val =~ tr/\r//d;
 105         $self->{$field} = $val;
 106 }
 107
 108 sub subject ($) { __hdr($_[0], 'subject') }
 109 sub to ($) { __hdr($_[0], 'to') }
 110 sub cc ($) { __hdr($_[0], 'cc') }
 111
 112 # no strftime, that is locale-dependent and not for RFC822
 113 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 114 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 115
 116 sub date ($) {
 117         my ($self) = @_;
 118         my $ds = $self->{ds};
 119         return unless defined $ds;
 120         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 121         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 122                                 $mday, $year+1900, $hour, $min, $sec);
 123
 124 }
 125
 126 sub from ($) {
 127         my ($self) = @_;
 128         my $from = __hdr($self, 'from');
 129         if (defined $from && !defined $self->{from_name}) {
 130                 my @n = PublicInbox::Address::names($from);
 131                 $self->{from_name} = join(', ', @n);
 132         }
 133         $from;
 134 }
 135
 136 sub from_name {
 137         my ($self) = @_;
 138         my $from_name = $self->{from_name};
 139         return $from_name if defined $from_name;
 140         $self->from;
 141         $self->{from_name};
 142 }
 143
 144 sub ts {
 145         my ($self) = @_;
 146         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 147 }
 148
 149 sub ds {
 150         my ($self) = @_;
 151         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 152 }
 153
 154 sub references {
 155         my ($self) = @_;
 156         my $x = $self->{references};
 157         defined $x ? $x : '';
 158 }
 159
 160 sub _get_term_val ($$$) {
 161         my ($self, $pfx, $re) = @_;
 162         my $doc = $self->{doc};
 163         my $end = $doc->termlist_end;
 164         my $i = $doc->termlist_begin;
 165         $i->skip_to($pfx);
 166         if ($i != $end) {
 167                 my $val = $i->get_termname;
 168                 $val =~ s/$re// and return $val;
 169         }
 170         undef;
 171 }
 172
 173 sub mid ($;$) {
 174         my ($self, $mid) = @_;
 175
 176         if (defined $mid) {
 177                 $self->{mid} = $mid;
 178         } elsif (my $rv = $self->{mid}) {
 179                 $rv;
 180         } elsif ($self->{doc}) {
 181                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/);
 182         } else {
 183                 $self->_extract_mid; # v1 w/o Xapian
 184         }
 185 }
 186
 187 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 188
 189 1;