lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MsgTime qw(msg_datestamp);
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::Linkify;
  12 use PublicInbox::MID qw/id_compress mid_escape mids references/;
  13 use PublicInbox::MsgIter;
  14 use PublicInbox::Address;
  15 use PublicInbox::WwwStream;
  16 use PublicInbox::Reply;
  17 require POSIX;
  18 use Time::Local qw(timegm);
  19
  20 use constant COLS => 72;
  21 use constant INDENT => '  ';
  22 use constant TCHILD => '` ';
  23 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  24
  25 # public functions: (unstable)
  26
  27 sub msg_html {
  28         my ($ctx, $mime, $more, $smsg) = @_;
  29         my $hdr = $mime->header_obj;
  30         my $ibx = $ctx->{-inbox};
  31         my $obfs_ibx = $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  32         my $tip = _msg_html_prepare($hdr, $ctx, $more, 0);
  33         my $end = 2;
  34         PublicInbox::WwwStream->response($ctx, 200, sub {
  35                 my ($nr, undef) = @_;
  36                 if ($nr == 1) {
  37                         # $more cannot be true w/o $smsg being defined:
  38                         my $upfx = $more ? '../'.mid_escape($smsg->mid).'/' : '';
  39                         $tip . multipart_text_as_html($mime, $upfx, $obfs_ibx) .
  40                                 '</pre><hr>'
  41                 } elsif ($more && @$more) {
  42                         ++$end;
  43                         msg_html_more($ctx, $more, $nr);
  44                 } elsif ($nr == $end) {
  45                         # fake an EOF if generating the footer fails;
  46                         # we want to at least show the message if something
  47                         # here crashes:
  48                         eval {
  49                                 '<pre>' . html_footer($hdr, 1, $ctx) .
  50                                 '</pre>' . msg_reply($ctx, $hdr)
  51                         };
  52                 } else {
  53                         undef
  54                 }
  55         });
  56 }
  57
  58 sub msg_page {
  59         my ($ctx) = @_;
  60         my $mid = $ctx->{mid};
  61         my $ibx = $ctx->{-inbox};
  62         my ($first, $more);
  63         my $smsg;
  64         if (my $srch = $ibx->search) {
  65                 my ($id, $prev);
  66                 $smsg = $srch->next_by_mid($mid, \$id, \$prev);
  67                 $first = $ibx->msg_by_smsg($smsg) if $smsg;
  68                 if ($first) {
  69                         my $next = $srch->next_by_mid($mid, \$id, \$prev);
  70                         $more = [ $id, $prev, $next ] if $next;
  71                 }
  72                 return unless $first;
  73         } else {
  74                 $first = $ibx->msg_by_mid($mid) or return;
  75         }
  76         msg_html($ctx, PublicInbox::MIME->new($first), $more, $smsg);
  77 }
  78
  79 sub msg_html_more {
  80         my ($ctx, $more, $nr) = @_;
  81         my $str = eval {
  82                 my ($id, $prev, $smsg) = @$more;
  83                 my $mid = $ctx->{mid};
  84                 $smsg = $ctx->{-inbox}->smsg_mime($smsg);
  85                 my $next = $ctx->{srch}->next_by_mid($mid, \$id, \$prev);
  86                 @$more = $next ? ($id, $prev, $next) : ();
  87                 if ($smsg) {
  88                         my $mime = $smsg->{mime};
  89                         my $upfx = '../' . mid_escape($smsg->mid) . '/';
  90                         _msg_html_prepare($mime->header_obj, $ctx, $more, $nr) .
  91                                 multipart_text_as_html($mime, $upfx,
  92                                                         $ctx->{-obfs_ibx}) .
  93                                 '</pre><hr>'
  94                 } else {
  95                         '';
  96                 }
  97         };
  98         if ($@) {
  99                 warn "Error lookup up additional messages: $@\n";
 100                 $str = '<pre>Error looking up additional messages</pre>';
 101         }
 102         $str;
 103 }
 104
 105 # /$INBOX/$MESSAGE_ID/#R
 106 sub msg_reply {
 107         my ($ctx, $hdr) = @_;
 108         my $se_url =
 109          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
 110         my $p_url =
 111          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
 112
 113         my $info = '';
 114         my $ibx = $ctx->{-inbox};
 115         if (my $url = $ibx->{infourl}) {
 116                 $url = PublicInbox::Hval::prurl($ctx->{env}, $url);
 117                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 118         }
 119
 120         my ($arg, $link, $reply_to_all) =
 121                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 122
 123         # mailto: link only works if address obfuscation is disabled
 124         if ($link) {
 125                 $link = <<EOF;
 126
 127 * If your mail client supports setting the <b>In-Reply-To</b> header
 128   via mailto: links, try the <a
 129 href="$link">mailto: link</a>
 130 EOF
 131         }
 132
 133         push @$arg, '/path/to/YOUR_REPLY';
 134         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 135         <<EOF
 136 <hr><pre
 137 id=R><b>Reply instructions:</b>
 138
 139 You may reply publically to <a
 140 href=#t>this message</a> via plain-text email
 141 using any one of the following methods:
 142
 143 * Save the following mbox file, import it into your mail client,
 144   and $reply_to_all from there: <a
 145 href=raw>mbox</a>
 146
 147   Avoid top-posting and favor interleaved quoting:
 148   <a
 149 href="$p_url">$p_url</a>
 150 $info
 151 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 152   switches of git-send-email(1):
 153
 154   git send-email$arg
 155
 156   <a
 157 href="$se_url">$se_url</a>
 158 $link</pre>
 159 EOF
 160 }
 161
 162 sub in_reply_to {
 163         my ($hdr) = @_;
 164         my $refs = references($hdr);
 165         $refs->[-1];
 166 }
 167
 168 sub fold_addresses ($) {
 169         return $_[0] if length($_[0]) <= COLS;
 170         # try to fold on commas after non-word chars before $lim chars,
 171         # Try to get the "," preceeded by ">" or ")", but avoid folding
 172         # on the comma where somebody uses "Lastname, Firstname".
 173         # We also try to keep the last and penultimate addresses in
 174         # the list on the same line if possible, hence the extra \z
 175         # Fall back to folding on spaces at $lim + 1 chars
 176         my $lim = COLS - 8; # 8 = "\t" display width
 177         my $too_long = $lim + 1;
 178         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 179         $_[0] = join("\n\t",
 180                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 181                                 .{1,$lim}(?:,|\z)|
 182                                 .{1,$lim}|
 183                                 .{$too_long,}?)(?:\s|\z)/xgo));
 184 }
 185
 186 sub _hdr_names_html ($$) {
 187         my ($hdr, $field) = @_;
 188         my $val = $hdr->header($field) or return '';
 189         ascii_html(join(', ', PublicInbox::Address::names($val)));
 190 }
 191
 192 sub nr_to_s ($$$) {
 193         my ($nr, $singular, $plural) = @_;
 194         return "0 $plural" if $nr == 0;
 195         $nr == 1 ? "$nr $singular" : "$nr $plural";
 196 }
 197
 198 # this is already inside a <pre>
 199 sub index_entry {
 200         my ($smsg, $ctx, $more) = @_;
 201         my $srch = $ctx->{srch};
 202         my $subj = $smsg->subject;
 203         my $mid_raw = $smsg->mid;
 204         my $id = id_compress($mid_raw, 1);
 205         my $id_m = 'm'.$id;
 206
 207         my $root_anchor = $ctx->{root_anchor} || '';
 208         my $irt;
 209         my $obfs_ibx = $ctx->{-obfs_ibx};
 210
 211         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 212         $subj = '<b>'.ascii_html($subj).'</b>';
 213         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 214         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 215         $rv .= $subj . "\n";
 216         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 217         my @tocc;
 218         my $mime = $smsg->{mime};
 219         my $hdr = $mime->header_obj;
 220         my $from = _hdr_names_html($hdr, 'From');
 221         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 222         $rv .= "From: $from @ ".fmt_ts($smsg->ds)." UTC";
 223         my $upfx = $ctx->{-upfx};
 224         my $mhref = $upfx . mid_escape($mid_raw) . '/';
 225         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 226         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 227         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 228         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 229         my ($tlen, $clen) = (length($to), length($cc));
 230         my $to_cc = '';
 231         if (($tlen + $clen) > COLS) {
 232                 $to_cc .= '  To: '.$to."\n" if $tlen;
 233                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 234         } else {
 235                 if ($tlen) {
 236                         $to_cc .= '  To: '.$to;
 237                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 238                 } else {
 239                         $to_cc .= '  Cc: '.$cc if $clen;
 240                 }
 241                 $to_cc .= "\n";
 242         }
 243         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 244         $rv .= $to_cc;
 245
 246         my $mapping = $ctx->{mapping};
 247         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 248                 my $mirt = PublicInbox::Hval->new_msgid($irt);
 249                 my $href = $upfx . $mirt->{href}. '/';
 250                 my $html = $mirt->as_html;
 251                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 252         }
 253         $rv .= "\n";
 254
 255         # scan through all parts, looking for displayable text
 256         msg_iter($mime, sub { $rv .= add_text_body($mhref, $obfs_ibx, $_[0]) });
 257
 258         # add the footer
 259         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 260                 "<a\nhref=\"$mhref\">permalink</a>" .
 261                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 262                 " <a\nhref=\"${mhref}#R\">reply</a>";
 263
 264         my $hr;
 265         if (my $pct = $ctx->{pct}) { # used by SearchView.pm
 266                 $rv .= "\t[relevance $pct->{$mid_raw}%]";
 267                 $hr = 1;
 268         } elsif ($mapping) {
 269                 my $nested = 'nested';
 270                 my $flat = 'flat';
 271                 my $end = '';
 272                 if ($ctx->{flat}) {
 273                         $hr = 1;
 274                         $flat = "<b>$flat</b>";
 275                 } else {
 276                         $nested = "<b>$nested</b>";
 277                 }
 278                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 279                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 280                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 281         } else {
 282                 $hr = $ctx->{-hr};
 283         }
 284
 285         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 286         $rv;
 287 }
 288
 289 sub pad_link ($$;$) {
 290         my ($mid, $level, $s) = @_;
 291         $s ||= '...';
 292         my $id = id_compress($mid, 1);
 293         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 294 }
 295
 296 sub _th_index_lite {
 297         my ($mid_raw, $irt, $id, $ctx) = @_;
 298         my $rv = '';
 299         my $mapping = $ctx->{mapping} or return $rv;
 300         my $pad = '  ';
 301         my $mid_map = $mapping->{$mid_raw};
 302         defined $mid_map or
 303                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 304         my ($attr, $node, $idx, $level) = @$mid_map;
 305         my $children = $node->{children};
 306         my $nr_c = scalar @$children;
 307         my $nr_s = 0;
 308         my $siblings;
 309         if (my $smsg = $node->{smsg}) {
 310                 ($$irt) = (($smsg->{references} || '') =~ m/<([^>]+)>\z/);
 311         }
 312         my $irt_map = $mapping->{$$irt} if defined $$irt;
 313         if (defined $irt_map) {
 314                 $siblings = $irt_map->[1]->{children};
 315                 $nr_s = scalar(@$siblings) - 1;
 316                 $rv .= $pad . $irt_map->[0];
 317                 if ($idx > 0) {
 318                         my $prev = $siblings->[$idx - 1];
 319                         my $pmid = $prev->{id};
 320                         if ($idx > 2) {
 321                                 my $s = ($idx - 1). ' preceding siblings ...';
 322                                 $rv .= pad_link($pmid, $level, $s);
 323                         } elsif ($idx == 2) {
 324                                 my $ppmid = $siblings->[0]->{id};
 325                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 326                         }
 327                         $rv .= $pad . $mapping->{$pmid}->[0];
 328                 }
 329         }
 330         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 331         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 332         $attr =~ s!\n\z!</b>\n!s;
 333         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 334         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 335         $rv .= "<b>@ $attr";
 336         if ($nr_c) {
 337                 my $cmid = $children->[0]->{id};
 338                 $rv .= $pad . $mapping->{$cmid}->[0];
 339                 if ($nr_c > 2) {
 340                         my $s = ($nr_c - 1). ' more replies';
 341                         $rv .= pad_link($cmid, $level + 1, $s);
 342                 } elsif (my $cn = $children->[1]) {
 343                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 344                 }
 345         }
 346
 347         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 348         if ($next) {
 349                 my $nmid = $next->{id};
 350                 $rv .= $pad . $mapping->{$nmid}->[0];
 351                 my $nnext = $nr_s - $idx;
 352                 if ($nnext > 2) {
 353                         my $s = ($nnext - 1).' subsequent siblings';
 354                         $rv .= pad_link($nmid, $level, $s);
 355                 } elsif (my $nn = $siblings->[$idx + 2]) {
 356                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 357                 }
 358         }
 359         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 360 }
 361
 362 sub walk_thread {
 363         my ($rootset, $ctx, $cb) = @_;
 364         my @q = map { (0, $_, -1) } @$rootset;
 365         while (@q) {
 366                 my ($level, $node, $i) = splice(@q, 0, 3);
 367                 defined $node or next;
 368                 $cb->($ctx, $level, $node, $i);
 369                 ++$level;
 370                 $i = 0;
 371                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 372         }
 373 }
 374
 375 sub pre_thread  {
 376         my ($ctx, $level, $node, $idx) = @_;
 377         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 378         skel_dump($ctx, $level, $node);
 379 }
 380
 381 sub thread_index_entry {
 382         my ($ctx, $level, $smsg) = @_;
 383         my ($beg, $end) = thread_adj_level($ctx, $level);
 384         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 385 }
 386
 387 sub stream_thread ($$) {
 388         my ($rootset, $ctx) = @_;
 389         my $inbox = $ctx->{-inbox};
 390         my @q = map { (0, $_) } @$rootset;
 391         my $level;
 392         my $smsg;
 393         while (@q) {
 394                 $level = shift @q;
 395                 my $node = shift @q or next;
 396                 my $cl = $level + 1;
 397                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 398                 $smsg = $inbox->smsg_mime($node->{smsg}) and last;
 399         }
 400         return missing_thread($ctx) unless $smsg;
 401
 402         $ctx->{-obfs_ibx} = $inbox->{obfuscate} ? $inbox : undef;
 403         $ctx->{-title_html} = ascii_html($smsg->subject);
 404         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 405         $smsg = undef;
 406         PublicInbox::WwwStream->response($ctx, 200, sub {
 407                 return unless $ctx;
 408                 while (@q) {
 409                         $level = shift @q;
 410                         my $node = shift @q or next;
 411                         my $cl = $level + 1;
 412                         unshift @q, map { ($cl, $_) } @{$node->{children}};
 413                         if ($smsg = $inbox->smsg_mime($node->{smsg})) {
 414                                 return thread_index_entry($ctx, $level, $smsg);
 415                         } else {
 416                                 return ghost_index_entry($ctx, $level, $node);
 417                         }
 418                 }
 419                 my $ret = join('', thread_adj_level($ctx, 0));
 420                 $ret .= ${$ctx->{dst}}; # skel
 421                 $ctx = undef;
 422                 $ret;
 423         });
 424 }
 425
 426 sub thread_html {
 427         my ($ctx) = @_;
 428         my $mid = $ctx->{mid};
 429         my $srch = $ctx->{srch};
 430         my ($nr, $msgs) = $srch->get_thread($mid);
 431         return missing_thread($ctx) if $nr == 0;
 432         my $skel = '<hr><pre>';
 433         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 434         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 435         $skel .= "<b\nid=t>Thread overview:</b> ";
 436         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 437         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 438         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 439         $skel .= "-- links below jump to the message on this page --\n";
 440         $ctx->{-upfx} = '../../';
 441         $ctx->{cur_level} = 0;
 442         $ctx->{dst} = \$skel;
 443         $ctx->{prev_attr} = '';
 444         $ctx->{prev_level} = 0;
 445         $ctx->{root_anchor} = anchor_for($mid);
 446         $ctx->{mapping} = {};
 447         $ctx->{s_nr} = "$nr+ messages in thread";
 448
 449         my $rootset = thread_results($ctx, $msgs);
 450
 451         # reduce hash lookups in pre_thread->skel_dump
 452         my $inbox = $ctx->{-inbox};
 453         $ctx->{-obfs_ibx} = $inbox->{obfuscate} ? $inbox : undef;
 454         walk_thread($rootset, $ctx, *pre_thread);
 455
 456         $skel .= '</pre>';
 457         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 458
 459         # flat display: lazy load the full message from smsg
 460         my $smsg;
 461         while (my $m = shift @$msgs) {
 462                 $smsg = $inbox->smsg_mime($m) and last;
 463         }
 464         return missing_thread($ctx) unless $smsg;
 465         $ctx->{-title_html} = ascii_html($smsg->subject);
 466         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 467         $smsg = undef;
 468         PublicInbox::WwwStream->response($ctx, 200, sub {
 469                 return unless $msgs;
 470                 $smsg = undef;
 471                 while (my $m = shift @$msgs) {
 472                         $smsg = $inbox->smsg_mime($m) and last;
 473                 }
 474                 return index_entry($smsg, $ctx, scalar @$msgs) if $smsg;
 475                 $msgs = undef;
 476                 $skel;
 477         });
 478 }
 479
 480 sub multipart_text_as_html {
 481         my ($mime, $upfx, $obfs_ibx) = @_;
 482         my $rv = "";
 483
 484         # scan through all parts, looking for displayable text
 485         msg_iter($mime, sub { $rv .= add_text_body($upfx, $obfs_ibx, $_[0]) });
 486         $rv;
 487 }
 488
 489 sub flush_quote {
 490         my ($s, $l, $quot) = @_;
 491
 492         # show everything in the full version with anchor from
 493         # short version (see above)
 494         my $rv = $l->linkify_1(join('', @$quot));
 495         @$quot = ();
 496
 497         # we use a <span> here to allow users to specify their own
 498         # color for quoted text
 499         $rv = $l->linkify_2(ascii_html($rv));
 500         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 501 }
 502
 503 sub attach_link ($$$$;$) {
 504         my ($upfx, $ct, $p, $fn, $err) = @_;
 505         my ($part, $depth, @idx) = @$p;
 506         my $nl = $idx[-1] > 1 ? "\n" : '';
 507         my $idx = join('.', @idx);
 508         my $size = bytes::length($part->body);
 509
 510         # hide attributes normally, unless we want to aid users in
 511         # spotting MUA problems:
 512         $ct =~ s/;.*// unless $err;
 513         $ct = ascii_html($ct);
 514         my $desc = $part->header('Content-Description');
 515         $desc = $fn unless defined $desc;
 516         $desc = '' unless defined $desc;
 517         my $sfn;
 518         if (defined $fn && $fn =~ /\A[[:alnum:]][\w\.-]+[[:alnum:]]\z/) {
 519                 $sfn = $fn;
 520         } elsif ($ct eq 'text/plain') {
 521                 $sfn = 'a.txt';
 522         } else {
 523                 $sfn = 'a.bin';
 524         }
 525         my $ret = qq($nl<a\nhref="$upfx$idx-$sfn">);
 526         if ($err) {
 527                 $ret .=
 528 "[-- Warning: decoded text below may be mangled --]\n";
 529         }
 530         $ret .= "[-- Attachment #$idx: ";
 531         my $ts = "Type: $ct, Size: $size bytes";
 532         $desc = ascii_html($desc);
 533         $ret .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 534         $ret .= "</a>\n";
 535 }
 536
 537 sub add_text_body {
 538         my ($upfx, $obfs_ibx, $p) = @_;
 539         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 540         my ($part, $depth) = @$p; # attachment @idx is unused
 541         my $ct = $part->content_type || 'text/plain';
 542         my $fn = $part->filename;
 543
 544         if ($ct =~ m!\btext/x?html\b!i) {
 545                 return attach_link($upfx, $ct, $p, $fn);
 546         }
 547
 548         my $s = eval { $part->body_str };
 549
 550         # badly-encoded message? tell the world about it!
 551         my $err = $@;
 552         if ($err) {
 553                 if ($ct =~ m!\btext/plain\b!i) {
 554                         # Try to assume UTF-8 because Alpine seems to
 555                         # do wacky things and set charset=X-UNKNOWN
 556                         $part->charset_set('UTF-8');
 557                         $s = eval { $part->body_str };
 558
 559                         # If forcing charset=UTF-8 failed,
 560                         # attach_link will warn further down...
 561                         $s = $part->body if $@;
 562                 } else {
 563                         return attach_link($upfx, $ct, $p, $fn);
 564                 }
 565         }
 566
 567         my @lines = split(/^/m, $s);
 568         $s = '';
 569         if (defined($fn) || $depth > 0 || $err) {
 570                 $s .= attach_link($upfx, $ct, $p, $fn, $err);
 571                 $s .= "\n";
 572         }
 573         my @quot;
 574         my $l = PublicInbox::Linkify->new;
 575         foreach my $cur (@lines) {
 576                 if ($cur !~ /^>/) {
 577                         # show the previously buffered quote inline
 578                         flush_quote(\$s, $l, \@quot) if @quot;
 579
 580                         # regular line, OK
 581                         $l->linkify_1($cur);
 582                         $s .= $l->linkify_2(ascii_html($cur));
 583                 } else {
 584                         push @quot, $cur;
 585                 }
 586         }
 587
 588         if (@quot) { # ugh, top posted
 589                 flush_quote(\$s, $l, \@quot);
 590                 obfuscate_addrs($obfs_ibx, $s) if $obfs_ibx;
 591                 $s;
 592         } else {
 593                 obfuscate_addrs($obfs_ibx, $s) if $obfs_ibx;
 594                 if ($s =~ /\n\z/s) { # common, last line ends with a newline
 595                         $s;
 596                 } else { # some editors don't do newlines...
 597                         $s .= "\n";
 598                 }
 599         }
 600 }
 601
 602 sub _msg_html_prepare {
 603         my ($hdr, $ctx, $more, $nr) = @_;
 604         my $srch = $ctx->{srch} if $ctx;
 605         my $atom = '';
 606         my $obfs_ibx = $ctx->{-obfs_ibx};
 607         my $rv = '';
 608         my $mids = mids($hdr);
 609         my $multiple = scalar(@$mids) > 1; # zero, one, infinity
 610         if ($nr == 0) {
 611                 if ($more) {
 612                         $rv .=
 613 "<pre>WARNING: multiple messages refer to this Message-ID\n</pre>";
 614                 }
 615                 $rv .= "<pre\nid=b>"; # anchor for body start
 616         } else {
 617                 $rv .= '<pre>';
 618         }
 619         if ($srch) {
 620                 $ctx->{-upfx} = '../';
 621         }
 622         my @title;
 623         my $v;
 624         if (defined($v = $hdr->header('From'))) {
 625                 $v = PublicInbox::Hval->new($v);
 626                 my @n = PublicInbox::Address::names($v->raw);
 627                 $title[1] = ascii_html(join(', ', @n));
 628                 $v = $v->as_html;
 629                 if ($obfs_ibx) {
 630                         obfuscate_addrs($obfs_ibx, $v);
 631                         obfuscate_addrs($obfs_ibx, $title[1]);
 632                 }
 633                 $rv .= "From: $v\n" if $v ne '';
 634         }
 635         foreach my $h (qw(To Cc)) {
 636                 defined($v = $hdr->header($h)) or next;
 637                 fold_addresses($v);
 638                 $v = ascii_html($v);
 639                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 640                 $rv .= "$h: $v\n" if $v ne '';
 641         }
 642         if (defined($v = $hdr->header('Subject')) && ($v ne '')) {
 643                 $v = ascii_html($v);
 644                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 645                 if ($srch) {
 646                         $rv .= qq(Subject: <a\nhref="#r"\nid=t>$v</a>\n);
 647                 } else {
 648                         $rv .= "Subject: $v\n";
 649                 }
 650                 $title[0] = $v;
 651         } else { # dummy anchor for thread skeleton at bottom of page
 652                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $srch;
 653                 $title[0] = '(no subject)';
 654         }
 655         if (defined($v = $hdr->header('Date'))) {
 656                 $v = ascii_html($v);
 657                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 658                 $rv .= "Date: $v\n";
 659         }
 660         $ctx->{-title_html} = join(' - ', @title);
 661         foreach (@$mids) {
 662                 my $mid = PublicInbox::Hval->new_msgid($_) ;
 663                 my $mhtml = $mid->as_html;
 664                 if ($multiple) {
 665                         my $href = $mid->{href};
 666                         $rv .= "Message-ID: ";
 667                         $rv .= "<a\nhref=\"../$href/\">";
 668                         $rv .= "&lt;$mhtml&gt;</a> ";
 669                         $rv .= "(<a\nhref=\"../$href/raw\">raw</a>)\n";
 670                 } else {
 671                         $rv .= "Message-ID: &lt;$mhtml&gt; ";
 672                         $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 673                 }
 674         }
 675         $rv .= _parent_headers($hdr, $srch);
 676         $rv .= "\n";
 677 }
 678
 679 sub thread_skel {
 680         my ($dst, $ctx, $hdr, $tpfx) = @_;
 681         my $srch = $ctx->{srch};
 682         my $mid = mids($hdr)->[0];
 683         my ($nr, $msgs) = $srch->get_thread($mid);
 684         my $expand = qq(expand[<a\nhref="${tpfx}T/#u">flat</a>) .
 685                         qq(|<a\nhref="${tpfx}t/#u">nested</a>]  ) .
 686                         qq(<a\nhref="${tpfx}t.mbox.gz">mbox.gz</a>  ) .
 687                         qq(<a\nhref="${tpfx}t.atom">Atom feed</a>);
 688
 689         my $parent = in_reply_to($hdr);
 690         $$dst .= "\n<b>Thread overview: </b>";
 691         if ($nr <= 1) {
 692                 if (defined $parent) {
 693                         $$dst .= "$expand\n ";
 694                         $$dst .= ghost_parent("$tpfx../", $parent) . "\n";
 695                 } else {
 696                         $$dst .= "[no followups] $expand\n";
 697                 }
 698                 $ctx->{next_msg} = undef;
 699                 $ctx->{parent_msg} = $parent;
 700                 return;
 701         }
 702
 703         $$dst .= "$nr+ messages / $expand";
 704         $$dst .= qq!  <a\nhref="#b">top</a>\n!;
 705
 706         my $subj = $hdr->header('Subject');
 707         defined $subj or $subj = '';
 708         $ctx->{prev_subj} = [ split(/ /, $srch->subject_normalized($subj)) ];
 709         $ctx->{cur} = $mid;
 710         $ctx->{prev_attr} = '';
 711         $ctx->{prev_level} = 0;
 712         $ctx->{dst} = $dst;
 713
 714         # reduce hash lookups in skel_dump
 715         my $ibx = $ctx->{-inbox};
 716         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 717         walk_thread(thread_results($ctx, $msgs), $ctx, *skel_dump);
 718
 719         $ctx->{parent_msg} = $parent;
 720 }
 721
 722 sub _parent_headers {
 723         my ($hdr, $srch) = @_;
 724         my $rv = '';
 725
 726         my $refs = references($hdr);
 727         my $irt = pop @$refs;
 728         if (defined $irt) {
 729                 my $v = PublicInbox::Hval->new_msgid($irt);
 730                 my $html = $v->as_html;
 731                 my $href = $v->{href};
 732                 $rv .= "In-Reply-To: &lt;";
 733                 $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 734         }
 735
 736         # do not display References: if search is present,
 737         # we show the thread skeleton at the bottom, instead.
 738         return $rv if $srch;
 739
 740         if (@$refs) {
 741                 @$refs = map { linkify_ref_nosrch($_) } @$refs;
 742                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 743         }
 744         $rv;
 745 }
 746
 747 sub html_footer {
 748         my ($hdr, $standalone, $ctx, $rhref) = @_;
 749
 750         my $srch = $ctx->{srch} if $ctx;
 751         my $upfx = '../';
 752         my $tpfx = '';
 753         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 754         my $irt = '';
 755         if ($idx && $srch) {
 756                 $idx .= "\n";
 757                 thread_skel(\$idx, $ctx, $hdr, $tpfx);
 758                 my ($next, $prev);
 759                 my $parent = '       ';
 760                 $next = $prev = '    ';
 761
 762                 if (my $n = $ctx->{next_msg}) {
 763                         $n = PublicInbox::Hval->new_msgid($n)->{href};
 764                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 765                 }
 766                 my $u;
 767                 my $par = $ctx->{parent_msg};
 768                 if ($par) {
 769                         $u = PublicInbox::Hval->new_msgid($par)->{href};
 770                         $u = "$upfx$u/";
 771                 }
 772                 if (my $p = $ctx->{prev_msg}) {
 773                         $prev = PublicInbox::Hval->new_msgid($p)->{href};
 774                         if ($p && $par && $p eq $par) {
 775                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 776                                         'rel=prev>prev parent</a>';
 777                                 $parent = '';
 778                         } else {
 779                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 780                                         'rel=prev>prev</a>';
 781                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 782                         }
 783                 } elsif ($u) { # unlikely
 784                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 785                 }
 786                 $irt = "$next $prev$parent ";
 787         } else {
 788                 $irt = '';
 789         }
 790         $rhref ||= '#R';
 791         $irt .= qq(<a\nhref="$rhref">reply</a>);
 792         $irt .= $idx;
 793 }
 794
 795 sub linkify_ref_nosrch {
 796         my $v = PublicInbox::Hval->new_msgid($_[0]);
 797         my $html = $v->as_html;
 798         my $href = $v->{href};
 799         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 800 }
 801
 802 sub anchor_for {
 803         my ($msgid) = @_;
 804         'm' . id_compress($msgid, 1);
 805 }
 806
 807 sub ghost_parent {
 808         my ($upfx, $mid) = @_;
 809
 810         $mid = PublicInbox::Hval->new_msgid($mid);
 811         my $href = $mid->{href};
 812         my $html = $mid->as_html;
 813         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 814 }
 815
 816 sub indent_for {
 817         my ($level) = @_;
 818         $level ? INDENT x ($level - 1) : '';
 819 }
 820
 821 sub thread_results {
 822         my ($ctx, $msgs) = @_;
 823         require PublicInbox::SearchThread;
 824         PublicInbox::SearchThread::thread($msgs, *sort_ds, $ctx->{-inbox});
 825 }
 826
 827 sub missing_thread {
 828         my ($ctx) = @_;
 829         require PublicInbox::ExtMsg;
 830         PublicInbox::ExtMsg::ext_msg($ctx);
 831 }
 832
 833 sub _msg_date {
 834         my ($hdr) = @_;
 835         fmt_ts(msg_datestamp($hdr));
 836 }
 837
 838 sub fmt_ts { POSIX::strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 839
 840 sub dedupe_subject {
 841         my ($prev_subj, $subj, $val) = @_;
 842
 843         my $omit = ''; # '"' denotes identical text omitted
 844         my (@prev_pop, @curr_pop);
 845         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 846                 push(@prev_pop, pop(@$prev_subj));
 847                 push(@curr_pop, pop(@$subj));
 848                 $omit ||= $val;
 849         }
 850         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 851         if (scalar(@curr_pop) == 1) {
 852                 $omit = '';
 853                 push @$prev_subj, @prev_pop;
 854                 push @$subj, @curr_pop;
 855         }
 856         $omit;
 857 }
 858
 859 sub skel_dump {
 860         my ($ctx, $level, $node) = @_;
 861         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 862
 863         my $dst = $ctx->{dst};
 864         my $cur = $ctx->{cur};
 865         my $mid = $smsg->{mid};
 866
 867         my $f = ascii_html($smsg->from_name);
 868         my $obfs_ibx = $ctx->{-obfs_ibx};
 869         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 870
 871         my $d = fmt_ts($smsg->{ds}) . ' ' . indent_for($level) . th_pfx($level);
 872         my $attr = $f;
 873         $ctx->{first_level} ||= $level;
 874
 875         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 876                 $ctx->{prev_attr} = $attr;
 877         }
 878         $ctx->{prev_level} = $level;
 879
 880         if ($cur) {
 881                 if ($cur eq $mid) {
 882                         delete $ctx->{cur};
 883                         $$dst .= "<b>$d<a\nid=r\nhref=\"#t\">".
 884                                  "$attr [this message]</a></b>\n";
 885                         return;
 886                 } else {
 887                         $ctx->{prev_msg} = $mid;
 888                 }
 889         } else {
 890                 $ctx->{next_msg} ||= $mid;
 891         }
 892
 893         # Subject is never undef, this mail was loaded from
 894         # our Xapian which would've resulted in '' if it were
 895         # really missing (and Filter rejects empty subjects)
 896         my @subj = split(/ /, $ctx->{srch}->subject_normalized($smsg->subject));
 897
 898         # remove common suffixes from the subject if it matches the previous,
 899         # so we do not show redundant text at the end.
 900         my $prev_subj = $ctx->{prev_subj} || [];
 901         $ctx->{prev_subj} = [ @subj ];
 902         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 903         my $end;
 904         if (@subj) {
 905                 my $subj = join(' ', @subj);
 906                 $subj = ascii_html($subj);
 907                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 908                 $end = "$subj</a> $omit$f\n"
 909         } else {
 910                 $end = "$f</a>\n";
 911         }
 912         my $m;
 913         my $id = '';
 914         my $mapping = $ctx->{mapping};
 915         if ($mapping) {
 916                 my $map = $mapping->{$mid};
 917                 $id = id_compress($mid, 1);
 918                 $m = '#m'.$id;
 919                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 920                 $id = "\nid=r".$id;
 921         } else {
 922                 $m = $ctx->{-upfx}.mid_escape($mid).'/';
 923         }
 924         $$dst .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 925 }
 926
 927 sub _skel_ghost {
 928         my ($ctx, $level, $node) = @_;
 929
 930         my $mid = $node->{id};
 931         my $d = $ctx->{pct} ? '    [irrelevant] ' # search result
 932                             : '     [not found] ';
 933         $d .= indent_for($level) . th_pfx($level);
 934         my $upfx = $ctx->{-upfx};
 935         my $m = PublicInbox::Hval->new_msgid($mid);
 936         my $href = $upfx . $m->{href} . '/';
 937         my $html = $m->as_html;
 938
 939         my $mapping = $ctx->{mapping};
 940         my $map = $mapping->{$mid} if $mapping;
 941         if ($map) {
 942                 my $id = id_compress($mid, 1);
 943                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
 944                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
 945         } else {
 946                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
 947         }
 948         my $dst = $ctx->{dst};
 949         $$dst .= $d;
 950 }
 951
 952 sub sort_ds {
 953         [ sort {
 954                 (eval { $a->topmost->{smsg}->ds } || 0) <=>
 955                 (eval { $b->topmost->{smsg}->ds } || 0)
 956         } @{$_[0]} ];
 957 }
 958
 959 # accumulate recent topics if search is supported
 960 # returns 200 if done, 404 if not
 961 sub acc_topic {
 962         my ($ctx, $level, $node) = @_;
 963         my $srch = $ctx->{srch};
 964         my $mid = $node->{id};
 965         my $x = $node->{smsg} || $ctx->{-inbox}->smsg_by_mid($mid);
 966         my ($subj, $ds);
 967         my $topic;
 968         if ($x) {
 969                 $subj = $x->subject;
 970                 $subj = $srch->subject_normalized($subj);
 971                 $ds = $x->ds;
 972                 if ($level == 0) {
 973                         $topic = [ $ds, 1, { $subj => $mid }, $subj ];
 974                         $ctx->{-cur_topic} = $topic;
 975                         push @{$ctx->{order}}, $topic;
 976                         return;
 977                 }
 978
 979                 $topic = $ctx->{-cur_topic}; # should never be undef
 980                 $topic->[0] = $ds if $ds > $topic->[0];
 981                 $topic->[1]++;
 982                 my $seen = $topic->[2];
 983                 if (scalar(@$topic) == 3) { # parent was a ghost
 984                         push @$topic, $subj;
 985                 } elsif (!$seen->{$subj}) {
 986                         push @$topic, $level, $subj;
 987                 }
 988                 $seen->{$subj} = $mid; # latest for subject
 989         } else { # ghost message
 990                 return if $level != 0; # ignore child ghosts
 991                 $topic = [ -666, 0, {} ];
 992                 $ctx->{-cur_topic} = $topic;
 993                 push @{$ctx->{order}}, $topic;
 994         }
 995 }
 996
 997 sub dump_topics {
 998         my ($ctx) = @_;
 999         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1000         if (!@$order) {
1001                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1002                 return 404;
1003         }
1004
1005         my @out;
1006         my $ibx = $ctx->{-inbox};
1007         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1008         my $srch = $ctx->{srch};
1009
1010         # sort by recency, this allows new posts to "bump" old topics...
1011         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1012                 my ($ds, $n, $seen, $top, @ex) = @$topic;
1013                 @$topic = ();
1014                 next unless defined $top;  # ghost topic
1015                 my $mid = delete $seen->{$top};
1016                 my $href = mid_escape($mid);
1017                 my $prev_subj = [ split(/ /, $top) ];
1018                 $top = PublicInbox::Hval->new($top)->as_html;
1019                 $ds = fmt_ts($ds);
1020
1021                 # $n isn't the total number of posts on the topic,
1022                 # just the number of posts in the current results window
1023                 my $anchor;
1024                 if ($n == 1) {
1025                         $n = '';
1026                         $anchor = '#u'; # top of only message
1027                 } else {
1028                         $n = " ($n+ messages)";
1029                         $anchor = '#t'; # thread skeleton
1030                 }
1031
1032                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1033                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1034                 my $s = "<a\nhref=\"$href/T/$anchor\"><b>$top</b></a>\n" .
1035                         " $ds UTC $n - $mbox / $atom\n";
1036                 for (my $i = 0; $i < scalar(@ex); $i += 2) {
1037                         my $level = $ex[$i];
1038                         my $subj = $ex[$i + 1];
1039                         $mid = delete $seen->{$subj};
1040                         my @subj = split(/ /, $srch->subject_normalized($subj));
1041                         my @next_prev = @subj; # full copy
1042                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1043                         $prev_subj = \@next_prev;
1044                         $subj = ascii_html(join(' ', @subj));
1045                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1046                         $href = mid_escape($mid);
1047                         $s .= indent_for($level) . TCHILD;
1048                         $s .= "<a\nhref=\"$href/T/#u\">$subj</a>$omit\n";
1049                 }
1050                 push @out, $s;
1051         }
1052         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1053         200;
1054 }
1055
1056 sub ts2str ($) {
1057         my ($ts) = @_;
1058         POSIX::strftime('%Y%m%d%H%M%S', gmtime($ts));
1059 }
1060
1061 sub str2ts ($) {
1062         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1063         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1064 }
1065
1066 sub pagination_footer ($$) {
1067         my ($ctx, $latest) = @_;
1068         delete $ctx->{qp} or return;
1069         my $next = $ctx->{next_page} || '';
1070         my $prev = $ctx->{prev_page} || '';
1071         if ($prev) {
1072                 $next = $next ? "$next " : '     ';
1073                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1074         }
1075         "<hr><pre>page: $next$prev</pre>";
1076 }
1077
1078 sub index_nav { # callback for WwwStream
1079         my (undef, $ctx) = @_;
1080         pagination_footer($ctx, '.')
1081 }
1082
1083 sub paginate_recent ($$) {
1084         my ($ctx, $lim) = @_;
1085         my $t = $ctx->{qp}->{t} || '';
1086         my $opts = { limit => $lim };
1087         my ($after, $before);
1088
1089         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1090         # if only $after exists "YYYYMMDD.." because "." could be skipped
1091         # if interpreted as an end-of-sentence
1092         $t =~ s/\A(\d{8,14})-// and $after = str2ts($1);
1093         $t =~ /\A(\d{8,14})\z/ and $before = str2ts($1);
1094
1095         my $ibx = $ctx->{-inbox};
1096         my $msgs = $ibx->recent($opts, $after, $before);
1097         my $nr = scalar @$msgs;
1098         if ($nr < $lim && defined($after)) {
1099                 $after = $before = undef;
1100                 $msgs = $ibx->recent($opts);
1101                 $nr = scalar @$msgs;
1102         }
1103         my $more = $nr == $lim;
1104         my ($newest, $oldest);
1105         if ($nr) {
1106                 $newest = $msgs->[0]->{ts};
1107                 $oldest = $msgs->[-1]->{ts};
1108                 # if we only had $after, our SQL query in ->recent ordered
1109                 if ($newest < $oldest) {
1110                         ($oldest, $newest) = ($newest, $oldest);
1111                         $more = 0 if defined($after) && $after < $oldest;
1112                 }
1113         }
1114         if (defined($oldest) && $more) {
1115                 my $s = ts2str($oldest);
1116                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1117         }
1118         if (defined($newest) && (defined($before) || defined($after))) {
1119                 my $s = ts2str($newest);
1120                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1121         }
1122         $msgs;
1123 }
1124
1125 sub index_topics {
1126         my ($ctx) = @_;
1127         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1128         if (@$msgs) {
1129                 walk_thread(thread_results($ctx, $msgs), $ctx, *acc_topic);
1130         }
1131         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), *index_nav);
1132 }
1133
1134 sub thread_adj_level {
1135         my ($ctx, $level) = @_;
1136
1137         my $max = $ctx->{cur_level};
1138         if ($level <= 0) {
1139                 return ('', '') if $max == 0; # flat output
1140
1141                 # reset existing lists
1142                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1143                 $ctx->{cur_level} = 0;
1144                 ("$beg</ul>", '');
1145         } elsif ($level == $max) { # continue existing list
1146                 qw(<li> </li>);
1147         } elsif ($level < $max) {
1148                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1149                 $ctx->{cur_level} = $level;
1150                 ("$beg<li>", '</li>');
1151         } else { # ($level > $max) # start a new level
1152                 $ctx->{cur_level} = $level;
1153                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1154                 ($beg, '</li>');
1155         }
1156 }
1157
1158 sub ghost_index_entry {
1159         my ($ctx, $level, $node) = @_;
1160         my ($beg, $end) = thread_adj_level($ctx,  $level);
1161         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1162                 . '</pre>' . $end;
1163 }
1164
1165 1;