+ # same limit as cgit/configfile.c::parse_configfile
+ return if $nesting > 8;
+
+ open my $fh, '<', $cgitrc or do {
+ warn "failed to open cgitrc=$cgitrc: $!\n";
+ return;
+ };
+
+ # FIXME: this doesn't support macro expansion via $VARS, yet
+ my $repo;
+ while (<$fh>) {
+ chomp;
+ if (m!\Arepo\.url=(.+?)/*\z!) {
+ my $nick = $1;
+ cgit_repo_merge($self, $repo->{dir}, $repo) if $repo;
+ $repo = { url => $nick };
+ } elsif (m!\Arepo\.path=(.+)\z!) {
+ if (defined $repo) {
+ $repo->{dir} = $1;
+ } else {
+ warn "$_ without repo.url\n";
+ }
+ } elsif (m!\Ainclude=(.+)\z!) {
+ parse_cgitrc($self, $1, $nesting + 1);
+ } elsif (m!\A(scan-hidden-path|remove-suffix)=([0-9]+)\z!) {
+ my ($k, $v) = ($1, $2);
+ $k =~ tr/-/_/;
+ $self->{"-cgit_$k"} = $v;
+ } elsif (m!\A(project-list|strict-export)=(.+)\z!) {
+ my ($k, $v) = ($1, $2);
+ $k =~ tr/-/_/;
+ $self->{"-cgit_$k"} = $v;
+ } elsif (m!\Ascan-path=(.+)\z!) {
+ if (defined(my $list = $self->{-cgit_project_list})) {
+ scan_projects_coderepo($self, $list, $1);
+ } else {
+ scan_tree_coderepo($self, $1);
+ }
+ } elsif (m!\A(?:css|favicon|logo|repo\.logo)=(/.+)\z!) {
+ # absolute paths for static files via PublicInbox::Cgit
+ $self->{-cgit_static}->{$1} = 1;
+ }
+ }
+ cgit_repo_merge($self, $repo->{dir}, $repo) if $repo;
+}
+
+# parse a code repo
+# Only git is supported at the moment, but SVN and Hg are possibilities
+sub _fill_code_repo {
+ my ($self, $nick) = @_;
+ my $pfx = "coderepo.$nick";
+ my $dir = $self->{"$pfx.dir"} // do { # aka "GIT_DIR"
+ warn "$pfx.dir unset\n";
+ return;
+ };
+ my $git = PublicInbox::Git->new($dir);
+ if (defined(my $cgits = $self->{"$pfx.cgiturl"})) {
+ $git->{cgit_url} = $cgits = _array($cgits);
+ $self->{"$pfx.cgiturl"} = $cgits;
+ }
+
+ $git;
+}
+
+sub get_all {
+ my ($self, $key) = @_;
+ my $v = $self->{$key} // return;
+ _array($v);
+}
+
+sub git_bool {
+ my ($val) = $_[-1]; # $_[0] may be $self, or $val
+ if ($val =~ /\A(?:false|no|off|[\-\+]?(?:0x)?0+)\z/i) {
+ 0;
+ } elsif ($val =~ /\A(?:true|yes|on|[\-\+]?(?:0x)?[0-9]+)\z/i) {
+ 1;
+ } else {
+ undef;
+ }
+}
+
+# abs_path resolves symlinks, so we want to avoid it if rel2abs
+# is sufficient and doesn't leave "/.." or "/../"
+sub rel2abs_collapsed {
+ require File::Spec;
+ my $p = File::Spec->rel2abs($_[-1]);
+ return $p if substr($p, -3, 3) ne '/..' && index($p, '/../') < 0;
+ require Cwd;
+ Cwd::abs_path($p);
+}
+
+sub get_1 {
+ my ($self, $key) = @_;
+ my $v = $self->{$key};
+ return $v if !ref($v);
+ warn "W: $key has multiple values, only using `$v->[-1]'\n";
+ $v->[-1];
+}
+
+sub repo_objs {
+ my ($self, $ibxish) = @_;
+ my $ibx_code_repos = $ibxish->{coderepo} or return;
+ $ibxish->{-repo_objs} //= do {
+ my $code_repos = $self->{-code_repos};
+ my @repo_objs;
+ for my $nick (@$ibx_code_repos) {
+ my @parts = split(m!/!, $nick);
+ for (@parts) {
+ @parts = () unless valid_foo_name($_);
+ }
+ unless (@parts) {
+ warn "invalid coderepo name: `$nick'\n";
+ next;
+ }
+ my $repo = $code_repos->{$nick} //=
+ _fill_code_repo($self, $nick);
+ push @repo_objs, $repo if $repo;
+ }
+ if (scalar @repo_objs) {
+ \@repo_objs;
+ } else {
+ delete $ibxish->{coderepo};
+ undef;
+ }
+ }
+}
+
+sub _fill_ibx {
+ my ($self, $name) = @_;
+ my $pfx = "publicinbox.$name";
+ my $ibx = {};
+ for my $k (qw(watch)) {
+ my $v = $self->{"$pfx.$k"};
+ $ibx->{$k} = $v if defined $v;
+ }
+ for my $k (qw(filter inboxdir newsgroup replyto httpbackendmax feedmax
+ indexlevel indexsequentialshard boost)) {
+ my $v = get_1($self, "$pfx.$k") // next;
+ $ibx->{$k} = $v;
+ }
+
+ # "mainrepo" is backwards compatibility:
+ my $dir = $ibx->{inboxdir} //= $self->{"$pfx.mainrepo"} // return;
+ if (index($dir, "\n") >= 0) {
+ warn "E: `$dir' must not contain `\\n'\n";
+ return;
+ }
+ for my $k (qw(obfuscate)) {
+ my $v = $self->{"$pfx.$k"} // next;
+ if (defined(my $bval = git_bool($v))) {
+ $ibx->{$k} = $bval;
+ } else {
+ warn "Ignoring $pfx.$k=$v in config, not boolean\n";
+ }
+ }
+ # TODO: more arrays, we should support multi-value for
+ # more things to encourage decentralization
+ for my $k (qw(address altid nntpmirror imapmirror
+ coderepo hide listid url
+ infourl watchheader nntpserver imapserver)) {
+ my $v = $self->{"$pfx.$k"} // next;
+ $ibx->{$k} = _array($v);
+ }
+
+ return unless valid_foo_name($name, 'publicinbox');
+ $ibx->{name} = $name;
+ $ibx->{-pi_cfg} = $self;
+ $ibx = PublicInbox::Inbox->new($ibx);
+ foreach (@{$ibx->{address}}) {