t/cgi.t

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # FIXME: this test is too slow and most non-CGI-requirements
   4 # should be moved over to things which use test_psgi
   5 use strict;
   6 use warnings;
   7 use Test::More;
   8 use Email::MIME;
   9 use File::Temp qw/tempdir/;
  10 use Cwd;
  11 eval { require IPC::Run };
  12 plan skip_all => "missing IPC::Run for t/cgi.t" if $@;
  13
  14 use constant CGI => "blib/script/public-inbox.cgi";
  15 my $index = "blib/script/public-inbox-index";
  16 my $tmpdir = tempdir('pi-cgi-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  17 my $home = "$tmpdir/pi-home";
  18 my $pi_home = "$home/.public-inbox";
  19 my $pi_config = "$pi_home/config";
  20 my $maindir = "$tmpdir/main.git";
  21 my $addr = 'test-public@example.com';
  22 my $cfgpfx = "publicinbox.test";
  23
  24 {
  25         is(1, mkdir($home, 0755), "setup ~/ for testing");
  26         is(1, mkdir($pi_home, 0755), "setup ~/.public-inbox");
  27         is(0, system(qw(git init -q --bare), $maindir), "git init (main)");
  28
  29         open my $fh, '>', "$maindir/description" or die "open: $!\n";
  30         print $fh "test for public-inbox\n";
  31         close $fh or die "close: $!\n";
  32         my %cfg = (
  33                 "$cfgpfx.address" => $addr,
  34                 "$cfgpfx.mainrepo" => $maindir,
  35         );
  36         while (my ($k,$v) = each %cfg) {
  37                 is(0, system(qw(git config --file), $pi_config, $k, $v),
  38                         "setup $k");
  39         }
  40 }
  41
  42 use_ok 'PublicInbox::Git';
  43 use_ok 'PublicInbox::Import';
  44 use_ok 'Email::MIME';
  45 my $git = PublicInbox::Git->new($maindir);
  46 my $im = PublicInbox::Import->new($git, 'test', $addr);
  47
  48 {
  49         local $ENV{HOME} = $home;
  50
  51         # inject some messages:
  52         my $mime = Email::MIME->new(<<EOF);
  53 From: Me <me\@example.com>
  54 To: You <you\@example.com>
  55 Cc: $addr
  56 Message-Id: <blah\@example.com>
  57 Subject: hihi
  58 Date: Thu, 01 Jan 1970 00:00:00 +0000
  59
  60 zzzzzz
  61 EOF
  62         $im->add($mime);
  63
  64         # deliver a reply, too
  65         my $reply = Email::MIME->new(<<EOF);
  66 From: You <you\@example.com>
  67 To: Me <me\@example.com>
  68 Cc: $addr
  69 In-Reply-To: <blah\@example.com>
  70 Message-Id: <blahblah\@example.com>
  71 Subject: Re: hihi
  72 Date: Thu, 01 Jan 1970 00:00:01 +0000
  73
  74 Me wrote:
  75 > zzzzzz
  76
  77 what?
  78 EOF
  79         $im->add($reply);
  80         $im->done;
  81 }
  82
  83 # obvious failures, first
  84 {
  85         local $ENV{HOME} = $home;
  86         my $res = cgi_run("/", "", "PUT");
  87         like($res->{head}, qr/Status:\s*405/i, "PUT not allowed");
  88
  89         $res = cgi_run("/");
  90         like($res->{head}, qr/Status:\s*404/i, "index returns 404");
  91 }
  92
  93 # dumb HTTP support
  94 {
  95         local $ENV{HOME} = $home;
  96         my $path = "/test/info/refs";
  97         my $res = cgi_run($path);
  98         like($res->{head}, qr/Status:\s*200/i, "info/refs readable");
  99         my $orig = $res->{body};
 100
 101         local $ENV{HTTP_RANGE} = 'bytes=5-10';
 102         $res = cgi_run($path);
 103         like($res->{head}, qr/Status:\s*206/i, "info/refs partial OK");
 104         is($res->{body}, substr($orig, 5, 6), 'partial body OK');
 105
 106         local $ENV{HTTP_RANGE} = 'bytes=5-';
 107         $res = cgi_run($path);
 108         like($res->{head}, qr/Status:\s*206/i, "info/refs partial past end OK");
 109         is($res->{body}, substr($orig, 5), 'partial body OK past end');
 110 }
 111
 112 # message-id pages
 113 {
 114         local $ENV{HOME} = $home;
 115         my $slashy_mid = 'slashy/asdf@example.com';
 116         my $reply = Email::MIME->new(<<EOF);
 117 From: You <you\@example.com>
 118 To: Me <me\@example.com>
 119 Cc: $addr
 120 Message-Id: <$slashy_mid>
 121 Subject: Re: hihi
 122 Date: Thu, 01 Jan 1970 00:00:01 +0000
 123
 124 slashy
 125 EOF
 126         $im->add($reply);
 127         $im->done;
 128
 129         my $res = cgi_run("/test/slashy/asdf\@example.com/raw");
 130         like($res->{body}, qr/Message-Id: <\Q$slashy_mid\E>/,
 131                 "slashy mid raw hit");
 132
 133         $res = cgi_run("/test/blahblah\@example.com/raw");
 134         like($res->{body}, qr/Message-Id: <blahblah\@example\.com>/,
 135                 "mid raw hit");
 136
 137         $res = cgi_run("/test/blahblah\@example.com/");
 138         like($res->{body}, qr/\A<html>/, "mid html hit");
 139         like($res->{head}, qr/Status: 200 OK/, "200 response");
 140
 141         $res = cgi_run("/test/blahblah\@example.com/f/");
 142         like($res->{head}, qr/Status: 301 Moved/, "301 response");
 143         like($res->{head},
 144                 qr!^Location: http://[^/]+/test/blahblah\@example\.com/\r\n!ms,
 145                 '301 redirect location');
 146
 147         $res = cgi_run("/test/new.html");
 148         like($res->{body}, qr/slashy%2Fasdf\@example\.com/,
 149                 "slashy URL generated correctly");
 150 }
 151
 152 # retrieve thread as an mbox
 153 {
 154         local $ENV{HOME} = $home;
 155         my $path = "/test/blahblah\@example.com/t.mbox.gz";
 156         my $res = cgi_run($path);
 157         like($res->{head}, qr/^Status: 501 /, "search not-yet-enabled");
 158         my $indexed = system($index, $maindir) == 0;
 159         if ($indexed) {
 160                 $res = cgi_run($path);
 161                 like($res->{head}, qr/^Status: 200 /, "search returned mbox");
 162                 eval {
 163                         require IO::Uncompress::Gunzip;
 164                         my $in = $res->{body};
 165                         my $out;
 166                         IO::Uncompress::Gunzip::gunzip(\$in => \$out);
 167                         like($out, qr/^From /m, "From lines in mbox");
 168                 };
 169         } else {
 170                 like($res->{head}, qr/^Status: 501 /, "search not available");
 171         }
 172
 173         my $have_xml_feed = eval { require XML::Feed; 1 } if $indexed;
 174         if ($have_xml_feed) {
 175                 $path = "/test/blahblah\@example.com/t.atom";
 176                 $res = cgi_run($path);
 177                 like($res->{head}, qr/^Status: 200 /, "atom returned 200");
 178                 like($res->{head}, qr!^Content-Type: application/atom\+xml!m,
 179                         "search returned atom");
 180                 my $p = XML::Feed->parse(\($res->{body}));
 181                 is($p->format, "Atom", "parsed atom feed");
 182                 is(scalar $p->entries, 3, "parsed three entries");
 183         }
 184 }
 185
 186 done_testing();
 187
 188 sub run_with_env {
 189         my ($env, @args) = @_;
 190         IPC::Run::run(@args, init => sub { %ENV = (%ENV, %$env) });
 191 }
 192
 193 sub cgi_run {
 194         my %env = (
 195                 PATH_INFO => $_[0],
 196                 QUERY_STRING => $_[1] || "",
 197                 SCRIPT_NAME => '',
 198                 REQUEST_URI => $_[0] . ($_[1] ? "?$_[1]" : ''),
 199                 REQUEST_METHOD => $_[2] || "GET",
 200                 GATEWAY_INTERFACE => 'CGI/1.1',
 201                 HTTP_ACCEPT => '*/*',
 202                 HTTP_HOST => 'test.example.com',
 203         );
 204         my ($in, $out, $err) = ("", "", "");
 205         my $rc = run_with_env(\%env, [CGI], \$in, \$out, \$err);
 206         my ($head, $body) = split(/\r\n\r\n/, $out, 2);
 207         { head => $head, body => $body, rc => $rc, err => $err }
 208 }