lib/PublicInbox/Smsg.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # A small/skeleton/slim representation of a message.
   5
   6 # This used to be "SearchMsg", but we split out overview
   7 # indexing into over.sqlite3 so it's not just "search".  There
   8 # may be many of these objects loaded in memory at once for
   9 # large threads in our WWW UI and the NNTP range responses.
  10 package PublicInbox::Smsg;
  11 use strict;
  12 use warnings;
  13 use base qw(Exporter);
  14 our @EXPORT_OK = qw(subject_normalized);
  15 use PublicInbox::MID qw(mids);
  16 use PublicInbox::Address;
  17 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  18
  19 sub to_doc_data {
  20         my ($self) = @_;
  21         join("\n",
  22                 $self->{subject},
  23                 $self->{from},
  24                 $self->{references} // '',
  25                 $self->{to},
  26                 $self->{cc},
  27                 $self->{blob},
  28                 $self->{mid},
  29                 $self->{bytes} // '',
  30                 $self->{lines} // ''
  31         );
  32 }
  33
  34 sub load_from_data ($$) {
  35         my ($self) = $_[0]; # data = $_[1]
  36         utf8::decode($_[1]);
  37         (
  38                 $self->{subject},
  39                 $self->{from},
  40                 $self->{references},
  41
  42                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  43                 # some NNTP clients will use that for message displays.
  44                 # NNTP only, and only stored in Over(view), not Xapian
  45                 $self->{to},
  46                 $self->{cc},
  47
  48                 $self->{blob},
  49                 $self->{mid},
  50
  51                 # NNTP only
  52                 $self->{bytes},
  53                 $self->{lines}
  54         ) = split(/\n/, $_[1]);
  55 }
  56
  57 sub psgi_cull ($) {
  58         my ($self) = @_;
  59
  60         # ghosts don't have ->{from}
  61         my $from = delete($self->{from}) // '';
  62         my @n = PublicInbox::Address::names($from);
  63         $self->{from_name} = join(', ', @n);
  64
  65         # drop NNTP-only fields which aren't relevant to PSGI results:
  66         # saves ~80K on a 200 item search result:
  67         # TODO: we may need to keep some of these for JMAP...
  68         delete @$self{qw(tid to cc bytes lines)};
  69         $self;
  70 }
  71
  72 # for Import and v1 non-SQLite WWW code paths
  73 sub populate {
  74         my ($self, $hdr, $sync) = @_;
  75         for my $f (qw(From To Cc Subject)) {
  76                 my @all = $hdr->header($f);
  77                 my $val = join(', ', @all);
  78                 $val =~ tr/\r//d;
  79                 # MIME decoding can create NULs, replace them with spaces
  80                 # to protect git and NNTP clients
  81                 $val =~ tr/\0\t\n/   /;
  82
  83                 # rare: in case headers have wide chars (not RFC2047-encoded)
  84                 utf8::decode($val);
  85
  86                 # lower-case fields for read-only stuff
  87                 $self->{lc($f)} = $val;
  88
  89                 # Capitalized From/Subject for git-fast-import
  90                 next if $f eq 'To' || $f eq 'Cc';
  91                 if (scalar(@all) > 1) {
  92                         $val = $all[0];
  93                         $val =~ tr/\r//d;
  94                         $val =~ tr/\0\t\n/   /;
  95                 }
  96                 $self->{$f} = $val if $val ne '';
  97         }
  98         $sync //= {};
  99         $self->{-ds} = [ my @ds = msg_datestamp($hdr, $sync->{autime}) ];
 100         $self->{-ts} = [ my @ts = msg_timestamp($hdr, $sync->{cotime}) ];
 101         $self->{ds} //= $ds[0]; # no zone
 102         $self->{ts} //= $ts[0];
 103
 104         # for v1 users w/o SQLite
 105         $self->{mid} //= eval { mids($hdr)->[0] } // '';
 106 }
 107
 108 # no strftime, that is locale-dependent and not for RFC822
 109 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 110 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 111
 112 sub date ($) { # for NNTP
 113         my ($self) = @_;
 114         my $ds = $self->{ds};
 115         return unless defined $ds;
 116         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 117         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 118                                 $mday, $year+1900, $hour, $min, $sec);
 119 }
 120
 121 sub internaldate { # for IMAP
 122         my ($self) = @_;
 123         my ($sec, $min, $hour, $mday, $mon, $year) = gmtime($self->{ts} // 0);
 124         sprintf("%02d-$MoY[$mon]-%04d %02d:%02d:%02d +0000",
 125                                 $mday, $year+1900, $hour, $min, $sec);
 126 }
 127
 128 our $REPLY_RE = qr/^re:\s+/i;
 129
 130 sub subject_normalized ($) {
 131         my ($subj) = @_;
 132         $subj =~ s/\A\s+//s; # no leading space
 133         $subj =~ s/\s+\z//s; # no trailing space
 134         $subj =~ s/\s+/ /gs; # no redundant spaces
 135         $subj =~ s/\.+\z//; # no trailing '.'
 136         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 137         $subj;
 138 }
 139
 140 1;