t/inbox_idle.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use PublicInbox::TestCommon;
   7 use PublicInbox::Config;
   8 require_git 2.6;
   9 require_mods(qw(DBD::SQLite));
  10 require PublicInbox::SearchIdx;
  11 use_ok 'PublicInbox::InboxIdle';
  12 my ($tmpdir, $for_destroy) = tmpdir();
  13
  14 for my $V (1, 2) {
  15         my $inboxdir = "$tmpdir/$V";
  16         my $ibx = create_inbox "idle$V", tmpdir => $inboxdir, version => $V,
  17                                 indexlevel => 'basic', -no_gc => 1, sub {
  18                 my ($im, $ibx) = @_; # capture
  19                 $im->done;
  20                 $ibx->init_inbox(0);
  21                 $_[0] = undef;
  22                 return if $V != 1;
  23                 my $sidx = PublicInbox::SearchIdx->new($ibx, 1);
  24                 $sidx->idx_acquire;
  25                 $sidx->set_metadata_once;
  26                 $sidx->idx_release; # allow watching on lockfile
  27         };
  28         my $obj = InboxIdleTestObj->new;
  29         my $pi_cfg = PublicInbox::Config->new(\<<EOF);
  30 publicinbox.inbox-idle.inboxdir=$inboxdir
  31 publicinbox.inbox-idle.indexlevel=basic
  32 publicinbox.inbox-idle.address=$ibx->{-primary_address}
  33 EOF
  34         my $ident = 'whatever';
  35         $pi_cfg->each_inbox(sub { shift->subscribe_unlock($ident, $obj) });
  36         my $ii = PublicInbox::InboxIdle->new($pi_cfg);
  37         ok($ii, 'InboxIdle created');
  38         SKIP: {
  39                 skip('inotify or kqueue missing', 1) unless $ii->{sock};
  40                 ok(fileno($ii->{sock}) >= 0, 'fileno() gave valid FD');
  41         }
  42         my $im = $ibx->importer(0);
  43         ok($im->add(eml_load('t/utf8.eml')), "$V added");
  44         $im->done;
  45         $ii->event_step;
  46         is(scalar @{$obj->{called}}, 1, 'called on unlock');
  47         $pi_cfg->each_inbox(sub { shift->unsubscribe_unlock($ident) });
  48         ok($im->add(eml_load('t/data/0001.patch')), "$V added #2");
  49         $im->done;
  50         $ii->event_step;
  51         is(scalar @{$obj->{called}}, 1, 'not called when unsubbed');
  52         $ii->close;
  53 }
  54
  55 done_testing;
  56
  57 package InboxIdleTestObj;
  58 use strict;
  59
  60 sub new { bless {}, shift }
  61
  62 sub on_inbox_unlock {
  63         my ($self, $ibx) = @_;
  64         push @{$self->{called}}, $ibx;
  65 }