lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MIME;
  10 use PublicInbox::Git;
  11 use PublicInbox::Import;
  12 use PublicInbox::MDA;
  13 use PublicInbox::Spawn qw(spawn);
  14 use PublicInbox::InboxWritable;
  15 use File::Temp qw//;
  16 use PublicInbox::Filter::Base;
  17 use PublicInbox::Spamcheck;
  18 *REJECT = *PublicInbox::Filter::Base::REJECT;
  19
  20 sub new {
  21         my ($class, $config) = @_;
  22         my (%mdmap, @mdir, $spamc);
  23         my %uniq;
  24
  25         # "publicinboxwatch" is the documented namespace
  26         # "publicinboxlearn" is legacy but may be supported
  27         # indefinitely...
  28         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  29                 my $k = "$pfx.watchspam";
  30                 if (my $dir = $config->{$k}) {
  31                         if (is_maildir($dir)) {
  32                                 # skip "new", no MUA has seen it, yet.
  33                                 my $cur = "$dir/cur";
  34                                 my $old = $mdmap{$cur};
  35                                 if (ref($old)) {
  36                                         foreach my $ibx (@$old) {
  37                                                 warn <<"";
  38 "$cur already watched for `$ibx->{name}'
  39
  40                                         }
  41                                         die;
  42                                 }
  43                                 push @mdir, $cur;
  44                                 $uniq{$cur}++;
  45                                 $mdmap{$cur} = 'watchspam';
  46                         } else {
  47                                 warn "unsupported $k=$dir\n";
  48                         }
  49                 }
  50         }
  51
  52         my $k = 'publicinboxwatch.spamcheck';
  53         my $default = undef;
  54         my $spamcheck = PublicInbox::Spamcheck::get($config, $k, $default);
  55         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  56
  57         $config->each_inbox(sub {
  58                 # need to make all inboxes writable for spam removal:
  59                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  60
  61                 my $watch = $ibx->{watch} or return;
  62                 if (is_maildir($watch)) {
  63                         if (my $wm = $ibx->{watchheader}) {
  64                                 my ($k, $v) = split(/:/, $wm, 2);
  65                                 $ibx->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  66                         }
  67                         my $new = "$watch/new";
  68                         my $cur = "$watch/cur";
  69                         push @mdir, $new unless $uniq{$new}++;
  70                         push @mdir, $cur unless $uniq{$cur}++;
  71
  72                         push @{$mdmap{$new} ||= []}, $ibx;
  73                         push @{$mdmap{$cur} ||= []}, $ibx;
  74                 } else {
  75                         warn "watch unsupported: $k=$watch\n";
  76                 }
  77         });
  78         return unless @mdir;
  79
  80         my $mdre = join('|', map { quotemeta($_) } @mdir);
  81         $mdre = qr!\A($mdre)/!;
  82         bless {
  83                 spamcheck => $spamcheck,
  84                 mdmap => \%mdmap,
  85                 mdir => \@mdir,
  86                 mdre => $mdre,
  87                 config => $config,
  88                 importers => {},
  89                 opendirs => {}, # dirname => dirhandle (in progress scans)
  90         }, $class;
  91 }
  92
  93 sub _done_for_now {
  94         my ($self) = @_;
  95         my $importers = $self->{importers};
  96         foreach my $im (values %$importers) {
  97                 $im->done;
  98         }
  99 }
 100
 101 sub _try_fsn_paths {
 102         my ($self, $scan_re, $paths) = @_;
 103         foreach (@$paths) {
 104                 my $path = $_->{path};
 105                 if ($path =~ $scan_re) {
 106                         scan($self, $path);
 107                 } else {
 108                         _try_path($self, $path);
 109                 }
 110         }
 111         _done_for_now($self);
 112 }
 113
 114 sub _remove_spam {
 115         my ($self, $path) = @_;
 116         # path must be marked as (S)een
 117         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 118         my $mime = _path_to_mime($path) or return;
 119         $self->{config}->each_inbox(sub {
 120                 my ($ibx) = @_;
 121                 eval {
 122                         my $im = _importer_for($self, $ibx);
 123                         $im->remove($mime, 'spam');
 124                         if (my $scrub = $ibx->filter($im)) {
 125                                 my $scrubbed = $scrub->scrub($mime, 1);
 126                                 $scrubbed or return;
 127                                 $scrubbed == REJECT() and return;
 128                                 $im->remove($scrubbed, 'spam');
 129                         }
 130                 };
 131                 if ($@) {
 132                         warn "error removing spam at: ", $path,
 133                                 " from ", $ibx->{name}, ': ', $@, "\n";
 134                 }
 135         })
 136 }
 137
 138 sub _try_path {
 139         my ($self, $path) = @_;
 140         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 141         if ($path !~ $self->{mdre}) {
 142                 warn "unrecognized path: $path\n";
 143                 return;
 144         }
 145         my $inboxes = $self->{mdmap}->{$1};
 146         unless ($inboxes) {
 147                 warn "unmappable dir: $1\n";
 148                 return;
 149         }
 150         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 151                 return _remove_spam($self, $path);
 152         }
 153         foreach my $ibx (@$inboxes) {
 154                 my $mime = _path_to_mime($path) or next;
 155                 my $im = _importer_for($self, $ibx);
 156
 157                 my $wm = $ibx->{-watchheader};
 158                 if ($wm) {
 159                         my $v = $mime->header_obj->header_raw($wm->[0]);
 160                         next unless ($v && $v =~ $wm->[1]);
 161                 }
 162
 163                 if (my $scrub = $ibx->filter($im)) {
 164                         my $ret = $scrub->scrub($mime) or next;
 165                         $ret == REJECT() and next;
 166                         $mime = $ret;
 167                 }
 168                 $im->add($mime, $self->{spamcheck});
 169         }
 170 }
 171
 172 sub quit { trigger_scan($_[0], 'quit') }
 173
 174 sub watch {
 175         my ($self) = @_;
 176         my $scan = File::Temp->newdir("public-inbox-watch.$$.scan.XXXXXX",
 177                                         TMPDIR => 1);
 178         my $scandir = $self->{scandir} = $scan->dirname;
 179         my $re = qr!\A$scandir/!;
 180         my $cb = sub { _try_fsn_paths($self, $re, \@_) };
 181
 182         # lazy load here, we may support watching via IMAP IDLE
 183         # in the future...
 184         require Filesys::Notify::Simple;
 185         my $fsn = Filesys::Notify::Simple->new([@{$self->{mdir}}, $scandir]);
 186         $fsn->wait($cb) until $self->{quit};
 187 }
 188
 189 sub trigger_scan {
 190         my ($self, $base) = @_;
 191         my $dir = $self->{scandir} or return;
 192         open my $fh, '>', "$dir/$base" or die "open $dir/$base failed: $!\n";
 193         close $fh or die "close $dir/$base failed: $!\n";
 194 }
 195
 196 sub scan {
 197         my ($self, $path) = @_;
 198         if ($path =~ /quit\z/) {
 199                 %{$self->{opendirs}} = ();
 200                 _done_for_now($self);
 201                 delete $self->{scandir};
 202                 $self->{quit} = 1;
 203                 return;
 204         }
 205         # else: $path =~ /(cont|full)\z/
 206         return if $self->{quit};
 207         my $max = 10;
 208         my $opendirs = $self->{opendirs};
 209         my @dirnames = keys %$opendirs;
 210         foreach my $dir (@dirnames) {
 211                 my $dh = delete $opendirs->{$dir};
 212                 my $n = $max;
 213                 while (my $fn = readdir($dh)) {
 214                         _try_path($self, "$dir/$fn");
 215                         last if --$n < 0;
 216                 }
 217                 $opendirs->{$dir} = $dh if $n < 0;
 218         }
 219         if ($path =~ /full\z/) {
 220                 foreach my $dir (@{$self->{mdir}}) {
 221                         next if $opendirs->{$dir}; # already in progress
 222                         my $ok = opendir(my $dh, $dir);
 223                         unless ($ok) {
 224                                 warn "failed to open $dir: $!\n";
 225                                 next;
 226                         }
 227                         my $n = $max;
 228                         while (my $fn = readdir($dh)) {
 229                                 _try_path($self, "$dir/$fn");
 230                                 last if --$n < 0;
 231                         }
 232                         $opendirs->{$dir} = $dh if $n < 0;
 233                 }
 234         }
 235         _done_for_now($self);
 236         # do we have more work to do?
 237         trigger_scan($self, 'cont') if keys %$opendirs;
 238 }
 239
 240 sub _path_to_mime {
 241         my ($path) = @_;
 242         if (open my $fh, '<', $path) {
 243                 local $/;
 244                 my $str = <$fh>;
 245                 $str or return;
 246                 return PublicInbox::MIME->new(\$str);
 247         } elsif ($!{ENOENT}) {
 248                 return;
 249         } else {
 250                 warn "failed to open $path: $!\n";
 251                 return;
 252         }
 253 }
 254
 255 sub _importer_for {
 256         my ($self, $ibx) = @_;
 257         my $importers = $self->{importers};
 258         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
 259         if (scalar(keys(%$importers)) > 2) {
 260                 delete $importers->{"$ibx"};
 261                 _done_for_now($self);
 262         }
 263
 264         $importers->{"$ibx"} = $im;
 265 }
 266
 267 sub _spamcheck_cb {
 268         my ($sc) = @_;
 269         sub {
 270                 my ($mime) = @_;
 271                 my $tmp = '';
 272                 if ($sc->spamcheck($mime, \$tmp)) {
 273                         return PublicInbox::MIME->new(\$tmp);
 274                 }
 275                 warn $mime->header('Message-ID')." failed spam check\n";
 276                 undef;
 277         }
 278 }
 279
 280 sub is_maildir {
 281         $_[0] =~ s!\Amaildir:!! or return;
 282         $_[0] =~ tr!/!/!s;
 283         $_[0] =~ s!/\z!!;
 284         $_[0];
 285 }
 286
 287 1;