lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 # There may be many of these objects loaded in memory at once
   7 # for large threads in our WWW UI.
   8 package PublicInbox::SearchMsg;
   9 use strict;
  10 use warnings;
  11 use PublicInbox::MID qw/mid_clean mid_mime/;
  12 use PublicInbox::Address;
  13 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  14 use Time::Local qw(timegm);
  15
  16 sub new {
  17         my ($class, $mime) = @_;
  18         bless { mime => $mime }, $class;
  19 }
  20
  21 sub wrap {
  22         my ($class, $mid) = @_;
  23         bless { mid => $mid }, $class;
  24 }
  25
  26 sub get {
  27         my ($class, $head, $db, $mid) = @_;
  28         my $doc_id = $head->get_docid;
  29         load_expand(wrap($class, $mid), $db->get_document($doc_id));
  30 }
  31
  32 sub get_val ($$) {
  33         my ($doc, $col) = @_;
  34         Search::Xapian::sortable_unserialise($doc->get_value($col));
  35 }
  36
  37 sub to_doc_data {
  38         my ($self, $oid, $mid0) = @_;
  39         $oid = '' unless defined $oid;
  40         join("\n",
  41                 $self->subject,
  42                 $self->from,
  43                 $self->references,
  44                 $self->to,
  45                 $self->cc,
  46                 $oid,
  47                 $mid0,
  48                 $self->{bytes} || '',
  49                 $self->{lines} || ''
  50         );
  51 }
  52
  53 sub load_from_data ($$) {
  54         my ($self) = $_[0]; # data = $_[1]
  55         (
  56                 $self->{subject},
  57                 $self->{from},
  58                 $self->{references},
  59
  60                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  61                 # some NNTP clients will use that for message displays.
  62                 # NNTP only, and only stored in Over(view), not Xapian
  63                 $self->{to},
  64                 $self->{cc},
  65
  66                 $self->{blob},
  67                 $self->{mid},
  68
  69                 # NNTP only
  70                 $self->{bytes},
  71                 $self->{lines}
  72         ) = split(/\n/, $_[1]);
  73 }
  74
  75 sub load_expand {
  76         my ($self, $doc) = @_;
  77         my $data = $doc->get_data or return;
  78         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  79         my $dt = get_val($doc, PublicInbox::Search::DT());
  80         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  81         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  82         utf8::decode($data);
  83         load_from_data($self, $data);
  84         $self;
  85 }
  86
  87 sub psgi_cull ($) {
  88         my ($self) = @_;
  89         from_name($self); # fill in {from_name} so we can delete {from}
  90
  91         # drop NNTP-only fields which aren't relevant to PSGI results:
  92         # saves ~80K on a 200 item search result:
  93         delete @$self{qw(from ts to cc bytes lines)};
  94         $self;
  95 }
  96
  97 # Only called by PSGI interface, not NNTP
  98 sub load_doc {
  99         my ($class, $doc) = @_;
 100         my $self = bless {}, $class;
 101         psgi_cull(load_expand($self, $doc));
 102 }
 103
 104 # :bytes and :lines metadata in RFC 3977
 105 sub bytes ($) { $_[0]->{bytes} }
 106 sub lines ($) { $_[0]->{lines} }
 107
 108 sub __hdr ($$) {
 109         my ($self, $field) = @_;
 110         my $val = $self->{$field};
 111         return $val if defined $val;
 112
 113         my $mime = $self->{mime} or return;
 114         $val = $mime->header($field);
 115         $val = '' unless defined $val;
 116         $val =~ tr/\t\n/  /;
 117         $val =~ tr/\r//d;
 118         $self->{$field} = $val;
 119 }
 120
 121 sub subject ($) { __hdr($_[0], 'subject') }
 122 sub to ($) { __hdr($_[0], 'to') }
 123 sub cc ($) { __hdr($_[0], 'cc') }
 124
 125 # no strftime, that is locale-dependent and not for RFC822
 126 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 127 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 128
 129 sub date ($) {
 130         my ($self) = @_;
 131         my $ds = $self->{ds};
 132         return unless defined $ds;
 133         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 134         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 135                                 $mday, $year+1900, $hour, $min, $sec);
 136
 137 }
 138
 139 sub from ($) {
 140         my ($self) = @_;
 141         my $from = __hdr($self, 'from');
 142         if (defined $from && !defined $self->{from_name}) {
 143                 my @n = PublicInbox::Address::names($from);
 144                 $self->{from_name} = join(', ', @n);
 145         }
 146         $from;
 147 }
 148
 149 sub from_name {
 150         my ($self) = @_;
 151         my $from_name = $self->{from_name};
 152         return $from_name if defined $from_name;
 153         $self->from;
 154         $self->{from_name};
 155 }
 156
 157 sub ts {
 158         my ($self) = @_;
 159         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 160 }
 161
 162 sub ds {
 163         my ($self) = @_;
 164         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 165 }
 166
 167 sub references {
 168         my ($self) = @_;
 169         my $x = $self->{references};
 170         defined $x ? $x : '';
 171 }
 172
 173 sub mid ($;$) {
 174         my ($self, $mid) = @_;
 175
 176         if (defined $mid) {
 177                 $self->{mid} = $mid;
 178         } elsif (defined(my $rv = $self->{mid})) {
 179                 $rv;
 180         } else {
 181                 die "NO {mime} for mid\n" unless $self->{mime};
 182                 $self->_extract_mid; # v1 w/o Xapian
 183         }
 184 }
 185
 186 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 187
 188 1;