script/lei

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
   7 use Errno qw(EINTR ECONNRESET);
   8 use PublicInbox::CmdIPC4;
   9 my $narg = 5;
  10 my ($sock, $pwd);
  11 my $recv_cmd = PublicInbox::CmdIPC4->can('recv_cmd4');
  12 my $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4') // do {
  13         require PublicInbox::Spawn; # takes ~50ms even if built *sigh*
  14         $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  15         PublicInbox::Spawn->can('send_cmd4');
  16 };
  17
  18 sub sigchld {
  19         my ($sig) = @_;
  20         my $flags = $sig ? POSIX::WNOHANG() : 0;
  21         while (waitpid(-1, $flags) > 0) {}
  22 }
  23
  24 sub exec_cmd {
  25         my ($fds, $argc, @argv) = @_;
  26         my @old = (*STDIN{IO}, *STDOUT{IO}, *STDERR{IO});
  27         my @rdr;
  28         for my $fd (@$fds) {
  29                 open(my $tmpfh, '+<&=', $fd) or die "open +<&=$fd: $!";
  30                 push @rdr, shift(@old), $tmpfh;
  31         }
  32         require POSIX; # WNOHANG
  33         $SIG{CHLD} = \&sigchld;
  34         my $pid = fork // die "fork: $!";
  35         if ($pid == 0) {
  36                 my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
  37                 while (my ($old_io, $tmpfh) = splice(@rdr, 0, 2)) {
  38                         open $old_io, '+<&', $tmpfh or die "open +<&=: $!";
  39                 }
  40                 %ENV = (%ENV, %env);
  41                 exec(@argv);
  42                 die "exec: @argv: $!";
  43         }
  44 }
  45
  46 if ($send_cmd && eval {
  47         my $path = do {
  48                 my $runtime_dir = ($ENV{XDG_RUNTIME_DIR} // '') . '/lei';
  49                 if ($runtime_dir eq '/lei') {
  50                         require File::Spec;
  51                         $runtime_dir = File::Spec->tmpdir."/lei-$<";
  52                 }
  53                 unless (-d $runtime_dir) {
  54                         require File::Path;
  55                         File::Path::mkpath($runtime_dir, 0, 0700);
  56                 }
  57                 "$runtime_dir/$narg.seq.sock";
  58         };
  59         my $addr = pack_sockaddr_un($path);
  60         socket($sock, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
  61         unless (connect($sock, $addr)) { # start the daemon if not started
  62                 local $ENV{PERL5LIB} = join(':', @INC);
  63                 open(my $daemon, '-|', $^X, qw[-MPublicInbox::LEI
  64                         -E PublicInbox::LEI::lazy_start(@ARGV)],
  65                         $path, $! + 0, $narg) or die "popen: $!";
  66                 while (<$daemon>) { warn $_ } # EOF when STDERR is redirected
  67                 close($daemon) or warn <<"";
  68 lei-daemon could not start, exited with \$?=$?
  69
  70                 # try connecting again anyways, unlink+bind may be racy
  71                 connect($sock, $addr) or die <<"";
  72 connect($path): $! (after attempted daemon start)
  73 Falling back to (slow) one-shot mode
  74
  75         }
  76         1;
  77 }) { # (Socket::MsgHdr|Inline::C), $sock, $pwd are all available:
  78         open my $dh, '<', '.' or die "open(.) $!";
  79         my $buf = join("\0", scalar(@ARGV), @ARGV);
  80         while (my ($k, $v) = each %ENV) { $buf .= "\0$k=$v" }
  81         $buf .= "\0\0";
  82         $send_cmd->($sock, [ 0, 1, 2, fileno($dh) ], $buf, MSG_EOR);
  83         my $x_it_code = 0;
  84         while (1) {
  85                 my (@fds) = $recv_cmd->($sock, $buf, 4096 * 33);
  86                 if (scalar(@fds) == 1 && !defined($fds[0])) {
  87                         last if $! == ECONNRESET;
  88                         next if $! == EINTR;
  89                         die "recvmsg: $!";
  90                 }
  91                 last if $buf eq '';
  92                 if ($buf =~ /\Ax_it ([0-9]+)\z/) {
  93                         $x_it_code = $1 + 0;
  94                         last;
  95                 } elsif ($buf =~ /\Achild_error ([0-9]+)\z/) {
  96                         $x_it_code = $1 + 0;
  97                 } elsif ($buf =~ /\Aexec (.+)\z/) {
  98                         exec_cmd(\@fds, split(/\0/, $1));
  99                 } else {
 100                         sigchld();
 101                         die $buf;
 102                 }
 103         }
 104         sigchld();
 105         if (my $sig = ($x_it_code & 127)) {
 106                 kill $sig, $$;
 107                 sleep;
 108         }
 109         exit($x_it_code >> 8);
 110 } else { # for systems lacking Socket::MsgHdr or Inline::C
 111         warn $@ if $@;
 112         require PublicInbox::LEI;
 113         PublicInbox::LEI::oneshot(__PACKAGE__);
 114 }