lib/PublicInbox/SpawnPP.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Pure-Perl implementation of "spawn".  This can't take advantage
   5 # of vfork, so no speedups under Linux for spawning from large processes.
   6 package PublicInbox::SpawnPP;
   7 use strict;
   8 use v5.10.1;
   9 use POSIX qw(dup2 _exit setpgid :signal_h);
  10
  11 # Pure Perl implementation for folks that do not use Inline::C
  12 sub pi_fork_exec ($$$$$$$) {
  13         my ($redir, $f, $cmd, $env, $rlim, $cd, $pgid) = @_;
  14         my $old = POSIX::SigSet->new();
  15         my $set = POSIX::SigSet->new();
  16         $set->fillset or die "fillset failed: $!";
  17         sigprocmask(SIG_SETMASK, $set, $old) or die "can't block signals: $!";
  18         my $syserr;
  19         my $pid = fork;
  20         unless (defined $pid) { # compat with Inline::C version
  21                 $syserr = $!;
  22                 $pid = -1;
  23         }
  24         if ($pid == 0) {
  25                 for my $child_fd (0..$#$redir) {
  26                         my $parent_fd = $redir->[$child_fd];
  27                         next if $parent_fd == $child_fd;
  28                         dup2($parent_fd, $child_fd) or
  29                                 die "dup2($parent_fd, $child_fd): $!\n";
  30                 }
  31                 if ($pgid >= 0 && !defined(setpgid(0, $pgid))) {
  32                         warn "setpgid: $!";
  33                         _exit(1);
  34                 }
  35                 $SIG{$_} = 'DEFAULT' for keys %SIG;
  36                 if ($cd ne '') {
  37                         chdir $cd or die "chdir $cd: $!";
  38                 }
  39                 while (@$rlim) {
  40                         my ($r, $soft, $hard) = splice(@$rlim, 0, 3);
  41                         BSD::Resource::setrlimit($r, $soft, $hard) or
  42                           warn "failed to set $r=[$soft,$hard]\n";
  43                 }
  44                 $old->delset(POSIX::SIGCHLD) or die "delset SIGCHLD: $!";
  45                 sigprocmask(SIG_SETMASK, $old) or die "SETMASK: ~SIGCHLD: $!";
  46                 if ($ENV{MOD_PERL}) {
  47                         exec which('env'), '-i', @$env, @$cmd;
  48                         die "exec env -i ... $cmd->[0] failed: $!\n";
  49                 } else {
  50                         local %ENV = map { split(/=/, $_, 2) } @$env;
  51                         my @cmd = @$cmd;
  52                         $cmd[0] = $f;
  53                         exec @cmd;
  54                         die "exec $cmd->[0] failed: $!\n";
  55                 }
  56         }
  57         sigprocmask(SIG_SETMASK, $old) or die "can't unblock signals: $!";
  58         $! = $syserr;
  59         $pid;
  60 }
  61
  62 1;