lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use v5.10.1;
   9 use List::Util qw(max);
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href
  12                         ts2str fmt_ts);
  13 use PublicInbox::Linkify;
  14 use PublicInbox::MID qw(id_compress mids mids_for_index references
  15                         $MID_EXTRACT);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::Address;
  18 use PublicInbox::WwwStream qw(html_oneshot);
  19 use PublicInbox::Reply;
  20 use PublicInbox::ViewDiff qw(flush_diff);
  21 use PublicInbox::Eml;
  22 use Time::Local qw(timegm);
  23 use PublicInbox::Smsg qw(subject_normalized);
  24 use PublicInbox::ContentHash qw(content_hash);
  25 use constant COLS => 72;
  26 use constant INDENT => '  ';
  27 use constant TCHILD => '` ';
  28 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  29
  30 sub msg_page_i {
  31         my ($ctx, $eml) = @_;
  32         if ($eml) { # called by WwwStream::async_eml or getline
  33                 my $smsg = $ctx->{smsg};
  34                 my $over = $ctx->{ibx}->over;
  35                 $ctx->{smsg} = $over ? $over->next_by_mid(@{$ctx->{next_arg}})
  36                                 : $ctx->gone('over');
  37                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  38                                 "../${\mid_href($smsg->{mid})}/" : '';
  39                 my $obuf = $ctx->{obuf} = _msg_page_prepare_obuf($eml, $ctx);
  40                 if (length($$obuf)) {
  41                         multipart_text_as_html($eml, $ctx);
  42                         $$obuf .= '</pre><hr>';
  43                 }
  44                 delete $ctx->{obuf};
  45                 $$obuf .= html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  46                 $$obuf;
  47         } else { # called by WwwStream::async_next or getline
  48                 $ctx->{smsg}; # may be undef
  49         }
  50 }
  51
  52 # /$INBOX/$MSGID/ for unindexed v1 inboxes
  53 sub no_over_html ($) {
  54         my ($ctx) = @_;
  55         my $bref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return; # 404
  56         my $eml = PublicInbox::Eml->new($bref);
  57         $ctx->{mhref} = '';
  58         PublicInbox::WwwStream::init($ctx);
  59         my $obuf = $ctx->{obuf} = _msg_page_prepare_obuf($eml, $ctx);
  60         if (length($$obuf)) {
  61                 multipart_text_as_html($eml, $ctx);
  62                 $$obuf .= '</pre><hr>';
  63         }
  64         delete $ctx->{obuf};
  65         eval { $$obuf .= html_footer($ctx, $eml) };
  66         html_oneshot($ctx, 200, $obuf);
  67 }
  68
  69 # public functions: (unstable)
  70
  71 sub msg_page {
  72         my ($ctx) = @_;
  73         my $ibx = $ctx->{ibx};
  74         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  75         my $over = $ibx->over or return no_over_html($ctx);
  76         my ($id, $prev);
  77         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  78
  79         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$next_arg) or
  80                 return; # undef == 404
  81
  82         # allow user to easily browse the range around this message if
  83         # they have ->over
  84         $ctx->{-t_max} = $smsg->{ts};
  85         PublicInbox::WwwStream::aresponse($ctx, 200, \&msg_page_i);
  86 }
  87
  88 # /$INBOX/$MESSAGE_ID/#R
  89 sub msg_reply ($$) {
  90         my ($ctx, $hdr) = @_;
  91         my $se_url =
  92          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  93         my $p_url =
  94          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  95
  96         my $info = '';
  97         my $ibx = $ctx->{ibx};
  98         if (my $url = $ibx->{infourl}) {
  99                 $url = prurl($ctx->{env}, $url);
 100                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 101         }
 102
 103         my ($arg, $link, $reply_to_all) =
 104                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 105         if (ref($arg) eq 'SCALAR') {
 106                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 107         }
 108
 109         # mailto: link only works if address obfuscation is disabled
 110         if ($link) {
 111                 $link = <<EOF;
 112
 113 * If your mail client supports setting the <b>In-Reply-To</b> header
 114   via mailto: links, try the <a
 115 href="$link">mailto: link</a>
 116 EOF
 117         }
 118
 119         push @$arg, '/path/to/YOUR_REPLY';
 120         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 121         <<EOF
 122 <hr><pre
 123 id=R><b>Reply instructions:</b>
 124
 125 You may reply publicly to <a
 126 href=#t>this message</a> via plain-text email
 127 using any one of the following methods:
 128
 129 * Save the following mbox file, import it into your mail client,
 130   and $reply_to_all from there: <a
 131 href=raw>mbox</a>
 132
 133   Avoid top-posting and favor interleaved quoting:
 134   <a
 135 href="$p_url">$p_url</a>
 136 $info
 137 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 138   switches of git-send-email(1):
 139
 140   git send-email$arg
 141
 142   <a
 143 href="$se_url">$se_url</a>
 144 $link</pre>
 145 EOF
 146 }
 147
 148 sub in_reply_to {
 149         my ($hdr) = @_;
 150         my $refs = references($hdr);
 151         $refs->[-1];
 152 }
 153
 154 sub fold_addresses ($) {
 155         return $_[0] if length($_[0]) <= COLS;
 156         # try to fold on commas after non-word chars before $lim chars,
 157         # Try to get the "," preceded by ">" or ")", but avoid folding
 158         # on the comma where somebody uses "Lastname, Firstname".
 159         # We also try to keep the last and penultimate addresses in
 160         # the list on the same line if possible, hence the extra \z
 161         # Fall back to folding on spaces at $lim + 1 chars
 162         my $lim = COLS - 8; # 8 = "\t" display width
 163         my $too_long = $lim + 1;
 164         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 165         $_[0] = join("\n\t",
 166                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 167                                 .{1,$lim}(?:,|\z)|
 168                                 .{1,$lim}|
 169                                 .{$too_long,}?)(?:\s|\z)/xgo));
 170 }
 171
 172 sub _hdr_names_html ($$) {
 173         my ($hdr, $field) = @_;
 174         my @vals = $hdr->header($field) or return '';
 175         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 176 }
 177
 178 sub nr_to_s ($$$) {
 179         my ($nr, $singular, $plural) = @_;
 180         return "0 $plural" if $nr == 0;
 181         $nr == 1 ? "$nr $singular" : "$nr $plural";
 182 }
 183
 184 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 185 # this is already inside a <pre>
 186 sub eml_entry {
 187         my ($ctx, $eml) = @_;
 188         my $smsg = delete $ctx->{smsg};
 189         my $subj = delete $smsg->{subject};
 190         my $mid_raw = $smsg->{mid};
 191         my $id = id_compress($mid_raw, 1);
 192         my $id_m = 'm'.$id;
 193         my $root_anchor = $ctx->{root_anchor} || '';
 194         my $irt;
 195         my $obfs_ibx = $ctx->{-obfs_ibx};
 196
 197         $subj = '(no subject)' if $subj eq '';
 198         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 199         $subj = '<b>'.ascii_html($subj).'</b>';
 200         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 201         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 202         $rv .= $subj . "\n";
 203         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 204         my @tocc;
 205         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 206
 207         # Deleting these fields saves about 400K as we iterate across 1K msgs
 208         delete @$smsg{qw(ts blob)};
 209
 210         my $from = _hdr_names_html($eml, 'From');
 211         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 212         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 213         my $upfx = $ctx->{-upfx};
 214         my $mhref = $upfx . mid_href($mid_raw) . '/';
 215         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 216         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 217         my $to = fold_addresses(_hdr_names_html($eml, 'To'));
 218         my $cc = fold_addresses(_hdr_names_html($eml, 'Cc'));
 219         my ($tlen, $clen) = (length($to), length($cc));
 220         my $to_cc = '';
 221         if (($tlen + $clen) > COLS) {
 222                 $to_cc .= '  To: '.$to."\n" if $tlen;
 223                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 224         } else {
 225                 if ($tlen) {
 226                         $to_cc .= '  To: '.$to;
 227                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 228                 } else {
 229                         $to_cc .= '  Cc: '.$cc if $clen;
 230                 }
 231                 $to_cc .= "\n";
 232         }
 233         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 234         $rv .= $to_cc;
 235
 236         my $mapping = $ctx->{mapping};
 237         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($eml)))) {
 238                 my $href = $upfx . mid_href($irt) . '/';
 239                 my $html = ascii_html($irt);
 240                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 241         }
 242         $rv .= "\n";
 243
 244         # scan through all parts, looking for displayable text
 245         $ctx->{mhref} = $mhref;
 246         $ctx->{obuf} = \$rv;
 247         $eml->each_part(\&add_text_body, $ctx, 1);
 248         delete $ctx->{obuf};
 249
 250         # add the footer
 251         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 252                 "<a\nhref=\"$mhref\">permalink</a>" .
 253                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 254                 " <a\nhref=\"${mhref}#R\">reply</a>";
 255
 256         my $hr;
 257         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 258                 $rv .= "\t[relevance $pct%]";
 259                 $hr = 1;
 260         } elsif ($mapping) {
 261                 my $nested = 'nested';
 262                 my $flat = 'flat';
 263                 my $end = '';
 264                 if ($ctx->{flat}) {
 265                         $hr = 1;
 266                         $flat = "<b>$flat</b>";
 267                 } else {
 268                         $nested = "<b>$nested</b>";
 269                 }
 270                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 271                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 272                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 273         } else {
 274                 $hr = $ctx->{-hr};
 275         }
 276
 277         # do we have more messages? start a new <pre> if so
 278         $rv .= scalar(@{$ctx->{msgs}}) ? '</pre><hr><pre>' : '</pre>' if $hr;
 279         $rv;
 280 }
 281
 282 sub pad_link ($$;$) {
 283         my ($mid, $level, $s) = @_;
 284         $s ||= '...';
 285         my $href = defined($mid) ?
 286                 ("<a\nhref=#r".id_compress($mid, 1).">($s)</a>\n") :
 287                 "($s)\n";
 288         (' 'x19).indent_for($level).th_pfx($level).$href;
 289 }
 290
 291 sub _skel_hdr {
 292         # my ($mapping, $mid) = @_;
 293         ($_[0]->{$_[1] // \'bogus'} // [ "(?)\n" ])->[0];
 294 }
 295
 296 sub _th_index_lite {
 297         my ($mid_raw, $irt, $id, $ctx) = @_;
 298         my $rv = '';
 299         my $mapping = $ctx->{mapping} or return $rv;
 300         my $pad = '  ';
 301         my $mid_map = $mapping->{$mid_raw};
 302         defined $mid_map or
 303                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 304         my ($attr, $node, $idx, $level) = @$mid_map;
 305         my $children = $node->{children};
 306         my $nr_c = scalar @$children;
 307         my $nr_s = 0;
 308         my $siblings;
 309         # delete saves about 200KB on a 1K message thread
 310         if (my $refs = delete $node->{references}) {
 311                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 312         }
 313         my $irt_map = $mapping->{$$irt} if defined $$irt;
 314         if (defined $irt_map) {
 315                 $siblings = $irt_map->[1]->{children};
 316                 $nr_s = scalar(@$siblings) - 1;
 317                 $rv .= $pad . $irt_map->[0];
 318                 if ($idx > 0) {
 319                         my $prev = $siblings->[$idx - 1];
 320                         my $pmid = $prev->{mid};
 321                         if ($idx > 2) {
 322                                 my $s = ($idx - 1). ' preceding siblings ...';
 323                                 $rv .= pad_link($pmid, $level, $s);
 324                         } elsif ($idx == 2) {
 325                                 $rv .= $pad . _skel_hdr($mapping,
 326                                                 $siblings->[0] ?
 327                                                 $siblings->[0]->{mid} : undef);
 328                         }
 329                         $rv .= $pad . _skel_hdr($mapping, $pmid);
 330                 }
 331         }
 332         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 333         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 334         $attr =~ s!\n\z!</b>\n!s;
 335         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 336         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 337         $rv .= "<b>@ $attr";
 338         if ($nr_c) {
 339                 my $cmid = $children->[0] ? $children->[0]->{mid} : undef;
 340                 $rv .= $pad . _skel_hdr($mapping, $cmid);
 341                 if ($nr_c > 2) {
 342                         my $s = ($nr_c - 1). ' more replies';
 343                         $rv .= pad_link($cmid, $level + 1, $s);
 344                 } elsif (my $cn = $children->[1]) {
 345                         $rv .= $pad . _skel_hdr($mapping, $cn->{mid});
 346                 }
 347         }
 348
 349         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 350         if ($next) {
 351                 my $nmid = $next->{mid};
 352                 $rv .= $pad . _skel_hdr($mapping, $nmid);
 353                 my $nnext = $nr_s - $idx;
 354                 if ($nnext > 2) {
 355                         my $s = ($nnext - 1).' subsequent siblings';
 356                         $rv .= pad_link($nmid, $level, $s);
 357                 } elsif (my $nn = $siblings->[$idx + 2]) {
 358                         $rv .= $pad . _skel_hdr($mapping, $nn->{mid});
 359                 }
 360         }
 361         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 362 }
 363
 364 # non-recursive thread walker
 365 sub walk_thread ($$$) {
 366         my ($rootset, $ctx, $cb) = @_;
 367         my @q = map { (0, $_, -1) } @$rootset;
 368         while (@q) {
 369                 my ($level, $node, $i) = splice(@q, 0, 3);
 370                 defined $node or next;
 371                 $cb->($ctx, $level, $node, $i) or return;
 372                 ++$level;
 373                 $i = 0;
 374                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 375         }
 376 }
 377
 378 sub pre_thread  { # walk_thread callback
 379         my ($ctx, $level, $node, $idx) = @_;
 380         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 381         skel_dump($ctx, $level, $node);
 382 }
 383
 384 sub thread_eml_entry {
 385         my ($ctx, $eml) = @_;
 386         my ($beg, $end) = thread_adj_level($ctx, $ctx->{level});
 387         $beg . '<pre>' . eml_entry($ctx, $eml) . '</pre>' . $end;
 388 }
 389
 390 sub next_in_queue ($$) {
 391         my ($q, $ghost_ok) = @_;
 392         while (@$q) {
 393                 my ($level, $smsg) = splice(@$q, 0, 2);
 394                 my $cl = $level + 1;
 395                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 396                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 397         }
 398         undef;
 399 }
 400
 401 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 402         my ($ctx, $eml) = @_;
 403         return thread_eml_entry($ctx, $eml) if $eml;
 404         return unless exists($ctx->{skel});
 405         my $ghost_ok = $ctx->{nr}++;
 406         while (1) {
 407                 my ($lvl, $smsg) = next_in_queue($ctx->{-queue}, $ghost_ok);
 408                 if ($smsg) {
 409                         if (exists $smsg->{blob}) { # next message for cat-file
 410                                 $ctx->{level} = $lvl;
 411                                 if (!$ghost_ok) { # first non-ghost
 412                                         $ctx->{-title_html} =
 413                                                 ascii_html($smsg->{subject});
 414                                         $ctx->zmore($ctx->html_top);
 415                                 }
 416                                 return $smsg;
 417                         }
 418                         # buffer the ghost entry and loop
 419                         $ctx->zmore(ghost_index_entry($ctx, $lvl, $smsg));
 420                 } else { # all done
 421                         $ctx->zmore(join('', thread_adj_level($ctx, 0)));
 422                         $ctx->zmore(${delete($ctx->{skel})});
 423                         return;
 424                 }
 425         }
 426 }
 427
 428 sub stream_thread ($$) {
 429         my ($rootset, $ctx) = @_;
 430         $ctx->{-queue} = [ map { (0, $_) } @$rootset ];
 431         PublicInbox::WwwStream::aresponse($ctx, 200, \&stream_thread_i);
 432 }
 433
 434 # /$INBOX/$MSGID/t/ and /$INBOX/$MSGID/T/
 435 sub thread_html {
 436         my ($ctx) = @_;
 437         $ctx->{-upfx} = '../../';
 438         my $mid = $ctx->{mid};
 439         my $ibx = $ctx->{ibx};
 440         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 441         return missing_thread($ctx) if $nr == 0;
 442
 443         # link $INBOX_DIR/description text to "index_topics" view around
 444         # the newest message in this thread
 445         my $t = ts2str($ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs));
 446         my $t_fmt = fmt_ts($ctx->{-t_max});
 447
 448         my $skel = '<hr><pre>';
 449         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 450         $skel .= <<EOF;
 451 , other threads:[<a
 452 href="../../?t=$t">~$t_fmt UTC</a> | <a
 453 href="../../">newest</a>]
 454
 455 EOF
 456         $skel .= "<b\nid=t>Thread overview:</b> ";
 457         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 458         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 459         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 460         $skel .= "-- links below jump to the message on this page --\n";
 461         $ctx->{cur_level} = 0;
 462         $ctx->{skel} = \$skel;
 463         $ctx->{prev_attr} = '';
 464         $ctx->{prev_level} = 0;
 465         $ctx->{root_anchor} = 'm' . id_compress($mid, 1);
 466         $ctx->{mapping} = {}; # mid -> [ header_summary, node, idx, level ]
 467         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 468                        .' in thread';
 469
 470         my $rootset = thread_results($ctx, $msgs);
 471
 472         # reduce hash lookups in pre_thread->skel_dump
 473         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 474         walk_thread($rootset, $ctx, \&pre_thread);
 475
 476         $skel .= '</pre>';
 477         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 478
 479         # flat display: lazy load the full message from smsg
 480         $ctx->{msgs} = $msgs;
 481         $ctx->{-html_tip} = '<pre>';
 482         PublicInbox::WwwStream::aresponse($ctx, 200, \&thread_html_i);
 483 }
 484
 485 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 486         my ($ctx, $eml) = @_;
 487         if ($eml) {
 488                 my $smsg = $ctx->{smsg};
 489                 if (exists $ctx->{-html_tip}) {
 490                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 491                         $ctx->zmore($ctx->html_top);
 492                 }
 493                 return eml_entry($ctx, $eml);
 494         } else {
 495                 while (my $smsg = shift @{$ctx->{msgs}}) {
 496                         return $smsg if exists($smsg->{blob});
 497                 }
 498                 my $skel = delete($ctx->{skel}) or return; # all done
 499                 $ctx->zmore($$skel);
 500                 undef;
 501         }
 502 }
 503
 504 sub multipart_text_as_html {
 505         # ($mime, $ctx) = @_; # each_part may do "$_[0] = undef"
 506
 507         # scan through all parts, looking for displayable text
 508         $_[0]->each_part(\&add_text_body, $_[1], 1);
 509 }
 510
 511 sub submsg_hdr ($$) {
 512         my ($ctx, $eml) = @_;
 513         my $obfs_ibx = $ctx->{-obfs_ibx};
 514         my $rv = $ctx->{obuf};
 515         $$rv .= "\n";
 516         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 517                 my @v = $eml->header($h);
 518                 for my $v (@v) {
 519                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 520                         $v = ascii_html($v);
 521                         $$rv .= "$h: $v\n";
 522                 }
 523         }
 524 }
 525
 526 sub attach_link ($$$$;$) {
 527         my ($ctx, $ct, $p, $fn, $err) = @_;
 528         my ($part, $depth, $idx) = @$p;
 529
 530         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 531         # downloads for 0-byte multipart attachments
 532         return unless $part->{bdy};
 533
 534         my $nl = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 535         my $size = length($part->body);
 536         delete $part->{bdy}; # save memory
 537
 538         # hide attributes normally, unless we want to aid users in
 539         # spotting MUA problems:
 540         $ct =~ s/;.*// unless $err;
 541         $ct = ascii_html($ct);
 542         my $sfn;
 543         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 544                 $sfn = $fn;
 545         } elsif ($ct eq 'text/plain') {
 546                 $sfn = 'a.txt';
 547         } else {
 548                 $sfn = 'a.bin';
 549         }
 550         my $rv = $ctx->{obuf};
 551         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 552         if ($err) {
 553                 $$rv .= <<EOF;
 554 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 555 EOF
 556         }
 557         $$rv .= "[-- Attachment #$idx: ";
 558         my $ts = "Type: $ct, Size: $size bytes";
 559         my $desc = $part->header('Content-Description') // $fn // '';
 560         $desc = ascii_html($desc);
 561         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 562         $$rv .= "</a>\n";
 563
 564         submsg_hdr($ctx, $part) if $part->{is_submsg};
 565
 566         undef;
 567 }
 568
 569 sub add_text_body { # callback for each_part
 570         my ($p, $ctx) = @_;
 571         my $upfx = $ctx->{mhref};
 572         my $ibx = $ctx->{ibx};
 573         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 574         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 575         my ($part, $depth, $idx) = @$p;
 576         my $ct = $part->content_type || 'text/plain';
 577         my $fn = $part->filename;
 578         my ($s, $err) = msg_part_text($part, $ct);
 579         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 580
 581         my $rv = $ctx->{obuf};
 582         if ($part->{is_submsg}) {
 583                 submsg_hdr($ctx, $part);
 584                 $$rv .= "\n";
 585         }
 586
 587         # makes no difference to browsers, and don't screw up filename
 588         # link generation in diffs with the extra '%0D'
 589         $s =~ s/\r\n/\n/sg;
 590
 591         # will be escaped to `&#8226;' in HTML
 592         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 593
 594         # always support diff-highlighting, but we can't linkify hunk
 595         # headers for solver unless some coderepo are configured:
 596         my $diff;
 597         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 598                 # diffstat anchors do not link across attachments or messages,
 599                 # -apfx is just a stable prefix for making diffstat anchors
 600                 # linkable to the first diff hunk w/o crossing attachments
 601                 $idx =~ tr!.!/!; # compatibility with previous versions
 602                 $ctx->{-apfx} = $upfx . $idx;
 603
 604                 # do attr => filename mappings for diffstats in git diffs:
 605                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 606                 $diff = 1;
 607                 delete $ctx->{-long_path};
 608                 my $spfx;
 609                 # absolute URL (Atom feeds)
 610                 if ($ibx->{coderepo}) {
 611                         if (index($upfx, '//') >= 0) {
 612                                 $spfx = $upfx;
 613                                 $spfx =~ s!/([^/]*)/\z!/!;
 614                         } else {
 615                                 my $n_slash = $upfx =~ tr!/!/!;
 616                                 if ($n_slash == 0) {
 617                                         $spfx = '../';
 618                                 } elsif ($n_slash == 1) {
 619                                         $spfx = '';
 620                                 } else { # nslash == 2
 621                                         $spfx = '../../';
 622                                 }
 623                         }
 624                 }
 625                 $ctx->{-spfx} = $spfx;
 626         };
 627
 628         # split off quoted and unquoted blocks:
 629         my @sections = PublicInbox::MsgIter::split_quotes($s);
 630         undef $s; # free memory
 631         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 632                 # badly-encoded message with $err? tell the world about it!
 633                 attach_link($ctx, $ct, $p, $fn, $err);
 634                 $$rv .= "\n";
 635         }
 636         delete $part->{bdy}; # save memory
 637         foreach my $cur (@sections) {
 638                 if ($cur =~ /\A>/) {
 639                         # we use a <span> here to allow users to specify
 640                         # their own color for quoted text
 641                         $$rv .= qq(<span\nclass="q">);
 642                         $$rv .= $l->to_html($cur);
 643                         $$rv .= '</span>';
 644                 } elsif ($diff) {
 645                         flush_diff($ctx, \$cur);
 646                 } else {
 647                         # regular lines, OK
 648                         $$rv .= $l->to_html($cur);
 649                 }
 650                 undef $cur; # free memory
 651         }
 652 }
 653
 654 sub _msg_page_prepare_obuf {
 655         my ($eml, $ctx) = @_;
 656         my $over = $ctx->{ibx}->over;
 657         my $obfs_ibx = $ctx->{-obfs_ibx};
 658         my $rv = '';
 659         my $mids = mids_for_index($eml);
 660         my $nr = $ctx->{nr}++;
 661         if ($nr) { # unlikely
 662                 if ($ctx->{chash} eq content_hash($eml)) {
 663                         warn "W: BUG? @$mids not deduplicated properly\n";
 664                         return \$rv;
 665                 }
 666                 $rv .=
 667 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 668                 $rv .= '<pre>';
 669         } else {
 670                 $ctx->{first_hdr} = $eml->header_obj;
 671                 $ctx->{chash} = content_hash($eml) if $ctx->{smsg}; # reused MID
 672                 $rv .= "<pre\nid=b>"; # anchor for body start
 673         }
 674         $ctx->{-upfx} = '../' if $over;
 675         my @title; # (Subject[0], From[0])
 676         for my $v ($eml->header('From')) {
 677                 my @n = PublicInbox::Address::names($v);
 678                 $v = ascii_html($v);
 679                 $title[1] //= ascii_html(join(', ', @n));
 680                 if ($obfs_ibx) {
 681                         obfuscate_addrs($obfs_ibx, $v);
 682                         obfuscate_addrs($obfs_ibx, $title[1]);
 683                 }
 684                 $rv .= "From: $v\n" if $v ne '';
 685         }
 686         foreach my $h (qw(To Cc)) {
 687                 for my $v ($eml->header($h)) {
 688                         fold_addresses($v);
 689                         $v = ascii_html($v);
 690                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 691                         $rv .= "$h: $v\n" if $v ne '';
 692                 }
 693         }
 694         my @subj = $eml->header('Subject');
 695         if (@subj) {
 696                 my $v = ascii_html(shift @subj);
 697                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 698                 $rv .= 'Subject: ';
 699                 $rv .= $over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 700                 $title[0] = $v;
 701                 for $v (@subj) { # multi-Subject message :<
 702                         $v = ascii_html($v);
 703                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 704                         $rv .= "Subject: $v\n";
 705                 }
 706         } else { # dummy anchor for thread skeleton at bottom of page
 707                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 708                 $title[0] = '(no subject)';
 709         }
 710         for my $v ($eml->header('Date')) {
 711                 $v = ascii_html($v);
 712                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 713                 $rv .= qq{Date: $v\t<a\nhref="#r">[thread overview]</a>\n};
 714         }
 715         if (!$nr) { # first (and only) message, common case
 716                 $ctx->{-title_html} = join(' - ', @title);
 717                 $rv = $ctx->html_top . $rv;
 718         }
 719         if (scalar(@$mids) == 1) { # common case
 720                 my $mhtml = ascii_html($mids->[0]);
 721                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 722                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 723         } else {
 724                 # X-Alt-Message-ID can happen if a message is injected from
 725                 # public-inbox-nntpd because of multiple Message-ID headers.
 726                 my $lnk = PublicInbox::Linkify->new;
 727                 my $s = '';
 728                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 729                         $s .= "$h: $_\n" for ($eml->header_raw($h));
 730                 }
 731                 $lnk->linkify_mids('..', \$s, 1);
 732                 $rv .= $s;
 733         }
 734         $rv .= _parent_headers($eml, $over);
 735         $rv .= "\n";
 736         \$rv;
 737 }
 738
 739 sub SKEL_EXPAND () {
 740         qq(expand[<a\nhref="T/#u">flat</a>) .
 741                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 742                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 743                 qq(<a\nhref="t.atom">Atom feed</a>);
 744 }
 745
 746 sub thread_skel ($$$) {
 747         my ($skel, $ctx, $hdr) = @_;
 748         my $mid = mids($hdr)->[0];
 749         my $ibx = $ctx->{ibx};
 750         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 751         my $parent = in_reply_to($hdr);
 752         $$skel .= "\n<b>Thread overview: </b>";
 753         if ($nr <= 1) {
 754                 if (defined $parent) {
 755                         $$skel .= SKEL_EXPAND."\n ";
 756                         $$skel .= ghost_parent('../', $parent) . "\n";
 757                 } else {
 758                         $$skel .= "<a\nid=r>[no followups]</a> ".
 759                                         SKEL_EXPAND."\n";
 760                 }
 761                 $ctx->{next_msg} = undef;
 762                 $ctx->{parent_msg} = $parent;
 763                 return;
 764         }
 765
 766         $$skel .= $nr;
 767         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 768
 769         # nb: mutt only shows the first Subject in the index pane
 770         # when multiple Subject: headers are present, so we follow suit:
 771         my $subj = $hdr->header('Subject') // '';
 772         $subj = '(no subject)' if $subj eq '';
 773         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 774         $ctx->{cur} = $mid;
 775         $ctx->{prev_attr} = '';
 776         $ctx->{prev_level} = 0;
 777         $ctx->{skel} = $skel;
 778
 779         # reduce hash lookups in skel_dump
 780         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 781         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 782
 783         $ctx->{parent_msg} = $parent;
 784 }
 785
 786 sub _parent_headers {
 787         my ($hdr, $over) = @_;
 788         my $rv = '';
 789         my @irt = $hdr->header_raw('In-Reply-To');
 790         my $refs;
 791         if (@irt) {
 792                 my $lnk = PublicInbox::Linkify->new;
 793                 $rv .= "In-Reply-To: $_\n" for @irt;
 794                 $lnk->linkify_mids('..', \$rv);
 795         } else {
 796                 $refs = references($hdr);
 797                 my $irt = pop @$refs;
 798                 if (defined $irt) {
 799                         my $html = ascii_html($irt);
 800                         my $href = mid_href($irt);
 801                         $rv .= "In-Reply-To: &lt;";
 802                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 803                 }
 804         }
 805
 806         # do not display References: if search is present,
 807         # we show the thread skeleton at the bottom, instead.
 808         return $rv if $over;
 809
 810         $refs //= references($hdr);
 811         if (@$refs) {
 812                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 813                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 814         }
 815         $rv;
 816 }
 817
 818 # returns a string buffer
 819 sub html_footer {
 820         my ($ctx, $hdr) = @_;
 821         my $ibx = $ctx->{ibx};
 822         my $upfx = '../';
 823         my $skel;
 824         my $rv = '<pre>';
 825         if ($ibx->over) {
 826                 my $t = ts2str($ctx->{-t_max});
 827                 my $t_fmt = fmt_ts($ctx->{-t_max});
 828                 $skel .= <<EOF;
 829         other threads:[<a
 830 href="$upfx?t=$t">~$t_fmt UTC</a>|<a
 831 href="$upfx">newest</a>]
 832 EOF
 833
 834                 thread_skel(\$skel, $ctx, $hdr);
 835                 my ($next, $prev);
 836                 my $parent = '       ';
 837                 $next = $prev = '    ';
 838
 839                 if (my $n = $ctx->{next_msg}) {
 840                         $n = mid_href($n);
 841                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 842                 }
 843                 my $u;
 844                 my $par = $ctx->{parent_msg};
 845                 if ($par) {
 846                         $u = mid_href($par);
 847                         $u = "$upfx$u/";
 848                 }
 849                 if (my $p = $ctx->{prev_msg}) {
 850                         $prev = mid_href($p);
 851                         if ($p && $par && $p eq $par) {
 852                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 853                                         'rel=prev>prev parent</a>';
 854                                 $parent = '';
 855                         } else {
 856                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 857                                         'rel=prev>prev</a>';
 858                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 859                         }
 860                 } elsif ($u) { # unlikely
 861                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 862                 }
 863                 $rv .= "$next $prev$parent ";
 864         } else { # unindexed inboxes w/o over
 865                 $skel = qq( <a\nhref="$upfx">latest</a>);
 866         }
 867         $rv .= qq(<a\nhref="#R">reply</a>);
 868         $rv .= $skel;
 869         $rv .= '</pre>';
 870         $rv .= msg_reply($ctx, $hdr);
 871 }
 872
 873 sub linkify_ref_no_over {
 874         my ($mid) = @_;
 875         my $href = mid_href($mid);
 876         my $html = ascii_html($mid);
 877         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 878 }
 879
 880 sub ghost_parent {
 881         my ($upfx, $mid) = @_;
 882
 883         my $href = mid_href($mid);
 884         my $html = ascii_html($mid);
 885         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 886 }
 887
 888 sub indent_for {
 889         my ($level) = @_;
 890         $level ? INDENT x ($level - 1) : '';
 891 }
 892
 893 sub find_mid_root {
 894         my ($ctx, $level, $node, $idx) = @_;
 895         ++$ctx->{root_idx} if $level == 0;
 896         if ($node->{mid} eq $ctx->{mid}) {
 897                 $ctx->{found_mid_at} = $ctx->{root_idx};
 898                 return 0; # stop iterating
 899         }
 900         1;
 901 }
 902
 903 sub strict_loose_note ($) {
 904         my ($nr) = @_;
 905         my $msg =
 906 "  -- strict thread matches above, loose matches on Subject: below --\n";
 907
 908         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 909                 $msg .=
 910 "  -- use mbox.gz link to download all $nr messages --\n";
 911         }
 912         $msg;
 913 }
 914
 915 sub thread_results {
 916         my ($ctx, $msgs) = @_;
 917         require PublicInbox::SearchThread;
 918         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 919
 920         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 921         # and preserved in the future.  This bug is hidden by `sid' matches
 922         # in get_thread, so we never noticed it until now.  And even when
 923         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 924         # bump since reindexing is expensive and users may not do it
 925
 926         # loose threading could've returned too many results,
 927         # put the root the message we care about at the top:
 928         my $mid = $ctx->{mid};
 929         if (defined($mid) && scalar(@$rootset) > 1) {
 930                 $ctx->{root_idx} = -1;
 931                 my $nr = scalar @$msgs;
 932                 walk_thread($rootset, $ctx, \&find_mid_root);
 933                 my $idx = $ctx->{found_mid_at};
 934                 if (defined($idx) && $idx != 0) {
 935                         my $tip = splice(@$rootset, $idx, 1);
 936                         @$rootset = reverse @$rootset;
 937                         unshift @$rootset, $tip;
 938                         $ctx->{sl_note} = strict_loose_note($nr);
 939                 }
 940         }
 941         $rootset
 942 }
 943
 944 sub missing_thread {
 945         my ($ctx) = @_;
 946         require PublicInbox::ExtMsg;
 947         PublicInbox::ExtMsg::ext_msg($ctx);
 948 }
 949
 950 sub dedupe_subject {
 951         my ($prev_subj, $subj, $val) = @_;
 952
 953         my $omit; # '"' denotes identical text omitted
 954         my (@prev_pop, @curr_pop);
 955         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 956                 push(@prev_pop, pop(@$prev_subj));
 957                 push(@curr_pop, pop(@$subj));
 958                 $omit //= $val;
 959         }
 960         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 961         if (scalar(@curr_pop) == 1) {
 962                 $omit = undef;
 963                 push @$prev_subj, @prev_pop;
 964                 push @$subj, @curr_pop;
 965         }
 966         $omit // '';
 967 }
 968
 969 sub skel_dump { # walk_thread callback
 970         my ($ctx, $level, $smsg) = @_;
 971         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 972
 973         my $skel = $ctx->{skel};
 974         my $cur = $ctx->{cur};
 975         my $mid = $smsg->{mid};
 976
 977         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 978                 $$skel .= delete($ctx->{sl_note}) || '';
 979         }
 980
 981         my $f = ascii_html(delete $smsg->{from_name});
 982         my $obfs_ibx = $ctx->{-obfs_ibx};
 983         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 984
 985         my $d = fmt_ts($smsg->{ds});
 986         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 987         if (exists $ctx->{searchview}) {
 988                 if (defined(my $pct = $smsg->{pct})) {
 989                         $d .= (sprintf(' % 2u', $pct) . '%');
 990                 } else {
 991                         $unmatched = 1;
 992                         $d .= '    ';
 993                 }
 994         }
 995         $d .= ' ' . indent_for($level) . th_pfx($level);
 996         my $attr = $f;
 997         $ctx->{first_level} ||= $level;
 998
 999         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
