lib/PublicInbox/Syscall.pm

   1 # This is a fork of the (for now) unmaintained Sys::Syscall 0.25,
   2 # specifically the Debian libsys-syscall-perl 0.25-6 version to
   3 # fix upstream regressions in 0.25.
   4 #
   5 # This license differs from the rest of public-inbox
   6 #
   7 # This module is Copyright (c) 2005 Six Apart, Ltd.
   8 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   9 #
  10 # All rights reserved.
  11 #
  12 # You may distribute under the terms of either the GNU General Public
  13 # License or the Artistic License, as specified in the Perl README file.
  14 package PublicInbox::Syscall;
  15 use strict;
  16 use parent qw(Exporter);
  17 use POSIX qw(ENOSYS O_NONBLOCK);
  18 use Config;
  19
  20 # $VERSION = '0.25'; # Sys::Syscall version
  21 our @EXPORT_OK = qw(epoll_ctl epoll_create epoll_wait
  22                   EPOLLIN EPOLLOUT EPOLLET
  23                   EPOLL_CTL_ADD EPOLL_CTL_DEL EPOLL_CTL_MOD
  24                   EPOLLONESHOT EPOLLEXCLUSIVE
  25                   signalfd $SFD_NONBLOCK);
  26 our %EXPORT_TAGS = (epoll => [qw(epoll_ctl epoll_create epoll_wait
  27                              EPOLLIN EPOLLOUT
  28                              EPOLL_CTL_ADD EPOLL_CTL_DEL EPOLL_CTL_MOD
  29                              EPOLLONESHOT EPOLLEXCLUSIVE)],
  30                 );
  31
  32 use constant {
  33         EPOLLIN => 1,
  34         EPOLLOUT => 4,
  35         # EPOLLERR => 8,
  36         # EPOLLHUP => 16,
  37         # EPOLLRDBAND => 128,
  38         EPOLLEXCLUSIVE => (1 << 28),
  39         EPOLLONESHOT => (1 << 30),
  40         EPOLLET => (1 << 31),
  41         EPOLL_CTL_ADD => 1,
  42         EPOLL_CTL_DEL => 2,
  43         EPOLL_CTL_MOD => 3,
  44 };
  45
  46 our $loaded_syscall = 0;
  47
  48 sub _load_syscall {
  49     # props to Gaal for this!
  50     return if $loaded_syscall++;
  51     my $clean = sub {
  52         delete @INC{qw<syscall.ph asm/unistd.ph bits/syscall.ph
  53                         _h2ph_pre.ph sys/syscall.ph>};
  54     };
  55     $clean->(); # don't trust modules before us
  56     my $rv = eval { require 'syscall.ph'; 1 } || eval { require 'sys/syscall.ph'; 1 };
  57     $clean->(); # don't require modules after us trust us
  58     return $rv;
  59 }
  60
  61
  62 our (
  63      $SYS_epoll_create,
  64      $SYS_epoll_ctl,
  65      $SYS_epoll_wait,
  66      $SYS_signalfd4,
  67      );
  68
  69 my $SFD_CLOEXEC = 02000000; # Perl does not expose O_CLOEXEC
  70 our $SFD_NONBLOCK = O_NONBLOCK;
  71 our $no_deprecated = 0;
  72
  73 if ($^O eq "linux") {
  74     my $machine = (POSIX::uname())[-1];
  75     # whether the machine requires 64-bit numbers to be on 8-byte
  76     # boundaries.
  77     my $u64_mod_8 = 0;
  78
  79     # if we're running on an x86_64 kernel, but a 32-bit process,
  80     # we need to use the x32 or i386 syscall numbers.
  81     if ($machine eq "x86_64" && $Config{ptrsize} == 4) {
  82         $machine = $Config{cppsymbols} =~ /\b__ILP32__=1\b/ ? 'x32' : 'i386';
  83     }
  84
  85     # Similarly for mips64 vs mips
  86     if ($machine eq "mips64" && $Config{ptrsize} == 4) {
  87         $machine = "mips";
  88     }
  89
  90     if ($machine =~ m/^i[3456]86$/) {
  91         $SYS_epoll_create = 254;
  92         $SYS_epoll_ctl    = 255;
  93         $SYS_epoll_wait   = 256;
  94         $SYS_signalfd4 = 327;
  95     } elsif ($machine eq "x86_64") {
  96         $SYS_epoll_create = 213;
  97         $SYS_epoll_ctl    = 233;
  98         $SYS_epoll_wait   = 232;
  99         $SYS_signalfd4 = 289;
 100     } elsif ($machine eq 'x32') {
 101         $SYS_epoll_create = 1073742037;
 102         $SYS_epoll_ctl = 1073742057;
 103         $SYS_epoll_wait = 1073742056;
 104         $SYS_signalfd4 = 1073742113;
 105     } elsif ($machine eq 'sparc64') {
 106         $SYS_epoll_create = 193;
 107         $SYS_epoll_ctl = 194;
 108         $SYS_epoll_wait = 195;
 109         $u64_mod_8 = 1;
 110         $SYS_signalfd4 = 317;
 111         $SFD_CLOEXEC = 020000000;
 112     } elsif ($machine =~ m/^parisc/) {
 113         $SYS_epoll_create = 224;
 114         $SYS_epoll_ctl    = 225;
 115         $SYS_epoll_wait   = 226;
 116         $u64_mod_8        = 1;
 117         $SYS_signalfd4 = 309;
 118     } elsif ($machine =~ m/^ppc64/) {
 119         $SYS_epoll_create = 236;
 120         $SYS_epoll_ctl    = 237;
 121         $SYS_epoll_wait   = 238;
 122         $u64_mod_8        = 1;
 123         $SYS_signalfd4 = 313;
 124     } elsif ($machine eq "ppc") {
 125         $SYS_epoll_create = 236;
 126         $SYS_epoll_ctl    = 237;
 127         $SYS_epoll_wait   = 238;
 128         $u64_mod_8        = 1;
 129         $SYS_signalfd4 = 313;
 130     } elsif ($machine =~ m/^s390/) {
 131         $SYS_epoll_create = 249;
 132         $SYS_epoll_ctl    = 250;
 133         $SYS_epoll_wait   = 251;
 134         $u64_mod_8        = 1;
 135         $SYS_signalfd4 = 322;
 136     } elsif ($machine eq "ia64") {
 137         $SYS_epoll_create = 1243;
 138         $SYS_epoll_ctl    = 1244;
 139         $SYS_epoll_wait   = 1245;
 140         $u64_mod_8        = 1;
 141         $SYS_signalfd4 = 289;
 142     } elsif ($machine eq "alpha") {
 143         # natural alignment, ints are 32-bits
 144         $SYS_epoll_create = 407;
 145         $SYS_epoll_ctl    = 408;
 146         $SYS_epoll_wait   = 409;
 147         $u64_mod_8        = 1;
 148         $SYS_signalfd4 = 484;
 149         $SFD_CLOEXEC = 010000000;
 150     } elsif ($machine eq "aarch64") {
 151         $SYS_epoll_create = 20;  # (sys_epoll_create1)
 152         $SYS_epoll_ctl    = 21;
 153         $SYS_epoll_wait   = 22;  # (sys_epoll_pwait)
 154         $u64_mod_8        = 1;
 155         $no_deprecated    = 1;
 156         $SYS_signalfd4 = 74;
 157     } elsif ($machine =~ m/arm(v\d+)?.*l/) {
 158         # ARM OABI
 159         $SYS_epoll_create = 250;
 160         $SYS_epoll_ctl    = 251;
 161         $SYS_epoll_wait   = 252;
 162         $u64_mod_8        = 1;
 163         $SYS_signalfd4 = 355;
 164     } elsif ($machine =~ m/^mips64/) {
 165         $SYS_epoll_create = 5207;
 166         $SYS_epoll_ctl    = 5208;
 167         $SYS_epoll_wait   = 5209;
 168         $u64_mod_8        = 1;
 169         $SYS_signalfd4 = 5283;
 170     } elsif ($machine =~ m/^mips/) {
 171         $SYS_epoll_create = 4248;
 172         $SYS_epoll_ctl    = 4249;
 173         $SYS_epoll_wait   = 4250;
 174         $u64_mod_8        = 1;
 175         $SYS_signalfd4 = 4324;
 176     } else {
 177         # as a last resort, try using the *.ph files which may not
 178         # exist or may be wrong
 179         _load_syscall();
 180         $SYS_epoll_create = eval { &SYS_epoll_create; } || 0;
 181         $SYS_epoll_ctl    = eval { &SYS_epoll_ctl;    } || 0;
 182         $SYS_epoll_wait   = eval { &SYS_epoll_wait;   } || 0;
 183
 184         # Note: do NOT add new syscalls to depend on *.ph, here.
 185         # Better to miss syscalls (so we can fallback to IO::Poll)
 186         # than to use wrong ones, since the names are not stable
 187         # (at least not on FreeBSD), if the actual numbers are.
 188     }
 189
 190     if ($u64_mod_8) {
 191         *epoll_wait = \&epoll_wait_mod8;
 192         *epoll_ctl = \&epoll_ctl_mod8;
 193     } else {
 194         *epoll_wait = \&epoll_wait_mod4;
 195         *epoll_ctl = \&epoll_ctl_mod4;
 196     }
 197 }
 198
 199 elsif ($^O eq "freebsd") {
 200     if ($ENV{FREEBSD_SENDFILE}) {
 201         # this is still buggy and in development
 202     }
 203 }
 204
 205 ############################################################################
 206 # epoll functions
 207 ############################################################################
 208
 209 sub epoll_defined { return $SYS_epoll_create ? 1 : 0; }
 210
 211 sub epoll_create {
 212         syscall($SYS_epoll_create, $no_deprecated ? 0 : ($_[0]||100)+0);
 213 }
 214
 215 # epoll_ctl wrapper
 216 # ARGS: (epfd, op, fd, events_mask)
 217 sub epoll_ctl_mod4 {
 218     syscall($SYS_epoll_ctl, $_[0]+0, $_[1]+0, $_[2]+0, pack("LLL", $_[3], $_[2], 0));
 219 }
 220 sub epoll_ctl_mod8 {
 221     syscall($SYS_epoll_ctl, $_[0]+0, $_[1]+0, $_[2]+0, pack("LLLL", $_[3], 0, $_[2], 0));
 222 }
 223
 224 # epoll_wait wrapper
 225 # ARGS: (epfd, maxevents, timeout (milliseconds), arrayref)
 226 #  arrayref: values modified to be [$fd, $event]
 227 our $epoll_wait_events;
 228 our $epoll_wait_size = 0;
 229 sub epoll_wait_mod4 {
 230     # resize our static buffer if requested size is bigger than we've ever done
 231     if ($_[1] > $epoll_wait_size) {
 232         $epoll_wait_size = $_[1];
 233         $epoll_wait_events = "\0" x 12 x $epoll_wait_size;
 234     }
 235     my $ct = syscall($SYS_epoll_wait, $_[0]+0, $epoll_wait_events, $_[1]+0, $_[2]+0);
 236     for (0..$ct-1) {
 237         @{$_[3]->[$_]}[1,0] = unpack("LL", substr($epoll_wait_events, 12*$_, 8));
 238     }
 239     return $ct;
 240 }
 241
 242 sub epoll_wait_mod8 {
 243     # resize our static buffer if requested size is bigger than we've ever done
 244     if ($_[1] > $epoll_wait_size) {
 245         $epoll_wait_size = $_[1];
 246         $epoll_wait_events = "\0" x 16 x $epoll_wait_size;
 247     }
 248     my $ct;
 249     if ($no_deprecated) {
 250         $ct = syscall($SYS_epoll_wait, $_[0]+0, $epoll_wait_events, $_[1]+0, $_[2]+0, undef);
 251     } else {
 252         $ct = syscall($SYS_epoll_wait, $_[0]+0, $epoll_wait_events, $_[1]+0, $_[2]+0);
 253     }
 254     for (0..$ct-1) {
 255         # 16 byte epoll_event structs, with format:
 256         #    4 byte mask [idx 1]
 257         #    4 byte padding (we put it into idx 2, useless)
 258         #    8 byte data (first 4 bytes are fd, into idx 0)
 259         @{$_[3]->[$_]}[1,2,0] = unpack("LLL", substr($epoll_wait_events, 16*$_, 12));
 260     }
 261     return $ct;
 262 }
 263
 264 sub signalfd ($$$) {
 265         my ($fd, $signos, $flags) = @_;
 266         if ($SYS_signalfd4) {
 267                 my $set = POSIX::SigSet->new(@$signos);
 268                 syscall($SYS_signalfd4, $fd, "$$set",
 269                         # $Config{sig_count} is NSIG, so this is NSIG/8:
 270                         int($Config{sig_count}/8),
 271                         $flags|$SFD_CLOEXEC);
 272         } else {
 273                 $! = ENOSYS;
 274                 undef;
 275         }
 276 }
 277
 278 1;
 279
 280 =head1 WARRANTY
 281
 282 This is free software. IT COMES WITHOUT WARRANTY OF ANY KIND.
 283
 284 =head1 AUTHORS
 285
 286 Brad Fitzpatrick <brad@danga.com>