lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MIME;
  10 use PublicInbox::Git;
  11 use PublicInbox::Import;
  12 use PublicInbox::MDA;
  13 use PublicInbox::Spawn qw(spawn);
  14 use PublicInbox::InboxWritable;
  15 use File::Temp qw//;
  16 use PublicInbox::Filter::Base;
  17 use PublicInbox::Spamcheck;
  18 *REJECT = *PublicInbox::Filter::Base::REJECT;
  19
  20 sub new {
  21         my ($class, $config) = @_;
  22         my (%mdmap, @mdir, $spamc);
  23         my %uniq;
  24
  25         # "publicinboxwatch" is the documented namespace
  26         # "publicinboxlearn" is legacy but may be supported
  27         # indefinitely...
  28         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  29                 my $k = "$pfx.watchspam";
  30                 if (my $dir = $config->{$k}) {
  31                         if (is_maildir($dir)) {
  32                                 # skip "new", no MUA has seen it, yet.
  33                                 my $cur = "$dir/cur";
  34                                 my $old = $mdmap{$cur};
  35                                 if (ref($old)) {
  36                                         foreach my $ibx (@$old) {
  37                                                 warn <<"";
  38 "$cur already watched for `$ibx->{name}'
  39
  40                                         }
  41                                         die;
  42                                 }
  43                                 push @mdir, $cur;
  44                                 $uniq{$cur}++;
  45                                 $mdmap{$cur} = 'watchspam';
  46                         } else {
  47                                 warn "unsupported $k=$dir\n";
  48                         }
  49                 }
  50         }
  51
  52         my $k = 'publicinboxwatch.spamcheck';
  53         my $default = undef;
  54         my $spamcheck = PublicInbox::Spamcheck::get($config, $k, $default);
  55         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  56
  57         $config->each_inbox(sub {
  58                 # need to make all inboxes writable for spam removal:
  59                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  60
  61                 my $watch = $ibx->{watch} or return;
  62                 if (is_maildir($watch)) {
  63                         if (my $wm = $ibx->{watchheader}) {
  64                                 my ($k, $v) = split(/:/, $wm, 2);
  65                                 $ibx->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  66                         }
  67                         my $new = "$watch/new";
  68                         my $cur = "$watch/cur";
  69                         push @mdir, $new unless $uniq{$new}++;
  70                         push @mdir, $cur unless $uniq{$cur}++;
  71
  72                         push @{$mdmap{$new} ||= []}, $ibx;
  73                         push @{$mdmap{$cur} ||= []}, $ibx;
  74                 } else {
  75                         warn "watch unsupported: $k=$watch\n";
  76                 }
  77         });
  78         return unless @mdir;
  79
  80         my $mdre = join('|', map { quotemeta($_) } @mdir);
  81         $mdre = qr!\A($mdre)/!;
  82         bless {
  83                 spamcheck => $spamcheck,
  84                 mdmap => \%mdmap,
  85                 mdir => \@mdir,
  86                 mdre => $mdre,
  87                 config => $config,
  88                 importers => {},
  89                 opendirs => {}, # dirname => dirhandle (in progress scans)
  90         }, $class;
  91 }
  92
  93 sub _done_for_now {
  94         my ($self) = @_;
  95         my $importers = $self->{importers};
  96         foreach my $im (values %$importers) {
  97                 $im->done;
  98         }
  99 }
 100
 101 sub _try_fsn_paths {
 102         my ($self, $scan_re, $paths) = @_;
 103         foreach (@$paths) {
 104                 my $path = $_->{path};
 105                 if ($path =~ $scan_re) {
 106                         scan($self, $path);
 107                 } else {
 108                         _try_path($self, $path);
 109                 }
 110         }
 111         _done_for_now($self);
 112 }
 113
 114 sub _remove_spam {
 115         my ($self, $path) = @_;
 116         # path must be marked as (S)een
 117         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 118         my $mime = _path_to_mime($path) or return;
 119         $self->{config}->each_inbox(sub {
 120                 my ($ibx) = @_;
 121                 eval {
 122                         my $im = _importer_for($self, $ibx);
 123                         $im->remove($mime, 'spam');
 124                         if (my $scrub = $ibx->filter($im)) {
 125                                 my $scrubbed = $scrub->scrub($mime, 1);
 126                                 $scrubbed or return;
 127                                 $scrubbed == REJECT() and return;
 128                                 $im->remove($scrubbed, 'spam');
 129                         }
 130                 };
 131                 if ($@) {
 132                         warn "error removing spam at: ", $path,
 133                                 " from ", $ibx->{name}, ': ', $@, "\n";
 134                 }
 135         })
 136 }
 137
 138 sub _try_path {
 139         my ($self, $path) = @_;
 140         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 141         if ($path !~ $self->{mdre}) {
 142                 warn "unrecognized path: $path\n";
 143                 return;
 144         }
 145         my $inboxes = $self->{mdmap}->{$1};
 146         unless ($inboxes) {
 147                 warn "unmappable dir: $1\n";
 148                 return;
 149         }
 150         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 151                 return _remove_spam($self, $path);
 152         }
 153
 154         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 155         local $SIG{__WARN__} = sub {
 156                 $warn_cb->("path: $path\n");
 157                 $warn_cb->(@_);
 158         };
 159         foreach my $ibx (@$inboxes) {
 160                 my $mime = _path_to_mime($path) or next;
 161                 my $im = _importer_for($self, $ibx);
 162
 163                 my $wm = $ibx->{-watchheader};
 164                 if ($wm) {
 165                         my $v = $mime->header_obj->header_raw($wm->[0]);
 166                         next unless ($v && $v =~ $wm->[1]);
 167                 }
 168
 169                 if (my $scrub = $ibx->filter($im)) {
 170                         my $ret = $scrub->scrub($mime) or next;
 171                         $ret == REJECT() and next;
 172                         $mime = $ret;
 173                 }
 174                 $im->add($mime, $self->{spamcheck});
 175         }
 176 }
 177
 178 sub quit { trigger_scan($_[0], 'quit') }
 179
 180 sub watch {
 181         my ($self) = @_;
 182         my $scan = File::Temp->newdir("public-inbox-watch.$$.scan.XXXXXX",
 183                                         TMPDIR => 1);
 184         my $scandir = $self->{scandir} = $scan->dirname;
 185         my $re = qr!\A$scandir/!;
 186         my $cb = sub { _try_fsn_paths($self, $re, \@_) };
 187
 188         # lazy load here, we may support watching via IMAP IDLE
 189         # in the future...
 190         require Filesys::Notify::Simple;
 191         my $fsn = Filesys::Notify::Simple->new([@{$self->{mdir}}, $scandir]);
 192         $fsn->wait($cb) until $self->{quit};
 193 }
 194
 195 sub trigger_scan {
 196         my ($self, $base) = @_;
 197         my $dir = $self->{scandir} or return;
 198         open my $fh, '>', "$dir/$base" or die "open $dir/$base failed: $!\n";
 199         close $fh or die "close $dir/$base failed: $!\n";
 200 }
 201
 202 sub scan {
 203         my ($self, $path) = @_;
 204         if ($path =~ /quit\z/) {
 205                 %{$self->{opendirs}} = ();
 206                 _done_for_now($self);
 207                 delete $self->{scandir};
 208                 $self->{quit} = 1;
 209                 return;
 210         }
 211         # else: $path =~ /(cont|full)\z/
 212         return if $self->{quit};
 213         my $max = 10;
 214         my $opendirs = $self->{opendirs};
 215         my @dirnames = keys %$opendirs;
 216         foreach my $dir (@dirnames) {
 217                 my $dh = delete $opendirs->{$dir};
 218                 my $n = $max;
 219                 while (my $fn = readdir($dh)) {
 220                         _try_path($self, "$dir/$fn");
 221                         last if --$n < 0;
 222                 }
 223                 $opendirs->{$dir} = $dh if $n < 0;
 224         }
 225         if ($path =~ /full\z/) {
 226                 foreach my $dir (@{$self->{mdir}}) {
 227                         next if $opendirs->{$dir}; # already in progress
 228                         my $ok = opendir(my $dh, $dir);
 229                         unless ($ok) {
 230                                 warn "failed to open $dir: $!\n";
 231                                 next;
 232                         }
 233                         my $n = $max;
 234                         while (my $fn = readdir($dh)) {
 235                                 _try_path($self, "$dir/$fn");
 236                                 last if --$n < 0;
 237                         }
 238                         $opendirs->{$dir} = $dh if $n < 0;
 239                 }
 240         }
 241         _done_for_now($self);
 242         # do we have more work to do?
 243         trigger_scan($self, 'cont') if keys %$opendirs;
 244 }
 245
 246 sub _path_to_mime {
 247         my ($path) = @_;
 248         if (open my $fh, '<', $path) {
 249                 local $/;
 250                 my $str = <$fh>;
 251                 $str or return;
 252                 return PublicInbox::MIME->new(\$str);
 253         } elsif ($!{ENOENT}) {
 254                 return;
 255         } else {
 256                 warn "failed to open $path: $!\n";
 257                 return;
 258         }
 259 }
 260
 261 sub _importer_for {
 262         my ($self, $ibx) = @_;
 263         my $importers = $self->{importers};
 264         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
 265         if (scalar(keys(%$importers)) > 2) {
 266                 delete $importers->{"$ibx"};
 267                 _done_for_now($self);
 268         }
 269
 270         $importers->{"$ibx"} = $im;
 271 }
 272
 273 sub _spamcheck_cb {
 274         my ($sc) = @_;
 275         sub {
 276                 my ($mime) = @_;
 277                 my $tmp = '';
 278                 if ($sc->spamcheck($mime, \$tmp)) {
 279                         return PublicInbox::MIME->new(\$tmp);
 280                 }
 281                 warn $mime->header('Message-ID')." failed spam check\n";
 282                 undef;
 283         }
 284 }
 285
 286 sub is_maildir {
 287         $_[0] =~ s!\Amaildir:!! or return;
 288         $_[0] =~ tr!/!/!s;
 289         $_[0] =~ s!/\z!!;
 290         $_[0];
 291 }
 292
 293 1;