lib/PublicInbox/Smsg.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # A small/skeleton/slim representation of a message.
   5
   6 # This used to be "SearchMsg", but we split out overview
   7 # indexing into over.sqlite3 so it's not just "search".  There
   8 # may be many of these objects loaded in memory at once for
   9 # large threads in our WWW UI and the NNTP range responses.
  10 package PublicInbox::Smsg;
  11 use strict;
  12 use warnings;
  13 use base qw(Exporter);
  14 our @EXPORT_OK = qw(subject_normalized);
  15 use PublicInbox::MID qw(mids);
  16 use PublicInbox::Address;
  17 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  18 use Time::Local qw(timegm);
  19
  20 sub get_val ($$) {
  21         my ($doc, $col) = @_;
  22         # sortable_unserialise is defined by PublicInbox::Search::load_xapian()
  23         sortable_unserialise($doc->get_value($col));
  24 }
  25
  26 sub to_doc_data {
  27         my ($self) = @_;
  28         join("\n",
  29                 $self->{subject},
  30                 $self->{from},
  31                 $self->{references} // '',
  32                 $self->{to},
  33                 $self->{cc},
  34                 $self->{blob},
  35                 $self->{mid},
  36                 $self->{bytes} // '',
  37                 $self->{lines} // ''
  38         );
  39 }
  40
  41 sub load_from_data ($$) {
  42         my ($self) = $_[0]; # data = $_[1]
  43         utf8::decode($_[1]);
  44         (
  45                 $self->{subject},
  46                 $self->{from},
  47                 $self->{references},
  48
  49                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  50                 # some NNTP clients will use that for message displays.
  51                 # NNTP only, and only stored in Over(view), not Xapian
  52                 $self->{to},
  53                 $self->{cc},
  54
  55                 $self->{blob},
  56                 $self->{mid},
  57
  58                 # NNTP only
  59                 $self->{bytes},
  60                 $self->{lines}
  61         ) = split(/\n/, $_[1]);
  62 }
  63
  64 sub load_expand {
  65         my ($self, $doc) = @_;
  66         my $data = $doc->get_data or return;
  67         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  68         my $dt = get_val($doc, PublicInbox::Search::DT());
  69         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  70         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  71         load_from_data($self, $data);
  72         $self;
  73 }
  74
  75 sub psgi_cull ($) {
  76         my ($self) = @_;
  77
  78         # ghosts don't have ->{from}
  79         my $from = delete($self->{from}) // '';
  80         my @n = PublicInbox::Address::names($from);
  81         $self->{from_name} = join(', ', @n);
  82
  83         # drop NNTP-only fields which aren't relevant to PSGI results:
  84         # saves ~80K on a 200 item search result:
  85         # TODO: we may need to keep some of these for JMAP...
  86         delete @$self{qw(tid to cc bytes lines)};
  87         $self;
  88 }
  89
  90 # for Import and v1 non-SQLite WWW code paths
  91 sub populate {
  92         my ($self, $hdr, $sync) = @_;
  93         for my $f (qw(From To Cc Subject)) {
  94                 my @all = $hdr->header($f);
  95                 my $val = join(', ', @all);
  96                 $val =~ tr/\r//d;
  97                 # MIME decoding can create NULs, replace them with spaces
  98                 # to protect git and NNTP clients
  99                 $val =~ tr/\0\t\n/   /;
 100
 101                 # rare: in case headers have wide chars (not RFC2047-encoded)
 102                 utf8::decode($val);
 103
 104                 # lower-case fields for read-only stuff
 105                 $self->{lc($f)} = $val;
 106
 107                 # Capitalized From/Subject for git-fast-import
 108                 next if $f eq 'To' || $f eq 'Cc';
 109                 if (scalar(@all) > 1) {
 110                         $val = $all[0];
 111                         $val =~ tr/\r//d;
 112                         $val =~ tr/\0\t\n/   /;
 113                 }
 114                 $self->{$f} = $val if $val ne '';
 115         }
 116         $sync //= {};
 117         $self->{-ds} = [ my @ds = msg_datestamp($hdr, $sync->{autime}) ];
 118         $self->{-ts} = [ my @ts = msg_timestamp($hdr, $sync->{cotime}) ];
 119         $self->{ds} //= $ds[0]; # no zone
 120         $self->{ts} //= $ts[0];
 121
 122         # for v1 users w/o SQLite
 123         $self->{mid} //= eval { mids($hdr)->[0] } // '';
 124 }
 125
 126 # no strftime, that is locale-dependent and not for RFC822
 127 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 128 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 129
 130 sub date ($) { # for NNTP
 131         my ($self) = @_;
 132         my $ds = $self->{ds};
 133         return unless defined $ds;
 134         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 135         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 136                                 $mday, $year+1900, $hour, $min, $sec);
 137 }
 138
 139 sub internaldate { # for IMAP
 140         my ($self) = @_;
 141         my ($sec, $min, $hour, $mday, $mon, $year) = gmtime($self->{ts} // 0);
 142         sprintf("%02d-$MoY[$mon]-%04d %02d:%02d:%02d +0000",
 143                                 $mday, $year+1900, $hour, $min, $sec);
 144 }
 145
 146 our $REPLY_RE = qr/^re:\s+/i;
 147
 148 sub subject_normalized ($) {
 149         my ($subj) = @_;
 150         $subj =~ s/\A\s+//s; # no leading space
 151         $subj =~ s/\s+\z//s; # no trailing space
 152         $subj =~ s/\s+/ /gs; # no redundant spaces
 153         $subj =~ s/\.+\z//; # no trailing '.'
 154         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 155         $subj;
 156 }
 157
 158 1;