lib/PublicInbox/ViewDiff.pm

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # used by PublicInbox::View
   5 # This adds CSS spans for diff highlighting.
   6 # It also generates links for ViewVCS + SolverGit to show
   7 # (or reconstruct) blobs.
   8
   9 package PublicInbox::ViewDiff;
  10 use 5.010_001;
  11 use strict;
  12 use warnings;
  13 use base qw(Exporter);
  14 our @EXPORT_OK = qw(flush_diff);
  15 use URI::Escape qw(uri_escape_utf8);
  16 use PublicInbox::Hval qw(ascii_html to_attr);
  17 use PublicInbox::Git qw(git_unquote);
  18
  19 sub UNSAFE () { "^A-Za-z0-9\-\._~/" }
  20
  21 my $OID_NULL = '0{7,40}';
  22 my $OID_BLOB = '[a-f0-9]{7,40}';
  23
  24 # cf. git diff.c :: get_compact_summary
  25 my $DIFFSTAT_COMMENT = qr/\((?:new|gone|(?:(?:new|mode) [\+\-][lx]))\)/;
  26
  27 # link to line numbers in blobs
  28 sub diff_hunk ($$$$) {
  29         my ($dst, $dctx, $ca, $cb) = @_;
  30         my ($oid_a, $oid_b, $spfx) = @$dctx{qw(oid_a oid_b spfx)};
  31
  32         if (defined($spfx) && defined($oid_a) && defined($oid_b)) {
  33                 my ($n) = ($ca =~ /^-([0-9]+)/);
  34                 $n = defined($n) ? do { ++$n; "#n$n" } : '';
  35
  36                 $$dst .= qq(@@ <a\nhref="$spfx$oid_a/s/$dctx->{Q}$n">$ca</a>);
  37
  38                 ($n) = ($cb =~ /^\+([0-9]+)/);
  39                 $n = defined($n) ? do { ++$n; "#n$n" } : '';
  40                 $$dst .= qq( <a\nhref="$spfx$oid_b/s/$dctx->{Q}$n">$cb</a> @@);
  41         } else {
  42                 $$dst .= "@@ $ca $cb @@";
  43         }
  44 }
  45
  46 sub oid ($$$) {
  47         my ($dctx, $spfx, $oid) = @_;
  48         defined($spfx) ? qq(<a\nhref="$spfx$oid/s/$dctx->{Q}">$oid</a>) : $oid;
  49 }
  50
  51 # returns true if diffstat anchor written, false otherwise
  52 sub anchor0 ($$$$) {
  53         my ($dst, $ctx, $fn, $rest) = @_;
  54
  55         my $orig = $fn;
  56
  57         # normal git diffstat output is impossible to parse reliably
  58         # without --numstat, and that isn't the default for format-patch.
  59         # So only do best-effort handling of renames for common cases;
  60         # which works well in practice. If projects put "=>", or trailing
  61         # spaces in filenames, oh well :P
  62         $fn =~ s/(?: *$DIFFSTAT_COMMENT)? *\z//so;
  63         $fn =~ s/{(?:.+) => (.+)}/$1/ or $fn =~ s/.* => (.+)/$1/;
  64         $fn = git_unquote($fn);
  65
  66         # long filenames will require us to walk backwards in anchor1
  67         if ($fn =~ s!\A\.\.\./?!!) {
  68                 $ctx->{-long_path}->{$fn} = qr/\Q$fn\E\z/s;
  69         }
  70
  71         if (my $attr = to_attr($ctx->{-apfx}.$fn)) {
  72                 $ctx->{-anchors}->{$attr} = 1;
  73                 my $spaces = ($orig =~ s/( +)\z//) ? $1 : '';
  74                 $$dst .= " <a\nid=i$attr\nhref=#$attr>" .
  75                         ascii_html($orig) . '</a>' . $spaces .
  76                         $ctx->{-linkify}->to_html($rest);
  77                 return 1;
  78         }
  79         undef;
  80 }
  81
  82 # returns "diff --git" anchor destination, undef otherwise
  83 sub anchor1 ($$) {
  84         my ($ctx, $pb) = @_;
  85         my $attr = to_attr($ctx->{-apfx}.$pb) or return;
  86
  87         my $ok = delete $ctx->{-anchors}->{$attr};
  88
  89         # unlikely, check the end of all long path names we captured:
  90         unless ($ok) {
  91                 my $lp = $ctx->{-long_path} or return;
  92                 foreach my $fn (keys %$lp) {
  93                         $pb =~ $lp->{$fn} or next;
  94
  95                         delete $lp->{$fn};
  96                         $attr = to_attr($ctx->{-apfx}.$fn) or return;
  97                         $ok = delete $ctx->{-anchors}->{$attr} or return;
  98                         last;
  99                 }
 100         }
 101         $ok ? "<a\nhref=#i$attr\nid=$attr>diff</a> --git" : undef
 102 }
 103
 104 sub diff_header ($$$$) {
 105         my ($dst, $x, $ctx, $top) = @_;
 106         my (undef, undef, $pa, $pb) = splice(@$top, 0, 4); # ignore oid_{a,b}
 107         my $spfx = $ctx->{-spfx};
 108         my $dctx = { spfx => $spfx };
 109
 110         # get rid of leading "a/" or "b/" (or whatever --{src,dst}-prefix are)
 111         $pa = (split('/', git_unquote($pa), 2))[1] if $pa ne '/dev/null';
 112         $pb = (split('/', git_unquote($pb), 2))[1] if $pb ne '/dev/null';
 113         if ($pa eq $pb && $pb ne '/dev/null') {
 114                 $dctx->{Q} = "?b=".uri_escape_utf8($pb, UNSAFE);
 115         } else {
 116                 my @q;
 117                 if ($pb ne '/dev/null') {
 118                         push @q, 'b='.uri_escape_utf8($pb, UNSAFE);
 119                 }
 120                 if ($pa ne '/dev/null') {
 121                         push @q, 'a='.uri_escape_utf8($pa, UNSAFE);
 122                 }
 123                 $dctx->{Q} = '?'.join('&amp;', @q);
 124         }
 125
 126         # linkify early and all at once, since we know the following
 127         # subst ops on $$x won't need further escaping:
 128         $$x = $ctx->{-linkify}->to_html($$x);
 129
 130         # no need to capture oid_a and oid_b on add/delete,
 131         # we just linkify OIDs directly via s///e in conditional
 132         if (($$x =~ s/^(index $OID_NULL\.\.)($OID_BLOB)\b/
 133                         $1 . oid($dctx, $spfx, $2)/emos) ||
 134                 ($$x =~ s/^index ($OID_BLOB)(\.\.$OID_NULL)\b/
 135                         'index ' . oid($dctx, $spfx, $1) . $2/emos)) {
 136         } elsif ($$x =~ /^index ($OID_BLOB)\.\.($OID_BLOB)/mos) {
 137                 # modification-only, not add/delete:
 138                 # linkify hunk headers later using oid_a and oid_b
 139                 @$dctx{qw(oid_a oid_b)} = ($1, $2);
 140         } else {
 141                 warn "BUG? <$$x> had no ^index line";
 142         }
 143         $$x =~ s!^diff --git!anchor1($ctx, $pb) // 'diff --git'!emos;
 144         $$dst .= qq(<span\nclass="head">);
 145         $$dst .= $$x;
 146         $$dst .= '</span>';
 147         $dctx;
 148 }
 149
 150 sub diff_before_or_after ($$$) {
 151         my ($dst, $ctx, $x) = @_;
 152         my $linkify = $ctx->{-linkify};
 153         for my $y (split(/(^---\n)/sm, $$x)) {
 154                 if ($y =~ /\A---\n\z/s) {
 155                         $$dst .= "---\n"; # all HTML is "\r\n" => "\n"
 156                 } elsif ($y =~ /^ [0-9]+ files? changed, /sm) {
 157                         # ok, looks like a diffstat, go line-by-line:
 158                         for my $l (split(/^/m, $y)) {
 159                                 if ($l =~ /^ (.+)( +\| .*\z)/s) {
 160                                         anchor0($dst, $ctx, $1, $2) and next;
 161                                 }
 162                                 $$dst .= $linkify->to_html($l);
 163                         }
 164                 } else { # commit message, notes, etc
 165                         $$dst .= $linkify->to_html($y);
 166                 }
 167         }
 168 }
 169
 170 # callers must do CRLF => LF conversion before calling this
 171 sub flush_diff ($$$) {
 172         my ($dst, $ctx, $cur) = @_;
 173         state $LF = qr!\n!;
 174         state $ANY = qr![^\n]!;
 175         state $FN = qr!(?:"?[^/\n]+/[^\n]+|/dev/null)!;
 176
 177         my @top = split(/(
 178                 (?:     # begin header stuff, don't capture filenames, here,
 179                         # but instead wait for the --- and +++ lines.
 180                         (?:^diff\x20--git\x20$FN\x20$FN$LF)
 181
 182                         # old mode || new mode || copy|rename|deleted|...
 183                         (?:^[a-z]$ANY+$LF)*
 184                 )? # end of optional stuff, everything below is required
 185                 ^index\x20($OID_BLOB)\.\.($OID_BLOB)$ANY*$LF
 186                 ^---\x20($FN)$LF
 187                 ^\+{3}\x20($FN)$LF)/smxo, $$cur);
 188         $$cur = undef;
 189
 190         my $linkify = $ctx->{-linkify};
 191         my $dctx; # {}, keys: Q, oid_a, oid_b
 192
 193         while (defined(my $x = shift @top)) {
 194                 if (scalar(@top) >= 4 &&
 195                                 $top[1] =~ /\A$OID_BLOB\z/os &&
 196                                 $top[0] =~ /\A$OID_BLOB\z/os) {
 197                         $dctx = diff_header($dst, \$x, $ctx, \@top);
 198                 } elsif ($dctx) {
 199                         my $after = '';
 200                         for my $s (split(/((?:(?:^\+[^\n]*\n)+)|
 201                                         (?:(?:^-[^\n]*\n)+)|
 202                                         (?:^@@ [^\n]+\n))/xsm, $x)) {
 203                                 if (!defined($dctx)) {
 204                                         $after .= $s;
 205                                 } elsif ($s =~ s/\A@@ (\S+) (\S+) @@//) {
 206                                         $$dst .= qq(<span\nclass="hunk">);
 207                                         diff_hunk($dst, $dctx, $1, $2);
 208                                         $$dst .= $linkify->to_html($s);
 209                                         $$dst .= '</span>';
 210                                 } elsif ($s =~ /\A\+/) {
 211                                         $$dst .= qq(<span\nclass="add">);
 212                                         $$dst .= $linkify->to_html($s);
 213                                         $$dst .= '</span>';
 214                                 } elsif ($s =~ /\A-- $/sm) { # email sig starts
 215                                         $dctx = undef;
 216                                         $after .= $s;
 217                                 } elsif ($s =~ /\A-/) {
 218                                         $$dst .= qq(<span\nclass="del">);
 219                                         $$dst .= $linkify->to_html($s);
 220                                         $$dst .= '</span>';
 221                                 } else {
 222                                         $$dst .= $linkify->to_html($s);
 223                                 }
 224                         }
 225                         diff_before_or_after($dst, $ctx, \$after) unless $dctx;
 226                 } else {
 227                         diff_before_or_after($dst, $ctx, \$x);
 228                 }
 229         }
 230 }
 231
 232 1;