lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 # There may be many of these objects loaded in memory at once
   7 # for large threads in our WWW UI.
   8 package PublicInbox::SearchMsg;
   9 use strict;
  10 use warnings;
  11 use base qw(Exporter);
  12 our @EXPORT_OK = qw(subject_normalized);
  13 use PublicInbox::MID qw/mid_clean mid_mime/;
  14 use PublicInbox::Address;
  15 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  16 use Time::Local qw(timegm);
  17
  18 sub new {
  19         my ($class, $mime) = @_;
  20         bless { mime => $mime }, $class;
  21 }
  22
  23 sub wrap {
  24         my ($class, $mid) = @_;
  25         bless { mid => $mid }, $class;
  26 }
  27
  28 sub get_val ($$) {
  29         my ($doc, $col) = @_;
  30         # sortable_unserialise is defined by PublicInbox::Search::load_xapian()
  31         sortable_unserialise($doc->get_value($col));
  32 }
  33
  34 sub to_doc_data {
  35         my ($self, $oid, $mid0) = @_;
  36         $oid = '' unless defined $oid;
  37         join("\n",
  38                 $self->subject,
  39                 $self->from,
  40                 $self->references,
  41                 $self->to,
  42                 $self->cc,
  43                 $oid,
  44                 $mid0,
  45                 $self->{bytes} || '',
  46                 $self->{lines} || ''
  47         );
  48 }
  49
  50 sub load_from_data ($$) {
  51         my ($self) = $_[0]; # data = $_[1]
  52         (
  53                 $self->{subject},
  54                 $self->{from},
  55                 $self->{references},
  56
  57                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  58                 # some NNTP clients will use that for message displays.
  59                 # NNTP only, and only stored in Over(view), not Xapian
  60                 $self->{to},
  61                 $self->{cc},
  62
  63                 $self->{blob},
  64                 $self->{mid},
  65
  66                 # NNTP only
  67                 $self->{bytes},
  68                 $self->{lines}
  69         ) = split(/\n/, $_[1]);
  70 }
  71
  72 sub load_expand {
  73         my ($self, $doc) = @_;
  74         my $data = $doc->get_data or return;
  75         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  76         my $dt = get_val($doc, PublicInbox::Search::DT());
  77         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  78         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  79         utf8::decode($data);
  80         load_from_data($self, $data);
  81         $self;
  82 }
  83
  84 sub psgi_cull ($) {
  85         my ($self) = @_;
  86         from_name($self); # fill in {from_name} so we can delete {from}
  87
  88         # drop NNTP-only fields which aren't relevant to PSGI results:
  89         # saves ~80K on a 200 item search result:
  90         delete @$self{qw(from ts to cc bytes lines)};
  91         $self;
  92 }
  93
  94 # Only called by PSGI interface, not NNTP
  95 sub load_doc {
  96         my ($class, $doc) = @_;
  97         my $self = bless {}, $class;
  98         psgi_cull(load_expand($self, $doc));
  99 }
 100
 101 # :bytes and :lines metadata in RFC 3977
 102 sub bytes ($) { $_[0]->{bytes} }
 103 sub lines ($) { $_[0]->{lines} }
 104
 105 sub __hdr ($$) {
 106         my ($self, $field) = @_;
 107         my $val = $self->{$field};
 108         return $val if defined $val;
 109
 110         my $mime = $self->{mime} or return;
 111         my @raw = $mime->header($field);
 112         $val = join(', ', @raw);
 113         $val =~ tr/\t\n/  /;
 114         $val =~ tr/\r//d;
 115         $self->{$field} = $val;
 116 }
 117
 118 sub subject ($) { __hdr($_[0], 'subject') }
 119 sub to ($) { __hdr($_[0], 'to') }
 120 sub cc ($) { __hdr($_[0], 'cc') }
 121
 122 # no strftime, that is locale-dependent and not for RFC822
 123 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 124 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 125
 126 sub date ($) {
 127         my ($self) = @_;
 128         my $ds = $self->{ds};
 129         return unless defined $ds;
 130         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 131         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 132                                 $mday, $year+1900, $hour, $min, $sec);
 133
 134 }
 135
 136 sub from ($) {
 137         my ($self) = @_;
 138         my $from = __hdr($self, 'from');
 139         if (defined $from && !defined $self->{from_name}) {
 140                 my @n = PublicInbox::Address::names($from);
 141                 $self->{from_name} = join(', ', @n);
 142         }
 143         $from;
 144 }
 145
 146 sub from_name {
 147         my ($self) = @_;
 148         my $from_name = $self->{from_name};
 149         return $from_name if defined $from_name;
 150         $self->from;
 151         $self->{from_name};
 152 }
 153
 154 sub ts {
 155         my ($self) = @_;
 156         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 157 }
 158
 159 sub ds {
 160         my ($self) = @_;
 161         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 162 }
 163
 164 sub references {
 165         my ($self) = @_;
 166         my $x = $self->{references};
 167         defined $x ? $x : '';
 168 }
 169
 170 sub mid ($;$) {
 171         my ($self, $mid) = @_;
 172
 173         if (defined $mid) {
 174                 $self->{mid} = $mid;
 175         } elsif (defined(my $rv = $self->{mid})) {
 176                 $rv;
 177         } else {
 178                 die "NO {mime} for mid\n" unless $self->{mime};
 179                 $self->_extract_mid; # v1 w/o Xapian
 180         }
 181 }
 182
 183 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 184
 185 our $REPLY_RE = qr/^re:\s+/i;
 186
 187 sub subject_normalized ($) {
 188         my ($subj) = @_;
 189         $subj =~ s/\A\s+//s; # no leading space
 190         $subj =~ s/\s+\z//s; # no trailing space
 191         $subj =~ s/\s+/ /gs; # no redundant spaces
 192         $subj =~ s/\.+\z//; # no trailing '.'
 193         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 194         $subj;
 195 }
 196
 197 1;