1000                 $ctx->{prev_attr} = $attr;
1001         }
1002         $ctx->{prev_level} = $level;
1003
1004         if ($cur) {
1005                 if ($cur eq $mid) {
1006                         delete $ctx->{cur};
1007                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
1008                                  "$attr [this message]</a></b>\n";
1009                         return 1;
1010                 } else {
1011                         $ctx->{prev_msg} = $mid;
1012                 }
1013         } else {
1014                 $ctx->{next_msg} ||= $mid;
1015         }
1016
1017         # Subject is never undef, this mail was loaded from
1018         # our Xapian which would've resulted in '' if it were
1019         # really missing (and Filter rejects empty subjects)
1020         my @subj = split(/ /, subject_normalized($smsg->{subject}));
1021         # remove common suffixes from the subject if it matches the previous,
1022         # so we do not show redundant text at the end.
1023         my $prev_subj = $ctx->{prev_subj} || [];
1024         $ctx->{prev_subj} = [ @subj ];
1025         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
1026         my $end;
1027         if (@subj) {
1028                 my $subj = join(' ', @subj);
1029                 $subj = ascii_html($subj);
1030                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1031                 $end = "$subj</a> $omit$f\n"
1032         } else {
1033                 $end = "$f</a>\n";
1034         }
1035         my $m;
1036         my $id = '';
1037         my $mapping = $unmatched ? undef : $ctx->{mapping};
1038         if ($mapping) {
1039                 my $map = $mapping->{$mid};
1040                 $id = id_compress($mid, 1);
1041                 $m = '#m'.$id;
1042                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1043                 $id = "\nid=r".$id;
1044         } else {
1045                 $m = $ctx->{-upfx}.mid_href($mid).'/';
1046         }
1047         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1048         1;
1049 }
1050
1051 sub _skel_ghost {
1052         my ($ctx, $level, $node) = @_;
1053
1054         my $mid = $node->{mid};
1055         my $d = '     [not found] ';
1056         $d .= '    '  if exists $ctx->{searchview};
1057         $d .= indent_for($level) . th_pfx($level);
1058         my $upfx = $ctx->{-upfx};
1059         my $href = $upfx . mid_href($mid) . '/';
1060         my $html = ascii_html($mid);
1061
1062         my $mapping = $ctx->{mapping};
1063         my $map = $mapping->{$mid} if $mapping;
1064         if ($map) {
1065                 my $id = id_compress($mid, 1);
1066                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1067                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1068         } else {
1069                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1070         }
1071         ${$ctx->{skel}} .= $d;
1072         1;
1073 }
1074
1075 sub sort_ds {
1076         @{$_[0]} = sort {
1077                 (eval { $a->topmost->{ds} } || 0) <=>
1078                 (eval { $b->topmost->{ds} } || 0)
1079         } @{$_[0]};
1080 }
1081
1082 # accumulate recent topics if search is supported
1083 # returns 200 if done, 404 if not
1084 sub acc_topic { # walk_thread callback
1085         my ($ctx, $level, $smsg) = @_;
1086         my $mid = $smsg->{mid};
1087         my $has_blob = $smsg->{blob} // do {
1088                 if (my $by_mid = $ctx->{ibx}->smsg_by_mid($mid)) {
1089                         %$smsg = (%$smsg, %$by_mid);
1090                         1;
1091                 }
1092         };
1093         if ($has_blob) {
1094                 my $subj = subject_normalized($smsg->{subject});
1095                 $subj = '(no subject)' if $subj eq '';
1096                 my $ds = $smsg->{ds};
1097                 if ($level == 0) { # new, top-level topic
1098                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1099                         $ctx->{-cur_topic} = $topic;
1100                         push @{$ctx->{order}}, $topic;
1101                         return 1;
1102                 }
1103
1104                 # continue existing topic
1105                 my $topic = $ctx->{-cur_topic}; # should never be undef
1106                 $topic->[0] = $ds if $ds > $topic->[0];
1107                 $topic->[1]++; # bump N+ message counter
1108                 my $seen = $topic->[2];
1109                 if (scalar(@$topic) == 3) { # parent was a ghost
1110                         push @$topic, $subj;
1111                 } elsif (!defined($seen->{$subj})) {
1112                         push @$topic, $level, $subj; # @extra messages
1113                 }
1114                 $seen->{$subj} = $mid; # latest for subject
1115         } else { # ghost message
1116                 return 1 if $level != 0; # ignore child ghosts
1117                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1118                 push @{$ctx->{order}}, $topic;
1119         }
1120         1;
1121 }
1122
1123 sub dump_topics {
1124         my ($ctx) = @_;
1125         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1126         unless ($order) {
1127                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1128                 return 404;
1129         }
1130
1131         my @out;
1132         my $ibx = $ctx->{ibx};
1133         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1134
1135         # sort by recency, this allows new posts to "bump" old topics...
1136         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1137                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1138                 @$topic = ();
1139                 next unless defined $top_subj;  # ghost topic
1140                 my $mid = delete $seen->{$top_subj};
1141                 my $href = mid_href($mid);
1142                 my $prev_subj = [ split(/ /, $top_subj) ];
1143                 $top_subj = ascii_html($top_subj);
1144                 $ds = fmt_ts($ds);
1145
1146                 # $n isn't the total number of posts on the topic,
1147                 # just the number of posts in the current results window
1148                 my $anchor;
1149                 if ($n == 1) {
1150                         $n = '';
1151                         $anchor = '#u'; # top of only message
1152                 } else {
1153                         $n = " ($n+ messages)";
1154                         $anchor = '#t'; # thread skeleton
1155                 }
1156
1157                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1158                         " $ds UTC $n\n";
1159                 for (my $i = 0; $i < scalar(@extra); $i += 2) {
1160                         my $level = $extra[$i];
1161                         my $subj = $extra[$i + 1]; # already normalized
1162                         $mid = delete $seen->{$subj};
1163                         my @subj = split(/ /, $subj);
1164                         my @next_prev = @subj; # full copy
1165                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1166                         $prev_subj = \@next_prev;
1167                         $subj = join(' ', @subj);
1168                         $subj = ascii_html($subj);
1169                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1170                         $href = mid_href($mid);
1171                         $s .= indent_for($level) . TCHILD;
1172                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1173                 }
1174                 push @out, $s;
1175         }
1176         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1177         200;
1178 }
1179
1180 sub str2ts ($) {
1181         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1182         timegm($ss || 0, $mm || 0, $hh || 0, $dd, $mon - 1, $yyyy);
1183 }
1184
1185 sub pagination_footer ($$) {
1186         my ($ctx, $latest) = @_;
1187         my $next = $ctx->{next_page} || '';
1188         my $prev = $ctx->{prev_page} || '';
1189         if ($prev) {  # aligned padding for: 'next (older) | '
1190                 $next = $next ? "$next | " : '             | ';
1191                 $prev .= qq[ | <a\nhref="$latest">latest</a>];
1192         }
1193         "<hr><pre>page: $next$prev</pre>";
1194 }
1195
1196 sub paginate_recent ($$) {
1197         my ($ctx, $lim) = @_;
1198         my $t = $ctx->{qp}->{t} || '';
1199         my $opts = { limit => $lim };
1200         my ($after, $before);
1201
1202         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1203         # if only $after exists "YYYYMMDD.." because "." could be skipped
1204         # if interpreted as an end-of-sentence
1205         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1206         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1207
1208         my $ibx = $ctx->{ibx};
1209         my $msgs = $ibx->recent($opts, $after, $before);
1210         my $nr = scalar @$msgs;
1211         if ($nr < $lim && defined($after)) {
1212                 $after = $before = undef;
1213                 $msgs = $ibx->recent($opts);
1214                 $nr = scalar @$msgs;
1215         }
1216         my $more = $nr == $lim;
1217         my ($newest, $oldest);
1218         if ($nr) {
1219                 $newest = $msgs->[0]->{ts};
1220                 $oldest = $msgs->[-1]->{ts};
1221                 # if we only had $after, our SQL query in ->recent ordered
1222                 if ($newest < $oldest) {
1223                         ($oldest, $newest) = ($newest, $oldest);
1224                         $more = 0 if defined($after) && $after < $oldest;
1225                 }
1226         }
1227         if (defined($oldest) && $more) {
1228                 my $s = ts2str($oldest);
1229                 $ctx->{next_page} = qq[<a\nhref="?t=$s"\nrel=next>] .
1230                                         'next (older)</a>';
1231         }
1232         if (defined($newest) && (defined($before) || defined($after))) {
1233                 my $s = ts2str($newest);
1234                 $ctx->{prev_page} = qq[<a\nhref="?t=$s-"\nrel=prev>] .
1235                                         'prev (newer)</a>';
1236         }
1237         $msgs;
1238 }
1239
1240 # GET /$INBOX - top-level inbox view for indexed inboxes
1241 sub index_topics {
1242         my ($ctx) = @_;
1243         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1244         if (@$msgs) {
1245                 walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic);
1246         }
1247         html_oneshot($ctx, dump_topics($ctx), \pagination_footer($ctx, '.'));
1248
1249 }
1250
1251 sub thread_adj_level {
1252         my ($ctx, $level) = @_;
1253
1254         my $max = $ctx->{cur_level};
1255         if ($level <= 0) {
1256                 return ('', '') if $max == 0; # flat output
1257
1258                 # reset existing lists
1259                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1260                 $ctx->{cur_level} = 0;
1261                 ("$beg</ul>", '');
1262         } elsif ($level == $max) { # continue existing list
1263                 qw(<li> </li>);
1264         } elsif ($level < $max) {
1265                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1266                 $ctx->{cur_level} = $level;
1267                 ("$beg<li>", '</li>');
1268         } else { # ($level > $max) # start a new level
1269                 $ctx->{cur_level} = $level;
1270                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1271                 ($beg, '</li>');
1272         }
1273 }
1274
1275 sub ghost_index_entry {
1276         my ($ctx, $level, $node) = @_;
1277         my ($beg, $end) = thread_adj_level($ctx,  $level);
1278         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid} // '?')
1279                 . '</pre>' . $end;
1280 }
1281
1282 1;