lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_mime/;
  10 use PublicInbox::Address;
  11 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  12 use Time::Local qw(timegm);
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         bless { mime => $mime }, $class;
  17 }
  18
  19 sub wrap {
  20         my ($class, $mid) = @_;
  21         bless { mid => $mid }, $class;
  22 }
  23
  24 sub get {
  25         my ($class, $head, $db, $mid) = @_;
  26         my $doc_id = $head->get_docid;
  27         load_expand(wrap($class, $mid), $db->get_document($doc_id));
  28 }
  29
  30 sub get_val ($$) {
  31         my ($doc, $col) = @_;
  32         Search::Xapian::sortable_unserialise($doc->get_value($col));
  33 }
  34
  35 sub to_doc_data {
  36         my ($self, $oid, $mid0) = @_;
  37         $oid = '' unless defined $oid;
  38         join("\n",
  39                 $self->subject,
  40                 $self->from,
  41                 $self->references,
  42                 $self->to,
  43                 $self->cc,
  44                 $oid,
  45                 $mid0,
  46                 $self->{bytes} || '',
  47                 $self->{lines} || ''
  48         );
  49 }
  50
  51 sub load_from_data ($$) {
  52         my ($self) = $_[0]; # data = $_[1]
  53         (
  54                 $self->{subject},
  55                 $self->{from},
  56                 $self->{references},
  57
  58                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  59                 # some NNTP clients will use that for message displays.
  60                 # NNTP only, and only stored in Over(view), not Xapian
  61                 $self->{to},
  62                 $self->{cc},
  63
  64                 $self->{blob},
  65                 $self->{mid},
  66
  67                 # NNTP only
  68                 $self->{bytes},
  69                 $self->{lines}
  70         ) = split(/\n/, $_[1]);
  71 }
  72
  73 sub load_expand {
  74         my ($self, $doc) = @_;
  75         my $data = $doc->get_data or return;
  76         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  77         my $dt = get_val($doc, PublicInbox::Search::DT());
  78         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  79         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  80         utf8::decode($data);
  81         load_from_data($self, $data);
  82         $self;
  83 }
  84
  85 # Only called by PSGI interface, not NNTP
  86 sub load_doc {
  87         my ($class, $doc) = @_;
  88         my $self = bless {}, $class;
  89         my $smsg = load_expand($self, $doc);
  90
  91         from_name($smsg); # fill in {from_name} so we can delete {from}
  92
  93         # drop NNTP-only fields which aren't relevant to PSGI results:
  94         # saves ~80K on a 200 item search result:
  95         delete @$smsg{qw(from ts to cc bytes lines)};
  96         $smsg;
  97 }
  98
  99 # :bytes and :lines metadata in RFC 3977
 100 sub bytes ($) { $_[0]->{bytes} }
 101 sub lines ($) { $_[0]->{lines} }
 102
 103 sub __hdr ($$) {
 104         my ($self, $field) = @_;
 105         my $val = $self->{$field};
 106         return $val if defined $val;
 107
 108         my $mime = $self->{mime} or return;
 109         $val = $mime->header($field);
 110         $val = '' unless defined $val;
 111         $val =~ tr/\t\n/  /;
 112         $val =~ tr/\r//d;
 113         $self->{$field} = $val;
 114 }
 115
 116 sub subject ($) { __hdr($_[0], 'subject') }
 117 sub to ($) { __hdr($_[0], 'to') }
 118 sub cc ($) { __hdr($_[0], 'cc') }
 119
 120 # no strftime, that is locale-dependent and not for RFC822
 121 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 122 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 123
 124 sub date ($) {
 125         my ($self) = @_;
 126         my $ds = $self->{ds};
 127         return unless defined $ds;
 128         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 129         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 130                                 $mday, $year+1900, $hour, $min, $sec);
 131
 132 }
 133
 134 sub from ($) {
 135         my ($self) = @_;
 136         my $from = __hdr($self, 'from');
 137         if (defined $from && !defined $self->{from_name}) {
 138                 my @n = PublicInbox::Address::names($from);
 139                 $self->{from_name} = join(', ', @n);
 140         }
 141         $from;
 142 }
 143
 144 sub from_name {
 145         my ($self) = @_;
 146         my $from_name = $self->{from_name};
 147         return $from_name if defined $from_name;
 148         $self->from;
 149         $self->{from_name};
 150 }
 151
 152 sub ts {
 153         my ($self) = @_;
 154         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 155 }
 156
 157 sub ds {
 158         my ($self) = @_;
 159         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 160 }
 161
 162 sub references {
 163         my ($self) = @_;
 164         my $x = $self->{references};
 165         defined $x ? $x : '';
 166 }
 167
 168 sub mid ($;$) {
 169         my ($self, $mid) = @_;
 170
 171         if (defined $mid) {
 172                 $self->{mid} = $mid;
 173         } elsif (defined(my $rv = $self->{mid})) {
 174                 $rv;
 175         } else {
 176                 die "NO {mime} for mid\n" unless $self->{mime};
 177                 $self->_extract_mid; # v1 w/o Xapian
 178         }
 179 }
 180
 181 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 182
 183 1;