xt/imapd-mbsync-oimap.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # ensure mbsync and offlineimap compatibility
   5 use strict;
   6 use Test::More;
   7 use File::Path qw(mkpath);
   8 use PublicInbox::TestCommon;
   9 use PublicInbox::Spawn qw(which spawn);
  10 require_mods(qw(DBD::SQLite Email::Address::XS||Mail::Address));
  11 my $inboxdir = $ENV{GIANT_INBOX_DIR};
  12 (defined($inboxdir) && -d $inboxdir) or
  13         plan skip_all => "GIANT_INBOX_DIR not defined for $0";
  14 plan skip_all => "bad characters in $inboxdir" if $inboxdir =~ m![^\w\.\-/]!;
  15 my ($tmpdir, $for_destroy) = tmpdir();
  16 my $cfg = "$tmpdir/cfg";
  17 my $newsgroup = 'inbox.test';
  18 my $mailbox = "$newsgroup.0";
  19 {
  20         open my $fh, '>', $cfg or BAIL_OUT "open: $!";
  21         print $fh <<EOF or BAIL_OUT "print: $!";
  22 [publicinbox "test"]
  23         newsgroup = $newsgroup
  24         address = oimap\@example.com
  25         inboxdir = $inboxdir
  26 EOF
  27         close $fh or BAIL_OUT "close: $!";
  28 }
  29 my ($out, $err) = ("$tmpdir/stdout.log", "$tmpdir/stderr.log");
  30 my $sock = tcp_server();
  31 my $cmd = [ '-imapd', '-W0', "--stdout=$out", "--stderr=$err" ];
  32 my $env = { PI_CONFIG => $cfg };
  33 my $td = start_script($cmd, $env, { 3 => $sock }) or BAIL_OUT "-imapd: $?";
  34 {
  35         my $c = tcp_connect($sock);
  36         like(readline($c), qr/CAPABILITY /, 'got greeting');
  37 }
  38 my ($host, $port) = ($sock->sockhost, $sock->sockport);
  39 my %pids;
  40
  41 SKIP: {
  42         mkpath([map { "$tmpdir/oimapdir/$_" } qw(cur new tmp)]);
  43         my $oimap = which('offlineimap') or skip 'no offlineimap(1)', 1;
  44         open my $fh, '>', "$tmpdir/.offlineimaprc" or BAIL_OUT "open: $!";
  45         print $fh <<EOF or BAIL_OUT "print: $!";
  46 [general]
  47 accounts = test
  48 socktimeout = 10
  49 fsync = false
  50
  51 [Account test]
  52 localrepository = l.test
  53 remoterepository = r.test
  54
  55 [Repository l.test]
  56 type = Maildir
  57 localfolders = ~/oimapdir
  58
  59 [Repository r.test]
  60 type = IMAP
  61 ssl = no
  62 remotehost = $host
  63 remoteport = $port
  64 remoteuser = anonymous
  65 remotepass = Hunter2
  66
  67 # python-imaplib2 times out on select/poll when compression is enabled
  68 # <https://bugs.debian.org/961713>
  69 usecompression = no
  70 EOF
  71         close $fh or BAIL_OUT "close: $!";
  72         my $cmd = [ $oimap, qw(-o -q -u quiet) ];
  73         my $pid = spawn($cmd, { HOME => $tmpdir }, { 1 => 2 });
  74         $pids{$pid} = $cmd;
  75 }
  76
  77 SKIP: {
  78         mkpath([map { "$tmpdir/mbsyncdir/test/$_" } qw(cur new tmp)]);
  79         my $mbsync = which('mbsync') or skip 'no mbsync(1)', 1;
  80         open my $fh, '>', "$tmpdir/.mbsyncrc" or BAIL_OUT "open: $!";
  81         print $fh <<EOF or BAIL_OUT "print: $!";
  82 Create Slave
  83 SyncState *
  84 Remove None
  85 FSync no
  86
  87 MaildirStore local
  88 Path ~/mbsyncdir/
  89 Inbox ~/mbsyncdir/test
  90 SubFolders verbatim
  91
  92 IMAPStore remote
  93 Host $host
  94 Port $port
  95 User anonymous
  96 Pass Hunter2
  97 SSLType None
  98 UseNamespace no
  99 # DisableExtension COMPRESS=DEFLATE
 100
 101 Channel "test"
 102 Master ":remote:INBOX"
 103 Slave ":local:test"
 104 Expunge None
 105 Sync PullNew
 106 Patterns *
 107 EOF
 108         close $fh or BAIL_OUT "close: $!";
 109         my $cmd = [ $mbsync, qw(-aqq) ];
 110         my $pid = spawn($cmd, { HOME => $tmpdir }, { 1 => 2 });
 111         $pids{$pid} = $cmd;
 112 }
 113
 114 while (scalar keys %pids) {
 115         my $pid = waitpid(-1, 0) or next;
 116         my $cmd = delete $pids{$pid} or next;
 117         is($?, 0, join(' ', @$cmd, 'done'));
 118 }
 119
 120 my $sec = $ENV{TEST_PERSIST} // 0;
 121 diag "TEST_PERSIST=$sec";
 122 if ($sec) {
 123         diag "sleeping ${sec}s, imap://$host:$port/$mailbox available";
 124         diag "tmpdir=$tmpdir (Maildirs available)";
 125         diag "stdout=$out";
 126         diag "stderr=$err";
 127         diag "pid=$td->{pid}";
 128         sleep $sec;
 129 }
 130 $td->kill;
 131 $td->join;
 132 is($?, 0, 'no error on -imapd exit');
 133 done_testing;