t/nntp.t

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Data::Dumper;
   7
   8 foreach my $mod (qw(DBD::SQLite Search::Xapian Danga::Socket)) {
   9         eval "require $mod";
  10         plan skip_all => "$mod missing for nntp.t" if $@;
  11 }
  12
  13 use_ok 'PublicInbox::NNTP';
  14 use_ok 'PublicInbox::Inbox';
  15
  16 {
  17         sub quote_str {
  18                 my (undef, $s) = split(/ = /, Dumper($_[0]), 2);
  19                 $s =~ s/;\n//;
  20                 $s;
  21         }
  22
  23         sub wm_prepare {
  24                 my ($wm) = @_;
  25                 my $orig = qq{'$wm'};
  26                 PublicInbox::NNTP::wildmat2re($_[0]);
  27                 my $new = quote_str($_[0]);
  28                 ($orig, $new);
  29         }
  30
  31         sub wildmat_like {
  32                 my ($str, $wm) = @_;
  33                 my ($orig, $new) = wm_prepare($wm);
  34                 like($str, $wm, "$orig matches '$str' using $new");
  35         }
  36
  37         sub wildmat_unlike {
  38                 my ($str, $wm, $check_ex) = @_;
  39                 if ($check_ex) {
  40                         use re 'eval';
  41                         my $re = qr/$wm/;
  42                         like($str, $re, "normal re with $wm matches, but ...");
  43                 }
  44                 my ($orig, $new) = wm_prepare($wm);
  45                 unlike($str, $wm, "$orig does not match '$str' using $new");
  46         }
  47
  48         wildmat_like('[foo]', '[\[foo\]]');
  49         wildmat_like('any', '*');
  50         wildmat_unlike('bar.foo.bar', 'foo.*');
  51
  52         # no code execution
  53         wildmat_unlike('HI', '(?{"HI"})', 1);
  54         wildmat_unlike('HI', '[(?{"HI"})]', 1);
  55 }
  56
  57 {
  58         sub ngpat_like {
  59                 my ($str, $pat) = @_;
  60                 my $orig = $pat;
  61                 PublicInbox::NNTP::ngpat2re($pat);
  62                 like($str, $pat, "'$orig' matches '$str' using $pat");
  63         }
  64
  65         ngpat_like('any', '*');
  66         ngpat_like('a.s.r', 'a.t,a.s.r');
  67         ngpat_like('a.s.r', 'a.t,a.s.*');
  68 }
  69
  70 {
  71         use POSIX qw(strftime);
  72         sub time_roundtrip {
  73                 my ($date, $time, $gmt) = @_;
  74                 my $m = join(' ', @_);
  75                 my $ts = PublicInbox::NNTP::parse_time(@_);
  76                 my @t = gmtime($ts);
  77                 my ($d, $t);
  78                 if (length($date) == 8) {
  79                         ($d, $t) = split(' ', strftime('%Y%m%d %H%M%S', @t));
  80                 } else {
  81                         ($d, $t) = split(' ', strftime('%g%m%d %H%M%S', @t));
  82                 }
  83                 is_deeply([$d, $t], [$date, $time], "roundtripped: $m");
  84                 $ts;
  85         }
  86         my $x1 = time_roundtrip(qw(20141109 060606 GMT));
  87         my $x2 = time_roundtrip(qw(141109 060606 GMT));
  88         my $x3 = time_roundtrip(qw(930724 060606 GMT));
  89
  90         SKIP: {
  91                 skip('YYMMDD test needs updating', 2) if (time > 0x7fffffff);
  92                 # our world probably ends in 2038, but if not we'll try to
  93                 # remember to update the test then
  94                 is($x1, $x2, 'YYYYMMDD and YYMMDD parse identically');
  95                 is(strftime('%Y', gmtime($x3)), '1993', '930724 was in 1993');
  96         }
  97 }
  98
  99 { # test setting NNTP headers in HEAD and ARTICLE requests
 100         require Email::MIME;
 101         my $u = 'https://example.com/a/';
 102         my $ng = PublicInbox::Inbox->new({ name => 'test',
 103                                         mainrepo => 'test.git',
 104                                         address => 'a@example.com',
 105                                         -primary_address => 'a@example.com',
 106                                         newsgroup => 'test',
 107                                         domain => 'example.com',
 108                                         url => '//example.com/a'});
 109         is($ng->base_url, $u, 'URL expanded');
 110         my $mid = 'a@b';
 111         my $mime = Email::MIME->new("Message-ID: <$mid>\r\n\r\n");
 112         my $hdr = $mime->header_obj;
 113         my $mock_self = { nntpd => { grouplist => [],
 114                                      servername => 'example.com' } };
 115         PublicInbox::NNTP::set_nntp_headers($mock_self, $hdr, $ng, 1, $mid);
 116         is_deeply([ $mime->header('Message-ID') ], [ "<$mid>" ],
 117                 'Message-ID unchanged');
 118         is_deeply([ $mime->header('Archived-At') ], [ "<${u}a\@b/>" ],
 119                 'Archived-At: set');
 120         is_deeply([ $mime->header('List-Archive') ], [ "<$u>" ],
 121                 'List-Archive: set');
 122         is_deeply([ $mime->header('List-Post') ], [ '<mailto:a@example.com>' ],
 123                 'List-Post: set');
 124         is_deeply([ $mime->header('Newsgroups') ], [ 'test' ],
 125                 'Newsgroups: set');
 126         is_deeply([ $mime->header('Xref') ], [ 'example.com test:1' ],
 127                 'Xref: set');
 128
 129         $ng->{-base_url} = 'http://mirror.example.com/m/';
 130         PublicInbox::NNTP::set_nntp_headers($mock_self, $hdr, $ng, 2, $mid);
 131         is_deeply([ $mime->header('Message-ID') ], [ "<$mid>" ],
 132                 'Message-ID unchanged');
 133         is_deeply([ $mime->header('Archived-At') ],
 134                 [ "<${u}a\@b/>", '<http://mirror.example.com/m/a@b/>' ],
 135                 'Archived-At: appended');
 136         is_deeply([ $mime->header('Xref') ], [ 'example.com test:2' ],
 137                 'Old Xref: clobbered');
 138 }
 139
 140 done_testing();