+use PublicInbox::Hval qw(ascii_html prurl mid_href);
+use PublicInbox::WwwStream qw(html_oneshot);
+use PublicInbox::Smsg;
+our $MIN_PARTIAL_LEN = 14; # for 'XXXXXXXXXX.fsf' msgids gnus generates
+
+# TODO: user-configurable
+our @EXT_URL = map { ascii_html($_) } (
+ # leading "//" denotes protocol-relative (http:// or https://)
+ '//marc.info/?i=%s',
+ '//www.mail-archive.com/search?l=mid&q=%s',
+ 'nntp://news.gmane.io/%s',
+ 'https://lists.debian.org/msgid-search/%s',
+ '//docs.FreeBSD.org/cgi/mid.cgi?db=mid&id=%s',
+ 'https://www.w3.org/mid/%s',
+ 'http://www.postgresql.org/message-id/%s',
+ 'https://lists.debconf.org/cgi-lurker/keyword.cgi?'.
+ 'doc-url=/lurker&format=en.html&query=id:%s'
+);
+
+sub PARTIAL_MAX () { 100 }
+
+sub search_partial ($$) {
+ my ($ibx, $mid) = @_;
+ return if length($mid) < $MIN_PARTIAL_LEN;
+ my $srch = $ibx->isrch or return;
+ my $opt = { limit => PARTIAL_MAX, relevance => -1 };
+ my @try = ("m:$mid*");
+ my $chop = $mid;
+ if ($chop =~ s/(\W+)(\w*)\z//) {
+ my ($delim, $word) = ($1, $2);
+ if (length($word)) {
+ push @try, "m:$chop$delim";
+ push @try, "m:$chop$delim*";
+ }
+ push @try, "m:$chop";
+ push @try, "m:$chop*";
+ }
+
+ # break out long words individually to search for, because
+ # too many messages begin with "Pine.LNX." (or "alpine" or "nycvar")
+ if ($mid =~ /\w{9,}/) {
+ my @long = ($mid =~ m!(\w{3,})!g);
+ push(@try, join(' ', map { "m:$_" } @long));
+
+ # is the last element long enough to not trigger excessive
+ # wildcard matches?
+ if (length($long[-1]) > 8) {
+ $long[-1] .= '*';
+ push(@try, join(' ', map { "m:$_" } @long));
+ }
+ }
+
+ foreach my $m (@try) {
+ # If Xapian can't handle the wildcard since it
+ # has too many results. $@ can be
+ # Search::Xapian::QueryParserError or even:
+ # "something terrible happened at ../Search/Xapian/Enquire.pm"
+ my $mset = eval { $srch->mset($m, $opt) } or next;
+ my @mids = map {
+ $_->{mid}
+ } @{$srch->mset_to_smsg($ibx, $mset)};
+ return \@mids if scalar(@mids);
+ }
+}
+
+sub ext_msg_i {
+ my ($other, $ctx) = @_;
+
+ return if $other->{name} eq $ctx->{ibx}->{name} || !$other->base_url;
+
+ my $mm = $other->mm or return;
+
+ # try to find the URL with Msgmap to avoid forking
+ my $num = $mm->num_for($ctx->{mid});
+ if (defined $num) {
+ push @{$ctx->{found}}, $other;
+ } else {
+ # no point in trying the fork fallback if we
+ # know Xapian is up-to-date but missing the
+ # message in the current repo
+ push @{$ctx->{again}}, $other;
+ }
+}
+
+sub ext_msg_step {
+ my ($pi_cfg, $section, $ctx) = @_;
+ if (defined($section)) {
+ return if $section !~ m!\Apublicinbox\.([^/]+)\z!;
+ my $ibx = $pi_cfg->lookup_name($1) or return;
+ ext_msg_i($ibx, $ctx);
+ } else { # undef == "EOF"
+ finalize_exact($ctx);
+ }
+}
+
+sub ext_msg_ALL ($) {
+ my ($ctx) = @_;
+ my $ALL = $ctx->{www}->{pi_cfg}->ALL or return;
+ my $by_eidx_key = $ctx->{www}->{pi_cfg}->{-by_eidx_key};
+ my $cur_key = eval { $ctx->{ibx}->eidx_key } //
+ return partial_response($ctx); # $cur->{ibx} == $ALL
+ my %seen = ($cur_key => 1);
+ my ($id, $prev);
+ while (my $x = $ALL->over->next_by_mid($ctx->{mid}, \$id, \$prev)) {
+ my $xr3 = $ALL->over->get_xref3($x->{num});
+ for my $k (@$xr3) {
+ $k =~ s/:[0-9]+:$x->{blob}\z// or next;
+ next if $k eq $cur_key;
+ my $ibx = $by_eidx_key->{$k} // next;
+ $ibx->base_url or next;
+ push(@{$ctx->{found}}, $ibx) unless $seen{$k}++;
+ }
+ }
+ return exact($ctx) if $ctx->{found};
+
+ # fall back to partial MID matching
+ for my $ibxish ($ctx->{ibx}, $ALL) {
+ my $mids = search_partial($ibxish, $ctx->{mid}) or next;
+ push @{$ctx->{partial}}, [ $ibxish, $mids ];
+ last if ($ctx->{n_partial} += scalar(@$mids)) >= PARTIAL_MAX;
+ }
+ partial_response($ctx);
+}