t/lei-daemon.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
   6
   7 test_lei({ daemon_only => 1 }, sub {
   8         my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
   9                 require PublicInbox::CmdIPC4;
  10                 PublicInbox::CmdIPC4->can('send_cmd4');
  11         };
  12         $send_cmd or BAIL_OUT 'started testing lei-daemon w/o send_cmd4!';
  13
  14         my $sock = "$ENV{XDG_RUNTIME_DIR}/lei/5.seq.sock";
  15         my $err_log = "$ENV{XDG_RUNTIME_DIR}/lei/errors.log";
  16         lei_ok('daemon-pid');
  17         is($lei_err, '', 'no error from daemon-pid');
  18         like($lei_out, qr/\A[0-9]+\n\z/s, 'pid returned') or BAIL_OUT;
  19         chomp(my $pid = $lei_out);
  20         ok(kill(0, $pid), 'pid is valid');
  21         ok(-S $sock, 'sock created');
  22         is(-s $err_log, 0, 'nothing in errors.log');
  23         lei_ok('daemon-pid');
  24         chomp(my $pid_again = $lei_out);
  25         is($pid, $pid_again, 'daemon-pid idempotent');
  26
  27         SKIP: {
  28                 skip 'only testing open files on Linux', 1 if $^O ne 'linux';
  29                 my $d = "/proc/$pid/fd";
  30                 skip "no $d on Linux" unless -d $d;
  31                 my @before = sort(glob("$d/*"));
  32                 my $addr = pack_sockaddr_un($sock);
  33                 open my $null, '<', '/dev/null' or BAIL_OUT "/dev/null: $!";
  34                 my @fds = map { fileno($null) } (0..2);
  35                 for (0..10) {
  36                         socket(my $c, AF_UNIX, SOCK_SEQPACKET, 0) or
  37                                                         BAIL_OUT "socket: $!";
  38                         connect($c, $addr) or BAIL_OUT "connect: $!";
  39                         $send_cmd->($c, \@fds, 'hi',  MSG_EOR);
  40                 }
  41                 lei_ok('daemon-pid');
  42                 chomp($pid = $lei_out);
  43                 is($pid, $pid_again, 'pid unchanged after failed reqs');
  44                 my @after = sort(glob("$d/*"));
  45                 is_deeply(\@before, \@after, 'open files unchanged') or
  46                         diag explain([\@before, \@after]);;
  47         }
  48         lei_ok(qw(daemon-kill));
  49         is($lei_out, '', 'no output from daemon-kill');
  50         is($lei_err, '', 'no error from daemon-kill');
  51         for (0..100) {
  52                 kill(0, $pid) or last;
  53                 tick();
  54         }
  55         ok(-S $sock, 'sock still exists');
  56         ok(!kill(0, $pid), 'pid gone after stop');
  57
  58         lei_ok(qw(daemon-pid));
  59         chomp(my $new_pid = $lei_out);
  60         ok(kill(0, $new_pid), 'new pid is running');
  61         ok(-S $sock, 'sock still exists');
  62
  63         for my $sig (qw(-0 -CHLD)) {
  64                 lei_ok('daemon-kill', $sig, \"handles $sig");
  65         }
  66         is($lei_out.$lei_err, '', 'no output on innocuous signals');
  67         lei_ok('daemon-pid');
  68         chomp $lei_out;
  69         is($lei_out, $new_pid, 'PID unchanged after -0/-CHLD');
  70         unlink $sock or BAIL_OUT "unlink($sock) $!";
  71         for (0..100) {
  72                 kill('CHLD', $new_pid) or last;
  73                 tick();
  74         }
  75         ok(!kill(0, $new_pid), 'daemon exits after unlink');
  76 });
  77
  78 done_testing;